source: branches/1.3/gui/scripts/vtkheightmapviewer.tcl @ 4750

Last change on this file since 4750 was 4750, checked in by ldelgass, 6 years ago

merge r4749 from trunk

File size: 87.6 KB
Line 
1# -*- mode: tcl; indent-tabs-mode: nil -*-
2# ----------------------------------------------------------------------
3#  COMPONENT: vtkheightmapviewer - Vtk heightmap viewer
4#
5#  It connects to the Vtk server running on a rendering farm,
6#  transmits data, and displays the results.
7# ======================================================================
8#  AUTHOR:  Michael McLennan, Purdue University
9#  Copyright (c) 2004-2014  HUBzero Foundation, LLC
10#
11#  See the file "license.terms" for information on usage and
12#  redistribution of this file, and for a DISCLAIMER OF ALL WARRANTIES.
13# ======================================================================
14package require Itk
15package require BLT
16#package require Img
17
18option add *VtkHeightmapViewer.width 4i widgetDefault
19option add *VtkHeightmapViewer*cursor crosshair widgetDefault
20option add *VtkHeightmapViewer.height 4i widgetDefault
21option add *VtkHeightmapViewer.foreground black widgetDefault
22option add *VtkHeightmapViewer.controlBackground gray widgetDefault
23option add *VtkHeightmapViewer.controlDarkBackground #999999 widgetDefault
24option add *VtkHeightmapViewer.plotBackground black widgetDefault
25option add *VtkHeightmapViewer.plotForeground white widgetDefault
26option add *VtkHeightmapViewer.font \
27    -*-helvetica-medium-r-normal-*-12-* widgetDefault
28
29# must use this name -- plugs into Rappture::resources::load
30proc VtkHeightmapViewer_init_resources {} {
31    Rappture::resources::register \
32        vtkvis_server Rappture::VtkHeightmapViewer::SetServerList
33}
34
35itcl::class Rappture::VtkHeightmapViewer {
36    inherit Rappture::VisViewer
37
38    itk_option define -plotforeground plotForeground Foreground ""
39    itk_option define -plotbackground plotBackground Background ""
40    itk_option define -mode mode Mode "contour"
41
42    constructor { hostlist args } {
43        Rappture::VisViewer::constructor $hostlist
44    } {
45        # defined below
46    }
47    destructor {
48        # defined below
49    }
50    public proc SetServerList { namelist } {
51        Rappture::VisViewer::SetServerList "vtkvis" $namelist
52    }
53    public method add {dataobj {settings ""}}
54    public method camera {option args}
55    public method delete {args}
56    public method disconnect {}
57    public method download {option args}
58    public method get {args}
59    public method isconnected {}
60    public method parameters {title args} {
61        # do nothing
62    }
63    public method scale {args}
64
65    protected method CameraReset {}
66    protected method Connect {}
67    protected method CurrentDatasets {args}
68    protected method Disconnect {}
69    protected method DoResize {}
70    protected method DoRotate {}
71    protected method AdjustSetting {what {value ""}}
72    protected method AdjustMode {}
73    protected method InitSettings { args  }
74    protected method Pan {option x y}
75    protected method Pick {x y}
76    protected method Rebuild {}
77    protected method ReceiveDataset { args }
78    protected method ReceiveImage { args }
79    protected method ReceiveLegend { colormap title min max size }
80    protected method Rotate {option x y}
81    protected method Zoom {option}
82
83    # The following methods are only used by this class.
84    private method BuildAxisTab {}
85    private method BuildCameraTab {}
86    private method BuildColormap { name }
87    private method BuildContourTab {}
88    private method BuildDownloadPopup { widget command }
89    private method Combo { option }
90    private method DrawLegend {}
91    private method EnterLegend { x y }
92    private method EventuallyRequestLegend {}
93    private method EventuallyResize { w h }
94    private method EventuallyRotate { q }
95    private method GetImage { args }
96    private method GetVtkData { args }
97    private method IsValidObject { dataobj }
98    private method LeaveLegend {}
99    private method MotionLegend { x y }
100    private method PanCamera {}
101    private method RequestLegend {}
102    private method SetCurrentColormap { color }
103    private method SetLegendTip { x y }
104    private method SetObjectStyle { dataobj comp }
105    private method GetHeightmapScale {}
106    private method ResetAxes {}
107    private method SetOrientation { side }
108    private method UpdateContourList {}
109
110    private variable _arcball ""
111    private variable _dlist ""     ;    # list of data objects
112    private variable _obj2datasets
113    private variable _obj2ovride   ;    # maps dataobj => style override
114    private variable _comp2scale;       # maps dataset to the heightmap scale.
115    private variable _datasets     ;    # contains all the dataobj-component
116                                   ;    # datasets in the server
117    private variable _colormaps    ;    # contains all the colormaps
118                                   ;    # in the server.
119
120    # The name of the current colormap used.  The colormap is global to all
121    # heightmaps displayed.
122    private variable _currentColormap ""
123    private variable _currentNumIsolines -1
124
125    private variable _maxScale 100;     # This is the # of times the x-axis
126                                        # and y-axis ranges can differ before
127                                        # automatically turning on
128                                        # -stretchtofit
129
130    private variable _click        ;    # info used for rotate operations
131    private variable _limits       ;    # Holds overall limits for all dataobjs
132                                        # using the viewer.
133    private variable _view         ;    # view params for 3D view
134    private variable _settings
135    private variable _changed
136    private variable _initialStyle "";  # First found style in dataobjects.
137    private variable _reset 1;          # Indicates if camera needs to be reset
138                                        # to starting position.
139    private variable _beforeConnect 1;  # Indicates if camera needs to be reset
140                                        # to starting position.
141
142    private variable _first ""     ;    # This is the topmost dataset.
143    private variable _start 0
144    private variable _isolines
145    private variable _contourList ""
146
147    common _downloadPopup;              # download options from popup
148    private common _hardcopy
149    private variable _width 0
150    private variable _height 0
151    private variable _legendWidth 0
152    private variable _legendHeight 0
153    private variable _resizePending 0
154    private variable _rotatePending 0
155    private variable _legendPending 0
156    private variable _fieldNames {}
157    private variable _fields
158    private variable _curFldName ""
159    private variable _curFldLabel ""
160    private variable _colorMode "scalar";#  Mode of colormap (vmag or scalar)
161}
162
163itk::usual VtkHeightmapViewer {
164    keep -background -foreground -cursor -font
165    keep -plotbackground -plotforeground -mode
166}
167
168# ----------------------------------------------------------------------
169# CONSTRUCTOR
170# ----------------------------------------------------------------------
171itcl::body Rappture::VtkHeightmapViewer::constructor {hostlist args} {
172    set _serverType "vtkvis"
173
174    EnableWaitDialog 900
175    # Rebuild event
176    $_dispatcher register !rebuild
177    $_dispatcher dispatch $this !rebuild "[itcl::code $this Rebuild]; list"
178
179    # Resize event
180    $_dispatcher register !resize
181    $_dispatcher dispatch $this !resize "[itcl::code $this DoResize]; list"
182
183    # Rotate event
184    $_dispatcher register !rotate
185    $_dispatcher dispatch $this !rotate "[itcl::code $this DoRotate]; list"
186
187    # Legend event
188    $_dispatcher register !legend
189    $_dispatcher dispatch $this !legend "[itcl::code $this RequestLegend]; list"
190
191    #
192    # Populate parser with commands handle incoming requests
193    #
194    $_parser alias image [itcl::code $this ReceiveImage]
195    $_parser alias dataset [itcl::code $this ReceiveDataset]
196    $_parser alias legend [itcl::code $this ReceiveLegend]
197
198    # Create image for legend colorbar.
199    set _image(legend) [image create photo]
200
201    # Initialize the view to some default parameters.
202    array set _view {
203        qw      0.36
204        qx      0.25
205        qy      0.50
206        qz      0.70
207        zoom    1.0
208        xpan    0
209        ypan    0
210        ortho   0
211    }
212    set _arcball [blt::arcball create 100 100]
213    set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
214    $_arcball quaternion $q
215
216    array set _settings {
217        -axisflymode            "static"
218        -axislabels             1
219        -axisminorticks         1
220        -axisvisible            1
221        -colormap               BCGYR
222        -colormapdiscrete       0
223        -colormapvisible        1
224        -edges                  0
225        -field                  "Default"
226        -heightmapscale         50
227        -isheightmap            0
228        -isolinecolor           black
229        -isolinesvisible        1
230        -legendvisible          1
231        -lighting               1
232        -numisolines            10
233        -opacity                100
234        -outline                0
235        -savelighting           1
236        -saveopacity            100
237        -saveoutline            0
238        -stretchtofit           0
239        -wireframe              0
240        -xgrid                  0
241        -ygrid                  0
242        -zgrid                  0
243    }
244    array set _changed {
245        -colormap               0
246        -numisolines            0
247        -opacity                0
248    }
249    itk_component add view {
250        canvas $itk_component(plotarea).view \
251            -highlightthickness 0 -borderwidth 0
252    } {
253        usual
254        ignore -highlightthickness -borderwidth -background
255    }
256
257    itk_component add fieldmenu {
258        menu $itk_component(plotarea).menu \
259            -relief flat \
260            -tearoff no
261    } {
262        usual
263        ignore -background -foreground -relief -tearoff
264    }
265    set c $itk_component(view)
266    bind $c <Configure> [itcl::code $this EventuallyResize %w %h]
267    bind $c <4> [itcl::code $this Zoom in 0.25]
268    bind $c <5> [itcl::code $this Zoom out 0.25]
269    bind $c <KeyPress-Left>  [list %W xview scroll 10 units]
270    bind $c <KeyPress-Right> [list %W xview scroll -10 units]
271    bind $c <KeyPress-Up>    [list %W yview scroll 10 units]
272    bind $c <KeyPress-Down>  [list %W yview scroll -10 units]
273    bind $c <Enter> "focus %W"
274    bind $c <Control-F1> [itcl::code $this ToggleConsole]
275
276    # Fix the scrollregion in case we go off screen
277    $c configure -scrollregion [$c bbox all]
278
279    set _map(id) [$c create image 0 0 -anchor nw -image $_image(plot)]
280    set _map(cwidth) -1
281    set _map(cheight) -1
282    set _map(zoom) 1.0
283    set _map(original) ""
284
285    set f [$itk_component(main) component controls]
286    itk_component add reset {
287        button $f.reset -borderwidth 1 -padx 1 -pady 1 \
288            -highlightthickness 0 \
289            -image [Rappture::icon reset-view] \
290            -command [itcl::code $this CameraReset]
291    } {
292        usual
293        ignore -highlightthickness
294    }
295    pack $itk_component(reset) -side top -padx 2 -pady { 2 0 }
296    Rappture::Tooltip::for $itk_component(reset) "Reset the view to the default zoom level"
297
298    itk_component add zoomin {
299        button $f.zin -borderwidth 1 -padx 1 -pady 1 \
300            -highlightthickness 0 \
301            -image [Rappture::icon zoom-in] \
302            -command [itcl::code $this Zoom in]
303    } {
304        usual
305        ignore -highlightthickness
306    }
307    pack $itk_component(zoomin) -side top -padx 2 -pady { 2 0 }
308    Rappture::Tooltip::for $itk_component(zoomin) "Zoom in"
309
310    itk_component add zoomout {
311        button $f.zout -borderwidth 1 -padx 1 -pady 1 \
312            -highlightthickness 0 \
313            -image [Rappture::icon zoom-out] \
314            -command [itcl::code $this Zoom out]
315    } {
316        usual
317        ignore -highlightthickness
318    }
319    pack $itk_component(zoomout) -side top -padx 2 -pady { 2 0 }
320    Rappture::Tooltip::for $itk_component(zoomout) "Zoom out"
321
322    itk_component add mode {
323        Rappture::PushButton $f.mode \
324            -onimage [Rappture::icon surface] \
325            -offimage [Rappture::icon surface] \
326            -variable [itcl::scope _settings(-isheightmap)] \
327            -command [itcl::code $this AdjustSetting -isheightmap] \
328    }
329    Rappture::Tooltip::for $itk_component(mode) \
330        "Toggle the surface/contour on/off"
331    pack $itk_component(mode) -padx 2 -pady { 2 0 }
332
333    itk_component add stretchtofit {
334        Rappture::PushButton $f.stretchtofit \
335            -onimage [Rappture::icon stretchtofit] \
336            -offimage [Rappture::icon stretchtofit] \
337            -variable [itcl::scope _settings(-stretchtofit)] \
338            -command [itcl::code $this AdjustSetting -stretchtofit] \
339    }
340    Rappture::Tooltip::for $itk_component(stretchtofit) \
341        "Stretch plot to fit window on/off"
342    pack $itk_component(stretchtofit) -padx 2 -pady 2
343
344    if { [catch {
345        BuildContourTab
346        BuildAxisTab
347        BuildCameraTab
348    } errs] != 0 } {
349        global errorInfo
350        puts stderr "errs=$errs errorInfo=$errorInfo"
351    }
352
353    # Hack around the Tk panewindow.  The problem is that the requested
354    # size of the 3d view isn't set until an image is retrieved from
355    # the server.  So the panewindow uses the tiny size.
356    set w 10000
357    pack forget $itk_component(view)
358    blt::table $itk_component(plotarea) \
359        0,0 $itk_component(view) -fill both -reqwidth $w
360    blt::table configure $itk_component(plotarea) c1 -resize none
361
362    # Bindings for panning via mouse
363    bind $itk_component(view) <ButtonPress-2> \
364        [itcl::code $this Pan click %x %y]
365    bind $itk_component(view) <B2-Motion> \
366        [itcl::code $this Pan drag %x %y]
367    bind $itk_component(view) <ButtonRelease-2> \
368        [itcl::code $this Pan release %x %y]
369
370    #bind $itk_component(view) <ButtonRelease-3> \
371    #    [itcl::code $this Pick %x %y]
372
373    # Bindings for panning via keyboard
374    bind $itk_component(view) <KeyPress-Left> \
375        [itcl::code $this Pan set -10 0]
376    bind $itk_component(view) <KeyPress-Right> \
377        [itcl::code $this Pan set 10 0]
378    bind $itk_component(view) <KeyPress-Up> \
379        [itcl::code $this Pan set 0 -10]
380    bind $itk_component(view) <KeyPress-Down> \
381        [itcl::code $this Pan set 0 10]
382    bind $itk_component(view) <Shift-KeyPress-Left> \
383        [itcl::code $this Pan set -2 0]
384    bind $itk_component(view) <Shift-KeyPress-Right> \
385        [itcl::code $this Pan set 2 0]
386    bind $itk_component(view) <Shift-KeyPress-Up> \
387        [itcl::code $this Pan set 0 -2]
388    bind $itk_component(view) <Shift-KeyPress-Down> \
389        [itcl::code $this Pan set 0 2]
390
391    # Bindings for zoom via keyboard
392    bind $itk_component(view) <KeyPress-Prior> \
393        [itcl::code $this Zoom out]
394    bind $itk_component(view) <KeyPress-Next> \
395        [itcl::code $this Zoom in]
396
397    bind $itk_component(view) <Enter> "focus $itk_component(view)"
398
399    if {[string equal "x11" [tk windowingsystem]]} {
400        # Bindings for zoom via mouse
401        bind $itk_component(view) <4> [itcl::code $this Zoom out]
402        bind $itk_component(view) <5> [itcl::code $this Zoom in]
403    }
404
405    set _image(download) [image create photo]
406    eval itk_initialize $args
407    Connect
408    set _beforeConnect 0
409}
410
411# ----------------------------------------------------------------------
412# DESTRUCTOR
413# ----------------------------------------------------------------------
414itcl::body Rappture::VtkHeightmapViewer::destructor {} {
415    Disconnect
416    image delete $_image(plot)
417    image delete $_image(download)
418    catch { blt::arcball destroy $_arcball }
419}
420
421itcl::body Rappture::VtkHeightmapViewer::DoResize {} {
422    if { $_width < 2 } {
423        set _width 500
424    }
425    if { $_height < 2 } {
426        set _height 500
427    }
428    set _start [clock clicks -milliseconds]
429    SendCmd "screen size [expr $_width - 20] $_height"
430
431    set font "Arial 8"
432    set lh [font metrics $font -linespace]
433    set h [expr {$_height - 2 * ($lh + 2)}]
434    if { $h != $_legendHeight } {
435        EventuallyRequestLegend
436    } else {
437        DrawLegend
438    }
439    set _resizePending 0
440}
441
442itcl::body Rappture::VtkHeightmapViewer::DoRotate {} {
443    set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
444    SendCmd "camera orient $q"
445    set _rotatePending 0
446}
447
448itcl::body Rappture::VtkHeightmapViewer::EventuallyRequestLegend {} {
449    if { !$_legendPending } {
450        set _legendPending 1
451        $_dispatcher event -idle !legend
452    }
453}
454
455itcl::body Rappture::VtkHeightmapViewer::EventuallyResize { w h } {
456    set _width $w
457    set _height $h
458    $_arcball resize $w $h
459    if { !$_resizePending } {
460        set _resizePending 1
461        $_dispatcher event -after 250 !resize
462    }
463}
464
465set rotate_delay 100
466
467itcl::body Rappture::VtkHeightmapViewer::EventuallyRotate { q } {
468    foreach { _view(qw) _view(qx) _view(qy) _view(qz) } $q break
469    if { !$_rotatePending } {
470        set _rotatePending 1
471        global rotate_delay
472        $_dispatcher event -after $rotate_delay !rotate
473    }
474}
475
476# ----------------------------------------------------------------------
477# USAGE: add <dataobj> ?<settings>?
478#
479# Clients use this to add a data object to the plot.  The optional
480# <settings> are used to configure the plot.  Allowed settings are
481# -color, -brightness, -width, -linestyle, and -raise.
482# ----------------------------------------------------------------------
483itcl::body Rappture::VtkHeightmapViewer::add {dataobj {settings ""}} {
484    if { ![$dataobj isvalid] } {
485        return;                         # Object doesn't contain valid data.
486    }
487    array set params {
488        -color auto
489        -width 1
490        -linestyle solid
491        -brightness 0
492        -raise 0
493        -description ""
494        -param ""
495        -type ""
496    }
497    array set params $settings
498    set params(-description) ""
499    set params(-param) ""
500    array set params $settings
501
502    if {$params(-color) == "auto" || $params(-color) == "autoreset"} {
503        # can't handle -autocolors yet
504        set params(-color) white
505    }
506    set pos [lsearch -exact $_dlist $dataobj]
507    if {$pos < 0} {
508        lappend _dlist $dataobj
509    }
510    set _obj2ovride($dataobj-color) $params(-color)
511    set _obj2ovride($dataobj-width) $params(-width)
512    set _obj2ovride($dataobj-raise) $params(-raise)
513    $_dispatcher event -idle !rebuild
514}
515
516
517# ----------------------------------------------------------------------
518# USAGE: delete ?<dataobj1> <dataobj2> ...?
519#
520#       Clients use this to delete a dataobj from the plot.  If no dataobjs
521#       are specified, then all dataobjs are deleted.  No data objects are
522#       deleted.  They are only removed from the display list.
523#
524# ----------------------------------------------------------------------
525itcl::body Rappture::VtkHeightmapViewer::delete {args} {
526    if { [llength $args] == 0} {
527        set args $_dlist
528    }
529    # Delete all specified dataobjs
530    set changed 0
531    foreach dataobj $args {
532        set pos [lsearch -exact $_dlist $dataobj]
533        if { $pos < 0 } {
534            continue;                   # Don't know anything about it.
535        }
536        # Remove it from the dataobj list.
537        set _dlist [lreplace $_dlist $pos $pos]
538        array unset _obj2ovride $dataobj-*
539        array unset _settings $dataobj-*
540        set changed 1
541    }
542    # If anything changed, then rebuild the plot
543    if { $changed } {
544        $_dispatcher event -idle !rebuild
545    }
546}
547
548# ----------------------------------------------------------------------
549# USAGE: get ?-objects?
550# USAGE: get ?-visible?
551# USAGE: get ?-image view?
552#
553# Clients use this to query the list of objects being plotted, in
554# order from bottom to top of this result.  The optional "-image"
555# flag can also request the internal images being shown.
556# ----------------------------------------------------------------------
557itcl::body Rappture::VtkHeightmapViewer::get {args} {
558    if {[llength $args] == 0} {
559        set args "-objects"
560    }
561    set op [lindex $args 0]
562    switch -- $op {
563        "-objects" {
564            # put the dataobj list in order according to -raise options
565            set dlist {}
566            foreach dataobj $_dlist {
567                if { ![IsValidObject $dataobj] } {
568                    continue
569                }
570                if {[info exists _obj2ovride($dataobj-raise)] &&
571                    $_obj2ovride($dataobj-raise)} {
572                    set dlist [linsert $dlist 0 $dataobj]
573                } else {
574                    lappend dlist $dataobj
575                }
576            }
577            return $dlist
578        }
579        "-visible" {
580            set dlist {}
581            foreach dataobj $_dlist {
582                if { ![IsValidObject $dataobj] } {
583                    continue
584                }
585                if { ![info exists _obj2ovride($dataobj-raise)] } {
586                    # No setting indicates that the object isn't visible.
587                    continue
588                }
589                # Otherwise use the -raise parameter to put the object to
590                # the front of the list.
591                if { $_obj2ovride($dataobj-raise) } {
592                    set dlist [linsert $dlist 0 $dataobj]
593                } else {
594                    lappend dlist $dataobj
595                }
596            }
597            return $dlist
598        }           
599        -image {
600            if {[llength $args] != 2} {
601                error "wrong # args: should be \"get -image view\""
602            }
603            switch -- [lindex $args end] {
604                view {
605                    return $_image(plot)
606                }
607                default {
608                    error "bad image name \"[lindex $args end]\": should be view"
609                }
610            }
611        }
612        default {
613            error "bad option \"$op\": should be -objects or -image"
614        }
615    }
616}
617
618#
619# scale  --
620#
621#       This gets called either incrementally as new simulations are
622#       added or all at once as a sequence of heightmaps.
623#       This  accounts for all objects--even those not showing on the
624#       screen.  Because of this, the limits are appropriate for all
625#       objects as the user scans through data in the ResultSet viewer.
626#
627itcl::body Rappture::VtkHeightmapViewer::scale {args} {
628    foreach dataobj $args {
629        if { ![$dataobj isvalid] } {
630            continue;                   # Object doesn't contain valid data.
631        }
632        foreach axis { x y } {
633            set lim [$dataobj limits $axis]
634            if { ![info exists _limits($axis)] } {
635                set _limits($axis) $lim
636                continue
637            }
638            foreach {min max} $lim break
639            foreach {amin amax} $_limits($axis) break
640            if { $amin > $min } {
641                set amin $min
642            }
643            if { $amax < $max } {
644                set amax $max
645            }
646            set _limits($axis) [list $amin $amax]
647            set units [$dataobj hints ${axis}units]
648            set found($units) 1
649        }
650        foreach { fname lim } [$dataobj fieldlimits] {
651            if { ![info exists _limits($fname)] } {
652                set _limits($fname) $lim
653                continue
654            }
655            foreach {min max} $lim break
656            foreach {fmin fmax} $_limits($fname) break
657            if { $fmin > $min } {
658                set fmin $min
659            }
660            if { $fmax < $max } {
661                set fmax $max
662            }
663            set _limits($fname) [list $fmin $fmax]
664        }
665    }
666    if { [array size found] > 1 } {
667        set _settings(-stretchtofit) 1
668    } else {
669        # Check if the range of the x and y axes requires that we stretch
670        # the contour to fit the plotting area.  This can happen when the
671        # x and y scales differ greatly (> 100x)
672        foreach {xmin xmax} $_limits(x) break
673        foreach {ymin ymax} $_limits(y) break
674        if { (($xmax - $xmin) > (($ymax -$ymin) * $_maxScale)) ||
675             ((($xmax - $xmin) * $_maxScale) < ($ymax -$ymin)) } {
676            set _settings(-stretchtofit) 1
677        }
678    }
679}
680
681# ----------------------------------------------------------------------
682# USAGE: download coming
683# USAGE: download controls <downloadCommand>
684# USAGE: download now
685#
686# Clients use this method to create a downloadable representation
687# of the plot.  Returns a list of the form {ext string}, where
688# "ext" is the file extension (indicating the type of data) and
689# "string" is the data itself.
690# ----------------------------------------------------------------------
691itcl::body Rappture::VtkHeightmapViewer::download {option args} {
692    switch $option {
693        coming {
694            if {[catch {
695                blt::winop snap $itk_component(plotarea) $_image(download)
696            }]} {
697                $_image(download) configure -width 1 -height 1
698                $_image(download) put #000000
699            }
700        }
701        controls {
702            set popup .vtkviewerdownload
703            if { ![winfo exists .vtkviewerdownload] } {
704                set inner [BuildDownloadPopup $popup [lindex $args 0]]
705            } else {
706                set inner [$popup component inner]
707            }
708            set _downloadPopup(image_controls) $inner.image_frame
709            set num [llength [get]]
710            set num [expr {($num == 1) ? "1 result" : "$num results"}]
711            set word [Rappture::filexfer::label downloadWord]
712            $inner.summary configure -text "$word $num in the following format:"
713            update idletasks            ;# Fix initial sizes
714            return $popup
715        }
716        now {
717            set popup .vtkviewerdownload
718            if {[winfo exists .vtkviewerdownload]} {
719                $popup deactivate
720            }
721            switch -- $_downloadPopup(format) {
722                "image" {
723                    return [$this GetImage [lindex $args 0]]
724                }
725                "vtk" {
726                    return [$this GetVtkData [lindex $args 0]]
727                }
728            }
729            return ""
730        }
731        default {
732            error "bad option \"$option\": should be coming, controls, now"
733        }
734    }
735}
736
737# ----------------------------------------------------------------------
738# USAGE: Connect ?<host:port>,<host:port>...?
739#
740# Clients use this method to establish a connection to a new
741# server, or to reestablish a connection to the previous server.
742# Any existing connection is automatically closed.
743# ----------------------------------------------------------------------
744itcl::body Rappture::VtkHeightmapViewer::Connect {} {
745    global readyForNextFrame
746    set readyForNextFrame 1
747    set _reset 1
748    set _hosts [GetServerList "vtkvis"]
749    if { "" == $_hosts } {
750        return 0
751    }
752    set result [VisViewer::Connect $_hosts]
753    if { $result } {
754        if { $_reportClientInfo }  {
755            # Tell the server the viewer, hub, user and session.
756            # Do this immediately on connect before buffering any commands
757            global env
758
759            set info {}
760            set user "???"
761            if { [info exists env(USER)] } {
762                set user $env(USER)
763            }
764            set session "???"
765            if { [info exists env(SESSION)] } {
766                set session $env(SESSION)
767            }
768            lappend info "version" "$Rappture::version"
769            lappend info "build" "$Rappture::build"
770            lappend info "svnurl" "$Rappture::svnurl"
771            lappend info "installdir" "$Rappture::installdir"
772            lappend info "hub" [exec hostname]
773            lappend info "client" "vtkheightmapviewer"
774            lappend info "user" $user
775            lappend info "session" $session
776            SendCmd "clientinfo [list $info]"
777        }
778        set w [winfo width $itk_component(view)]
779        set h [winfo height $itk_component(view)]
780        EventuallyResize $w $h
781    }
782    return $result
783}
784
785#
786# isconnected --
787#
788#       Indicates if we are currently connected to the visualization server.
789#
790itcl::body Rappture::VtkHeightmapViewer::isconnected {} {
791    return [VisViewer::IsConnected]
792}
793
794#
795# disconnect --
796#
797itcl::body Rappture::VtkHeightmapViewer::disconnect {} {
798    Disconnect
799    set _reset 1
800}
801
802#
803# Disconnect --
804#
805#       Clients use this method to disconnect from the current rendering
806#       server.
807#
808itcl::body Rappture::VtkHeightmapViewer::Disconnect {} {
809    VisViewer::Disconnect
810
811    $_dispatcher cancel !rebuild
812    $_dispatcher cancel !resize
813    $_dispatcher cancel !rotate
814    $_dispatcher cancel !legend
815    # disconnected -- no more data sitting on server
816    array unset _datasets
817    array unset _data
818    array unset _colormaps
819    array unset _obj2datasets
820    global readyForNextFrame
821    set readyForNextFrame 1
822}
823
824# ----------------------------------------------------------------------
825# USAGE: ReceiveImage -bytes <size> -type <type> -token <token>
826#
827# Invoked automatically whenever the "image" command comes in from
828# the rendering server.  Indicates that binary image data with the
829# specified <size> will follow.
830# ----------------------------------------------------------------------
831itcl::body Rappture::VtkHeightmapViewer::ReceiveImage { args } {
832    global readyForNextFrame
833    set readyForNextFrame 1
834    array set info {
835        -token "???"
836        -bytes 0
837        -type image
838    }
839    array set info $args
840    set bytes [ReceiveBytes $info(-bytes)]
841    if { $info(-type) == "image" } {
842        if 0 {
843            set f [open "last.ppm" "w"]
844            puts $f $bytes
845            close $f
846        }
847        $_image(plot) configure -data $bytes
848        set time [clock seconds]
849        set date [clock format $time]
850        #puts stderr "$date: received image [image width $_image(plot)]x[image height $_image(plot)] image>"       
851        if { $_start > 0 } {
852            set finish [clock clicks -milliseconds]
853            #puts stderr "round trip time [expr $finish -$_start] milliseconds"
854            set _start 0
855        }
856    } elseif { $info(type) == "print" } {
857        set tag $this-print-$info(-token)
858        set _hardcopy($tag) $bytes
859    }
860}
861
862#
863# ReceiveDataset --
864#
865itcl::body Rappture::VtkHeightmapViewer::ReceiveDataset { args } {
866    if { ![isconnected] } {
867        return
868    }
869    set option [lindex $args 0]
870    switch -- $option {
871        "scalar" {
872            set option [lindex $args 1]
873            switch -- $option {
874                "world" {
875                    foreach { x y z value tag } [lrange $args 2 end] break
876                }
877                "pixel" {
878                    foreach { x y value tag } [lrange $args 2 end] break
879                }
880            }
881        }
882        "vector" {
883            set option [lindex $args 1]
884            switch -- $option {
885                "world" {
886                    foreach { x y z vx vy vz tag } [lrange $args 2 end] break
887                }
888                "pixel" {
889                    foreach { x y vx vy vz tag } [lrange $args 2 end] break
890                }
891            }
892        }
893        "names" {
894            foreach { name } [lindex $args 1] {
895                #puts stderr "Dataset: $name"
896            }
897        }
898        default {
899            error "unknown dataset option \"$option\" from server"
900        }
901    }
902}
903
904# ----------------------------------------------------------------------
905# USAGE: Rebuild
906#
907# Called automatically whenever something changes that affects the
908# data in the widget.  Clears any existing data and rebuilds the
909# widget to display new data.
910# ----------------------------------------------------------------------
911itcl::body Rappture::VtkHeightmapViewer::Rebuild {} {
912    set w [winfo width $itk_component(view)]
913    set h [winfo height $itk_component(view)]
914    if { $w < 2 || $h < 2 } {
915        $_dispatcher event -idle !rebuild
916        return
917    }
918
919    # Turn on buffering of commands to the server.  We don't want to
920    # be preempted by a server disconnect/reconnect (which automatically
921    # generates a new call to Rebuild).   
922    StartBufferingCommands
923
924    if { $_width != $w || $_height != $h || $_reset } {
925        set _width $w
926        set _height $h
927        $_arcball resize $w $h
928        DoResize
929        if { $_settings(-stretchtofit) } {
930            AdjustSetting -stretchtofit
931        }
932    }
933    if { $_reset } {
934        #
935        # Reset the camera and other view parameters
936        #
937        InitSettings -isheightmap -background
938
939        # Setting a custom exponent and label format for axes is causing
940        # a problem with rounding.  Near zero ticks aren't rounded by
941        # the %g format.  The VTK CubeAxes seem to currently work best
942        # when allowed to automatically set the exponent and precision
943        # based on the axis ranges.  This does tend to result in less
944        # visual clutter, so I think it is best to use the automatic
945        # settings by default.  We can test more fine-grained
946        # controls on the axis settings tab if necessary.
947        # -Leif
948        #SendCmd "axis exp 0 0 0 1"
949
950        SendCmd "axis lrot z 90"
951        set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
952        $_arcball quaternion $q
953        if {$_settings(-isheightmap) } {
954            if { $_view(ortho)} {
955                SendCmd "camera mode ortho"
956            } else {
957                SendCmd "camera mode persp"
958            }
959            DoRotate
960            SendCmd "camera reset"
961        }
962        PanCamera
963        StopBufferingCommands
964        SendCmd "imgflush"
965        StartBufferingCommands
966    }
967
968    set _first ""
969    # Start off with no datasets are visible.
970    SendCmd "dataset visible 0"
971    set scale [GetHeightmapScale]
972    foreach dataobj [get -objects] {
973        if { [info exists _obj2ovride($dataobj-raise)] &&  $_first == "" } {
974            set _first $dataobj
975        }
976        set _obj2datasets($dataobj) ""
977        foreach comp [$dataobj components] {
978            set tag $dataobj-$comp
979            if { ![info exists _datasets($tag)] } {
980                set bytes [$dataobj vtkdata $comp]
981                if 0 {
982                    set f [open /tmp/vtkheightmap.vtk "w"]
983                    puts $f $bytes
984                    close $f
985                }
986                set length [string length $bytes]
987                if { $_reportClientInfo }  {
988                    set info {}
989                    lappend info "tool_id"       [$dataobj hints toolid]
990                    lappend info "tool_name"     [$dataobj hints toolname]
991                    lappend info "tool_title"    [$dataobj hints tooltitle]
992                    lappend info "tool_command"  [$dataobj hints toolcommand]
993                    lappend info "tool_revision" [$dataobj hints toolrevision]
994                    lappend info "dataset_label" [$dataobj hints label]
995                    lappend info "dataset_size"  $length
996                    lappend info "dataset_tag"   $tag
997                    SendCmd [list "clientinfo" $info]
998                }
999                SendCmd "dataset add $tag data follows $length"
1000                append _outbuf $bytes
1001                set _datasets($tag) 1
1002                SetObjectStyle $dataobj $comp
1003            }
1004            lappend _obj2datasets($dataobj) $tag
1005            if { [info exists _obj2ovride($dataobj-raise)] } {
1006                # Setting dataset visible enables outline
1007                # and heightmap
1008                SendCmd "dataset visible 1 $tag"
1009            }
1010            if { ![info exists _comp2scale($tag)] ||
1011                 $_comp2scale($tag) != $scale } {
1012                SendCmd "heightmap heightscale $scale $tag"
1013                set _comp2scale($tag) $scale
1014            }
1015        }
1016    }
1017    if { $_first != ""  } {
1018        $itk_component(field) choices delete 0 end
1019        $itk_component(fieldmenu) delete 0 end
1020        array unset _fields
1021        set _curFldName ""
1022        foreach cname [$_first components] {
1023            foreach fname [$_first fieldnames $cname] {
1024                if { [info exists _fields($fname)] } {
1025                    continue
1026                }
1027                foreach { label units components } \
1028                    [$_first fieldinfo $fname] break
1029                $itk_component(field) choices insert end "$fname" "$label"
1030                $itk_component(fieldmenu) add radiobutton -label "$label" \
1031                    -value $label -variable [itcl::scope _curFldLabel] \
1032                    -selectcolor red \
1033                    -activebackground $itk_option(-plotbackground) \
1034                    -activeforeground $itk_option(-plotforeground) \
1035                    -font "Arial 8" \
1036                    -command [itcl::code $this Combo invoke]
1037                set _fields($fname) [list $label $units $components]
1038                if { $_curFldName == "" } {
1039                    set _curFldName $fname
1040                    set _curFldLabel $label
1041                }
1042            }
1043        }
1044        $itk_component(field) value $_curFldLabel
1045    }
1046    InitSettings -stretchtofit -outline
1047
1048    if { $_reset } {
1049        SendCmd "axis tickpos outside"
1050        #SendCmd "axis lformat all %g"
1051       
1052        foreach axis { x y z } {
1053            if { $axis == "z" } {
1054                set label [$_first hints label]
1055            } else {
1056                set label [$_first hints ${axis}label]
1057            }
1058            if { $label == "" } {
1059                if {$axis == "z"} {
1060                    if { [string match "component*" $_curFldName] } {
1061                        set label [string toupper $axis]
1062                    } else {
1063                        set label $_curFldLabel
1064                    }
1065                } else {
1066                    set label [string toupper $axis]
1067                }
1068            }
1069            # May be a space in the axis label.
1070            SendCmd [list axis name $axis $label]
1071
1072            if {$axis == "z" && [$_first hints ${axis}units] == ""} {
1073                set units [lindex $_fields($_curFldName) 1]
1074            } else {
1075                set units [$_first hints ${axis}units]
1076            }
1077            if { $units != "" } {
1078                # May be a space in the axis units.
1079                SendCmd [list axis units $axis $units]
1080            }
1081        }
1082        #
1083        # Reset the camera and other view parameters
1084        #
1085        ResetAxes
1086        set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
1087        $_arcball quaternion $q
1088        if {$_settings(-isheightmap) } {
1089            if { $_view(ortho)} {
1090                SendCmd "camera mode ortho"
1091            } else {
1092                SendCmd "camera mode persp"
1093            }
1094            DoRotate
1095            SendCmd "camera reset"
1096        }
1097        PanCamera
1098        InitSettings -xgrid -ygrid -zgrid \
1099            -axisvisible -axislabels -heightmapscale -field -isheightmap \
1100            -numisolines
1101        if { [array size _fields] < 2 } {
1102            catch {blt::table forget $itk_component(field) $itk_component(field_l)}
1103        }
1104        RequestLegend
1105        set _reset 0
1106    }
1107    global readyForNextFrame
1108    set readyForNextFrame 0;            # Don't advance to the next frame
1109
1110    # Actually write the commands to the server socket.  If it fails, we don't
1111    # care.  We're finished here.
1112    blt::busy hold $itk_component(hull)
1113    StopBufferingCommands
1114    blt::busy release $itk_component(hull)
1115}
1116
1117# ----------------------------------------------------------------------
1118# USAGE: CurrentDatasets ?-all -visible? ?dataobjs?
1119#
1120# Returns a list of server IDs for the current datasets being displayed.  This
1121# is normally a single ID, but it might be a list of IDs if the current data
1122# object has multiple components.
1123# ----------------------------------------------------------------------
1124itcl::body Rappture::VtkHeightmapViewer::CurrentDatasets {args} {
1125    set flag [lindex $args 0]
1126    switch -- $flag {
1127        "-all" {
1128            if { [llength $args] > 1 } {
1129                error "CurrentDatasets: can't specify dataobj after \"-all\""
1130            }
1131            set dlist [get -objects]
1132        }
1133        "-visible" {
1134            if { [llength $args] > 1 } {
1135                set dlist {}
1136                set args [lrange $args 1 end]
1137                foreach dataobj $args {
1138                    if { [info exists _obj2ovride($dataobj-raise)] } {
1139                        lappend dlist $dataobj
1140                    }
1141                }
1142            } else {
1143                set dlist [get -visible]
1144            }
1145        }           
1146        default {
1147            set dlist $args
1148        }
1149    }
1150    set rlist ""
1151    foreach dataobj $dlist {
1152        foreach comp [$dataobj components] {
1153            set tag $dataobj-$comp
1154            if { [info exists _datasets($tag)] && $_datasets($tag) } {
1155                lappend rlist $tag
1156            }
1157        }
1158    }
1159    return $rlist
1160}
1161
1162itcl::body Rappture::VtkHeightmapViewer::CameraReset {} {
1163    array set _view {
1164        qw      0.36
1165        qx      0.25
1166        qy      0.50
1167        qz      0.70
1168        zoom    1.0
1169        xpan    0
1170        ypan    0
1171    }
1172    if { $_first != "" } {
1173        set location [$_first hints camera]
1174        if { $location != "" } {
1175            array set _view $location
1176        }
1177    }
1178    set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
1179    $_arcball quaternion $q
1180    if {$_settings(-isheightmap) } {
1181        DoRotate
1182    }
1183    SendCmd "camera reset"
1184}
1185
1186# ----------------------------------------------------------------------
1187# USAGE: Zoom in
1188# USAGE: Zoom out
1189# USAGE: Zoom reset
1190#
1191# Called automatically when the user clicks on one of the zoom
1192# controls for this widget.  Changes the zoom for the current view.
1193# ----------------------------------------------------------------------
1194itcl::body Rappture::VtkHeightmapViewer::Zoom {option} {
1195    switch -- $option {
1196        "in" {
1197            set _view(zoom) [expr {$_view(zoom)*1.25}]
1198            SendCmd "camera zoom $_view(zoom)"
1199        }
1200        "out" {
1201            set _view(zoom) [expr {$_view(zoom)*0.8}]
1202            SendCmd "camera zoom $_view(zoom)"
1203        }
1204        "reset" {
1205            array set _view {
1206                zoom    1.0
1207                xpan    0
1208                ypan    0
1209            }
1210            SendCmd "camera reset"
1211        }
1212    }
1213}
1214
1215itcl::body Rappture::VtkHeightmapViewer::PanCamera {} {
1216    set x $_view(xpan)
1217    set y $_view(ypan)
1218    SendCmd "camera pan $x $y"
1219}
1220
1221
1222# ----------------------------------------------------------------------
1223# USAGE: Rotate click <x> <y>
1224# USAGE: Rotate drag <x> <y>
1225# USAGE: Rotate release <x> <y>
1226#
1227# Called automatically when the user clicks/drags/releases in the
1228# plot area.  Moves the plot according to the user's actions.
1229# ----------------------------------------------------------------------
1230itcl::body Rappture::VtkHeightmapViewer::Rotate {option x y} {
1231    switch -- $option {
1232        "click" {
1233            $itk_component(view) configure -cursor fleur
1234            set _click(x) $x
1235            set _click(y) $y
1236        }
1237        "drag" {
1238            if {[array size _click] == 0} {
1239                Rotate click $x $y
1240            } else {
1241                set w [winfo width $itk_component(view)]
1242                set h [winfo height $itk_component(view)]
1243                if {$w <= 0 || $h <= 0} {
1244                    return
1245                }
1246
1247                if {[catch {
1248                    # this fails sometimes for no apparent reason
1249                    set dx [expr {double($x-$_click(x))/$w}]
1250                    set dy [expr {double($y-$_click(y))/$h}]
1251                }]} {
1252                    return
1253                }
1254                if { $dx == 0 && $dy == 0 } {
1255                    return
1256                }
1257                set q [$_arcball rotate $x $y $_click(x) $_click(y)]
1258                EventuallyRotate $q
1259                set _click(x) $x
1260                set _click(y) $y
1261            }
1262        }
1263        "release" {
1264            Rotate drag $x $y
1265            $itk_component(view) configure -cursor ""
1266            catch {unset _click}
1267        }
1268        default {
1269            error "bad option \"$option\": should be click, drag, release"
1270        }
1271    }
1272}
1273
1274itcl::body Rappture::VtkHeightmapViewer::Pick {x y} {
1275    foreach tag [CurrentDatasets -visible] {
1276        SendCmd "dataset getscalar pixel $x $y $tag"
1277    }
1278}
1279
1280# ----------------------------------------------------------------------
1281# USAGE: $this Pan click x y
1282#        $this Pan drag x y
1283#        $this Pan release x y
1284#
1285# Called automatically when the user clicks on one of the zoom
1286# controls for this widget.  Changes the zoom for the current view.
1287# ----------------------------------------------------------------------
1288itcl::body Rappture::VtkHeightmapViewer::Pan {option x y} {
1289    switch -- $option {
1290        "set" {
1291            set w [winfo width $itk_component(view)]
1292            set h [winfo height $itk_component(view)]
1293            set x [expr $x / double($w)]
1294            set y [expr $y / double($h)]
1295            set _view(xpan) [expr $_view(xpan) + $x]
1296            set _view(ypan) [expr $_view(ypan) + $y]
1297            PanCamera
1298            return
1299        }
1300        "click" {
1301            set _click(x) $x
1302            set _click(y) $y
1303            $itk_component(view) configure -cursor hand1
1304        }
1305        "drag" {
1306            if { ![info exists _click(x)] } {
1307                set _click(x) $x
1308            }
1309            if { ![info exists _click(y)] } {
1310                set _click(y) $y
1311            }
1312            set w [winfo width $itk_component(view)]
1313            set h [winfo height $itk_component(view)]
1314            set dx [expr ($_click(x) - $x)/double($w)]
1315            set dy [expr ($_click(y) - $y)/double($h)]
1316            set _click(x) $x
1317            set _click(y) $y
1318            set _view(xpan) [expr $_view(xpan) - $dx]
1319            set _view(ypan) [expr $_view(ypan) - $dy]
1320            PanCamera
1321        }
1322        "release" {
1323            Pan drag $x $y
1324            $itk_component(view) configure -cursor ""
1325        }
1326        default {
1327            error "unknown option \"$option\": should set, click, drag, or release"
1328        }
1329    }
1330}
1331
1332# ----------------------------------------------------------------------
1333# USAGE: InitSettings <what> ?<value>?
1334#
1335# Used internally to update rendering settings whenever parameters
1336# change in the popup settings panel.  Sends the new settings off
1337# to the back end.
1338# ----------------------------------------------------------------------
1339itcl::body Rappture::VtkHeightmapViewer::InitSettings { args } {
1340    foreach spec $args {
1341        if { [info exists _settings($_first${spec})] } {
1342            # Reset global setting with dataobj specific setting
1343            set _settings($spec) $_settings($_first${spec})
1344        }
1345        AdjustSetting $spec
1346    }
1347}
1348
1349#
1350# AdjustSetting --
1351#
1352#       Changes/updates a specific setting in the widget.  There are
1353#       usually user-setable option.  Commands are sent to the render
1354#       server.
1355#
1356itcl::body Rappture::VtkHeightmapViewer::AdjustSetting {what {value ""}} {
1357    if { $_beforeConnect } {
1358        return
1359    }
1360    switch -- $what {
1361        "-axisflymode" {
1362            set mode [$itk_component(axisflymode) value]
1363            set mode [$itk_component(axisflymode) translate $mode]
1364            set _settings($what) $mode
1365            SendCmd "axis flymode $mode"
1366        }
1367        "-axislabels" {
1368            set bool $_settings($what)
1369            SendCmd "axis labels all $bool"
1370        }
1371        "-axisminorticks" {
1372            set bool $_settings($what)
1373            SendCmd "axis minticks all $bool"
1374        }
1375        "-axisvisible" {
1376            set bool $_settings($what)
1377            SendCmd "axis visible all $bool"
1378        }
1379        "-xgrid" - "-ygrid" - "-zgrid" {
1380            set axis [string tolower [string range $what 1 1]]
1381            set bool $_settings($what)
1382            SendCmd "axis grid $axis $bool"
1383        }
1384        "-background" {
1385            set bg [$itk_component(background) value]
1386            array set fgcolors {
1387                "black" "white"
1388                "white" "black"
1389                "grey"  "black"
1390            }
1391            set fg $fgcolors($bg)
1392            configure -plotbackground $bg -plotforeground $fg
1393            $itk_component(view) delete "legend"
1394            SendCmd "screen bgcolor [Color2RGB $bg]"
1395            SendCmd "outline color [Color2RGB $fg]"
1396            SendCmd "axis color all [Color2RGB $fg]"
1397            DrawLegend
1398        }
1399        "-colormap" {
1400            set _changed($what) 1
1401            StartBufferingCommands
1402            set color [$itk_component(colormap) value]
1403            set _settings($what) $color
1404            if { $color == "none" } {
1405                if { $_settings(-colormapvisible) } {
1406                    SendCmd "heightmap surface 0"
1407                    set _settings(-colormapvisible) 0
1408                }
1409            } else {
1410                if { !$_settings(-colormapvisible) } {
1411                    SendCmd "heightmap surface 1"
1412                    set _settings(-colormapvisible) 1
1413                }
1414                SetCurrentColormap $color
1415                if {$_settings(-colormapdiscrete)} {
1416                    set numColors [expr $_settings(-numisolines) + 1]
1417                    SendCmd "colormap res $numColors $color"
1418                }
1419            }
1420            StopBufferingCommands
1421            EventuallyRequestLegend
1422        }
1423        "-colormapvisible" {
1424            set bool $_settings($what)
1425            SendCmd "heightmap surface $bool"
1426        }
1427        "-colormapdiscrete" {
1428            set bool $_settings($what)
1429            set numColors [expr $_settings(-numisolines) + 1]
1430            StartBufferingCommands
1431            if {$bool} {
1432                SendCmd "colormap res $numColors"
1433                # Discrete colormap requires preinterp on
1434                SendCmd "heightmap preinterp on"
1435            } else {
1436                SendCmd "colormap res default"
1437                # FIXME: add setting for preinterp (default on)
1438                SendCmd "heightmap preinterp on"
1439            }
1440            StopBufferingCommands
1441            EventuallyRequestLegend
1442        }
1443        "-edges" {
1444            set bool $_settings($what)
1445            SendCmd "heightmap edges $bool"
1446        }
1447        "-field" {
1448            set label [$itk_component(field) value]
1449            set fname [$itk_component(field) translate $label]
1450            set _settings($what) $fname
1451            if { [info exists _fields($fname)] } {
1452                foreach { label units components } $_fields($fname) break
1453                if { $components > 1 } {
1454                    set _colorMode vmag
1455                } else {
1456                    set _colorMode scalar
1457                }
1458                set _curFldName $fname
1459                set _curFldLabel $label
1460            } else {
1461                puts stderr "unknown field \"$fname\""
1462                return
1463            }
1464            set label [$_first hints label]
1465            if { $label == "" } {
1466                if { [string match "component*" $_curFldName] } {
1467                    set label Z
1468                } else {
1469                    set label $_curFldLabel
1470                }
1471            }
1472            # May be a space in the axis label.
1473            SendCmd [list axis name z $label]
1474
1475            if { [$_first hints zunits] == "" } {
1476                set units [lindex $_fields($_curFldName) 1]
1477            } else {
1478                set units [$_first hints zunits]
1479            }
1480            if { $units != "" } {
1481                # May be a space in the axis units.
1482                SendCmd [list axis units z $units]
1483            }
1484            # Get the new limits because the field changed.
1485            ResetAxes
1486            SendCmd "dataset scalar $_curFldName"
1487            SendCmd "heightmap colormode scalar $_curFldName"
1488            Zoom reset
1489            UpdateContourList
1490            DrawLegend
1491        }
1492        "-heightmapscale" {
1493            if { $_settings(-isheightmap) } {
1494                set scale [GetHeightmapScale]
1495                # Have to set the datasets individually because we are
1496                # tracking them in _comp2scale.
1497                foreach dataset [CurrentDatasets -all] {
1498                    SendCmd "heightmap heightscale $scale $dataset"
1499                    set _comp2scale($dataset) $scale
1500                }
1501                ResetAxes
1502            }
1503        }
1504        "-isheightmap" {
1505            set bool $_settings($what)
1506            set c $itk_component(view)
1507            StartBufferingCommands
1508            # Fix heightmap scale: 0 for contours, 1 for heightmaps.
1509            if { $bool } {
1510                set _settings(-heightmapscale) 50
1511                set _settings(-opacity) $_settings(-saveopacity)
1512                set _settings(-lighting) $_settings(-savelighting)
1513                set _settings(-outline) 0
1514            } else {
1515                set _settings(-heightmapscale) 0
1516                set _settings(-lighting) 0
1517                set _settings(-opacity) 100
1518                set _settings(-outline)  $_settings(-saveoutline)
1519            }
1520            InitSettings -lighting -opacity -outline
1521            set scale [GetHeightmapScale]
1522            # Have to set the datasets individually because we are
1523            # tracking them in _comp2scale.
1524            foreach dataset [CurrentDatasets -all] {
1525                SendCmd "heightmap heightscale $scale $dataset"
1526                set _comp2scale($dataset) $scale
1527            }
1528            if { $bool } {
1529                $itk_component(lighting) configure -state normal
1530                $itk_component(opacity) configure -state normal
1531                $itk_component(scale) configure -state normal
1532                $itk_component(opacity_l) configure -state normal
1533                $itk_component(scale_l) configure -state normal
1534                $itk_component(outline) configure -state disabled
1535                if {$_view(ortho)} {
1536                    SendCmd "camera mode ortho"
1537                } else {
1538                    SendCmd "camera mode persp"
1539                }
1540            } else {
1541                $itk_component(lighting) configure -state disabled
1542                $itk_component(opacity) configure -state disabled
1543                $itk_component(scale) configure -state disabled
1544                $itk_component(opacity_l) configure -state disabled
1545                $itk_component(scale_l) configure -state disabled
1546                $itk_component(outline) configure -state normal
1547                SendCmd "camera mode image"
1548            }
1549            if {$_settings(-stretchtofit)} {
1550                if {$scale == 0} {
1551                    SendCmd "camera aspect window"
1552                } else {
1553                    SendCmd "camera aspect square"
1554                }
1555            }
1556            ResetAxes
1557            if { $bool } {
1558                set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
1559                $_arcball quaternion $q
1560                SendCmd "camera orient $q"
1561            } else {
1562                bind $c <ButtonPress-1> {}
1563                bind $c <B1-Motion> {}
1564                bind $c <ButtonRelease-1> {}
1565            }
1566            Zoom reset
1567            # Fix the mouse bindings for rotation/panning and the
1568            # camera mode. Ideally we'd create a bindtag for these.
1569            if { $bool } {
1570                # Bindings for rotation via mouse
1571                bind $c <ButtonPress-1> \
1572                    [itcl::code $this Rotate click %x %y]
1573                bind $c <B1-Motion> \
1574                    [itcl::code $this Rotate drag %x %y]
1575                bind $c <ButtonRelease-1> \
1576                    [itcl::code $this Rotate release %x %y]
1577            }
1578            StopBufferingCommands
1579        }
1580        "-isolinecolor" {
1581            set color [$itk_component(isolinecolor) value]
1582            if { $color == "none" } {
1583                if { $_settings(-isolinesvisible) } {
1584                    SendCmd "heightmap isolines 0"
1585                    set _settings(-isolinesvisible) 0
1586                }
1587            } else {
1588                if { !$_settings(-isolinesvisible) } {
1589                    SendCmd "heightmap isolines 1"
1590                    set _settings(-isolinesvisible) 1
1591                }
1592                SendCmd "heightmap isolinecolor [Color2RGB $color]"
1593            }
1594            DrawLegend
1595        }
1596        "-isolinesvisible" {
1597            set bool $_settings($what)
1598            SendCmd "heightmap isolines $bool"
1599            DrawLegend
1600        }
1601        "-legendvisible" {
1602            if { !$_settings($what) } {
1603                $itk_component(view) delete legend
1604            }
1605            DrawLegend
1606        }
1607        "-lighting" {
1608            if { $_settings(-isheightmap) } {
1609                set _settings(-savelighting) $_settings($what)
1610                set bool $_settings($what)
1611                SendCmd "heightmap lighting $bool"
1612            } else {
1613                SendCmd "heightmap lighting 0"
1614            }
1615        }
1616        "-numisolines" {
1617            set _settings($what) [$itk_component(numisolines) value]
1618            set _currentNumIsolines $_settings($what)
1619            UpdateContourList
1620            set _changed($what) 1
1621            SendCmd "heightmap contourlist [list $_contourList]"
1622            if {$_settings(-colormapdiscrete)} {
1623                set numColors [expr $_settings($what) + 1]
1624                SendCmd "colormap res $numColors"
1625                EventuallyRequestLegend
1626            } else {
1627                DrawLegend
1628            }
1629        }
1630        "-opacity" {
1631            set _changed($what) 1
1632            set val [expr $_settings($what) * 0.01]
1633            if { $_settings(-isheightmap) } {
1634                set _settings(-saveopacity) $_settings($what)
1635                SendCmd "heightmap opacity $val"
1636            } else {
1637                SendCmd "heightmap opacity 1.0"
1638            }
1639        }
1640        "-outline" {
1641            if { $_settings(-isheightmap) } {
1642                SendCmd "outline visible 0"
1643            } else {
1644                set _settings(-saveoutline) $_settings($what)
1645                set bool $_settings($what)
1646                SendCmd "outline visible $bool"
1647            }
1648        }
1649        "-stretchtofit" {
1650            set bool $_settings($what)
1651            if { $bool } {
1652                set heightScale [GetHeightmapScale]
1653                if {$heightScale == 0} {
1654                    SendCmd "camera aspect window"
1655                } else {
1656                    SendCmd "camera aspect square"
1657                }
1658            } else {
1659                SendCmd "camera aspect native"
1660            }
1661            Zoom reset
1662        }
1663        "-wireframe" {
1664            set bool $_settings($what)
1665            SendCmd "heightmap wireframe $bool"
1666        }
1667        default {
1668            error "don't know how to fix $what"
1669        }
1670    }
1671}
1672
1673#
1674# RequestLegend --
1675#
1676#       Request a new legend from the server.  The size of the legend
1677#       is determined from the height of the canvas. 
1678#
1679# This should be called when
1680#       1.  A new current colormap is set.
1681#       2.  Window is resized.
1682#       3.  The limits of the data have changed.  (Just need a redraw).
1683#       4.  Number of isolines have changed. (Just need a redraw).
1684#       5.  Legend becomes visible (Just need a redraw).
1685#
1686itcl::body Rappture::VtkHeightmapViewer::RequestLegend {} {
1687    set _legendPending 0
1688    set font "Arial 8"
1689    set w 12
1690    set lineht [font metrics $font -linespace]
1691    # color ramp height = (canvas height) - (min and max value lines) - 2
1692    set h [expr {$_height - 2 * ($lineht + 2)}]
1693    set _legendHeight $h
1694
1695    set fname $_curFldName
1696    if { [string match "component*" $fname] } {
1697        set title ""
1698    } else {
1699        if { [info exists _fields($fname)] } {
1700            foreach { title units } $_fields($fname) break
1701            if { $units != "" } {
1702                set title [format "%s (%s)" $title $units]
1703            }
1704        } else {
1705            set title $fname
1706        }
1707    }
1708    # If there's a title too, substract one more line
1709    if { $title != "" } {
1710        incr h -$lineht
1711    }
1712    if { $h < 1 } {
1713        return
1714    }
1715    # Set the legend on the first heightmap dataset.
1716    if { $_currentColormap != ""  } {
1717        set cmap $_currentColormap
1718        SendCmd "legend $cmap scalar $_curFldName {} $w $h 0"
1719    }
1720}
1721
1722#
1723# ResetAxes --
1724#
1725#       Set axis z bounds and range
1726#
1727itcl::body Rappture::VtkHeightmapViewer::ResetAxes {} {
1728    if { ![info exists _limits($_curFldName)]} {
1729        SendCmd "dataset maprange all"
1730        SendCmd "axis autorange z on"
1731        SendCmd "axis autobounds z on"
1732        return
1733    }
1734    foreach { xmin xmax } $_limits(x) break
1735    foreach { ymin ymax } $_limits(y) break
1736    foreach { vmin vmax } $_limits($_curFldName) break
1737
1738    global tcl_precision
1739    set tcl_precision 17
1740    set xr [expr $xmax - $xmin]
1741    set yr [expr $ymax - $ymin]
1742    set vr [expr $vmax - $vmin]
1743    set r  [expr ($yr > $xr) ? $yr : $xr]
1744    if { $vr < 1.0e-17 } {
1745        set dataScale 1.0
1746    } else {
1747        set dataScale [expr $r / $vr]
1748    }
1749    set heightScale [GetHeightmapScale]
1750    set bmin [expr $heightScale * $dataScale * $vmin]
1751    set bmax [expr $heightScale * $dataScale * $vmax]
1752    if {$heightScale > 0} {
1753        set zpos [expr - $bmin]
1754        SendCmd "heightmap pos 0 0 $zpos"
1755    } else {
1756        SendCmd "heightmap pos 0 0 0"
1757    }
1758    set bmax [expr $bmax - $bmin]
1759    set bmin 0
1760    SendCmd "dataset maprange explicit $_limits($_curFldName) $_curFldName"
1761    SendCmd "axis bounds z $bmin $bmax"
1762    SendCmd "axis range z $_limits($_curFldName)"
1763}
1764
1765#
1766# SetCurrentColormap --
1767#
1768itcl::body Rappture::VtkHeightmapViewer::SetCurrentColormap { name } {
1769    # Keep track of the colormaps that we build.
1770    if { $name != "none" && ![info exists _colormaps($name)] } {
1771        BuildColormap $name
1772        set _colormaps($name) 1
1773    }
1774    set _currentColormap $name
1775    SendCmd "heightmap colormap $_currentColormap"
1776}
1777
1778
1779#
1780# BuildColormap --
1781#
1782#       Build the designated colormap on the server.
1783#
1784itcl::body Rappture::VtkHeightmapViewer::BuildColormap { name } {
1785    set cmap [ColorsToColormap $name]
1786    if { [llength $cmap] == 0 } {
1787        set cmap "0.0 0.0 0.0 0.0 1.0 1.0 1.0 1.0"
1788    }
1789    set wmap "0.0 1.0 1.0 1.0"
1790    SendCmd "colormap add $name { $cmap } { $wmap }"
1791}
1792
1793# ----------------------------------------------------------------------
1794# CONFIGURATION OPTION: -mode
1795# ----------------------------------------------------------------------
1796itcl::configbody Rappture::VtkHeightmapViewer::mode {
1797    switch -- $itk_option(-mode) {
1798        "heightmap" {
1799            set _settings(-isheightmap) 1
1800        }
1801        "contour" {
1802            set _settings(-isheightmap) 0
1803        }
1804        default {
1805            error "unknown mode settings \"$itk_option(-mode)\""
1806        }
1807    }
1808    if { !$_reset } {
1809        AdjustSetting -isheightmap
1810    }
1811}
1812
1813# ----------------------------------------------------------------------
1814# CONFIGURATION OPTION: -plotbackground
1815# ----------------------------------------------------------------------
1816itcl::configbody Rappture::VtkHeightmapViewer::plotbackground {
1817    if { [isconnected] } {
1818        set rgb [Color2RGB $itk_option(-plotbackground)]
1819        if { !$_reset } {
1820            SendCmd "screen bgcolor $rgb"
1821        }
1822        $itk_component(view) configure -background $itk_option(-plotbackground)
1823    }
1824}
1825
1826# ----------------------------------------------------------------------
1827# CONFIGURATION OPTION: -plotforeground
1828# ----------------------------------------------------------------------
1829itcl::configbody Rappture::VtkHeightmapViewer::plotforeground {
1830    if { [isconnected] } {
1831        set rgb [Color2RGB $itk_option(-plotforeground)]
1832        if { !$_reset } {
1833            SendCmd "outline color $rgb"
1834            SendCmd "axis color all $rgb"
1835        }
1836    }
1837}
1838
1839itcl::body Rappture::VtkHeightmapViewer::BuildContourTab {} {
1840
1841    set fg [option get $itk_component(hull) font Font]
1842    #set bfg [option get $itk_component(hull) boldFont Font]
1843
1844    set inner [$itk_component(main) insert end \
1845        -title "Contour/Surface Settings" \
1846        -icon [Rappture::icon contour2]]
1847    $inner configure -borderwidth 4
1848
1849    checkbutton $inner.legend \
1850        -text "Legend" \
1851        -variable [itcl::scope _settings(-legendvisible)] \
1852        -command [itcl::code $this AdjustSetting -legendvisible] \
1853        -font "Arial 9"
1854
1855    checkbutton $inner.wireframe \
1856        -text "Wireframe" \
1857        -variable [itcl::scope _settings(-wireframe)] \
1858        -command [itcl::code $this AdjustSetting -wireframe] \
1859        -font "Arial 9"
1860
1861    itk_component add lighting {
1862        checkbutton $inner.lighting \
1863            -text "Enable Lighting" \
1864            -variable [itcl::scope _settings(-lighting)] \
1865            -command [itcl::code $this AdjustSetting -lighting] \
1866            -font "Arial 9"
1867    } {
1868        ignore -font
1869    }
1870    checkbutton $inner.edges \
1871        -text "Edges" \
1872        -variable [itcl::scope _settings(-edges)] \
1873        -command [itcl::code $this AdjustSetting -edges] \
1874        -font "Arial 9"
1875
1876    itk_component add outline {
1877        checkbutton $inner.outline \
1878            -text "Outline" \
1879            -variable [itcl::scope _settings(-outline)] \
1880            -command [itcl::code $this AdjustSetting -outline] \
1881            -font "Arial 9"
1882    } {
1883        ignore -font
1884    }
1885    checkbutton $inner.stretch \
1886        -text "Stretch to fit" \
1887        -variable [itcl::scope _settings(-stretchtofit)] \
1888        -command [itcl::code $this AdjustSetting -stretchtofit] \
1889        -font "Arial 9"
1890
1891    checkbutton $inner.isolines \
1892        -text "Isolines" \
1893        -variable [itcl::scope _settings(-isolinesvisible)] \
1894        -command [itcl::code $this AdjustSetting -isolinesvisible] \
1895        -font "Arial 9"
1896
1897    checkbutton $inner.colormapDiscrete \
1898        -text "Discrete Colormap" \
1899        -variable [itcl::scope _settings(-colormapdiscrete)] \
1900        -command [itcl::code $this AdjustSetting -colormapdiscrete] \
1901        -font "Arial 9"
1902
1903    itk_component add field_l {
1904        label $inner.field_l -text "Field" -font "Arial 9"
1905    } {
1906        ignore -font
1907    }
1908    itk_component add field {
1909        Rappture::Combobox $inner.field -width 10 -editable no
1910    }
1911    bind $inner.field <<Value>> \
1912        [itcl::code $this AdjustSetting -field]
1913
1914    label $inner.colormap_l -text "Colormap" -font "Arial 9"
1915    itk_component add colormap {
1916        Rappture::Combobox $inner.colormap -width 10 -editable no
1917    }
1918    $inner.colormap choices insert end [GetColormapList -includeNone]
1919    $itk_component(colormap) value $_settings(-colormap)
1920    bind $inner.colormap <<Value>> \
1921        [itcl::code $this AdjustSetting -colormap]
1922
1923    label $inner.isolinecolor_l -text "Isolines Color" -font "Arial 9"
1924    itk_component add isolinecolor {
1925        Rappture::Combobox $inner.isolinecolor -width 10 -editable no
1926    }
1927    $inner.isolinecolor choices insert end \
1928        "black"              "black"            \
1929        "blue"               "blue"             \
1930        "cyan"               "cyan"             \
1931        "green"              "green"            \
1932        "grey"               "grey"             \
1933        "magenta"            "magenta"          \
1934        "orange"             "orange"           \
1935        "red"                "red"              \
1936        "white"              "white"            \
1937        "none"               "none"
1938
1939    $itk_component(isolinecolor) value $_settings(-isolinecolor)
1940    bind $inner.isolinecolor <<Value>> \
1941        [itcl::code $this AdjustSetting -isolinecolor]
1942
1943    label $inner.background_l -text "Background Color" -font "Arial 9"
1944    itk_component add background {
1945        Rappture::Combobox $inner.background -width 10 -editable no
1946    }
1947    $inner.background choices insert end \
1948        "black"              "black"            \
1949        "white"              "white"            \
1950        "grey"               "grey"             
1951
1952    $itk_component(background) value "white"
1953    bind $inner.background <<Value>> \
1954        [itcl::code $this AdjustSetting -background]
1955
1956    itk_component add opacity_l {
1957        label $inner.opacity_l -text "Opacity" -font "Arial 9"
1958    } {
1959        ignore -font
1960    }
1961    itk_component add opacity {
1962        ::scale $inner.opacity -from 0 -to 100 -orient horizontal \
1963            -variable [itcl::scope _settings(-opacity)] \
1964            -showvalue off \
1965            -command [itcl::code $this AdjustSetting -opacity]
1966    }
1967    itk_component add scale_l {
1968        label $inner.scale_l -text "Scale" -font "Arial 9"
1969    } {
1970        ignore -font
1971    }
1972    itk_component add scale {
1973        ::scale $inner.scale -from 0 -to 100 -orient horizontal \
1974            -variable [itcl::scope _settings(-heightmapscale)] \
1975            -showvalue off \
1976            -command [itcl::code $this AdjustSetting -heightmapscale]
1977    }
1978    label $inner.numisolines_l -text "Number of Isolines" -font "Arial 9"
1979    itk_component add numisolines {
1980        Rappture::Spinint $inner.numisolines \
1981            -min 0 -max 50 -font "arial 9"
1982    }
1983    $itk_component(numisolines) value $_settings(-numisolines)
1984    bind $itk_component(numisolines) <<Value>> \
1985        [itcl::code $this AdjustSetting -numisolines]
1986
1987    frame $inner.separator1 -height 2 -relief sunken -bd 1
1988    frame $inner.separator2 -height 2 -relief sunken -bd 1
1989
1990    blt::table $inner \
1991        0,0 $inner.field_l -anchor w -pady 2 \
1992        0,1 $inner.field -anchor w -pady 2 -fill x \
1993        1,0 $inner.colormap_l -anchor w -pady 2  \
1994        1,1 $inner.colormap   -anchor w -pady 2 -fill x  \
1995        2,0 $inner.isolinecolor_l  -anchor w -pady 2  \
1996        2,1 $inner.isolinecolor    -anchor w -pady 2 -fill x  \
1997        3,0 $inner.background_l -anchor w -pady 2 \
1998        3,1 $inner.background -anchor w -pady 2  -fill x \
1999        4,0 $inner.numisolines_l -anchor w -pady 2 \
2000        4,1 $inner.numisolines -anchor w -pady 2 \
2001        5,0 $inner.stretch    -anchor w -pady 2 -cspan 2 \
2002        6,0 $inner.edges      -anchor w -pady 2 -cspan 2 \
2003        7,0 $inner.legend     -anchor w -pady 2 -cspan 2 \
2004        8,0 $inner.colormapDiscrete -anchor w -pady 2 -cspan 2 \
2005        9,0 $inner.wireframe  -anchor w -pady 2 -cspan 2\
2006        10,0 $inner.isolines   -anchor w -pady 2 -cspan 2 \
2007        11,0 $inner.separator1 -padx 2 -fill x -cspan 2 \
2008        12,0 $inner.outline    -anchor w -pady 2 -cspan 2 \
2009        13,0 $inner.separator2 -padx 2 -fill x -cspan 2 \
2010        14,0 $inner.lighting   -anchor w -pady 2 -cspan 2 \
2011        15,0 $inner.opacity_l -anchor w -pady 2 \
2012        15,1 $inner.opacity   -fill x   -pady 2 \
2013        16,0 $inner.scale_l   -anchor w -pady 2 -cspan 2 \
2014        16,1 $inner.scale     -fill x   -pady 2 -cspan 2 \
2015
2016    blt::table configure $inner r* c* -resize none
2017    blt::table configure $inner r17 c1 -resize expand
2018}
2019
2020itcl::body Rappture::VtkHeightmapViewer::BuildAxisTab {} {
2021
2022    set fg [option get $itk_component(hull) font Font]
2023    #set bfg [option get $itk_component(hull) boldFont Font]
2024
2025    set inner [$itk_component(main) insert end \
2026        -title "Axis Settings" \
2027        -icon [Rappture::icon axis2]]
2028    $inner configure -borderwidth 4
2029
2030    checkbutton $inner.visible \
2031        -text "Axes" \
2032        -variable [itcl::scope _settings(-axisvisible)] \
2033        -command [itcl::code $this AdjustSetting -axisvisible] \
2034        -font "Arial 9"
2035    checkbutton $inner.labels \
2036        -text "Axis Labels" \
2037        -variable [itcl::scope _settings(-axislabels)] \
2038        -command [itcl::code $this AdjustSetting -axislabels] \
2039        -font "Arial 9"
2040    label $inner.grid_l -text "Grid" -font "Arial 9"
2041    checkbutton $inner.xgrid \
2042        -text "X" \
2043        -variable [itcl::scope _settings(-xgrid)] \
2044        -command [itcl::code $this AdjustSetting -xgrid] \
2045        -font "Arial 9"
2046    checkbutton $inner.ygrid \
2047        -text "Y" \
2048        -variable [itcl::scope _settings(-ygrid)] \
2049        -command [itcl::code $this AdjustSetting -ygrid] \
2050        -font "Arial 9"
2051    checkbutton $inner.zgrid \
2052        -text "Z" \
2053        -variable [itcl::scope _settings(-zgrid)] \
2054        -command [itcl::code $this AdjustSetting -zgrid] \
2055        -font "Arial 9"
2056    checkbutton $inner.minorticks \
2057        -text "Minor Ticks" \
2058        -variable [itcl::scope _settings(-axisminorticks)] \
2059        -command [itcl::code $this AdjustSetting -axisminorticks] \
2060        -font "Arial 9"
2061
2062    label $inner.mode_l -text "Mode" -font "Arial 9"
2063
2064    itk_component add axisflymode {
2065        Rappture::Combobox $inner.mode -width 10 -editable no
2066    }
2067    $inner.mode choices insert end \
2068        "static_triad"    "static" \
2069        "closest_triad"   "closest" \
2070        "furthest_triad"  "farthest" \
2071        "outer_edges"     "outer"         
2072    $itk_component(axisflymode) value $_settings(-axisflymode)
2073    bind $inner.mode <<Value>> [itcl::code $this AdjustSetting -axisflymode]
2074
2075    blt::table $inner \
2076        0,0 $inner.visible -anchor w -cspan 4 \
2077        1,0 $inner.labels  -anchor w -cspan 4 \
2078        2,0 $inner.minorticks  -anchor w -cspan 4 \
2079        4,0 $inner.grid_l  -anchor w \
2080        4,1 $inner.xgrid   -anchor w \
2081        4,2 $inner.ygrid   -anchor w \
2082        4,3 $inner.zgrid   -anchor w \
2083        5,0 $inner.mode_l  -anchor w -padx { 2 0 } \
2084        5,1 $inner.mode    -fill x -cspan 3
2085
2086    blt::table configure $inner r* c* -resize none
2087    blt::table configure $inner r7 c6 -resize expand
2088    blt::table configure $inner r3 -height 0.125i
2089}
2090
2091
2092itcl::body Rappture::VtkHeightmapViewer::BuildCameraTab {} {
2093    set inner [$itk_component(main) insert end \
2094        -title "Camera Settings" \
2095        -icon [Rappture::icon camera]]
2096    $inner configure -borderwidth 4
2097
2098    label $inner.view_l -text "view" -font "Arial 9"
2099    set f [frame $inner.view]
2100    foreach side { front back left right top bottom } {
2101        button $f.$side  -image [Rappture::icon view$side] \
2102            -command [itcl::code $this SetOrientation $side]
2103        Rappture::Tooltip::for $f.$side "Change the view to $side"
2104        pack $f.$side -side left
2105    }
2106
2107    blt::table $inner \
2108        0,0 $inner.view_l -anchor e -pady 2 \
2109        0,1 $inner.view -anchor w -pady 2
2110
2111    set labels { qx qy qz qw xpan ypan zoom }
2112    set row 1
2113    foreach tag $labels {
2114        label $inner.${tag}label -text $tag -font "Arial 9"
2115        entry $inner.${tag} -font "Arial 9"  -bg white \
2116            -textvariable [itcl::scope _view($tag)]
2117        bind $inner.${tag} <Return> \
2118            [itcl::code $this camera set ${tag}]
2119        bind $inner.${tag} <KP_Enter> \
2120            [itcl::code $this camera set ${tag}]
2121        blt::table $inner \
2122            $row,0 $inner.${tag}label -anchor e -pady 2 \
2123            $row,1 $inner.${tag} -anchor w -pady 2
2124        blt::table configure $inner r$row -resize none
2125        incr row
2126    }
2127    checkbutton $inner.ortho \
2128        -text "Orthographic Projection" \
2129        -variable [itcl::scope _view(ortho)] \
2130        -command [itcl::code $this camera set ortho] \
2131        -font "Arial 9"
2132    blt::table $inner \
2133            $row,0 $inner.ortho -cspan 2 -anchor w -pady 2
2134    blt::table configure $inner r$row -resize none
2135    incr row
2136
2137    blt::table configure $inner c* r* -resize none
2138    blt::table configure $inner c2 -resize expand
2139    blt::table configure $inner r$row -resize expand
2140}
2141
2142#
2143#  camera --
2144#
2145itcl::body Rappture::VtkHeightmapViewer::camera {option args} {
2146    switch -- $option {
2147        "show" {
2148            puts [array get _view]
2149        }
2150        "set" {
2151            set who [lindex $args 0]
2152            set x $_view($who)
2153            set code [catch { string is double $x } result]
2154            if { $code != 0 || !$result } {
2155                return
2156            }
2157            switch -- $who {
2158                "ortho" {
2159                    if {$_view(ortho)} {
2160                        SendCmd "camera mode ortho"
2161                    } else {
2162                        SendCmd "camera mode persp"
2163                    }
2164                }
2165                "xpan" - "ypan" {
2166                    PanCamera
2167                }
2168                "qx" - "qy" - "qz" - "qw" {
2169                    set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
2170                    $_arcball quaternion $q
2171                    EventuallyRotate $q
2172                }
2173                "zoom" {
2174                    SendCmd "camera zoom $_view(zoom)"
2175                }
2176            }
2177        }
2178    }
2179}
2180
2181itcl::body Rappture::VtkHeightmapViewer::GetVtkData { args } {
2182    set bytes ""
2183    foreach dataobj [get] {
2184        foreach comp [$dataobj components] {
2185            set tag $dataobj-$comp
2186            set contents [$dataobj vtkdata $comp]
2187            append bytes "$contents\n"
2188        }
2189    }
2190    return [list .vtk $bytes]
2191}
2192
2193itcl::body Rappture::VtkHeightmapViewer::GetImage { args } {
2194    if { [image width $_image(download)] > 0 &&
2195         [image height $_image(download)] > 0 } {
2196        set bytes [$_image(download) data -format "jpeg -quality 100"]
2197        set bytes [Rappture::encoding::decode -as b64 $bytes]
2198        return [list .jpg $bytes]
2199    }
2200    return ""
2201}
2202
2203itcl::body Rappture::VtkHeightmapViewer::BuildDownloadPopup { popup command } {
2204    Rappture::Balloon $popup \
2205        -title "[Rappture::filexfer::label downloadWord] as..."
2206    set inner [$popup component inner]
2207    label $inner.summary -text "" -anchor w
2208    radiobutton $inner.vtk_button -text "VTK data file" \
2209        -variable [itcl::scope _downloadPopup(format)] \
2210        -font "Arial 9 " \
2211        -value vtk 
2212    Rappture::Tooltip::for $inner.vtk_button "Save as VTK data file."
2213    radiobutton $inner.image_button -text "Image File" \
2214        -variable [itcl::scope _downloadPopup(format)] \
2215        -font "Arial 9 " \
2216        -value image
2217    Rappture::Tooltip::for $inner.image_button \
2218        "Save as digital image."
2219
2220    button $inner.ok -text "Save" \
2221        -highlightthickness 0 -pady 2 -padx 3 \
2222        -command $command \
2223        -compound left \
2224        -image [Rappture::icon download]
2225
2226    button $inner.cancel -text "Cancel" \
2227        -highlightthickness 0 -pady 2 -padx 3 \
2228        -command [list $popup deactivate] \
2229        -compound left \
2230        -image [Rappture::icon cancel]
2231
2232    blt::table $inner \
2233        0,0 $inner.summary -cspan 2  \
2234        1,0 $inner.vtk_button -anchor w -cspan 2 -padx { 4 0 } \
2235        2,0 $inner.image_button -anchor w -cspan 2 -padx { 4 0 } \
2236        4,1 $inner.cancel -width .9i -fill y \
2237        4,0 $inner.ok -padx 2 -width .9i -fill y
2238    blt::table configure $inner r3 -height 4
2239    blt::table configure $inner r4 -pady 4
2240    raise $inner.image_button
2241    $inner.vtk_button invoke
2242    return $inner
2243}
2244
2245#
2246# SetObjectStyle --
2247#
2248#       Set the style of the heightmap/contour object.  This gets calls
2249#       for each dataset once as it is loaded.  It can overridden by
2250#       the user controls.
2251#
2252#
2253itcl::body Rappture::VtkHeightmapViewer::SetObjectStyle { dataobj comp } {
2254    # Parse style string.
2255    set tag $dataobj-$comp
2256    array set style {
2257        -color BCGYR
2258        -levels 10
2259        -opacity 1.0
2260    }
2261    set stylelist [$dataobj style $comp]
2262    if { $stylelist != "" } {
2263        array set style $stylelist
2264    }
2265    # This is too complicated.  We want to set the colormap, number of
2266    # isolines and opacity for the dataset.  They can be the default values,
2267    # the style hints loaded with the dataset, or set by user controls.  As
2268    # datasets get loaded, they first use the defaults that are overidden
2269    # by the style hints.  If the user changes the global controls, then that
2270    # overrides everything else.  I don't know what it means when global
2271    # controls are specified as style hints by each dataset.  It complicates
2272    # the code to handle aberrant cases.
2273
2274    if { $_changed(-opacity) } {
2275        set style(-opacity) [expr $_settings(-opacity) * 0.01]
2276    }
2277    if { $_changed(-numisolines) } {
2278        set style(-levels) $_settings(-numisolines)
2279    }
2280    if { $_changed(-colormap) } {
2281        set style(-color) $_settings(-colormap)
2282    }
2283    if { $_currentColormap == "" } {
2284        $itk_component(colormap) value $style(-color)
2285    }
2286    if { [info exists style(-stretchtofit)] } {
2287        set _settings(-stretchtofit) $style(-stretchtofit)
2288        AdjustSetting -stretchtofit
2289    }
2290    if { $_currentNumIsolines != $style(-levels) } {
2291        set _currentNumIsolines $style(-levels)
2292        set _settings(-numisolines) $_currentNumIsolines
2293        $itk_component(numisolines) value $_currentNumIsolines
2294        UpdateContourList
2295        DrawLegend
2296    }
2297    SendCmd "outline add $tag"
2298    SendCmd "outline color [Color2RGB $itk_option(-plotforeground)] $tag"
2299    SendCmd "outline visible $_settings(-outline) $tag"
2300    set scale [GetHeightmapScale]
2301    SendCmd "[list heightmap add contourlist $_contourList $scale $tag]"
2302    set _comp2scale($tag) $_settings(-heightmapscale)
2303    SendCmd "heightmap edges $_settings(-edges) $tag"
2304    SendCmd "heightmap wireframe $_settings(-wireframe) $tag"
2305    SetCurrentColormap $style(-color)
2306    set color [$itk_component(isolinecolor) value]
2307    SendCmd "heightmap isolinecolor [Color2RGB $color] $tag"
2308    SendCmd "heightmap lighting $_settings(-isheightmap) $tag"
2309    SendCmd "heightmap isolines $_settings(-isolinesvisible) $tag"
2310    SendCmd "heightmap surface $_settings(-colormapvisible) $tag"
2311    SendCmd "heightmap opacity $style(-opacity) $tag"
2312    set _settings(-opacity) [expr $style(-opacity) * 100.0]
2313}
2314
2315itcl::body Rappture::VtkHeightmapViewer::IsValidObject { dataobj } {
2316    if {[catch {$dataobj isa Rappture::Field} valid] != 0 || !$valid} {
2317        return 0
2318    }
2319    return 1
2320}
2321
2322# ----------------------------------------------------------------------
2323# USAGE: ReceiveLegend <colormap> <title> <min> <max> <size>
2324#
2325# Invoked automatically whenever the "legend" command comes in from
2326# the rendering server.  Indicates that binary image data with the
2327# specified <size> will follow.
2328# ----------------------------------------------------------------------
2329itcl::body Rappture::VtkHeightmapViewer::ReceiveLegend { colormap title min max size } {
2330    #puts stderr "ReceiveLegend colormap=$colormap title=$title range=$min,$max size=$size"
2331    if { [isconnected] } {
2332        set bytes [ReceiveBytes $size]
2333        if { ![info exists _image(legend)] } {
2334            set _image(legend) [image create photo]
2335        }
2336        $_image(legend) configure -data $bytes
2337        #puts stderr "read $size bytes for [image width $_image(legend)]x[image height $_image(legend)] legend>"
2338        if { [catch {DrawLegend} errs] != 0 } {
2339            global errorInfo
2340            puts stderr "errs=$errs errorInfo=$errorInfo"
2341        }
2342    }
2343}
2344
2345#
2346# DrawLegend --
2347#
2348#       Draws the legend in the own canvas on the right side of the plot area.
2349#
2350itcl::body Rappture::VtkHeightmapViewer::DrawLegend {} {
2351    set fname $_curFldName
2352    set c $itk_component(view)
2353    set w [winfo width $c]
2354    set h [winfo height $c]
2355    set font "Arial 8"
2356    set lineht [font metrics $font -linespace]
2357   
2358    if { [string match "component*" $fname] } {
2359        set title ""
2360    } else {
2361        if { [info exists _fields($fname)] } {
2362            foreach { title units } $_fields($fname) break
2363            if { $units != "" } {
2364                set title [format "%s (%s)" $title $units]
2365            }
2366        } else {
2367            set title $fname
2368        }
2369    }
2370    set x [expr $w - 2]
2371    if { !$_settings(-legendvisible) } {
2372        $c delete legend
2373        return
2374    }
2375    if { [$c find withtag "legend"] == "" } {
2376        set y 2
2377        # If there's a legend title, create a text item for the title.
2378        $c create text $x $y \
2379            -anchor ne \
2380            -fill $itk_option(-plotforeground) -tags "title legend" \
2381            -font $font
2382        if { $title != "" } {
2383            incr y $lineht
2384        }
2385        $c create text $x $y \
2386            -anchor ne \
2387            -fill $itk_option(-plotforeground) -tags "vmax legend" \
2388            -font $font
2389        incr y $lineht
2390        $c create image $x $y \
2391            -anchor ne \
2392            -image $_image(legend) -tags "colormap legend"
2393        $c create rectangle $x $y 1 1 \
2394            -fill "" -outline "" -tags "sensor legend"
2395        $c create text $x [expr {$h-2}] \
2396            -anchor se \
2397            -fill $itk_option(-plotforeground) -tags "vmin legend" \
2398            -font $font
2399        $c bind sensor <Enter> [itcl::code $this EnterLegend %x %y]
2400        $c bind sensor <Leave> [itcl::code $this LeaveLegend]
2401        $c bind sensor <Motion> [itcl::code $this MotionLegend %x %y]
2402    }
2403    $c delete isoline
2404    set x2 $x
2405    set iw [image width $_image(legend)]
2406    set ih [image height $_image(legend)]
2407    set x1 [expr $x2 - ($iw*12)/10]
2408    set color [$itk_component(isolinecolor) value]
2409
2410    # Draw the isolines on the legend.
2411    array unset _isolines
2412    if { $color != "none"  && [info exists _limits($_curFldName)] &&
2413         $_settings(-isolinesvisible) && $_currentNumIsolines > 0 } {
2414
2415        foreach { vmin vmax } $_limits($_curFldName) break
2416        set range [expr double($vmax - $vmin)]
2417        if { $range <= 0.0 } {
2418            set range 1.0;              # Min is greater or equal to max.
2419        }
2420        set tags "isoline legend"
2421        set offset [expr 2 + $lineht]
2422        if { $title != "" } {
2423            incr offset $lineht
2424        }
2425        foreach value $_contourList {
2426            set norm [expr 1.0 - (($value - $vmin) / $range)]
2427            set y1 [expr int(round(($norm * $ih) + $offset))]
2428            for { set off 0 } { $off < 3 } { incr off } {
2429                set _isolines([expr $y1 + $off]) $value
2430                set _isolines([expr $y1 - $off]) $value
2431            }
2432            $c create line $x1 $y1 $x2 $y1 -fill $color -tags $tags
2433        }
2434    }
2435
2436    $c bind title <ButtonPress> [itcl::code $this Combo post]
2437    $c bind title <Enter> [itcl::code $this Combo activate]
2438    $c bind title <Leave> [itcl::code $this Combo deactivate]
2439    # Reset the item coordinates according the current size of the plot.
2440    if { [info exists _limits($_curFldName)] } {
2441        foreach { vmin vmax } $_limits($_curFldName) break
2442        $c itemconfigure vmin -text [format %g $vmin]
2443        $c itemconfigure vmax -text [format %g $vmax]
2444    }
2445    set y 2
2446    # If there's a legend title, move the title to the correct position
2447    if { $title != "" } {
2448        $c itemconfigure title -text $title
2449        $c coords title $x $y
2450        incr y $lineht
2451    }
2452    $c coords vmax $x $y
2453    incr y $lineht
2454    $c coords colormap $x $y
2455    $c coords sensor [expr $x - $iw] $y $x [expr $y + $ih]
2456    $c raise sensor
2457    $c coords vmin $x [expr {$h - 2}]
2458}
2459
2460#
2461# EnterLegend --
2462#
2463itcl::body Rappture::VtkHeightmapViewer::EnterLegend { x y } {
2464    SetLegendTip $x $y
2465}
2466
2467#
2468# MotionLegend --
2469#
2470itcl::body Rappture::VtkHeightmapViewer::MotionLegend { x y } {
2471    Rappture::Tooltip::tooltip cancel
2472    set c $itk_component(view)
2473    set cw [winfo width $c]
2474    set ch [winfo height $c]
2475    if { $x >= 0 && $x < $cw && $y >= 0 && $y < $ch } {
2476        SetLegendTip $x $y
2477    }
2478}
2479
2480#
2481# LeaveLegend --
2482#
2483itcl::body Rappture::VtkHeightmapViewer::LeaveLegend { } {
2484    Rappture::Tooltip::tooltip cancel
2485    .rappturetooltip configure -icon ""
2486}
2487
2488#
2489# SetLegendTip --
2490#
2491itcl::body Rappture::VtkHeightmapViewer::SetLegendTip { x y } {
2492    set fname $_curFldName
2493    set c $itk_component(view)
2494    set w [winfo width $c]
2495    set h [winfo height $c]
2496    set font "Arial 8"
2497    set lineht [font metrics $font -linespace]
2498   
2499    set ih [image height $_image(legend)]
2500    # Subtract off the offset of the color ramp from the top of the canvas
2501    set iy [expr $y - ($lineht + 2)]
2502
2503    if { [string match "component*" $fname] } {
2504        set title ""
2505    } else {
2506        if { [info exists _fields($fname)] } {
2507            foreach { title units } $_fields($fname) break
2508            if { $units != "" } {
2509                set title [format "%s (%s)" $title $units]
2510            }
2511        } else {
2512            set title $fname
2513        }
2514    }
2515    # If there's a legend title, increase the offset by the line height.
2516    if { $title != "" } {
2517        incr iy -$lineht
2518    }
2519
2520    # Make a swatch of the selected color
2521    if { [catch { $_image(legend) get 10 $iy } pixel] != 0 } {
2522        return
2523    }
2524
2525    if { ![info exists _image(swatch)] } {
2526        set _image(swatch) [image create photo -width 24 -height 24]
2527    }
2528    set color [eval format "\#%02x%02x%02x" $pixel]
2529    $_image(swatch) put black  -to 0 0 23 23
2530    $_image(swatch) put $color -to 1 1 22 22
2531
2532    # Compute the value of the point
2533    if { [info exists _limits($fname)] } {
2534        foreach { vmin vmax } $_limits($fname) break
2535        set t [expr 1.0 - (double($iy) / double($ih-1))]
2536        set value [expr $t * ($vmax - $vmin) + $vmin]
2537    } else {
2538        set value 0.0
2539    }
2540    set tipx [expr $x + 15]
2541    set tipy [expr $y - 5]
2542    .rappturetooltip configure -icon $_image(swatch)
2543    if { [info exists _isolines($y)] } {
2544        Rappture::Tooltip::text $c [format "$title %g (isoline)" $_isolines($y)]
2545    } else {
2546        Rappture::Tooltip::text $c [format "$title %g" $value]
2547    }
2548    Rappture::Tooltip::tooltip show $c +$tipx,+$tipy   
2549}
2550
2551# ----------------------------------------------------------------------
2552# USAGE: _dropdown post
2553# USAGE: _dropdown unpost
2554# USAGE: _dropdown select
2555#
2556# Used internally to handle the dropdown list for this combobox.  The
2557# post/unpost options are invoked when the list is posted or unposted
2558# to manage the relief of the controlling button.  The select option
2559# is invoked whenever there is a selection from the list, to assign
2560# the value back to the gauge.
2561# ----------------------------------------------------------------------
2562itcl::body Rappture::VtkHeightmapViewer::Combo {option} {
2563    set c $itk_component(view)
2564    switch -- $option {
2565        post {
2566            foreach { x1 y1 x2 y2 } [$c bbox title] break
2567            set x1 [expr [winfo width $itk_component(view)] - [winfo reqwidth $itk_component(fieldmenu)]]
2568            set x [expr $x1 + [winfo rootx $itk_component(view)]]
2569            set y [expr $y2 + [winfo rooty $itk_component(view)]]
2570            tk_popup $itk_component(fieldmenu) $x $y
2571        }
2572        activate {
2573            $c itemconfigure title -fill red
2574        }
2575        deactivate {
2576            $c itemconfigure title -fill $itk_option(-plotforeground)
2577        }
2578        invoke {
2579            $itk_component(field) value $_curFldLabel
2580            AdjustSetting -field
2581        }
2582        default {
2583            error "bad option \"$option\": should be post, unpost, select"
2584        }
2585    }
2586}
2587
2588itcl::body Rappture::VtkHeightmapViewer::GetHeightmapScale {} {
2589    if {  $_settings(-isheightmap) } {
2590        set val $_settings(-heightmapscale)
2591        set sval [expr { $val >= 50 ? double($val)/50.0 : 1.0/(2.0-(double($val)/50.0)) }]
2592        return $sval
2593    }
2594    return 0
2595}
2596
2597itcl::body Rappture::VtkHeightmapViewer::SetOrientation { side } {
2598    array set positions {
2599        front  "0.707107 0.707107 0 0"
2600        back   "0 0 0.707107 0.707107"
2601        left   "0.5 0.5 -0.5 -0.5"
2602        right  "0.5 0.5 0.5 0.5"
2603        top    "1 0 0 0"
2604        bottom "0 1 0 0"
2605    }
2606    foreach name { qw qx qy qz } value $positions($side) {
2607        set _view($name) $value
2608    }
2609    set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
2610    $_arcball quaternion $q
2611    SendCmd "camera orient $q"
2612    SendCmd "camera reset"
2613    set _view(xpan) 0
2614    set _view(ypan) 0
2615    set _view(zoom) 1.0
2616}
2617
2618itcl::body Rappture::VtkHeightmapViewer::UpdateContourList {} {
2619    if {$_currentNumIsolines == 0} {
2620        set _contourList ""
2621        return
2622    }
2623    if { ![info exists _limits($_curFldName)] } {
2624        return
2625    }
2626    foreach { vmin vmax } $_limits($_curFldName) break
2627    set v [blt::vector create \#auto]
2628    $v seq $vmin $vmax [expr $_currentNumIsolines+2]
2629    $v delete end 0
2630    set _contourList [$v range 0 end]
2631    blt::vector destroy $v
2632}
Note: See TracBrowser for help on using the repository browser.