| 1 | # ---------------------------------------------------------------------- |
|---|
| 2 | # COMPONENT: ResultViewer - plots a collection of related results |
|---|
| 3 | # |
|---|
| 4 | # This widget plots a collection of results that all represent |
|---|
| 5 | # the same quantity, but for various ranges of input values. It |
|---|
| 6 | # is normally used as part of an Analyzer, to plot the various |
|---|
| 7 | # results selected by a ResultSet. |
|---|
| 8 | # ====================================================================== |
|---|
| 9 | # AUTHOR: Michael McLennan, Purdue University |
|---|
| 10 | # Copyright (c) 2004-2005 Purdue Research Foundation |
|---|
| 11 | # |
|---|
| 12 | # See the file "license.terms" for information on usage and |
|---|
| 13 | # redistribution of this file, and for a DISCLAIMER OF ALL WARRANTIES. |
|---|
| 14 | # ====================================================================== |
|---|
| 15 | package require Itk |
|---|
| 16 | |
|---|
| 17 | itcl::class Rappture::ResultViewer { |
|---|
| 18 | inherit itk::Widget |
|---|
| 19 | |
|---|
| 20 | itk_option define -width width Width 4i |
|---|
| 21 | itk_option define -height height Height 4i |
|---|
| 22 | itk_option define -colors colors Colors "" |
|---|
| 23 | itk_option define -clearcommand clearCommand ClearCommand "" |
|---|
| 24 | itk_option define -simulatecommand simulateCommand SimulateCommand "" |
|---|
| 25 | |
|---|
| 26 | constructor {args} { # defined below } |
|---|
| 27 | destructor { # defined below } |
|---|
| 28 | |
|---|
| 29 | public method add {index xmlobj path} |
|---|
| 30 | public method clear {{index ""}} |
|---|
| 31 | public method value {xmlobj} |
|---|
| 32 | |
|---|
| 33 | public method plot {option args} |
|---|
| 34 | public method download {option args} |
|---|
| 35 | |
|---|
| 36 | protected method _plotAdd {xmlobj {settings ""}} |
|---|
| 37 | protected method _fixScale {args} |
|---|
| 38 | protected proc _xml2data {xmlobj path} |
|---|
| 39 | |
|---|
| 40 | private variable _dispatcher "" ;# dispatchers for !events |
|---|
| 41 | private variable _mode "" ;# current plotting mode (xy, etc.) |
|---|
| 42 | private variable _mode2widget ;# maps plotting mode => widget |
|---|
| 43 | private variable _dataslots "" ;# list of all data objects in this widget |
|---|
| 44 | } |
|---|
| 45 | |
|---|
| 46 | itk::usual ResultViewer { |
|---|
| 47 | keep -background -foreground -cursor -font |
|---|
| 48 | } |
|---|
| 49 | |
|---|
| 50 | # ---------------------------------------------------------------------- |
|---|
| 51 | # CONSTRUCTOR |
|---|
| 52 | # ---------------------------------------------------------------------- |
|---|
| 53 | itcl::body Rappture::ResultViewer::constructor {args} { |
|---|
| 54 | # create a dispatcher for events |
|---|
| 55 | Rappture::dispatcher _dispatcher |
|---|
| 56 | $_dispatcher register !scale |
|---|
| 57 | $_dispatcher dispatch $this !scale \ |
|---|
| 58 | [itcl::code $this _fixScale] |
|---|
| 59 | |
|---|
| 60 | eval itk_initialize $args |
|---|
| 61 | } |
|---|
| 62 | |
|---|
| 63 | # ---------------------------------------------------------------------- |
|---|
| 64 | # DESTRUCTOR |
|---|
| 65 | # ---------------------------------------------------------------------- |
|---|
| 66 | itcl::body Rappture::ResultViewer::destructor {} { |
|---|
| 67 | foreach slot $_dataslots { |
|---|
| 68 | foreach obj $slot { |
|---|
| 69 | itcl::delete object $obj |
|---|
| 70 | } |
|---|
| 71 | } |
|---|
| 72 | } |
|---|
| 73 | |
|---|
| 74 | # ---------------------------------------------------------------------- |
|---|
| 75 | # USAGE: add <index> <xmlobj> <path> |
|---|
| 76 | # |
|---|
| 77 | # Adds a new result to this result viewer at the specified <index>. |
|---|
| 78 | # Data is taken from the <xmlobj> object at the <path>. |
|---|
| 79 | # ---------------------------------------------------------------------- |
|---|
| 80 | itcl::body Rappture::ResultViewer::add {index xmlobj path} { |
|---|
| 81 | set dobj [_xml2data $xmlobj $path] |
|---|
| 82 | |
|---|
| 83 | # |
|---|
| 84 | # If the index doesn't exist, then fill in empty slots and |
|---|
| 85 | # make it exist. |
|---|
| 86 | # |
|---|
| 87 | for {set i [llength $_dataslots]} {$i <= $index} {incr i} { |
|---|
| 88 | lappend _dataslots "" |
|---|
| 89 | } |
|---|
| 90 | set slot [lindex $_dataslots $index] |
|---|
| 91 | lappend slot $dobj |
|---|
| 92 | set _dataslots [lreplace $_dataslots $index $index $slot] |
|---|
| 93 | |
|---|
| 94 | $_dispatcher event -idle !scale |
|---|
| 95 | } |
|---|
| 96 | |
|---|
| 97 | # ---------------------------------------------------------------------- |
|---|
| 98 | # USAGE: clear ?<index>? |
|---|
| 99 | # |
|---|
| 100 | # Clears one or all results in this result viewer. |
|---|
| 101 | # ---------------------------------------------------------------------- |
|---|
| 102 | itcl::body Rappture::ResultViewer::clear {{index ""}} { |
|---|
| 103 | if {"" != $index} { |
|---|
| 104 | # clear one result |
|---|
| 105 | if {$index >= 0 && $index < [llength $_dataslots]} { |
|---|
| 106 | set slot [lindex $_dataslots $index] |
|---|
| 107 | foreach dobj $slot { |
|---|
| 108 | itcl::delete object $dobj |
|---|
| 109 | } |
|---|
| 110 | set _dataslots [lreplace $_dataslots $index $index ""] |
|---|
| 111 | } |
|---|
| 112 | } else { |
|---|
| 113 | # clear all results |
|---|
| 114 | plot clear |
|---|
| 115 | foreach slot $_dataslots { |
|---|
| 116 | foreach dobj $slot { |
|---|
| 117 | itcl::delete object $dobj |
|---|
| 118 | } |
|---|
| 119 | } |
|---|
| 120 | set _dataslots "" |
|---|
| 121 | } |
|---|
| 122 | } |
|---|
| 123 | |
|---|
| 124 | # ---------------------------------------------------------------------- |
|---|
| 125 | # USAGE: value <xmlobj> |
|---|
| 126 | # |
|---|
| 127 | # Convenience method for showing a single value. Loads the value |
|---|
| 128 | # into the widget via add/clear, then immediately plots the value. |
|---|
| 129 | # This makes the widget consistent with other widgets, such as |
|---|
| 130 | # the DeviceEditor, etc. |
|---|
| 131 | # ---------------------------------------------------------------------- |
|---|
| 132 | itcl::body Rappture::ResultViewer::value {xmlobj} { |
|---|
| 133 | clear |
|---|
| 134 | if {"" != $xmlobj} { |
|---|
| 135 | add 0 $xmlobj "" |
|---|
| 136 | plot add 0 "" |
|---|
| 137 | } |
|---|
| 138 | } |
|---|
| 139 | |
|---|
| 140 | # ---------------------------------------------------------------------- |
|---|
| 141 | # USAGE: plot add ?<index> <settings> <index> <settings> ...? |
|---|
| 142 | # USAGE: plot clear |
|---|
| 143 | # |
|---|
| 144 | # Used to manipulate the contents of this viewer. The "plot clear" |
|---|
| 145 | # command clears the current viewer. Data is still stored in the |
|---|
| 146 | # widget, but the results are not shown on screen. The "plot add" |
|---|
| 147 | # command adds the data at the specified <index> to the plot. If |
|---|
| 148 | # the optional <settings> are specified, then they are applied |
|---|
| 149 | # to the plot; otherwise, default settings are used. |
|---|
| 150 | # ---------------------------------------------------------------------- |
|---|
| 151 | itcl::body Rappture::ResultViewer::plot {option args} { |
|---|
| 152 | switch -- $option { |
|---|
| 153 | add { |
|---|
| 154 | set params "" |
|---|
| 155 | foreach {index opts} $args { |
|---|
| 156 | if {$index == "params"} { |
|---|
| 157 | set params $opts |
|---|
| 158 | continue |
|---|
| 159 | } |
|---|
| 160 | set reset "-color autoreset" |
|---|
| 161 | set slot [lindex $_dataslots $index] |
|---|
| 162 | foreach dobj $slot { |
|---|
| 163 | set settings "" |
|---|
| 164 | # start with color reset, only for first object in series |
|---|
| 165 | if {"" != $reset} { |
|---|
| 166 | set settings $reset |
|---|
| 167 | set reset "" |
|---|
| 168 | } |
|---|
| 169 | # add default settings from data object |
|---|
| 170 | if {[catch {$dobj hints style} style] == 0} { |
|---|
| 171 | eval lappend settings $style |
|---|
| 172 | } |
|---|
| 173 | if {[catch {$dobj hints type} type] == 0} { |
|---|
| 174 | if {"" != $type} { |
|---|
| 175 | eval lappend settings "-type $type" |
|---|
| 176 | } |
|---|
| 177 | } |
|---|
| 178 | # add override settings passed in here |
|---|
| 179 | eval lappend settings $opts |
|---|
| 180 | |
|---|
| 181 | _plotAdd $dobj $settings |
|---|
| 182 | } |
|---|
| 183 | } |
|---|
| 184 | if {"" != $params && "" != $_mode} { |
|---|
| 185 | eval $_mode2widget($_mode) parameters $params |
|---|
| 186 | } |
|---|
| 187 | } |
|---|
| 188 | clear { |
|---|
| 189 | # clear the contents of the current mode |
|---|
| 190 | if {"" != $_mode} { |
|---|
| 191 | $_mode2widget($_mode) delete |
|---|
| 192 | } |
|---|
| 193 | } |
|---|
| 194 | default { |
|---|
| 195 | error "bad option \"$option\": should be add or clear" |
|---|
| 196 | } |
|---|
| 197 | } |
|---|
| 198 | } |
|---|
| 199 | |
|---|
| 200 | # ---------------------------------------------------------------------- |
|---|
| 201 | # USAGE: _plotAdd <dataobj> <settings> |
|---|
| 202 | # |
|---|
| 203 | # Used internally to add a <dataobj> representing some data to |
|---|
| 204 | # the plot at the top of this widget. The data is added to the |
|---|
| 205 | # current plot. Use the "clear" function to clear before adding |
|---|
| 206 | # new data. |
|---|
| 207 | # ---------------------------------------------------------------------- |
|---|
| 208 | itcl::body Rappture::ResultViewer::_plotAdd {dataobj {settings ""}} { |
|---|
| 209 | switch -- [$dataobj info class] { |
|---|
| 210 | ::Rappture::Histogram { |
|---|
| 211 | set mode "histogram" |
|---|
| 212 | if {![info exists _mode2widget($mode)]} { |
|---|
| 213 | set w $itk_interior.xy |
|---|
| 214 | Rappture::HistogramResult $w |
|---|
| 215 | set _mode2widget($mode) $w |
|---|
| 216 | } |
|---|
| 217 | } |
|---|
| 218 | ::Rappture::Curve { |
|---|
| 219 | set type [$dataobj hints type] |
|---|
| 220 | set mode "xy" |
|---|
| 221 | if { $type == "bars" } { |
|---|
| 222 | if {![info exists _mode2widget($mode)]} { |
|---|
| 223 | set w $itk_interior.xy |
|---|
| 224 | Rappture::BarResult $w |
|---|
| 225 | set _mode2widget($mode) $w |
|---|
| 226 | } |
|---|
| 227 | } else { |
|---|
| 228 | if {![info exists _mode2widget($mode)]} { |
|---|
| 229 | set w $itk_interior.xy |
|---|
| 230 | Rappture::XyResult $w |
|---|
| 231 | set _mode2widget($mode) $w |
|---|
| 232 | } |
|---|
| 233 | } |
|---|
| 234 | } |
|---|
| 235 | ::Rappture::Field { |
|---|
| 236 | set dims [lindex [lsort [$dataobj components -dimensions]] end] |
|---|
| 237 | switch -- $dims { |
|---|
| 238 | 1D { |
|---|
| 239 | set mode "xy" |
|---|
| 240 | if {![info exists _mode2widget($mode)]} { |
|---|
| 241 | set w $itk_interior.xy |
|---|
| 242 | Rappture::XyResult $w |
|---|
| 243 | set _mode2widget($mode) $w |
|---|
| 244 | } |
|---|
| 245 | } |
|---|
| 246 | 2D { |
|---|
| 247 | set mode "contour" |
|---|
| 248 | if {![info exists _mode2widget($mode)]} { |
|---|
| 249 | if { [$dataobj isunirect2d] } { |
|---|
| 250 | set resultMode "heightmap" |
|---|
| 251 | } else { |
|---|
| 252 | set resultMode "vtk" |
|---|
| 253 | } |
|---|
| 254 | set extents [$dataobj extents] |
|---|
| 255 | if { $extents > 1 } { |
|---|
| 256 | set resultMode "flowvis" |
|---|
| 257 | } |
|---|
| 258 | set w $itk_interior.contour |
|---|
| 259 | if { ![winfo exists $w] } { |
|---|
| 260 | Rappture::Field2DResult $w -mode $resultMode |
|---|
| 261 | } |
|---|
| 262 | set _mode2widget($mode) $w |
|---|
| 263 | } |
|---|
| 264 | } |
|---|
| 265 | 3D { |
|---|
| 266 | set mode "field3D" |
|---|
| 267 | if {![info exists _mode2widget($mode)]} { |
|---|
| 268 | set mesh [$dataobj mesh] |
|---|
| 269 | set fmt [expr {("" != $mesh) ? "vtk" : "nanovis"}] |
|---|
| 270 | set extents [$dataobj extents] |
|---|
| 271 | if { $extents > 1 } { |
|---|
| 272 | set fmt "flowvis" |
|---|
| 273 | } |
|---|
| 274 | set w $itk_interior.field3D |
|---|
| 275 | Rappture::Field3DResult $w -mode $fmt |
|---|
| 276 | set _mode2widget($mode) $w |
|---|
| 277 | } |
|---|
| 278 | } |
|---|
| 279 | default { |
|---|
| 280 | error "can't handle [$dataobj components -dimensions] field" |
|---|
| 281 | } |
|---|
| 282 | } |
|---|
| 283 | } |
|---|
| 284 | ::Rappture::Mesh { |
|---|
| 285 | switch -- [$dataobj dimensions] { |
|---|
| 286 | 2 { |
|---|
| 287 | set mode "mesh" |
|---|
| 288 | if {![info exists _mode2widget($mode)]} { |
|---|
| 289 | set w $itk_interior.mesh |
|---|
| 290 | Rappture::MeshResult $w |
|---|
| 291 | set _mode2widget($mode) $w |
|---|
| 292 | } |
|---|
| 293 | } |
|---|
| 294 | default { |
|---|
| 295 | error "can't handle [$dataobj dimensions]D field" |
|---|
| 296 | } |
|---|
| 297 | } |
|---|
| 298 | } |
|---|
| 299 | ::Rappture::Table { |
|---|
| 300 | set cols [Rappture::EnergyLevels::columns $dataobj] |
|---|
| 301 | if {"" != $cols} { |
|---|
| 302 | set mode "energies" |
|---|
| 303 | if {![info exists _mode2widget($mode)]} { |
|---|
| 304 | set w $itk_interior.energies |
|---|
| 305 | Rappture::EnergyLevels $w |
|---|
| 306 | set _mode2widget($mode) $w |
|---|
| 307 | } |
|---|
| 308 | } |
|---|
| 309 | } |
|---|
| 310 | ::Rappture::LibraryObj { |
|---|
| 311 | switch -- [$dataobj element -as type] { |
|---|
| 312 | string - log { |
|---|
| 313 | set mode "log" |
|---|
| 314 | if {![info exists _mode2widget($mode)]} { |
|---|
| 315 | set w $itk_interior.log |
|---|
| 316 | Rappture::TextResult $w |
|---|
| 317 | set _mode2widget($mode) $w |
|---|
| 318 | } |
|---|
| 319 | } |
|---|
| 320 | structure { |
|---|
| 321 | set mode "structure" |
|---|
| 322 | if {![info exists _mode2widget($mode)]} { |
|---|
| 323 | set w $itk_interior.struct |
|---|
| 324 | Rappture::DeviceResult $w |
|---|
| 325 | set _mode2widget($mode) $w |
|---|
| 326 | } |
|---|
| 327 | } |
|---|
| 328 | number - integer { |
|---|
| 329 | set mode "number" |
|---|
| 330 | if {![info exists _mode2widget($mode)]} { |
|---|
| 331 | set w $itk_interior.number |
|---|
| 332 | Rappture::NumberResult $w |
|---|
| 333 | set _mode2widget($mode) $w |
|---|
| 334 | } |
|---|
| 335 | } |
|---|
| 336 | boolean - choice { |
|---|
| 337 | set mode "value" |
|---|
| 338 | if {![info exists _mode2widget($mode)]} { |
|---|
| 339 | set w $itk_interior.value |
|---|
| 340 | Rappture::ValueResult $w |
|---|
| 341 | set _mode2widget($mode) $w |
|---|
| 342 | } |
|---|
| 343 | } |
|---|
| 344 | } |
|---|
| 345 | } |
|---|
| 346 | ::Rappture::Image { |
|---|
| 347 | set mode "image" |
|---|
| 348 | if {![info exists _mode2widget($mode)]} { |
|---|
| 349 | set w $itk_interior.image |
|---|
| 350 | Rappture::ImageResult $w |
|---|
| 351 | set _mode2widget($mode) $w |
|---|
| 352 | } |
|---|
| 353 | } |
|---|
| 354 | ::Rappture::Sequence { |
|---|
| 355 | set mode "sequence" |
|---|
| 356 | if {![info exists _mode2widget($mode)]} { |
|---|
| 357 | set w $itk_interior.image |
|---|
| 358 | Rappture::SequenceResult $w |
|---|
| 359 | set _mode2widget($mode) $w |
|---|
| 360 | } |
|---|
| 361 | } |
|---|
| 362 | default { |
|---|
| 363 | error "don't know how to plot <$type> data" |
|---|
| 364 | } |
|---|
| 365 | } |
|---|
| 366 | |
|---|
| 367 | if {$mode != $_mode && $_mode != ""} { |
|---|
| 368 | set nactive [llength [$_mode2widget($_mode) get]] |
|---|
| 369 | if {$nactive > 0} { |
|---|
| 370 | return ;# mixing data that doesn't mix -- ignore it! |
|---|
| 371 | } |
|---|
| 372 | } |
|---|
| 373 | |
|---|
| 374 | # are we plotting in a new mode? then change widgets |
|---|
| 375 | if {$_mode2widget($mode) != [pack slaves $itk_interior]} { |
|---|
| 376 | # remove any current window |
|---|
| 377 | foreach w [pack slaves $itk_interior] { |
|---|
| 378 | pack forget $w |
|---|
| 379 | } |
|---|
| 380 | pack $_mode2widget($mode) -expand yes -fill both |
|---|
| 381 | |
|---|
| 382 | set _mode $mode |
|---|
| 383 | $_dispatcher event -idle !scale |
|---|
| 384 | } |
|---|
| 385 | $_mode2widget($mode) add $dataobj $settings |
|---|
| 386 | } |
|---|
| 387 | |
|---|
| 388 | # ---------------------------------------------------------------------- |
|---|
| 389 | # USAGE: _fixScale ?<eventArgs>...? |
|---|
| 390 | # |
|---|
| 391 | # Invoked automatically whenever a new dataset is added to fix the |
|---|
| 392 | # overall scales of the viewer. This makes the visualizer consistent |
|---|
| 393 | # across all <dataobj> in this widget, so that it can plot all |
|---|
| 394 | # available data. |
|---|
| 395 | # ---------------------------------------------------------------------- |
|---|
| 396 | itcl::body Rappture::ResultViewer::_fixScale {args} { |
|---|
| 397 | if {"" != $_mode} { |
|---|
| 398 | set dlist "" |
|---|
| 399 | foreach slot $_dataslots { |
|---|
| 400 | foreach dobj $slot { |
|---|
| 401 | lappend dlist $dobj |
|---|
| 402 | } |
|---|
| 403 | } |
|---|
| 404 | eval $_mode2widget($_mode) scale $dlist |
|---|
| 405 | } |
|---|
| 406 | } |
|---|
| 407 | |
|---|
| 408 | # ---------------------------------------------------------------------- |
|---|
| 409 | # USAGE: download coming |
|---|
| 410 | # USAGE: download controls <downloadCommand> |
|---|
| 411 | # USAGE: download now |
|---|
| 412 | # |
|---|
| 413 | # Clients use this method to create a downloadable representation |
|---|
| 414 | # of the plot. Returns a list of the form {ext string}, where |
|---|
| 415 | # "ext" is the file extension (indicating the type of data) and |
|---|
| 416 | # "string" is the data itself. |
|---|
| 417 | # ---------------------------------------------------------------------- |
|---|
| 418 | itcl::body Rappture::ResultViewer::download {option args} { |
|---|
| 419 | if {"" == $_mode} { |
|---|
| 420 | return "" |
|---|
| 421 | } |
|---|
| 422 | return [eval $_mode2widget($_mode) download $option $args] |
|---|
| 423 | } |
|---|
| 424 | |
|---|
| 425 | # ---------------------------------------------------------------------- |
|---|
| 426 | # USAGE: _xml2data <xmlobj> <path> |
|---|
| 427 | # |
|---|
| 428 | # Used internally to create a data object for the data at the |
|---|
| 429 | # specified <path> in the <xmlobj>. |
|---|
| 430 | # ---------------------------------------------------------------------- |
|---|
| 431 | itcl::body Rappture::ResultViewer::_xml2data {xmlobj path} { |
|---|
| 432 | set type [$xmlobj element -as type $path] |
|---|
| 433 | switch -- $type { |
|---|
| 434 | curve { |
|---|
| 435 | return [Rappture::Curve ::#auto $xmlobj $path] |
|---|
| 436 | } |
|---|
| 437 | histogram { |
|---|
| 438 | return [Rappture::Histogram ::#auto $xmlobj $path] |
|---|
| 439 | } |
|---|
| 440 | field { |
|---|
| 441 | return [Rappture::Field ::#auto $xmlobj $path] |
|---|
| 442 | } |
|---|
| 443 | mesh { |
|---|
| 444 | return [Rappture::Mesh ::#auto $xmlobj $path] |
|---|
| 445 | } |
|---|
| 446 | table { |
|---|
| 447 | return [Rappture::Table ::#auto $xmlobj $path] |
|---|
| 448 | } |
|---|
| 449 | image { |
|---|
| 450 | return [Rappture::Image ::#auto $xmlobj $path] |
|---|
| 451 | } |
|---|
| 452 | sequence { |
|---|
| 453 | return [Rappture::Sequence ::#auto $xmlobj $path] |
|---|
| 454 | } |
|---|
| 455 | string - log { |
|---|
| 456 | return [$xmlobj element -as object $path] |
|---|
| 457 | } |
|---|
| 458 | structure { |
|---|
| 459 | return [$xmlobj element -as object $path] |
|---|
| 460 | } |
|---|
| 461 | number - integer - boolean - choice { |
|---|
| 462 | return [$xmlobj element -as object $path] |
|---|
| 463 | } |
|---|
| 464 | time - status { |
|---|
| 465 | return "" |
|---|
| 466 | } |
|---|
| 467 | } |
|---|
| 468 | error "don't know how to plot <$type> data" |
|---|
| 469 | } |
|---|
| 470 | |
|---|
| 471 | # ---------------------------------------------------------------------- |
|---|
| 472 | # CONFIGURATION OPTION: -width |
|---|
| 473 | # ---------------------------------------------------------------------- |
|---|
| 474 | itcl::configbody Rappture::ResultViewer::width { |
|---|
| 475 | set w [winfo pixels $itk_component(hull) $itk_option(-width)] |
|---|
| 476 | set h [winfo pixels $itk_component(hull) $itk_option(-height)] |
|---|
| 477 | if {$w == 0 || $h == 0} { |
|---|
| 478 | pack propagate $itk_component(hull) yes |
|---|
| 479 | } else { |
|---|
| 480 | component hull configure -width $w -height $h |
|---|
| 481 | pack propagate $itk_component(hull) no |
|---|
| 482 | } |
|---|
| 483 | } |
|---|
| 484 | |
|---|
| 485 | # ---------------------------------------------------------------------- |
|---|
| 486 | # CONFIGURATION OPTION: -height |
|---|
| 487 | # ---------------------------------------------------------------------- |
|---|
| 488 | itcl::configbody Rappture::ResultViewer::height { |
|---|
| 489 | set h [winfo pixels $itk_component(hull) $itk_option(-height)] |
|---|
| 490 | set w [winfo pixels $itk_component(hull) $itk_option(-width)] |
|---|
| 491 | if {$w == 0 || $h == 0} { |
|---|
| 492 | pack propagate $itk_component(hull) yes |
|---|
| 493 | } else { |
|---|
| 494 | component hull configure -width $w -height $h |
|---|
| 495 | pack propagate $itk_component(hull) no |
|---|
| 496 | } |
|---|
| 497 | } |
|---|
