source: branches/1.3/gui/scripts/vtkheightmapviewer.tcl @ 4759

Last change on this file since 4759 was 4759, checked in by ldelgass, 6 years ago

merge r4756:4758 from trunk

File size: 87.7 KB
Line 
1# -*- mode: tcl; indent-tabs-mode: nil -*-
2# ----------------------------------------------------------------------
3#  COMPONENT: vtkheightmapviewer - Vtk heightmap viewer
4#
5#  It connects to the Vtk server running on a rendering farm,
6#  transmits data, and displays the results.
7# ======================================================================
8#  AUTHOR:  Michael McLennan, Purdue University
9#  Copyright (c) 2004-2014  HUBzero Foundation, LLC
10#
11#  See the file "license.terms" for information on usage and
12#  redistribution of this file, and for a DISCLAIMER OF ALL WARRANTIES.
13# ======================================================================
14package require Itk
15package require BLT
16#package require Img
17
18option add *VtkHeightmapViewer.width 4i widgetDefault
19option add *VtkHeightmapViewer*cursor crosshair widgetDefault
20option add *VtkHeightmapViewer.height 4i widgetDefault
21option add *VtkHeightmapViewer.foreground black widgetDefault
22option add *VtkHeightmapViewer.controlBackground gray widgetDefault
23option add *VtkHeightmapViewer.controlDarkBackground #999999 widgetDefault
24option add *VtkHeightmapViewer.plotBackground black widgetDefault
25option add *VtkHeightmapViewer.plotForeground white widgetDefault
26option add *VtkHeightmapViewer.font \
27    -*-helvetica-medium-r-normal-*-12-* widgetDefault
28
29# must use this name -- plugs into Rappture::resources::load
30proc VtkHeightmapViewer_init_resources {} {
31    Rappture::resources::register \
32        vtkvis_server Rappture::VtkHeightmapViewer::SetServerList
33}
34
35itcl::class Rappture::VtkHeightmapViewer {
36    inherit Rappture::VisViewer
37
38    itk_option define -plotforeground plotForeground Foreground ""
39    itk_option define -plotbackground plotBackground Background ""
40    itk_option define -mode mode Mode "contour"
41
42    constructor { hostlist args } {
43        Rappture::VisViewer::constructor $hostlist
44    } {
45        # defined below
46    }
47    destructor {
48        # defined below
49    }
50    public proc SetServerList { namelist } {
51        Rappture::VisViewer::SetServerList "vtkvis" $namelist
52    }
53    public method add {dataobj {settings ""}}
54    public method camera {option args}
55    public method delete {args}
56    public method disconnect {}
57    public method download {option args}
58    public method get {args}
59    public method isconnected {}
60    public method parameters {title args} {
61        # do nothing
62    }
63    public method scale {args}
64
65    protected method CameraReset {}
66    protected method Connect {}
67    protected method CurrentDatasets {args}
68    protected method Disconnect {}
69    protected method DoResize {}
70    protected method DoRotate {}
71    protected method AdjustSetting {what {value ""}}
72    protected method AdjustMode {}
73    protected method InitSettings { args  }
74    protected method Pan {option x y}
75    protected method Pick {x y}
76    protected method Rebuild {}
77    protected method ReceiveDataset { args }
78    protected method ReceiveImage { args }
79    protected method ReceiveLegend { colormap title min max size }
80    protected method Rotate {option x y}
81    protected method Zoom {option}
82
83    # The following methods are only used by this class.
84    private method BuildAxisTab {}
85    private method BuildCameraTab {}
86    private method BuildColormap { name }
87    private method BuildContourTab {}
88    private method BuildDownloadPopup { widget command }
89    private method Combo { option }
90    private method DrawLegend {}
91    private method EnterLegend { x y }
92    private method EventuallyRequestLegend {}
93    private method EventuallyResize { w h }
94    private method EventuallyRotate { q }
95    private method GetImage { args }
96    private method GetVtkData { args }
97    private method IsValidObject { dataobj }
98    private method LeaveLegend {}
99    private method MotionLegend { x y }
100    private method PanCamera {}
101    private method RequestLegend {}
102    private method SetCurrentColormap { color }
103    private method SetLegendTip { x y }
104    private method SetObjectStyle { dataobj comp }
105    private method GetHeightmapScale {}
106    private method ResetAxes {}
107    private method SetOrientation { side }
108    private method UpdateContourList {}
109
110    private variable _arcball ""
111    private variable _dlist ""     ;    # list of data objects
112    private variable _obj2datasets
113    private variable _obj2ovride   ;    # maps dataobj => style override
114    private variable _comp2scale;       # maps dataset to the heightmap scale.
115    private variable _datasets     ;    # contains all the dataobj-component
116                                   ;    # datasets in the server
117    private variable _colormaps    ;    # contains all the colormaps
118                                   ;    # in the server.
119
120    # The name of the current colormap used.  The colormap is global to all
121    # heightmaps displayed.
122    private variable _currentColormap ""
123    private variable _currentNumIsolines -1
124
125    private variable _maxScale 100;     # This is the # of times the x-axis
126                                        # and y-axis ranges can differ before
127                                        # automatically turning on
128                                        # -stretchtofit
129
130    private variable _click        ;    # info used for rotate operations
131    private variable _limits       ;    # Holds overall limits for all dataobjs
132                                        # using the viewer.
133    private variable _view         ;    # view params for 3D view
134    private variable _settings
135    private variable _changed
136    private variable _initialStyle "";  # First found style in dataobjects.
137    private variable _reset 1;          # Indicates if camera needs to be reset
138                                        # to starting position.
139    private variable _beforeConnect 1;  # Indicates if camera needs to be reset
140                                        # to starting position.
141
142    private variable _first ""     ;    # This is the topmost dataset.
143    private variable _start 0
144    private variable _isolines
145    private variable _contourList ""
146
147    common _downloadPopup;              # download options from popup
148    private common _hardcopy
149    private variable _width 0
150    private variable _height 0
151    private variable _legendWidth 0
152    private variable _legendHeight 0
153    private variable _resizePending 0
154    private variable _rotatePending 0
155    private variable _legendPending 0
156    private variable _fieldNames {}
157    private variable _fields
158    private variable _curFldName ""
159    private variable _curFldLabel ""
160    private variable _colorMode "scalar";#  Mode of colormap (vmag or scalar)
161}
162
163itk::usual VtkHeightmapViewer {
164    keep -background -foreground -cursor -font
165    keep -plotbackground -plotforeground -mode
166}
167
168# ----------------------------------------------------------------------
169# CONSTRUCTOR
170# ----------------------------------------------------------------------
171itcl::body Rappture::VtkHeightmapViewer::constructor {hostlist args} {
172    set _serverType "vtkvis"
173
174    EnableWaitDialog 900
175    # Rebuild event
176    $_dispatcher register !rebuild
177    $_dispatcher dispatch $this !rebuild "[itcl::code $this Rebuild]; list"
178
179    # Resize event
180    $_dispatcher register !resize
181    $_dispatcher dispatch $this !resize "[itcl::code $this DoResize]; list"
182
183    # Rotate event
184    $_dispatcher register !rotate
185    $_dispatcher dispatch $this !rotate "[itcl::code $this DoRotate]; list"
186
187    # Legend event
188    $_dispatcher register !legend
189    $_dispatcher dispatch $this !legend "[itcl::code $this RequestLegend]; list"
190
191    #
192    # Populate parser with commands handle incoming requests
193    #
194    $_parser alias image [itcl::code $this ReceiveImage]
195    $_parser alias dataset [itcl::code $this ReceiveDataset]
196    $_parser alias legend [itcl::code $this ReceiveLegend]
197
198    # Create image for legend colorbar.
199    set _image(legend) [image create photo]
200
201    # Initialize the view to some default parameters.
202    array set _view {
203        qw      0.36
204        qx      0.25
205        qy      0.50
206        qz      0.70
207        zoom    1.0
208        xpan    0
209        ypan    0
210        ortho   0
211    }
212    set _arcball [blt::arcball create 100 100]
213    set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
214    $_arcball quaternion $q
215
216    array set _settings {
217        -axisflymode            "static"
218        -axislabels             1
219        -axisminorticks         1
220        -axisvisible            1
221        -colormap               BCGYR
222        -colormapdiscrete       0
223        -colormapvisible        1
224        -edges                  0
225        -field                  "Default"
226        -heightmapscale         50
227        -isheightmap            0
228        -isolinecolor           black
229        -isolinesvisible        1
230        -legendvisible          1
231        -lighting               1
232        -numisolines            10
233        -opacity                100
234        -outline                0
235        -savelighting           1
236        -saveopacity            100
237        -saveoutline            0
238        -stretchtofit           0
239        -wireframe              0
240        -xgrid                  0
241        -ygrid                  0
242        -zgrid                  0
243    }
244    array set _changed {
245        -colormap               0
246        -numisolines            0
247        -opacity                0
248    }
249    itk_component add view {
250        canvas $itk_component(plotarea).view \
251            -highlightthickness 0 -borderwidth 0
252    } {
253        usual
254        ignore -highlightthickness -borderwidth -background
255    }
256
257    itk_component add fieldmenu {
258        menu $itk_component(plotarea).menu \
259            -relief flat \
260            -tearoff no
261    } {
262        usual
263        ignore -background -foreground -relief -tearoff
264    }
265    set c $itk_component(view)
266    bind $c <Configure> [itcl::code $this EventuallyResize %w %h]
267    bind $c <4> [itcl::code $this Zoom in 0.25]
268    bind $c <5> [itcl::code $this Zoom out 0.25]
269    bind $c <KeyPress-Left>  [list %W xview scroll 10 units]
270    bind $c <KeyPress-Right> [list %W xview scroll -10 units]
271    bind $c <KeyPress-Up>    [list %W yview scroll 10 units]
272    bind $c <KeyPress-Down>  [list %W yview scroll -10 units]
273    bind $c <Enter> "focus %W"
274    bind $c <Control-F1> [itcl::code $this ToggleConsole]
275
276    # Fix the scrollregion in case we go off screen
277    $c configure -scrollregion [$c bbox all]
278
279    set _map(id) [$c create image 0 0 -anchor nw -image $_image(plot)]
280    set _map(cwidth) -1
281    set _map(cheight) -1
282    set _map(zoom) 1.0
283    set _map(original) ""
284
285    set f [$itk_component(main) component controls]
286    itk_component add reset {
287        button $f.reset -borderwidth 1 -padx 1 -pady 1 \
288            -highlightthickness 0 \
289            -image [Rappture::icon reset-view] \
290            -command [itcl::code $this CameraReset]
291    } {
292        usual
293        ignore -highlightthickness
294    }
295    pack $itk_component(reset) -side top -padx 2 -pady { 2 0 }
296    Rappture::Tooltip::for $itk_component(reset) "Reset the view to the default zoom level"
297
298    itk_component add zoomin {
299        button $f.zin -borderwidth 1 -padx 1 -pady 1 \
300            -highlightthickness 0 \
301            -image [Rappture::icon zoom-in] \
302            -command [itcl::code $this Zoom in]
303    } {
304        usual
305        ignore -highlightthickness
306    }
307    pack $itk_component(zoomin) -side top -padx 2 -pady { 2 0 }
308    Rappture::Tooltip::for $itk_component(zoomin) "Zoom in"
309
310    itk_component add zoomout {
311        button $f.zout -borderwidth 1 -padx 1 -pady 1 \
312            -highlightthickness 0 \
313            -image [Rappture::icon zoom-out] \
314            -command [itcl::code $this Zoom out]
315    } {
316        usual
317        ignore -highlightthickness
318    }
319    pack $itk_component(zoomout) -side top -padx 2 -pady { 2 0 }
320    Rappture::Tooltip::for $itk_component(zoomout) "Zoom out"
321
322    itk_component add mode {
323        Rappture::PushButton $f.mode \
324            -onimage [Rappture::icon surface] \
325            -offimage [Rappture::icon surface] \
326            -variable [itcl::scope _settings(-isheightmap)] \
327            -command [itcl::code $this AdjustSetting -isheightmap] \
328    }
329    Rappture::Tooltip::for $itk_component(mode) \
330        "Toggle the surface/contour on/off"
331    pack $itk_component(mode) -padx 2 -pady { 2 0 }
332
333    itk_component add stretchtofit {
334        Rappture::PushButton $f.stretchtofit \
335            -onimage [Rappture::icon stretchtofit] \
336            -offimage [Rappture::icon stretchtofit] \
337            -variable [itcl::scope _settings(-stretchtofit)] \
338            -command [itcl::code $this AdjustSetting -stretchtofit] \
339    }
340    Rappture::Tooltip::for $itk_component(stretchtofit) \
341        "Stretch plot to fit window on/off"
342    pack $itk_component(stretchtofit) -padx 2 -pady 2
343
344    if { [catch {
345        BuildContourTab
346        BuildAxisTab
347        BuildCameraTab
348    } errs] != 0 } {
349        global errorInfo
350        puts stderr "errs=$errs errorInfo=$errorInfo"
351    }
352
353    # Hack around the Tk panewindow.  The problem is that the requested
354    # size of the 3d view isn't set until an image is retrieved from
355    # the server.  So the panewindow uses the tiny size.
356    set w 10000
357    pack forget $itk_component(view)
358    blt::table $itk_component(plotarea) \
359        0,0 $itk_component(view) -fill both -reqwidth $w
360    blt::table configure $itk_component(plotarea) c1 -resize none
361
362    # Bindings for panning via mouse
363    bind $itk_component(view) <ButtonPress-2> \
364        [itcl::code $this Pan click %x %y]
365    bind $itk_component(view) <B2-Motion> \
366        [itcl::code $this Pan drag %x %y]
367    bind $itk_component(view) <ButtonRelease-2> \
368        [itcl::code $this Pan release %x %y]
369
370    #bind $itk_component(view) <ButtonRelease-3> \
371    #    [itcl::code $this Pick %x %y]
372
373    # Bindings for panning via keyboard
374    bind $itk_component(view) <KeyPress-Left> \
375        [itcl::code $this Pan set -10 0]
376    bind $itk_component(view) <KeyPress-Right> \
377        [itcl::code $this Pan set 10 0]
378    bind $itk_component(view) <KeyPress-Up> \
379        [itcl::code $this Pan set 0 -10]
380    bind $itk_component(view) <KeyPress-Down> \
381        [itcl::code $this Pan set 0 10]
382    bind $itk_component(view) <Shift-KeyPress-Left> \
383        [itcl::code $this Pan set -2 0]
384    bind $itk_component(view) <Shift-KeyPress-Right> \
385        [itcl::code $this Pan set 2 0]
386    bind $itk_component(view) <Shift-KeyPress-Up> \
387        [itcl::code $this Pan set 0 -2]
388    bind $itk_component(view) <Shift-KeyPress-Down> \
389        [itcl::code $this Pan set 0 2]
390
391    # Bindings for zoom via keyboard
392    bind $itk_component(view) <KeyPress-Prior> \
393        [itcl::code $this Zoom out]
394    bind $itk_component(view) <KeyPress-Next> \
395        [itcl::code $this Zoom in]
396
397    bind $itk_component(view) <Enter> "focus $itk_component(view)"
398
399    if {[string equal "x11" [tk windowingsystem]]} {
400        # Bindings for zoom via mouse
401        bind $itk_component(view) <4> [itcl::code $this Zoom out]
402        bind $itk_component(view) <5> [itcl::code $this Zoom in]
403    }
404
405    set _image(download) [image create photo]
406    eval itk_initialize $args
407    Connect
408    set _beforeConnect 0
409}
410
411# ----------------------------------------------------------------------
412# DESTRUCTOR
413# ----------------------------------------------------------------------
414itcl::body Rappture::VtkHeightmapViewer::destructor {} {
415    Disconnect
416    image delete $_image(plot)
417    image delete $_image(download)
418    catch { blt::arcball destroy $_arcball }
419}
420
421itcl::body Rappture::VtkHeightmapViewer::DoResize {} {
422    if { $_width < 2 } {
423        set _width 500
424    }
425    if { $_height < 2 } {
426        set _height 500
427    }
428    set _start [clock clicks -milliseconds]
429    SendCmd "screen size [expr $_width - 20] $_height"
430
431    set font "Arial 8"
432    set lh [font metrics $font -linespace]
433    set h [expr {$_height - 2 * ($lh + 2)}]
434    if { $h != $_legendHeight } {
435        EventuallyRequestLegend
436    } else {
437        DrawLegend
438    }
439    set _resizePending 0
440}
441
442itcl::body Rappture::VtkHeightmapViewer::DoRotate {} {
443    set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
444    SendCmd "camera orient $q"
445    set _rotatePending 0
446}
447
448itcl::body Rappture::VtkHeightmapViewer::EventuallyRequestLegend {} {
449    if { !$_legendPending } {
450        set _legendPending 1
451        $_dispatcher event -idle !legend
452    }
453}
454
455itcl::body Rappture::VtkHeightmapViewer::EventuallyResize { w h } {
456    set _width $w
457    set _height $h
458    $_arcball resize $w $h
459    if { !$_resizePending } {
460        set _resizePending 1
461        $_dispatcher event -after 250 !resize
462    }
463}
464
465set rotate_delay 100
466
467itcl::body Rappture::VtkHeightmapViewer::EventuallyRotate { q } {
468    foreach { _view(qw) _view(qx) _view(qy) _view(qz) } $q break
469    if { !$_rotatePending } {
470        set _rotatePending 1
471        global rotate_delay
472        $_dispatcher event -after $rotate_delay !rotate
473    }
474}
475
476# ----------------------------------------------------------------------
477# USAGE: add <dataobj> ?<settings>?
478#
479# Clients use this to add a data object to the plot.  The optional
480# <settings> are used to configure the plot.  Allowed settings are
481# -color, -brightness, -width, -linestyle, and -raise.
482# ----------------------------------------------------------------------
483itcl::body Rappture::VtkHeightmapViewer::add {dataobj {settings ""}} {
484    if { ![$dataobj isvalid] } {
485        return;                         # Object doesn't contain valid data.
486    }
487    array set params {
488        -color auto
489        -width 1
490        -linestyle solid
491        -brightness 0
492        -raise 0
493        -description ""
494        -param ""
495        -type ""
496    }
497    array set params $settings
498    set params(-description) ""
499    set params(-param) ""
500    array set params $settings
501
502    if {$params(-color) == "auto" || $params(-color) == "autoreset"} {
503        # can't handle -autocolors yet
504        set params(-color) white
505    }
506    set pos [lsearch -exact $_dlist $dataobj]
507    if {$pos < 0} {
508        lappend _dlist $dataobj
509    }
510    set _obj2ovride($dataobj-color) $params(-color)
511    set _obj2ovride($dataobj-width) $params(-width)
512    set _obj2ovride($dataobj-raise) $params(-raise)
513    $_dispatcher event -idle !rebuild
514}
515
516
517# ----------------------------------------------------------------------
518# USAGE: delete ?<dataobj1> <dataobj2> ...?
519#
520#       Clients use this to delete a dataobj from the plot.  If no dataobjs
521#       are specified, then all dataobjs are deleted.  No data objects are
522#       deleted.  They are only removed from the display list.
523#
524# ----------------------------------------------------------------------
525itcl::body Rappture::VtkHeightmapViewer::delete {args} {
526    if { [llength $args] == 0} {
527        set args $_dlist
528    }
529    # Delete all specified dataobjs
530    set changed 0
531    foreach dataobj $args {
532        set pos [lsearch -exact $_dlist $dataobj]
533        if { $pos < 0 } {
534            continue;                   # Don't know anything about it.
535        }
536        # Remove it from the dataobj list.
537        set _dlist [lreplace $_dlist $pos $pos]
538        array unset _obj2ovride $dataobj-*
539        array unset _settings $dataobj-*
540        set changed 1
541    }
542    # If anything changed, then rebuild the plot
543    if { $changed } {
544        $_dispatcher event -idle !rebuild
545    }
546}
547
548# ----------------------------------------------------------------------
549# USAGE: get ?-objects?
550# USAGE: get ?-visible?
551# USAGE: get ?-image view?
552#
553# Clients use this to query the list of objects being plotted, in
554# order from bottom to top of this result.  The optional "-image"
555# flag can also request the internal images being shown.
556# ----------------------------------------------------------------------
557itcl::body Rappture::VtkHeightmapViewer::get {args} {
558    if {[llength $args] == 0} {
559        set args "-objects"
560    }
561    set op [lindex $args 0]
562    switch -- $op {
563        "-objects" {
564            # put the dataobj list in order according to -raise options
565            set dlist {}
566            foreach dataobj $_dlist {
567                if { ![IsValidObject $dataobj] } {
568                    continue
569                }
570                if {[info exists _obj2ovride($dataobj-raise)] &&
571                    $_obj2ovride($dataobj-raise)} {
572                    set dlist [linsert $dlist 0 $dataobj]
573                } else {
574                    lappend dlist $dataobj
575                }
576            }
577            return $dlist
578        }
579        "-visible" {
580            set dlist {}
581            foreach dataobj $_dlist {
582                if { ![IsValidObject $dataobj] } {
583                    continue
584                }
585                if { ![info exists _obj2ovride($dataobj-raise)] } {
586                    # No setting indicates that the object isn't visible.
587                    continue
588                }
589                # Otherwise use the -raise parameter to put the object to
590                # the front of the list.
591                if { $_obj2ovride($dataobj-raise) } {
592                    set dlist [linsert $dlist 0 $dataobj]
593                } else {
594                    lappend dlist $dataobj
595                }
596            }
597            return $dlist
598        }           
599        -image {
600            if {[llength $args] != 2} {
601                error "wrong # args: should be \"get -image view\""
602            }
603            switch -- [lindex $args end] {
604                view {
605                    return $_image(plot)
606                }
607                default {
608                    error "bad image name \"[lindex $args end]\": should be view"
609                }
610            }
611        }
612        default {
613            error "bad option \"$op\": should be -objects or -image"
614        }
615    }
616}
617
618#
619# scale  --
620#
621#       This gets called either incrementally as new simulations are
622#       added or all at once as a sequence of heightmaps.
623#       This  accounts for all objects--even those not showing on the
624#       screen.  Because of this, the limits are appropriate for all
625#       objects as the user scans through data in the ResultSet viewer.
626#
627itcl::body Rappture::VtkHeightmapViewer::scale {args} {
628    foreach dataobj $args {
629        if { ![$dataobj isvalid] } {
630            continue;                   # Object doesn't contain valid data.
631        }
632        foreach axis { x y } {
633            set lim [$dataobj limits $axis]
634            if { ![info exists _limits($axis)] } {
635                set _limits($axis) $lim
636                continue
637            }
638            foreach {min max} $lim break
639            foreach {amin amax} $_limits($axis) break
640            if { $amin > $min } {
641                set amin $min
642            }
643            if { $amax < $max } {
644                set amax $max
645            }
646            set _limits($axis) [list $amin $amax]
647            set units [$dataobj hints ${axis}units]
648            set found($units) 1
649        }
650        foreach { fname lim } [$dataobj fieldlimits] {
651            if { ![info exists _limits($fname)] } {
652                set _limits($fname) $lim
653                continue
654            }
655            foreach {min max} $lim break
656            foreach {fmin fmax} $_limits($fname) break
657            if { $fmin > $min } {
658                set fmin $min
659            }
660            if { $fmax < $max } {
661                set fmax $max
662            }
663            set _limits($fname) [list $fmin $fmax]
664        }
665    }
666    if { [array size found] > 1 } {
667        set _settings(-stretchtofit) 1
668    } else {
669        # Check if the range of the x and y axes requires that we stretch
670        # the contour to fit the plotting area.  This can happen when the
671        # x and y scales differ greatly (> 100x)
672        foreach {xmin xmax} $_limits(x) break
673        foreach {ymin ymax} $_limits(y) break
674        if { (($xmax - $xmin) > (($ymax -$ymin) * $_maxScale)) ||
675             ((($xmax - $xmin) * $_maxScale) < ($ymax -$ymin)) } {
676            set _settings(-stretchtofit) 1
677        }
678    }
679}
680
681# ----------------------------------------------------------------------
682# USAGE: download coming
683# USAGE: download controls <downloadCommand>
684# USAGE: download now
685#
686# Clients use this method to create a downloadable representation
687# of the plot.  Returns a list of the form {ext string}, where
688# "ext" is the file extension (indicating the type of data) and
689# "string" is the data itself.
690# ----------------------------------------------------------------------
691itcl::body Rappture::VtkHeightmapViewer::download {option args} {
692    switch $option {
693        coming {
694            if {[catch {
695                blt::winop snap $itk_component(plotarea) $_image(download)
696            }]} {
697                $_image(download) configure -width 1 -height 1
698                $_image(download) put #000000
699            }
700        }
701        controls {
702            set popup .vtkviewerdownload
703            if { ![winfo exists .vtkviewerdownload] } {
704                set inner [BuildDownloadPopup $popup [lindex $args 0]]
705            } else {
706                set inner [$popup component inner]
707            }
708            set _downloadPopup(image_controls) $inner.image_frame
709            set num [llength [get]]
710            set num [expr {($num == 1) ? "1 result" : "$num results"}]
711            set word [Rappture::filexfer::label downloadWord]
712            $inner.summary configure -text "$word $num in the following format:"
713            update idletasks            ;# Fix initial sizes
714            return $popup
715        }
716        now {
717            set popup .vtkviewerdownload
718            if {[winfo exists .vtkviewerdownload]} {
719                $popup deactivate
720            }
721            switch -- $_downloadPopup(format) {
722                "image" {
723                    return [$this GetImage [lindex $args 0]]
724                }
725                "vtk" {
726                    return [$this GetVtkData [lindex $args 0]]
727                }
728            }
729            return ""
730        }
731        default {
732            error "bad option \"$option\": should be coming, controls, now"
733        }
734    }
735}
736
737# ----------------------------------------------------------------------
738# USAGE: Connect ?<host:port>,<host:port>...?
739#
740# Clients use this method to establish a connection to a new
741# server, or to reestablish a connection to the previous server.
742# Any existing connection is automatically closed.
743# ----------------------------------------------------------------------
744itcl::body Rappture::VtkHeightmapViewer::Connect {} {
745    global readyForNextFrame
746    set readyForNextFrame 1
747    set _reset 1
748    set _hosts [GetServerList "vtkvis"]
749    if { "" == $_hosts } {
750        return 0
751    }
752    set result [VisViewer::Connect $_hosts]
753    if { $result } {
754        if { $_reportClientInfo }  {
755            # Tell the server the viewer, hub, user and session.
756            # Do this immediately on connect before buffering any commands
757            global env
758
759            set info {}
760            set user "???"
761            if { [info exists env(USER)] } {
762                set user $env(USER)
763            }
764            set session "???"
765            if { [info exists env(SESSION)] } {
766                set session $env(SESSION)
767            }
768            lappend info "version" "$Rappture::version"
769            lappend info "build" "$Rappture::build"
770            lappend info "svnurl" "$Rappture::svnurl"
771            lappend info "installdir" "$Rappture::installdir"
772            lappend info "hub" [exec hostname]
773            lappend info "client" "vtkheightmapviewer"
774            lappend info "user" $user
775            lappend info "session" $session
776            SendCmd "clientinfo [list $info]"
777        }
778        set w [winfo width $itk_component(view)]
779        set h [winfo height $itk_component(view)]
780        EventuallyResize $w $h
781    }
782    return $result
783}
784
785#
786# isconnected --
787#
788#       Indicates if we are currently connected to the visualization server.
789#
790itcl::body Rappture::VtkHeightmapViewer::isconnected {} {
791    return [VisViewer::IsConnected]
792}
793
794#
795# disconnect --
796#
797itcl::body Rappture::VtkHeightmapViewer::disconnect {} {
798    Disconnect
799    set _reset 1
800}
801
802#
803# Disconnect --
804#
805#       Clients use this method to disconnect from the current rendering
806#       server.
807#
808itcl::body Rappture::VtkHeightmapViewer::Disconnect {} {
809    VisViewer::Disconnect
810
811    $_dispatcher cancel !rebuild
812    $_dispatcher cancel !resize
813    $_dispatcher cancel !rotate
814    $_dispatcher cancel !legend
815    # disconnected -- no more data sitting on server
816    array unset _datasets
817    array unset _data
818    array unset _colormaps
819    array unset _obj2datasets
820    global readyForNextFrame
821    set readyForNextFrame 1
822}
823
824# ----------------------------------------------------------------------
825# USAGE: ReceiveImage -bytes <size> -type <type> -token <token>
826#
827# Invoked automatically whenever the "image" command comes in from
828# the rendering server.  Indicates that binary image data with the
829# specified <size> will follow.
830# ----------------------------------------------------------------------
831itcl::body Rappture::VtkHeightmapViewer::ReceiveImage { args } {
832    global readyForNextFrame
833    set readyForNextFrame 1
834    array set info {
835        -token "???"
836        -bytes 0
837        -type image
838    }
839    array set info $args
840    set bytes [ReceiveBytes $info(-bytes)]
841    if { $info(-type) == "image" } {
842        if 0 {
843            set f [open "last.ppm" "w"]
844            puts $f $bytes
845            close $f
846        }
847        $_image(plot) configure -data $bytes
848        set time [clock seconds]
849        set date [clock format $time]
850        #puts stderr "$date: received image [image width $_image(plot)]x[image height $_image(plot)] image>"       
851        if { $_start > 0 } {
852            set finish [clock clicks -milliseconds]
853            #puts stderr "round trip time [expr $finish -$_start] milliseconds"
854            set _start 0
855        }
856    } elseif { $info(type) == "print" } {
857        set tag $this-print-$info(-token)
858        set _hardcopy($tag) $bytes
859    }
860}
861
862#
863# ReceiveDataset --
864#
865itcl::body Rappture::VtkHeightmapViewer::ReceiveDataset { args } {
866    if { ![isconnected] } {
867        return
868    }
869    set option [lindex $args 0]
870    switch -- $option {
871        "scalar" {
872            set option [lindex $args 1]
873            switch -- $option {
874                "world" {
875                    foreach { x y z value tag } [lrange $args 2 end] break
876                }
877                "pixel" {
878                    foreach { x y value tag } [lrange $args 2 end] break
879                }
880            }
881        }
882        "vector" {
883            set option [lindex $args 1]
884            switch -- $option {
885                "world" {
886                    foreach { x y z vx vy vz tag } [lrange $args 2 end] break
887                }
888                "pixel" {
889                    foreach { x y vx vy vz tag } [lrange $args 2 end] break
890                }
891            }
892        }
893        "names" {
894            foreach { name } [lindex $args 1] {
895                #puts stderr "Dataset: $name"
896            }
897        }
898        default {
899            error "unknown dataset option \"$option\" from server"
900        }
901    }
902}
903
904# ----------------------------------------------------------------------
905# USAGE: Rebuild
906#
907# Called automatically whenever something changes that affects the
908# data in the widget.  Clears any existing data and rebuilds the
909# widget to display new data.
910# ----------------------------------------------------------------------
911itcl::body Rappture::VtkHeightmapViewer::Rebuild {} {
912    set w [winfo width $itk_component(view)]
913    set h [winfo height $itk_component(view)]
914    if { $w < 2 || $h < 2 } {
915        $_dispatcher event -idle !rebuild
916        return
917    }
918
919    # Turn on buffering of commands to the server.  We don't want to
920    # be preempted by a server disconnect/reconnect (which automatically
921    # generates a new call to Rebuild).   
922    StartBufferingCommands
923
924    if { $_width != $w || $_height != $h || $_reset } {
925        set _width $w
926        set _height $h
927        $_arcball resize $w $h
928        DoResize
929        if { $_settings(-stretchtofit) } {
930            AdjustSetting -stretchtofit
931        }
932    }
933    if { $_reset } {
934        #
935        # Reset the camera and other view parameters
936        #
937        InitSettings -isheightmap -background
938
939        # Setting a custom exponent and label format for axes is causing
940        # a problem with rounding.  Near zero ticks aren't rounded by
941        # the %g format.  The VTK CubeAxes seem to currently work best
942        # when allowed to automatically set the exponent and precision
943        # based on the axis ranges.  This does tend to result in less
944        # visual clutter, so I think it is best to use the automatic
945        # settings by default.  We can test more fine-grained
946        # controls on the axis settings tab if necessary.
947        # -Leif
948        #SendCmd "axis exp 0 0 0 1"
949
950        SendCmd "axis lrot z 90"
951        set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
952        $_arcball quaternion $q
953        if {$_settings(-isheightmap) } {
954            if { $_view(ortho)} {
955                SendCmd "camera mode ortho"
956            } else {
957                SendCmd "camera mode persp"
958            }
959            DoRotate
960            SendCmd "camera reset"
961        }
962        PanCamera
963        StopBufferingCommands
964        SendCmd "imgflush"
965        StartBufferingCommands
966    }
967
968    set _first ""
969    # Start off with no datasets are visible.
970    SendCmd "dataset visible 0"
971    set scale [GetHeightmapScale]
972    foreach dataobj [get -objects] {
973        if { [info exists _obj2ovride($dataobj-raise)] &&  $_first == "" } {
974            set _first $dataobj
975        }
976        set _obj2datasets($dataobj) ""
977        foreach comp [$dataobj components] {
978            set tag $dataobj-$comp
979            if { ![info exists _datasets($tag)] } {
980                set bytes [$dataobj vtkdata $comp]
981                if 0 {
982                    set f [open /tmp/vtkheightmap.vtk "w"]
983                    puts $f $bytes
984                    close $f
985                }
986                set length [string length $bytes]
987                if { $_reportClientInfo }  {
988                    set info {}
989                    lappend info "tool_id"       [$dataobj hints toolid]
990                    lappend info "tool_name"     [$dataobj hints toolname]
991                    lappend info "tool_title"    [$dataobj hints tooltitle]
992                    lappend info "tool_command"  [$dataobj hints toolcommand]
993                    lappend info "tool_revision" [$dataobj hints toolrevision]
994                    lappend info "dataset_label" [$dataobj hints label]
995                    lappend info "dataset_size"  $length
996                    lappend info "dataset_tag"   $tag
997                    SendCmd [list "clientinfo" $info]
998                }
999                SendCmd "dataset add $tag data follows $length"
1000                append _outbuf $bytes
1001                set _datasets($tag) 1
1002                SetObjectStyle $dataobj $comp
1003            }
1004            lappend _obj2datasets($dataobj) $tag
1005            if { [info exists _obj2ovride($dataobj-raise)] } {
1006                # Setting dataset visible enables outline
1007                # and heightmap
1008                SendCmd "dataset visible 1 $tag"
1009            }
1010            if { ![info exists _comp2scale($tag)] ||
1011                 $_comp2scale($tag) != $scale } {
1012                SendCmd "heightmap heightscale $scale $tag"
1013                set _comp2scale($tag) $scale
1014            }
1015        }
1016    }
1017    if { $_first != ""  } {
1018        $itk_component(field) choices delete 0 end
1019        $itk_component(fieldmenu) delete 0 end
1020        array unset _fields
1021        set _curFldName ""
1022        foreach cname [$_first components] {
1023            foreach fname [$_first fieldnames $cname] {
1024                if { [info exists _fields($fname)] } {
1025                    continue
1026                }
1027                foreach { label units components } \
1028                    [$_first fieldinfo $fname] break
1029                $itk_component(field) choices insert end "$fname" "$label"
1030                $itk_component(fieldmenu) add radiobutton -label "$label" \
1031                    -value $label -variable [itcl::scope _curFldLabel] \
1032                    -selectcolor red \
1033                    -activebackground $itk_option(-plotbackground) \
1034                    -activeforeground $itk_option(-plotforeground) \
1035                    -font "Arial 8" \
1036                    -command [itcl::code $this Combo invoke]
1037                set _fields($fname) [list $label $units $components]
1038                if { $_curFldName == "" } {
1039                    set _curFldName $fname
1040                    set _curFldLabel $label
1041                }
1042            }
1043        }
1044        $itk_component(field) value $_curFldLabel
1045    }
1046    InitSettings -stretchtofit -outline
1047
1048    if { $_reset } {
1049        SendCmd "axis tickpos outside"
1050        #SendCmd "axis lformat all %g"
1051       
1052        foreach axis { x y z } {
1053            if { $axis == "z" } {
1054                set label [$_first hints label]
1055            } else {
1056                set label [$_first hints ${axis}label]
1057            }
1058            if { $label == "" } {
1059                if {$axis == "z"} {
1060                    if { [string match "component*" $_curFldName] } {
1061                        set label [string toupper $axis]
1062                    } else {
1063                        set label $_curFldLabel
1064                    }
1065                } else {
1066                    set label [string toupper $axis]
1067                }
1068            }
1069            # May be a space in the axis label.
1070            SendCmd [list axis name $axis $label]
1071
1072            if {$axis == "z" && [$_first hints ${axis}units] == ""} {
1073                if {$_curFldName != ""} {
1074                    set units [lindex $_fields($_curFldName) 1]
1075                }
1076            } else {
1077                set units [$_first hints ${axis}units]
1078            }
1079            if { $units != "" } {
1080                # May be a space in the axis units.
1081                SendCmd [list axis units $axis $units]
1082            }
1083        }
1084        #
1085        # Reset the camera and other view parameters
1086        #
1087        ResetAxes
1088        set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
1089        $_arcball quaternion $q
1090        if {$_settings(-isheightmap) } {
1091            if { $_view(ortho)} {
1092                SendCmd "camera mode ortho"
1093            } else {
1094                SendCmd "camera mode persp"
1095            }
1096            DoRotate
1097            SendCmd "camera reset"
1098        }
1099        PanCamera
1100        InitSettings -xgrid -ygrid -zgrid \
1101            -axisvisible -axislabels -heightmapscale -field -isheightmap \
1102            -numisolines
1103        if { [array size _fields] < 2 } {
1104            catch {blt::table forget $itk_component(field) $itk_component(field_l)}
1105        }
1106        RequestLegend
1107        set _reset 0
1108    }
1109    global readyForNextFrame
1110    set readyForNextFrame 0;            # Don't advance to the next frame
1111
1112    # Actually write the commands to the server socket.  If it fails, we don't
1113    # care.  We're finished here.
1114    blt::busy hold $itk_component(hull)
1115    StopBufferingCommands
1116    blt::busy release $itk_component(hull)
1117}
1118
1119# ----------------------------------------------------------------------
1120# USAGE: CurrentDatasets ?-all -visible? ?dataobjs?
1121#
1122# Returns a list of server IDs for the current datasets being displayed.  This
1123# is normally a single ID, but it might be a list of IDs if the current data
1124# object has multiple components.
1125# ----------------------------------------------------------------------
1126itcl::body Rappture::VtkHeightmapViewer::CurrentDatasets {args} {
1127    set flag [lindex $args 0]
1128    switch -- $flag {
1129        "-all" {
1130            if { [llength $args] > 1 } {
1131                error "CurrentDatasets: can't specify dataobj after \"-all\""
1132            }
1133            set dlist [get -objects]
1134        }
1135        "-visible" {
1136            if { [llength $args] > 1 } {
1137                set dlist {}
1138                set args [lrange $args 1 end]
1139                foreach dataobj $args {
1140                    if { [info exists _obj2ovride($dataobj-raise)] } {
1141                        lappend dlist $dataobj
1142                    }
1143                }
1144            } else {
1145                set dlist [get -visible]
1146            }
1147        }           
1148        default {
1149            set dlist $args
1150        }
1151    }
1152    set rlist ""
1153    foreach dataobj $dlist {
1154        foreach comp [$dataobj components] {
1155            set tag $dataobj-$comp
1156            if { [info exists _datasets($tag)] && $_datasets($tag) } {
1157                lappend rlist $tag
1158            }
1159        }
1160    }
1161    return $rlist
1162}
1163
1164itcl::body Rappture::VtkHeightmapViewer::CameraReset {} {
1165    array set _view {
1166        qw      0.36
1167        qx      0.25
1168        qy      0.50
1169        qz      0.70
1170        zoom    1.0
1171        xpan    0
1172        ypan    0
1173    }
1174    if { $_first != "" } {
1175        set location [$_first hints camera]
1176        if { $location != "" } {
1177            array set _view $location
1178        }
1179    }
1180    set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
1181    $_arcball quaternion $q
1182    if {$_settings(-isheightmap) } {
1183        DoRotate
1184    }
1185    SendCmd "camera reset"
1186}
1187
1188# ----------------------------------------------------------------------
1189# USAGE: Zoom in
1190# USAGE: Zoom out
1191# USAGE: Zoom reset
1192#
1193# Called automatically when the user clicks on one of the zoom
1194# controls for this widget.  Changes the zoom for the current view.
1195# ----------------------------------------------------------------------
1196itcl::body Rappture::VtkHeightmapViewer::Zoom {option} {
1197    switch -- $option {
1198        "in" {
1199            set _view(zoom) [expr {$_view(zoom)*1.25}]
1200            SendCmd "camera zoom $_view(zoom)"
1201        }
1202        "out" {
1203            set _view(zoom) [expr {$_view(zoom)*0.8}]
1204            SendCmd "camera zoom $_view(zoom)"
1205        }
1206        "reset" {
1207            array set _view {
1208                zoom    1.0
1209                xpan    0
1210                ypan    0
1211            }
1212            SendCmd "camera reset"
1213        }
1214    }
1215}
1216
1217itcl::body Rappture::VtkHeightmapViewer::PanCamera {} {
1218    set x $_view(xpan)
1219    set y $_view(ypan)
1220    SendCmd "camera pan $x $y"
1221}
1222
1223
1224# ----------------------------------------------------------------------
1225# USAGE: Rotate click <x> <y>
1226# USAGE: Rotate drag <x> <y>
1227# USAGE: Rotate release <x> <y>
1228#
1229# Called automatically when the user clicks/drags/releases in the
1230# plot area.  Moves the plot according to the user's actions.
1231# ----------------------------------------------------------------------
1232itcl::body Rappture::VtkHeightmapViewer::Rotate {option x y} {
1233    switch -- $option {
1234        "click" {
1235            $itk_component(view) configure -cursor fleur
1236            set _click(x) $x
1237            set _click(y) $y
1238        }
1239        "drag" {
1240            if {[array size _click] == 0} {
1241                Rotate click $x $y
1242            } else {
1243                set w [winfo width $itk_component(view)]
1244                set h [winfo height $itk_component(view)]
1245                if {$w <= 0 || $h <= 0} {
1246                    return
1247                }
1248
1249                if {[catch {
1250                    # this fails sometimes for no apparent reason
1251                    set dx [expr {double($x-$_click(x))/$w}]
1252                    set dy [expr {double($y-$_click(y))/$h}]
1253                }]} {
1254                    return
1255                }
1256                if { $dx == 0 && $dy == 0 } {
1257                    return
1258                }
1259                set q [$_arcball rotate $x $y $_click(x) $_click(y)]
1260                EventuallyRotate $q
1261                set _click(x) $x
1262                set _click(y) $y
1263            }
1264        }
1265        "release" {
1266            Rotate drag $x $y
1267            $itk_component(view) configure -cursor ""
1268            catch {unset _click}
1269        }
1270        default {
1271            error "bad option \"$option\": should be click, drag, release"
1272        }
1273    }
1274}
1275
1276itcl::body Rappture::VtkHeightmapViewer::Pick {x y} {
1277    foreach tag [CurrentDatasets -visible] {
1278        SendCmd "dataset getscalar pixel $x $y $tag"
1279    }
1280}
1281
1282# ----------------------------------------------------------------------
1283# USAGE: $this Pan click x y
1284#        $this Pan drag x y
1285#        $this Pan release x y
1286#
1287# Called automatically when the user clicks on one of the zoom
1288# controls for this widget.  Changes the zoom for the current view.
1289# ----------------------------------------------------------------------
1290itcl::body Rappture::VtkHeightmapViewer::Pan {option x y} {
1291    switch -- $option {
1292        "set" {
1293            set w [winfo width $itk_component(view)]
1294            set h [winfo height $itk_component(view)]
1295            set x [expr $x / double($w)]
1296            set y [expr $y / double($h)]
1297            set _view(xpan) [expr $_view(xpan) + $x]
1298            set _view(ypan) [expr $_view(ypan) + $y]
1299            PanCamera
1300            return
1301        }
1302        "click" {
1303            set _click(x) $x
1304            set _click(y) $y
1305            $itk_component(view) configure -cursor hand1
1306        }
1307        "drag" {
1308            if { ![info exists _click(x)] } {
1309                set _click(x) $x
1310            }
1311            if { ![info exists _click(y)] } {
1312                set _click(y) $y
1313            }
1314            set w [winfo width $itk_component(view)]
1315            set h [winfo height $itk_component(view)]
1316            set dx [expr ($_click(x) - $x)/double($w)]
1317            set dy [expr ($_click(y) - $y)/double($h)]
1318            set _click(x) $x
1319            set _click(y) $y
1320            set _view(xpan) [expr $_view(xpan) - $dx]
1321            set _view(ypan) [expr $_view(ypan) - $dy]
1322            PanCamera
1323        }
1324        "release" {
1325            Pan drag $x $y
1326            $itk_component(view) configure -cursor ""
1327        }
1328        default {
1329            error "unknown option \"$option\": should set, click, drag, or release"
1330        }
1331    }
1332}
1333
1334# ----------------------------------------------------------------------
1335# USAGE: InitSettings <what> ?<value>?
1336#
1337# Used internally to update rendering settings whenever parameters
1338# change in the popup settings panel.  Sends the new settings off
1339# to the back end.
1340# ----------------------------------------------------------------------
1341itcl::body Rappture::VtkHeightmapViewer::InitSettings { args } {
1342    foreach spec $args {
1343        if { [info exists _settings($_first${spec})] } {
1344            # Reset global setting with dataobj specific setting
1345            set _settings($spec) $_settings($_first${spec})
1346        }
1347        AdjustSetting $spec
1348    }
1349}
1350
1351#
1352# AdjustSetting --
1353#
1354#       Changes/updates a specific setting in the widget.  There are
1355#       usually user-setable option.  Commands are sent to the render
1356#       server.
1357#
1358itcl::body Rappture::VtkHeightmapViewer::AdjustSetting {what {value ""}} {
1359    if { $_beforeConnect } {
1360        return
1361    }
1362    switch -- $what {
1363        "-axisflymode" {
1364            set mode [$itk_component(axisflymode) value]
1365            set mode [$itk_component(axisflymode) translate $mode]
1366            set _settings($what) $mode
1367            SendCmd "axis flymode $mode"
1368        }
1369        "-axislabels" {
1370            set bool $_settings($what)
1371            SendCmd "axis labels all $bool"
1372        }
1373        "-axisminorticks" {
1374            set bool $_settings($what)
1375            SendCmd "axis minticks all $bool"
1376        }
1377        "-axisvisible" {
1378            set bool $_settings($what)
1379            SendCmd "axis visible all $bool"
1380        }
1381        "-xgrid" - "-ygrid" - "-zgrid" {
1382            set axis [string tolower [string range $what 1 1]]
1383            set bool $_settings($what)
1384            SendCmd "axis grid $axis $bool"
1385        }
1386        "-background" {
1387            set bg [$itk_component(background) value]
1388            array set fgcolors {
1389                "black" "white"
1390                "white" "black"
1391                "grey"  "black"
1392            }
1393            set fg $fgcolors($bg)
1394            configure -plotbackground $bg -plotforeground $fg
1395            $itk_component(view) delete "legend"
1396            SendCmd "screen bgcolor [Color2RGB $bg]"
1397            SendCmd "outline color [Color2RGB $fg]"
1398            SendCmd "axis color all [Color2RGB $fg]"
1399            DrawLegend
1400        }
1401        "-colormap" {
1402            set _changed($what) 1
1403            StartBufferingCommands
1404            set color [$itk_component(colormap) value]
1405            set _settings($what) $color
1406            if { $color == "none" } {
1407                if { $_settings(-colormapvisible) } {
1408                    SendCmd "heightmap surface 0"
1409                    set _settings(-colormapvisible) 0
1410                }
1411            } else {
1412                if { !$_settings(-colormapvisible) } {
1413                    SendCmd "heightmap surface 1"
1414                    set _settings(-colormapvisible) 1
1415                }
1416                SetCurrentColormap $color
1417                if {$_settings(-colormapdiscrete)} {
1418                    set numColors [expr $_settings(-numisolines) + 1]
1419                    SendCmd "colormap res $numColors $color"
1420                }
1421            }
1422            StopBufferingCommands
1423            EventuallyRequestLegend
1424        }
1425        "-colormapvisible" {
1426            set bool $_settings($what)
1427            SendCmd "heightmap surface $bool"
1428        }
1429        "-colormapdiscrete" {
1430            set bool $_settings($what)
1431            set numColors [expr $_settings(-numisolines) + 1]
1432            StartBufferingCommands
1433            if {$bool} {
1434                SendCmd "colormap res $numColors"
1435                # Discrete colormap requires preinterp on
1436                SendCmd "heightmap preinterp on"
1437            } else {
1438                SendCmd "colormap res default"
1439                # FIXME: add setting for preinterp (default on)
1440                SendCmd "heightmap preinterp on"
1441            }
1442            StopBufferingCommands
1443            EventuallyRequestLegend
1444        }
1445        "-edges" {
1446            set bool $_settings($what)
1447            SendCmd "heightmap edges $bool"
1448        }
1449        "-field" {
1450            set label [$itk_component(field) value]
1451            set fname [$itk_component(field) translate $label]
1452            set _settings($what) $fname
1453            if { [info exists _fields($fname)] } {
1454                foreach { label units components } $_fields($fname) break
1455                if { $components > 1 } {
1456                    set _colorMode vmag
1457                } else {
1458                    set _colorMode scalar
1459                }
1460                set _curFldName $fname
1461                set _curFldLabel $label
1462            } else {
1463                puts stderr "unknown field \"$fname\""
1464                return
1465            }
1466            set label [$_first hints label]
1467            if { $label == "" } {
1468                if { [string match "component*" $_curFldName] } {
1469                    set label Z
1470                } else {
1471                    set label $_curFldLabel
1472                }
1473            }
1474            # May be a space in the axis label.
1475            SendCmd [list axis name z $label]
1476
1477            if { [$_first hints zunits] == "" } {
1478                set units [lindex $_fields($_curFldName) 1]
1479            } else {
1480                set units [$_first hints zunits]
1481            }
1482            if { $units != "" } {
1483                # May be a space in the axis units.
1484                SendCmd [list axis units z $units]
1485            }
1486            # Get the new limits because the field changed.
1487            ResetAxes
1488            SendCmd "dataset scalar $_curFldName"
1489            SendCmd "heightmap colormode scalar $_curFldName"
1490            Zoom reset
1491            UpdateContourList
1492            DrawLegend
1493        }
1494        "-heightmapscale" {
1495            if { $_settings(-isheightmap) } {
1496                set scale [GetHeightmapScale]
1497                # Have to set the datasets individually because we are
1498                # tracking them in _comp2scale.
1499                foreach dataset [CurrentDatasets -all] {
1500                    SendCmd "heightmap heightscale $scale $dataset"
1501                    set _comp2scale($dataset) $scale
1502                }
1503                ResetAxes
1504            }
1505        }
1506        "-isheightmap" {
1507            set bool $_settings($what)
1508            set c $itk_component(view)
1509            StartBufferingCommands
1510            # Fix heightmap scale: 0 for contours, 1 for heightmaps.
1511            if { $bool } {
1512                set _settings(-heightmapscale) 50
1513                set _settings(-opacity) $_settings(-saveopacity)
1514                set _settings(-lighting) $_settings(-savelighting)
1515                set _settings(-outline) 0
1516            } else {
1517                set _settings(-heightmapscale) 0
1518                set _settings(-lighting) 0
1519                set _settings(-opacity) 100
1520                set _settings(-outline)  $_settings(-saveoutline)
1521            }
1522            InitSettings -lighting -opacity -outline
1523            set scale [GetHeightmapScale]
1524            # Have to set the datasets individually because we are
1525            # tracking them in _comp2scale.
1526            foreach dataset [CurrentDatasets -all] {
1527                SendCmd "heightmap heightscale $scale $dataset"
1528                set _comp2scale($dataset) $scale
1529            }
1530            if { $bool } {
1531                $itk_component(lighting) configure -state normal
1532                $itk_component(opacity) configure -state normal
1533                $itk_component(scale) configure -state normal
1534                $itk_component(opacity_l) configure -state normal
1535                $itk_component(scale_l) configure -state normal
1536                $itk_component(outline) configure -state disabled
1537                if {$_view(ortho)} {
1538                    SendCmd "camera mode ortho"
1539                } else {
1540                    SendCmd "camera mode persp"
1541                }
1542            } else {
1543                $itk_component(lighting) configure -state disabled
1544                $itk_component(opacity) configure -state disabled
1545                $itk_component(scale) configure -state disabled
1546                $itk_component(opacity_l) configure -state disabled
1547                $itk_component(scale_l) configure -state disabled
1548                $itk_component(outline) configure -state normal
1549                SendCmd "camera mode image"
1550            }
1551            if {$_settings(-stretchtofit)} {
1552                if {$scale == 0} {
1553                    SendCmd "camera aspect window"
1554                } else {
1555                    SendCmd "camera aspect square"
1556                }
1557            }
1558            ResetAxes
1559            if { $bool } {
1560                set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
1561                $_arcball quaternion $q
1562                SendCmd "camera orient $q"
1563            } else {
1564                bind $c <ButtonPress-1> {}
1565                bind $c <B1-Motion> {}
1566                bind $c <ButtonRelease-1> {}
1567            }
1568            Zoom reset
1569            # Fix the mouse bindings for rotation/panning and the
1570            # camera mode. Ideally we'd create a bindtag for these.
1571            if { $bool } {
1572                # Bindings for rotation via mouse
1573                bind $c <ButtonPress-1> \
1574                    [itcl::code $this Rotate click %x %y]
1575                bind $c <B1-Motion> \
1576                    [itcl::code $this Rotate drag %x %y]
1577                bind $c <ButtonRelease-1> \
1578                    [itcl::code $this Rotate release %x %y]
1579            }
1580            StopBufferingCommands
1581        }
1582        "-isolinecolor" {
1583            set color [$itk_component(isolinecolor) value]
1584            if { $color == "none" } {
1585                if { $_settings(-isolinesvisible) } {
1586                    SendCmd "heightmap isolines 0"
1587                    set _settings(-isolinesvisible) 0
1588                }
1589            } else {
1590                if { !$_settings(-isolinesvisible) } {
1591                    SendCmd "heightmap isolines 1"
1592                    set _settings(-isolinesvisible) 1
1593                }
1594                SendCmd "heightmap isolinecolor [Color2RGB $color]"
1595            }
1596            DrawLegend
1597        }
1598        "-isolinesvisible" {
1599            set bool $_settings($what)
1600            SendCmd "heightmap isolines $bool"
1601            DrawLegend
1602        }
1603        "-legendvisible" {
1604            if { !$_settings($what) } {
1605                $itk_component(view) delete legend
1606            }
1607            DrawLegend
1608        }
1609        "-lighting" {
1610            if { $_settings(-isheightmap) } {
1611                set _settings(-savelighting) $_settings($what)
1612                set bool $_settings($what)
1613                SendCmd "heightmap lighting $bool"
1614            } else {
1615                SendCmd "heightmap lighting 0"
1616            }
1617        }
1618        "-numisolines" {
1619            set _settings($what) [$itk_component(numisolines) value]
1620            set _currentNumIsolines $_settings($what)
1621            UpdateContourList
1622            set _changed($what) 1
1623            SendCmd "heightmap contourlist [list $_contourList]"
1624            if {$_settings(-colormapdiscrete)} {
1625                set numColors [expr $_settings($what) + 1]
1626                SendCmd "colormap res $numColors"
1627                EventuallyRequestLegend
1628            } else {
1629                DrawLegend
1630            }
1631        }
1632        "-opacity" {
1633            set _changed($what) 1
1634            set val [expr $_settings($what) * 0.01]
1635            if { $_settings(-isheightmap) } {
1636                set _settings(-saveopacity) $_settings($what)
1637                SendCmd "heightmap opacity $val"
1638            } else {
1639                SendCmd "heightmap opacity 1.0"
1640            }
1641        }
1642        "-outline" {
1643            if { $_settings(-isheightmap) } {
1644                SendCmd "outline visible 0"
1645            } else {
1646                set _settings(-saveoutline) $_settings($what)
1647                set bool $_settings($what)
1648                SendCmd "outline visible $bool"
1649            }
1650        }
1651        "-stretchtofit" {
1652            set bool $_settings($what)
1653            if { $bool } {
1654                set heightScale [GetHeightmapScale]
1655                if {$heightScale == 0} {
1656                    SendCmd "camera aspect window"
1657                } else {
1658                    SendCmd "camera aspect square"
1659                }
1660            } else {
1661                SendCmd "camera aspect native"
1662            }
1663            Zoom reset
1664        }
1665        "-wireframe" {
1666            set bool $_settings($what)
1667            SendCmd "heightmap wireframe $bool"
1668        }
1669        default {
1670            error "don't know how to fix $what"
1671        }
1672    }
1673}
1674
1675#
1676# RequestLegend --
1677#
1678#       Request a new legend from the server.  The size of the legend
1679#       is determined from the height of the canvas. 
1680#
1681# This should be called when
1682#       1.  A new current colormap is set.
1683#       2.  Window is resized.
1684#       3.  The limits of the data have changed.  (Just need a redraw).
1685#       4.  Number of isolines have changed. (Just need a redraw).
1686#       5.  Legend becomes visible (Just need a redraw).
1687#
1688itcl::body Rappture::VtkHeightmapViewer::RequestLegend {} {
1689    set _legendPending 0
1690    set font "Arial 8"
1691    set w 12
1692    set lineht [font metrics $font -linespace]
1693    # color ramp height = (canvas height) - (min and max value lines) - 2
1694    set h [expr {$_height - 2 * ($lineht + 2)}]
1695    set _legendHeight $h
1696
1697    set fname $_curFldName
1698    if { [string match "component*" $fname] } {
1699        set title ""
1700    } else {
1701        if { [info exists _fields($fname)] } {
1702            foreach { title units } $_fields($fname) break
1703            if { $units != "" } {
1704                set title [format "%s (%s)" $title $units]
1705            }
1706        } else {
1707            set title $fname
1708        }
1709    }
1710    # If there's a title too, substract one more line
1711    if { $title != "" } {
1712        incr h -$lineht
1713    }
1714    if { $h < 1 } {
1715        return
1716    }
1717    # Set the legend on the first heightmap dataset.
1718    if { $_currentColormap != ""  } {
1719        set cmap $_currentColormap
1720        #SendCmd "legend $cmap scalar $_curFldName {} $w $h 0"
1721        SendCmd "legend2 $cmap $w $h"
1722    }
1723}
1724
1725#
1726# ResetAxes --
1727#
1728#       Set axis z bounds and range
1729#
1730itcl::body Rappture::VtkHeightmapViewer::ResetAxes {} {
1731    if { ![info exists _limits($_curFldName)]} {
1732        SendCmd "dataset maprange all"
1733        SendCmd "axis autorange z on"
1734        SendCmd "axis autobounds z on"
1735        return
1736    }
1737    foreach { xmin xmax } $_limits(x) break
1738    foreach { ymin ymax } $_limits(y) break
1739    foreach { vmin vmax } $_limits($_curFldName) break
1740
1741    global tcl_precision
1742    set tcl_precision 17
1743    set xr [expr $xmax - $xmin]
1744    set yr [expr $ymax - $ymin]
1745    set vr [expr $vmax - $vmin]
1746    set r  [expr ($yr > $xr) ? $yr : $xr]
1747    if { $vr < 1.0e-17 } {
1748        set dataScale 1.0
1749    } else {
1750        set dataScale [expr $r / $vr]
1751    }
1752    set heightScale [GetHeightmapScale]
1753    set bmin [expr $heightScale * $dataScale * $vmin]
1754    set bmax [expr $heightScale * $dataScale * $vmax]
1755    if {$heightScale > 0} {
1756        set zpos [expr - $bmin]
1757        SendCmd "heightmap pos 0 0 $zpos"
1758    } else {
1759        SendCmd "heightmap pos 0 0 0"
1760    }
1761    set bmax [expr $bmax - $bmin]
1762    set bmin 0
1763    SendCmd "dataset maprange explicit $_limits($_curFldName) $_curFldName"
1764    SendCmd "axis bounds z $bmin $bmax"
1765    SendCmd "axis range z $_limits($_curFldName)"
1766}
1767
1768#
1769# SetCurrentColormap --
1770#
1771itcl::body Rappture::VtkHeightmapViewer::SetCurrentColormap { name } {
1772    # Keep track of the colormaps that we build.
1773    if { $name != "none" && ![info exists _colormaps($name)] } {
1774        BuildColormap $name
1775        set _colormaps($name) 1
1776    }
1777    set _currentColormap $name
1778    SendCmd "heightmap colormap $_currentColormap"
1779}
1780
1781
1782#
1783# BuildColormap --
1784#
1785#       Build the designated colormap on the server.
1786#
1787itcl::body Rappture::VtkHeightmapViewer::BuildColormap { name } {
1788    set cmap [ColorsToColormap $name]
1789    if { [llength $cmap] == 0 } {
1790        set cmap "0.0 0.0 0.0 0.0 1.0 1.0 1.0 1.0"
1791    }
1792    set wmap "0.0 1.0 1.0 1.0"
1793    SendCmd "colormap add $name { $cmap } { $wmap }"
1794}
1795
1796# ----------------------------------------------------------------------
1797# CONFIGURATION OPTION: -mode
1798# ----------------------------------------------------------------------
1799itcl::configbody Rappture::VtkHeightmapViewer::mode {
1800    switch -- $itk_option(-mode) {
1801        "heightmap" {
1802            set _settings(-isheightmap) 1
1803        }
1804        "contour" {
1805            set _settings(-isheightmap) 0
1806        }
1807        default {
1808            error "unknown mode settings \"$itk_option(-mode)\""
1809        }
1810    }
1811    if { !$_reset } {
1812        AdjustSetting -isheightmap
1813    }
1814}
1815
1816# ----------------------------------------------------------------------
1817# CONFIGURATION OPTION: -plotbackground
1818# ----------------------------------------------------------------------
1819itcl::configbody Rappture::VtkHeightmapViewer::plotbackground {
1820    if { [isconnected] } {
1821        set rgb [Color2RGB $itk_option(-plotbackground)]
1822        if { !$_reset } {
1823            SendCmd "screen bgcolor $rgb"
1824        }
1825        $itk_component(view) configure -background $itk_option(-plotbackground)
1826    }
1827}
1828
1829# ----------------------------------------------------------------------
1830# CONFIGURATION OPTION: -plotforeground
1831# ----------------------------------------------------------------------
1832itcl::configbody Rappture::VtkHeightmapViewer::plotforeground {
1833    if { [isconnected] } {
1834        set rgb [Color2RGB $itk_option(-plotforeground)]
1835        if { !$_reset } {
1836            SendCmd "outline color $rgb"
1837            SendCmd "axis color all $rgb"
1838        }
1839    }
1840}
1841
1842itcl::body Rappture::VtkHeightmapViewer::BuildContourTab {} {
1843
1844    set fg [option get $itk_component(hull) font Font]
1845    #set bfg [option get $itk_component(hull) boldFont Font]
1846
1847    set inner [$itk_component(main) insert end \
1848        -title "Contour/Surface Settings" \
1849        -icon [Rappture::icon contour2]]
1850    $inner configure -borderwidth 4
1851
1852    checkbutton $inner.legend \
1853        -text "Legend" \
1854        -variable [itcl::scope _settings(-legendvisible)] \
1855        -command [itcl::code $this AdjustSetting -legendvisible] \
1856        -font "Arial 9"
1857
1858    checkbutton $inner.wireframe \
1859        -text "Wireframe" \
1860        -variable [itcl::scope _settings(-wireframe)] \
1861        -command [itcl::code $this AdjustSetting -wireframe] \
1862        -font "Arial 9"
1863
1864    itk_component add lighting {
1865        checkbutton $inner.lighting \
1866            -text "Enable Lighting" \
1867            -variable [itcl::scope _settings(-lighting)] \
1868            -command [itcl::code $this AdjustSetting -lighting] \
1869            -font "Arial 9"
1870    } {
1871        ignore -font
1872    }
1873    checkbutton $inner.edges \
1874        -text "Edges" \
1875        -variable [itcl::scope _settings(-edges)] \
1876        -command [itcl::code $this AdjustSetting -edges] \
1877        -font "Arial 9"
1878
1879    itk_component add outline {
1880        checkbutton $inner.outline \
1881            -text "Outline" \
1882            -variable [itcl::scope _settings(-outline)] \
1883            -command [itcl::code $this AdjustSetting -outline] \
1884            -font "Arial 9"
1885    } {
1886        ignore -font
1887    }
1888    checkbutton $inner.stretch \
1889        -text "Stretch to fit" \
1890        -variable [itcl::scope _settings(-stretchtofit)] \
1891        -command [itcl::code $this AdjustSetting -stretchtofit] \
1892        -font "Arial 9"
1893
1894    checkbutton $inner.isolines \
1895        -text "Isolines" \
1896        -variable [itcl::scope _settings(-isolinesvisible)] \
1897        -command [itcl::code $this AdjustSetting -isolinesvisible] \
1898        -font "Arial 9"
1899
1900    checkbutton $inner.colormapDiscrete \
1901        -text "Discrete Colormap" \
1902        -variable [itcl::scope _settings(-colormapdiscrete)] \
1903        -command [itcl::code $this AdjustSetting -colormapdiscrete] \
1904        -font "Arial 9"
1905
1906    itk_component add field_l {
1907        label $inner.field_l -text "Field" -font "Arial 9"
1908    } {
1909        ignore -font
1910    }
1911    itk_component add field {
1912        Rappture::Combobox $inner.field -width 10 -editable no
1913    }
1914    bind $inner.field <<Value>> \
1915        [itcl::code $this AdjustSetting -field]
1916
1917    label $inner.colormap_l -text "Colormap" -font "Arial 9"
1918    itk_component add colormap {
1919        Rappture::Combobox $inner.colormap -width 10 -editable no
1920    }
1921    $inner.colormap choices insert end [GetColormapList -includeNone]
1922    $itk_component(colormap) value $_settings(-colormap)
1923    bind $inner.colormap <<Value>> \
1924        [itcl::code $this AdjustSetting -colormap]
1925
1926    label $inner.isolinecolor_l -text "Isolines Color" -font "Arial 9"
1927    itk_component add isolinecolor {
1928        Rappture::Combobox $inner.isolinecolor -width 10 -editable no
1929    }
1930    $inner.isolinecolor choices insert end \
1931        "black"              "black"            \
1932        "blue"               "blue"             \
1933        "cyan"               "cyan"             \
1934        "green"              "green"            \
1935        "grey"               "grey"             \
1936        "magenta"            "magenta"          \
1937        "orange"             "orange"           \
1938        "red"                "red"              \
1939        "white"              "white"            \
1940        "none"               "none"
1941
1942    $itk_component(isolinecolor) value $_settings(-isolinecolor)
1943    bind $inner.isolinecolor <<Value>> \
1944        [itcl::code $this AdjustSetting -isolinecolor]
1945
1946    label $inner.background_l -text "Background Color" -font "Arial 9"
1947    itk_component add background {
1948        Rappture::Combobox $inner.background -width 10 -editable no
1949    }
1950    $inner.background choices insert end \
1951        "black"              "black"            \
1952        "white"              "white"            \
1953        "grey"               "grey"             
1954
1955    $itk_component(background) value "white"
1956    bind $inner.background <<Value>> \
1957        [itcl::code $this AdjustSetting -background]
1958
1959    itk_component add opacity_l {
1960        label $inner.opacity_l -text "Opacity" -font "Arial 9"
1961    } {
1962        ignore -font
1963    }
1964    itk_component add opacity {
1965        ::scale $inner.opacity -from 0 -to 100 -orient horizontal \
1966            -variable [itcl::scope _settings(-opacity)] \
1967            -showvalue off \
1968            -command [itcl::code $this AdjustSetting -opacity]
1969    }
1970    itk_component add scale_l {
1971        label $inner.scale_l -text "Scale" -font "Arial 9"
1972    } {
1973        ignore -font
1974    }
1975    itk_component add scale {
1976        ::scale $inner.scale -from 0 -to 100 -orient horizontal \
1977            -variable [itcl::scope _settings(-heightmapscale)] \
1978            -showvalue off \
1979            -command [itcl::code $this AdjustSetting -heightmapscale]
1980    }
1981    label $inner.numisolines_l -text "Number of Isolines" -font "Arial 9"
1982    itk_component add numisolines {
1983        Rappture::Spinint $inner.numisolines \
1984            -min 0 -max 50 -font "arial 9"
1985    }
1986    $itk_component(numisolines) value $_settings(-numisolines)
1987    bind $itk_component(numisolines) <<Value>> \
1988        [itcl::code $this AdjustSetting -numisolines]
1989
1990    frame $inner.separator1 -height 2 -relief sunken -bd 1
1991    frame $inner.separator2 -height 2 -relief sunken -bd 1
1992
1993    blt::table $inner \
1994        0,0 $inner.field_l -anchor w -pady 2 \
1995        0,1 $inner.field -anchor w -pady 2 -fill x \
1996        1,0 $inner.colormap_l -anchor w -pady 2  \
1997        1,1 $inner.colormap   -anchor w -pady 2 -fill x  \
1998        2,0 $inner.isolinecolor_l  -anchor w -pady 2  \
1999        2,1 $inner.isolinecolor    -anchor w -pady 2 -fill x  \
2000        3,0 $inner.background_l -anchor w -pady 2 \
2001        3,1 $inner.background -anchor w -pady 2  -fill x \
2002        4,0 $inner.numisolines_l -anchor w -pady 2 \
2003        4,1 $inner.numisolines -anchor w -pady 2 \
2004        5,0 $inner.stretch    -anchor w -pady 2 -cspan 2 \
2005        6,0 $inner.edges      -anchor w -pady 2 -cspan 2 \
2006        7,0 $inner.legend     -anchor w -pady 2 -cspan 2 \
2007        8,0 $inner.colormapDiscrete -anchor w -pady 2 -cspan 2 \
2008        9,0 $inner.wireframe  -anchor w -pady 2 -cspan 2\
2009        10,0 $inner.isolines   -anchor w -pady 2 -cspan 2 \
2010        11,0 $inner.separator1 -padx 2 -fill x -cspan 2 \
2011        12,0 $inner.outline    -anchor w -pady 2 -cspan 2 \
2012        13,0 $inner.separator2 -padx 2 -fill x -cspan 2 \
2013        14,0 $inner.lighting   -anchor w -pady 2 -cspan 2 \
2014        15,0 $inner.opacity_l -anchor w -pady 2 \
2015        15,1 $inner.opacity   -fill x   -pady 2 \
2016        16,0 $inner.scale_l   -anchor w -pady 2 -cspan 2 \
2017        16,1 $inner.scale     -fill x   -pady 2 -cspan 2 \
2018
2019    blt::table configure $inner r* c* -resize none
2020    blt::table configure $inner r17 c1 -resize expand
2021}
2022
2023itcl::body Rappture::VtkHeightmapViewer::BuildAxisTab {} {
2024
2025    set fg [option get $itk_component(hull) font Font]
2026    #set bfg [option get $itk_component(hull) boldFont Font]
2027
2028    set inner [$itk_component(main) insert end \
2029        -title "Axis Settings" \
2030        -icon [Rappture::icon axis2]]
2031    $inner configure -borderwidth 4
2032
2033    checkbutton $inner.visible \
2034        -text "Axes" \
2035        -variable [itcl::scope _settings(-axisvisible)] \
2036        -command [itcl::code $this AdjustSetting -axisvisible] \
2037        -font "Arial 9"
2038    checkbutton $inner.labels \
2039        -text "Axis Labels" \
2040        -variable [itcl::scope _settings(-axislabels)] \
2041        -command [itcl::code $this AdjustSetting -axislabels] \
2042        -font "Arial 9"
2043    label $inner.grid_l -text "Grid" -font "Arial 9"
2044    checkbutton $inner.xgrid \
2045        -text "X" \
2046        -variable [itcl::scope _settings(-xgrid)] \
2047        -command [itcl::code $this AdjustSetting -xgrid] \
2048        -font "Arial 9"
2049    checkbutton $inner.ygrid \
2050        -text "Y" \
2051        -variable [itcl::scope _settings(-ygrid)] \
2052        -command [itcl::code $this AdjustSetting -ygrid] \
2053        -font "Arial 9"
2054    checkbutton $inner.zgrid \
2055        -text "Z" \
2056        -variable [itcl::scope _settings(-zgrid)] \
2057        -command [itcl::code $this AdjustSetting -zgrid] \
2058        -font "Arial 9"
2059    checkbutton $inner.minorticks \
2060        -text "Minor Ticks" \
2061        -variable [itcl::scope _settings(-axisminorticks)] \
2062        -command [itcl::code $this AdjustSetting -axisminorticks] \
2063        -font "Arial 9"
2064
2065    label $inner.mode_l -text "Mode" -font "Arial 9"
2066
2067    itk_component add axisflymode {
2068        Rappture::Combobox $inner.mode -width 10 -editable no
2069    }
2070    $inner.mode choices insert end \
2071        "static_triad"    "static" \
2072        "closest_triad"   "closest" \
2073        "furthest_triad"  "farthest" \
2074        "outer_edges"     "outer"         
2075    $itk_component(axisflymode) value $_settings(-axisflymode)
2076    bind $inner.mode <<Value>> [itcl::code $this AdjustSetting -axisflymode]
2077
2078    blt::table $inner \
2079        0,0 $inner.visible -anchor w -cspan 4 \
2080        1,0 $inner.labels  -anchor w -cspan 4 \
2081        2,0 $inner.minorticks  -anchor w -cspan 4 \
2082        4,0 $inner.grid_l  -anchor w \
2083        4,1 $inner.xgrid   -anchor w \
2084        4,2 $inner.ygrid   -anchor w \
2085        4,3 $inner.zgrid   -anchor w \
2086        5,0 $inner.mode_l  -anchor w -padx { 2 0 } \
2087        5,1 $inner.mode    -fill x -cspan 3
2088
2089    blt::table configure $inner r* c* -resize none
2090    blt::table configure $inner r7 c6 -resize expand
2091    blt::table configure $inner r3 -height 0.125i
2092}
2093
2094
2095itcl::body Rappture::VtkHeightmapViewer::BuildCameraTab {} {
2096    set inner [$itk_component(main) insert end \
2097        -title "Camera Settings" \
2098        -icon [Rappture::icon camera]]
2099    $inner configure -borderwidth 4
2100
2101    label $inner.view_l -text "view" -font "Arial 9"
2102    set f [frame $inner.view]
2103    foreach side { front back left right top bottom } {
2104        button $f.$side  -image [Rappture::icon view$side] \
2105            -command [itcl::code $this SetOrientation $side]
2106        Rappture::Tooltip::for $f.$side "Change the view to $side"
2107        pack $f.$side -side left
2108    }
2109
2110    blt::table $inner \
2111        0,0 $inner.view_l -anchor e -pady 2 \
2112        0,1 $inner.view -anchor w -pady 2
2113
2114    set labels { qx qy qz qw xpan ypan zoom }
2115    set row 1
2116    foreach tag $labels {
2117        label $inner.${tag}label -text $tag -font "Arial 9"
2118        entry $inner.${tag} -font "Arial 9"  -bg white \
2119            -textvariable [itcl::scope _view($tag)]
2120        bind $inner.${tag} <Return> \
2121            [itcl::code $this camera set ${tag}]
2122        bind $inner.${tag} <KP_Enter> \
2123            [itcl::code $this camera set ${tag}]
2124        blt::table $inner \
2125            $row,0 $inner.${tag}label -anchor e -pady 2 \
2126            $row,1 $inner.${tag} -anchor w -pady 2
2127        blt::table configure $inner r$row -resize none
2128        incr row
2129    }
2130    checkbutton $inner.ortho \
2131        -text "Orthographic Projection" \
2132        -variable [itcl::scope _view(ortho)] \
2133        -command [itcl::code $this camera set ortho] \
2134        -font "Arial 9"
2135    blt::table $inner \
2136            $row,0 $inner.ortho -cspan 2 -anchor w -pady 2
2137    blt::table configure $inner r$row -resize none
2138    incr row
2139
2140    blt::table configure $inner c* r* -resize none
2141    blt::table configure $inner c2 -resize expand
2142    blt::table configure $inner r$row -resize expand
2143}
2144
2145#
2146#  camera --
2147#
2148itcl::body Rappture::VtkHeightmapViewer::camera {option args} {
2149    switch -- $option {
2150        "show" {
2151            puts [array get _view]
2152        }
2153        "set" {
2154            set who [lindex $args 0]
2155            set x $_view($who)
2156            set code [catch { string is double $x } result]
2157            if { $code != 0 || !$result } {
2158                return
2159            }
2160            switch -- $who {
2161                "ortho" {
2162                    if {$_view(ortho)} {
2163                        SendCmd "camera mode ortho"
2164                    } else {
2165                        SendCmd "camera mode persp"
2166                    }
2167                }
2168                "xpan" - "ypan" {
2169                    PanCamera
2170                }
2171                "qx" - "qy" - "qz" - "qw" {
2172                    set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
2173                    $_arcball quaternion $q
2174                    EventuallyRotate $q
2175                }
2176                "zoom" {
2177                    SendCmd "camera zoom $_view(zoom)"
2178                }
2179            }
2180        }
2181    }
2182}
2183
2184itcl::body Rappture::VtkHeightmapViewer::GetVtkData { args } {
2185    set bytes ""
2186    foreach dataobj [get] {
2187        foreach comp [$dataobj components] {
2188            set tag $dataobj-$comp
2189            set contents [$dataobj vtkdata $comp]
2190            append bytes "$contents\n"
2191        }
2192    }
2193    return [list .vtk $bytes]
2194}
2195
2196itcl::body Rappture::VtkHeightmapViewer::GetImage { args } {
2197    if { [image width $_image(download)] > 0 &&
2198         [image height $_image(download)] > 0 } {
2199        set bytes [$_image(download) data -format "jpeg -quality 100"]
2200        set bytes [Rappture::encoding::decode -as b64 $bytes]
2201        return [list .jpg $bytes]
2202    }
2203    return ""
2204}
2205
2206itcl::body Rappture::VtkHeightmapViewer::BuildDownloadPopup { popup command } {
2207    Rappture::Balloon $popup \
2208        -title "[Rappture::filexfer::label downloadWord] as..."
2209    set inner [$popup component inner]
2210    label $inner.summary -text "" -anchor w
2211    radiobutton $inner.vtk_button -text "VTK data file" \
2212        -variable [itcl::scope _downloadPopup(format)] \
2213        -font "Arial 9 " \
2214        -value vtk 
2215    Rappture::Tooltip::for $inner.vtk_button "Save as VTK data file."
2216    radiobutton $inner.image_button -text "Image File" \
2217        -variable [itcl::scope _downloadPopup(format)] \
2218        -font "Arial 9 " \
2219        -value image
2220    Rappture::Tooltip::for $inner.image_button \
2221        "Save as digital image."
2222
2223    button $inner.ok -text "Save" \
2224        -highlightthickness 0 -pady 2 -padx 3 \
2225        -command $command \
2226        -compound left \
2227        -image [Rappture::icon download]
2228
2229    button $inner.cancel -text "Cancel" \
2230        -highlightthickness 0 -pady 2 -padx 3 \
2231        -command [list $popup deactivate] \
2232        -compound left \
2233        -image [Rappture::icon cancel]
2234
2235    blt::table $inner \
2236        0,0 $inner.summary -cspan 2  \
2237        1,0 $inner.vtk_button -anchor w -cspan 2 -padx { 4 0 } \
2238        2,0 $inner.image_button -anchor w -cspan 2 -padx { 4 0 } \
2239        4,1 $inner.cancel -width .9i -fill y \
2240        4,0 $inner.ok -padx 2 -width .9i -fill y
2241    blt::table configure $inner r3 -height 4
2242    blt::table configure $inner r4 -pady 4
2243    raise $inner.image_button
2244    $inner.vtk_button invoke
2245    return $inner
2246}
2247
2248#
2249# SetObjectStyle --
2250#
2251#       Set the style of the heightmap/contour object.  This gets calls
2252#       for each dataset once as it is loaded.  It can overridden by
2253#       the user controls.
2254#
2255#
2256itcl::body Rappture::VtkHeightmapViewer::SetObjectStyle { dataobj comp } {
2257    # Parse style string.
2258    set tag $dataobj-$comp
2259    array set style {
2260        -color BCGYR
2261        -levels 10
2262        -opacity 1.0
2263    }
2264    set stylelist [$dataobj style $comp]
2265    if { $stylelist != "" } {
2266        array set style $stylelist
2267    }
2268    # This is too complicated.  We want to set the colormap, number of
2269    # isolines and opacity for the dataset.  They can be the default values,
2270    # the style hints loaded with the dataset, or set by user controls.  As
2271    # datasets get loaded, they first use the defaults that are overidden
2272    # by the style hints.  If the user changes the global controls, then that
2273    # overrides everything else.  I don't know what it means when global
2274    # controls are specified as style hints by each dataset.  It complicates
2275    # the code to handle aberrant cases.
2276
2277    if { $_changed(-opacity) } {
2278        set style(-opacity) [expr $_settings(-opacity) * 0.01]
2279    }
2280    if { $_changed(-numisolines) } {
2281        set style(-levels) $_settings(-numisolines)
2282    }
2283    if { $_changed(-colormap) } {
2284        set style(-color) $_settings(-colormap)
2285    }
2286    if { $_currentColormap == "" } {
2287        $itk_component(colormap) value $style(-color)
2288    }
2289    if { [info exists style(-stretchtofit)] } {
2290        set _settings(-stretchtofit) $style(-stretchtofit)
2291        AdjustSetting -stretchtofit
2292    }
2293    if { $_currentNumIsolines != $style(-levels) } {
2294        set _currentNumIsolines $style(-levels)
2295        set _settings(-numisolines) $_currentNumIsolines
2296        $itk_component(numisolines) value $_currentNumIsolines
2297        UpdateContourList
2298        DrawLegend
2299    }
2300    SendCmd "outline add $tag"
2301    SendCmd "outline color [Color2RGB $itk_option(-plotforeground)] $tag"
2302    SendCmd "outline visible $_settings(-outline) $tag"
2303    set scale [GetHeightmapScale]
2304    SendCmd "[list heightmap add contourlist $_contourList $scale $tag]"
2305    set _comp2scale($tag) $_settings(-heightmapscale)
2306    SendCmd "heightmap edges $_settings(-edges) $tag"
2307    SendCmd "heightmap wireframe $_settings(-wireframe) $tag"
2308    SetCurrentColormap $style(-color)
2309    set color [$itk_component(isolinecolor) value]
2310    SendCmd "heightmap isolinecolor [Color2RGB $color] $tag"
2311    SendCmd "heightmap lighting $_settings(-isheightmap) $tag"
2312    SendCmd "heightmap isolines $_settings(-isolinesvisible) $tag"
2313    SendCmd "heightmap surface $_settings(-colormapvisible) $tag"
2314    SendCmd "heightmap opacity $style(-opacity) $tag"
2315    set _settings(-opacity) [expr $style(-opacity) * 100.0]
2316}
2317
2318itcl::body Rappture::VtkHeightmapViewer::IsValidObject { dataobj } {
2319    if {[catch {$dataobj isa Rappture::Field} valid] != 0 || !$valid} {
2320        return 0
2321    }
2322    return 1
2323}
2324
2325# ----------------------------------------------------------------------
2326# USAGE: ReceiveLegend <colormap> <title> <min> <max> <size>
2327#
2328# Invoked automatically whenever the "legend" command comes in from
2329# the rendering server.  Indicates that binary image data with the
2330# specified <size> will follow.
2331# ----------------------------------------------------------------------
2332itcl::body Rappture::VtkHeightmapViewer::ReceiveLegend { colormap title min max size } {
2333    #puts stderr "ReceiveLegend colormap=$colormap title=$title range=$min,$max size=$size"
2334    if { [isconnected] } {
2335        set bytes [ReceiveBytes $size]
2336        if { ![info exists _image(legend)] } {
2337            set _image(legend) [image create photo]
2338        }
2339        $_image(legend) configure -data $bytes
2340        #puts stderr "read $size bytes for [image width $_image(legend)]x[image height $_image(legend)] legend>"
2341        if { [catch {DrawLegend} errs] != 0 } {
2342            global errorInfo
2343            puts stderr "errs=$errs errorInfo=$errorInfo"
2344        }
2345    }
2346}
2347
2348#
2349# DrawLegend --
2350#
2351#       Draws the legend in the own canvas on the right side of the plot area.
2352#
2353itcl::body Rappture::VtkHeightmapViewer::DrawLegend {} {
2354    set fname $_curFldName
2355    set c $itk_component(view)
2356    set w [winfo width $c]
2357    set h [winfo height $c]
2358    set font "Arial 8"
2359    set lineht [font metrics $font -linespace]
2360   
2361    if { [string match "component*" $fname] } {
2362        set title ""
2363    } else {
2364        if { [info exists _fields($fname)] } {
2365            foreach { title units } $_fields($fname) break
2366            if { $units != "" } {
2367                set title [format "%s (%s)" $title $units]
2368            }
2369        } else {
2370            set title $fname
2371        }
2372    }
2373    set x [expr $w - 2]
2374    if { !$_settings(-legendvisible) } {
2375        $c delete legend
2376        return
2377    }
2378    if { [$c find withtag "legend"] == "" } {
2379        set y 2
2380        # If there's a legend title, create a text item for the title.
2381        $c create text $x $y \
2382            -anchor ne \
2383            -fill $itk_option(-plotforeground) -tags "title legend" \
2384            -font $font
2385        if { $title != "" } {
2386            incr y $lineht
2387        }
2388        $c create text $x $y \
2389            -anchor ne \
2390            -fill $itk_option(-plotforeground) -tags "vmax legend" \
2391            -font $font
2392        incr y $lineht
2393        $c create image $x $y \
2394            -anchor ne \
2395            -image $_image(legend) -tags "colormap legend"
2396        $c create rectangle $x $y 1 1 \
2397            -fill "" -outline "" -tags "sensor legend"
2398        $c create text $x [expr {$h-2}] \
2399            -anchor se \
2400            -fill $itk_option(-plotforeground) -tags "vmin legend" \
2401            -font $font
2402        $c bind sensor <Enter> [itcl::code $this EnterLegend %x %y]
2403        $c bind sensor <Leave> [itcl::code $this LeaveLegend]
2404        $c bind sensor <Motion> [itcl::code $this MotionLegend %x %y]
2405    }
2406    $c delete isoline
2407    set x2 $x
2408    set iw [image width $_image(legend)]
2409    set ih [image height $_image(legend)]
2410    set x1 [expr $x2 - ($iw*12)/10]
2411    set color [$itk_component(isolinecolor) value]
2412
2413    # Draw the isolines on the legend.
2414    array unset _isolines
2415    if { $color != "none"  && [info exists _limits($_curFldName)] &&
2416         $_settings(-isolinesvisible) && $_currentNumIsolines > 0 } {
2417
2418        foreach { vmin vmax } $_limits($_curFldName) break
2419        set range [expr double($vmax - $vmin)]
2420        if { $range <= 0.0 } {
2421            set range 1.0;              # Min is greater or equal to max.
2422        }
2423        set tags "isoline legend"
2424        set offset [expr 2 + $lineht]
2425        if { $title != "" } {
2426            incr offset $lineht
2427        }
2428        foreach value $_contourList {
2429            set norm [expr 1.0 - (($value - $vmin) / $range)]
2430            set y1 [expr int(round(($norm * $ih) + $offset))]
2431            for { set off 0 } { $off < 3 } { incr off } {
2432                set _isolines([expr $y1 + $off]) $value
2433                set _isolines([expr $y1 - $off]) $value
2434            }
2435            $c create line $x1 $y1 $x2 $y1 -fill $color -tags $tags
2436        }
2437    }
2438
2439    $c bind title <ButtonPress> [itcl::code $this Combo post]
2440    $c bind title <Enter> [itcl::code $this Combo activate]
2441    $c bind title <Leave> [itcl::code $this Combo deactivate]
2442    # Reset the item coordinates according the current size of the plot.
2443    if { [info exists _limits($_curFldName)] } {
2444        foreach { vmin vmax } $_limits($_curFldName) break
2445        $c itemconfigure vmin -text [format %g $vmin]
2446        $c itemconfigure vmax -text [format %g $vmax]
2447    }
2448    set y 2
2449    # If there's a legend title, move the title to the correct position
2450    if { $title != "" } {
2451        $c itemconfigure title -text $title
2452        $c coords title $x $y
2453        incr y $lineht
2454    }
2455    $c coords vmax $x $y
2456    incr y $lineht
2457    $c coords colormap $x $y
2458    $c coords sensor [expr $x - $iw] $y $x [expr $y + $ih]
2459    $c raise sensor
2460    $c coords vmin $x [expr {$h - 2}]
2461}
2462
2463#
2464# EnterLegend --
2465#
2466itcl::body Rappture::VtkHeightmapViewer::EnterLegend { x y } {
2467    SetLegendTip $x $y
2468}
2469
2470#
2471# MotionLegend --
2472#
2473itcl::body Rappture::VtkHeightmapViewer::MotionLegend { x y } {
2474    Rappture::Tooltip::tooltip cancel
2475    set c $itk_component(view)
2476    set cw [winfo width $c]
2477    set ch [winfo height $c]
2478    if { $x >= 0 && $x < $cw && $y >= 0 && $y < $ch } {
2479        SetLegendTip $x $y
2480    }
2481}
2482
2483#
2484# LeaveLegend --
2485#
2486itcl::body Rappture::VtkHeightmapViewer::LeaveLegend { } {
2487    Rappture::Tooltip::tooltip cancel
2488    .rappturetooltip configure -icon ""
2489}
2490
2491#
2492# SetLegendTip --
2493#
2494itcl::body Rappture::VtkHeightmapViewer::SetLegendTip { x y } {
2495    set fname $_curFldName
2496    set c $itk_component(view)
2497    set w [winfo width $c]
2498    set h [winfo height $c]
2499    set font "Arial 8"
2500    set lineht [font metrics $font -linespace]
2501   
2502    set ih [image height $_image(legend)]
2503    # Subtract off the offset of the color ramp from the top of the canvas
2504    set iy [expr $y - ($lineht + 2)]
2505
2506    if { [string match "component*" $fname] } {
2507        set title ""
2508    } else {
2509        if { [info exists _fields($fname)] } {
2510            foreach { title units } $_fields($fname) break
2511            if { $units != "" } {
2512                set title [format "%s (%s)" $title $units]
2513            }
2514        } else {
2515            set title $fname
2516        }
2517    }
2518    # If there's a legend title, increase the offset by the line height.
2519    if { $title != "" } {
2520        incr iy -$lineht
2521    }
2522
2523    # Make a swatch of the selected color
2524    if { [catch { $_image(legend) get 10 $iy } pixel] != 0 } {
2525        return
2526    }
2527
2528    if { ![info exists _image(swatch)] } {
2529        set _image(swatch) [image create photo -width 24 -height 24]
2530    }
2531    set color [eval format "\#%02x%02x%02x" $pixel]
2532    $_image(swatch) put black  -to 0 0 23 23
2533    $_image(swatch) put $color -to 1 1 22 22
2534
2535    # Compute the value of the point
2536    if { [info exists _limits($fname)] } {
2537        foreach { vmin vmax } $_limits($fname) break
2538        set t [expr 1.0 - (double($iy) / double($ih-1))]
2539        set value [expr $t * ($vmax - $vmin) + $vmin]
2540    } else {
2541        set value 0.0
2542    }
2543    set tipx [expr $x + 15]
2544    set tipy [expr $y - 5]
2545    .rappturetooltip configure -icon $_image(swatch)
2546    if { [info exists _isolines($y)] } {
2547        Rappture::Tooltip::text $c [format "$title %g (isoline)" $_isolines($y)]
2548    } else {
2549        Rappture::Tooltip::text $c [format "$title %g" $value]
2550    }
2551    Rappture::Tooltip::tooltip show $c +$tipx,+$tipy   
2552}
2553
2554# ----------------------------------------------------------------------
2555# USAGE: _dropdown post
2556# USAGE: _dropdown unpost
2557# USAGE: _dropdown select
2558#
2559# Used internally to handle the dropdown list for this combobox.  The
2560# post/unpost options are invoked when the list is posted or unposted
2561# to manage the relief of the controlling button.  The select option
2562# is invoked whenever there is a selection from the list, to assign
2563# the value back to the gauge.
2564# ----------------------------------------------------------------------
2565itcl::body Rappture::VtkHeightmapViewer::Combo {option} {
2566    set c $itk_component(view)
2567    switch -- $option {
2568        post {
2569            foreach { x1 y1 x2 y2 } [$c bbox title] break
2570            set x1 [expr [winfo width $itk_component(view)] - [winfo reqwidth $itk_component(fieldmenu)]]
2571            set x [expr $x1 + [winfo rootx $itk_component(view)]]
2572            set y [expr $y2 + [winfo rooty $itk_component(view)]]
2573            tk_popup $itk_component(fieldmenu) $x $y
2574        }
2575        activate {
2576            $c itemconfigure title -fill red
2577        }
2578        deactivate {
2579            $c itemconfigure title -fill $itk_option(-plotforeground)
2580        }
2581        invoke {
2582            $itk_component(field) value $_curFldLabel
2583            AdjustSetting -field
2584        }
2585        default {
2586            error "bad option \"$option\": should be post, unpost, select"
2587        }
2588    }
2589}
2590
2591itcl::body Rappture::VtkHeightmapViewer::GetHeightmapScale {} {
2592    if {  $_settings(-isheightmap) } {
2593        set val $_settings(-heightmapscale)
2594        set sval [expr { $val >= 50 ? double($val)/50.0 : 1.0/(2.0-(double($val)/50.0)) }]
2595        return $sval
2596    }
2597    return 0
2598}
2599
2600itcl::body Rappture::VtkHeightmapViewer::SetOrientation { side } {
2601    array set positions {
2602        front  "0.707107 0.707107 0 0"
2603        back   "0 0 0.707107 0.707107"
2604        left   "0.5 0.5 -0.5 -0.5"
2605        right  "0.5 0.5 0.5 0.5"
2606        top    "1 0 0 0"
2607        bottom "0 1 0 0"
2608    }
2609    foreach name { qw qx qy qz } value $positions($side) {
2610        set _view($name) $value
2611    }
2612    set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
2613    $_arcball quaternion $q
2614    SendCmd "camera orient $q"
2615    SendCmd "camera reset"
2616    set _view(xpan) 0
2617    set _view(ypan) 0
2618    set _view(zoom) 1.0
2619}
2620
2621itcl::body Rappture::VtkHeightmapViewer::UpdateContourList {} {
2622    if {$_currentNumIsolines == 0} {
2623        set _contourList ""
2624        return
2625    }
2626    if { ![info exists _limits($_curFldName)] } {
2627        return
2628    }
2629    foreach { vmin vmax } $_limits($_curFldName) break
2630    set v [blt::vector create \#auto]
2631    $v seq $vmin $vmax [expr $_currentNumIsolines+2]
2632    $v delete end 0
2633    set _contourList [$v range 0 end]
2634    blt::vector destroy $v
2635}
Note: See TracBrowser for help on using the repository browser.