| 1 | # ---------------------------------------------------------------------- |
|---|
| 2 | # COMPONENT: ResultViewer - plots a collection of related results |
|---|
| 3 | # |
|---|
| 4 | # This widget plots a collection of results that all represent |
|---|
| 5 | # the same quantity, but for various ranges of input values. It |
|---|
| 6 | # is normally used as part of an Analyzer, to plot the various |
|---|
| 7 | # results selected by a ResultSet. |
|---|
| 8 | # ====================================================================== |
|---|
| 9 | # AUTHOR: Michael McLennan, Purdue University |
|---|
| 10 | # Copyright (c) 2004-2005 Purdue Research Foundation |
|---|
| 11 | # |
|---|
| 12 | # See the file "license.terms" for information on usage and |
|---|
| 13 | # redistribution of this file, and for a DISCLAIMER OF ALL WARRANTIES. |
|---|
| 14 | # ====================================================================== |
|---|
| 15 | package require Itk |
|---|
| 16 | |
|---|
| 17 | itcl::class Rappture::ResultViewer { |
|---|
| 18 | inherit itk::Widget |
|---|
| 19 | |
|---|
| 20 | itk_option define -width width Width 4i |
|---|
| 21 | itk_option define -height height Height 4i |
|---|
| 22 | itk_option define -colors colors Colors "" |
|---|
| 23 | itk_option define -clearcommand clearCommand ClearCommand "" |
|---|
| 24 | itk_option define -simulatecommand simulateCommand SimulateCommand "" |
|---|
| 25 | |
|---|
| 26 | constructor {args} { # defined below } |
|---|
| 27 | destructor { # defined below } |
|---|
| 28 | |
|---|
| 29 | public method add {index xmlobj path} |
|---|
| 30 | public method clear {{index ""}} |
|---|
| 31 | public method value {xmlobj} |
|---|
| 32 | |
|---|
| 33 | public method plot {option args} |
|---|
| 34 | public method download {option args} |
|---|
| 35 | |
|---|
| 36 | protected method _plotAdd {xmlobj {settings ""}} |
|---|
| 37 | protected method _fixScale {args} |
|---|
| 38 | protected proc _xml2data {xmlobj path} |
|---|
| 39 | |
|---|
| 40 | private variable _dispatcher "" ;# dispatchers for !events |
|---|
| 41 | private variable _mode "" ;# current plotting mode (xy, etc.) |
|---|
| 42 | private variable _mode2widget ;# maps plotting mode => widget |
|---|
| 43 | private variable _dataslots "" ;# list of all data objects in this widget |
|---|
| 44 | } |
|---|
| 45 | |
|---|
| 46 | itk::usual ResultViewer { |
|---|
| 47 | keep -background -foreground -cursor -font |
|---|
| 48 | } |
|---|
| 49 | |
|---|
| 50 | # ---------------------------------------------------------------------- |
|---|
| 51 | # CONSTRUCTOR |
|---|
| 52 | # ---------------------------------------------------------------------- |
|---|
| 53 | itcl::body Rappture::ResultViewer::constructor {args} { |
|---|
| 54 | # create a dispatcher for events |
|---|
| 55 | Rappture::dispatcher _dispatcher |
|---|
| 56 | $_dispatcher register !scale |
|---|
| 57 | $_dispatcher dispatch $this !scale \ |
|---|
| 58 | [itcl::code $this _fixScale] |
|---|
| 59 | |
|---|
| 60 | eval itk_initialize $args |
|---|
| 61 | } |
|---|
| 62 | |
|---|
| 63 | # ---------------------------------------------------------------------- |
|---|
| 64 | # DESTRUCTOR |
|---|
| 65 | # ---------------------------------------------------------------------- |
|---|
| 66 | itcl::body Rappture::ResultViewer::destructor {} { |
|---|
| 67 | foreach slot $_dataslots { |
|---|
| 68 | foreach obj $slot { |
|---|
| 69 | itcl::delete object $obj |
|---|
| 70 | } |
|---|
| 71 | } |
|---|
| 72 | } |
|---|
| 73 | |
|---|
| 74 | # ---------------------------------------------------------------------- |
|---|
| 75 | # USAGE: add <index> <xmlobj> <path> |
|---|
| 76 | # |
|---|
| 77 | # Adds a new result to this result viewer at the specified <index>. |
|---|
| 78 | # Data is taken from the <xmlobj> object at the <path>. |
|---|
| 79 | # ---------------------------------------------------------------------- |
|---|
| 80 | itcl::body Rappture::ResultViewer::add {index xmlobj path} { |
|---|
| 81 | set dobj [_xml2data $xmlobj $path] |
|---|
| 82 | |
|---|
| 83 | # |
|---|
| 84 | # If the index doesn't exist, then fill in empty slots and |
|---|
| 85 | # make it exist. |
|---|
| 86 | # |
|---|
| 87 | for {set i [llength $_dataslots]} {$i <= $index} {incr i} { |
|---|
| 88 | lappend _dataslots "" |
|---|
| 89 | } |
|---|
| 90 | set slot [lindex $_dataslots $index] |
|---|
| 91 | lappend slot $dobj |
|---|
| 92 | set _dataslots [lreplace $_dataslots $index $index $slot] |
|---|
| 93 | |
|---|
| 94 | $_dispatcher event -idle !scale |
|---|
| 95 | } |
|---|
| 96 | |
|---|
| 97 | # ---------------------------------------------------------------------- |
|---|
| 98 | # USAGE: clear ?<index>? |
|---|
| 99 | # |
|---|
| 100 | # Clears one or all results in this result viewer. |
|---|
| 101 | # ---------------------------------------------------------------------- |
|---|
| 102 | itcl::body Rappture::ResultViewer::clear {{index ""}} { |
|---|
| 103 | if {"" != $index} { |
|---|
| 104 | # clear one result |
|---|
| 105 | if {$index >= 0 && $index < [llength $_dataslots]} { |
|---|
| 106 | set slot [lindex $_dataslots $index] |
|---|
| 107 | foreach dobj $slot { |
|---|
| 108 | itcl::delete object $dobj |
|---|
| 109 | } |
|---|
| 110 | set _dataslots [lreplace $_dataslots $index $index ""] |
|---|
| 111 | } |
|---|
| 112 | } else { |
|---|
| 113 | # clear all results |
|---|
| 114 | plot clear |
|---|
| 115 | foreach slot $_dataslots { |
|---|
| 116 | foreach dobj $slot { |
|---|
| 117 | itcl::delete object $dobj |
|---|
| 118 | } |
|---|
| 119 | } |
|---|
| 120 | set _dataslots "" |
|---|
| 121 | } |
|---|
| 122 | } |
|---|
| 123 | |
|---|
| 124 | # ---------------------------------------------------------------------- |
|---|
| 125 | # USAGE: value <xmlobj> |
|---|
| 126 | # |
|---|
| 127 | # Convenience method for showing a single value. Loads the value |
|---|
| 128 | # into the widget via add/clear, then immediately plots the value. |
|---|
| 129 | # This makes the widget consistent with other widgets, such as |
|---|
| 130 | # the DeviceEditor, etc. |
|---|
| 131 | # ---------------------------------------------------------------------- |
|---|
| 132 | itcl::body Rappture::ResultViewer::value {xmlobj} { |
|---|
| 133 | clear |
|---|
| 134 | if {"" != $xmlobj} { |
|---|
| 135 | add 0 $xmlobj "" |
|---|
| 136 | plot add 0 "" |
|---|
| 137 | } |
|---|
| 138 | } |
|---|
| 139 | |
|---|
| 140 | # ---------------------------------------------------------------------- |
|---|
| 141 | # USAGE: plot add ?<index> <settings> <index> <settings> ...? |
|---|
| 142 | # USAGE: plot clear |
|---|
| 143 | # |
|---|
| 144 | # Used to manipulate the contents of this viewer. The "plot clear" |
|---|
| 145 | # command clears the current viewer. Data is still stored in the |
|---|
| 146 | # widget, but the results are not shown on screen. The "plot add" |
|---|
| 147 | # command adds the data at the specified <index> to the plot. If |
|---|
| 148 | # the optional <settings> are specified, then they are applied |
|---|
| 149 | # to the plot; otherwise, default settings are used. |
|---|
| 150 | # ---------------------------------------------------------------------- |
|---|
| 151 | itcl::body Rappture::ResultViewer::plot {option args} { |
|---|
| 152 | switch -- $option { |
|---|
| 153 | add { |
|---|
| 154 | set params "" |
|---|
| 155 | foreach {index opts} $args { |
|---|
| 156 | if {$index == "params"} { |
|---|
| 157 | set params $opts |
|---|
| 158 | continue |
|---|
| 159 | } |
|---|
| 160 | set reset "-color autoreset" |
|---|
| 161 | set slot [lindex $_dataslots $index] |
|---|
| 162 | foreach dobj $slot { |
|---|
| 163 | set settings "" |
|---|
| 164 | # start with color reset, only for first object in series |
|---|
| 165 | if {"" != $reset} { |
|---|
| 166 | set settings $reset |
|---|
| 167 | set reset "" |
|---|
| 168 | } |
|---|
| 169 | # add default settings from data object |
|---|
| 170 | if {[catch {$dobj hints style} style] == 0} { |
|---|
| 171 | eval lappend settings $style |
|---|
| 172 | } |
|---|
| 173 | if {[catch {$dobj hints type} type] == 0} { |
|---|
| 174 | if {"" != $type} { |
|---|
| 175 | eval lappend settings "-type $type" |
|---|
| 176 | } |
|---|
| 177 | } |
|---|
| 178 | # add override settings passed in here |
|---|
| 179 | eval lappend settings $opts |
|---|
| 180 | |
|---|
| 181 | _plotAdd $dobj $settings |
|---|
| 182 | } |
|---|
| 183 | } |
|---|
| 184 | if {"" != $params && "" != $_mode} { |
|---|
| 185 | eval $_mode2widget($_mode) parameters $params |
|---|
| 186 | } |
|---|
| 187 | } |
|---|
| 188 | clear { |
|---|
| 189 | # clear the contents of the current mode |
|---|
| 190 | if {"" != $_mode} { |
|---|
| 191 | $_mode2widget($_mode) delete |
|---|
| 192 | } |
|---|
| 193 | } |
|---|
| 194 | default { |
|---|
| 195 | error "bad option \"$option\": should be add or clear" |
|---|
| 196 | } |
|---|
| 197 | } |
|---|
| 198 | } |
|---|
| 199 | |
|---|
| 200 | # ---------------------------------------------------------------------- |
|---|
| 201 | # USAGE: _plotAdd <dataobj> <settings> |
|---|
| 202 | # |
|---|
| 203 | # Used internally to add a <dataobj> representing some data to |
|---|
| 204 | # the plot at the top of this widget. The data is added to the |
|---|
| 205 | # current plot. Use the "clear" function to clear before adding |
|---|
| 206 | # new data. |
|---|
| 207 | # ---------------------------------------------------------------------- |
|---|
| 208 | itcl::body Rappture::ResultViewer::_plotAdd {dataobj {settings ""}} { |
|---|
| 209 | switch -- [$dataobj info class] { |
|---|
| 210 | ::Rappture::Drawing3d { |
|---|
| 211 | set mode "vtkviewer" |
|---|
| 212 | if {![info exists _mode2widget($mode)]} { |
|---|
| 213 | set w $itk_interior.xy |
|---|
| 214 | Rappture::VtkViewer $w |
|---|
| 215 | set _mode2widget($mode) $w |
|---|
| 216 | } |
|---|
| 217 | } |
|---|
| 218 | ::Rappture::Histogram { |
|---|
| 219 | set mode "histogram" |
|---|
| 220 | if {![info exists _mode2widget($mode)]} { |
|---|
| 221 | set w $itk_interior.xy |
|---|
| 222 | Rappture::HistogramResult $w |
|---|
| 223 | set _mode2widget($mode) $w |
|---|
| 224 | } |
|---|
| 225 | } |
|---|
| 226 | ::Rappture::Curve { |
|---|
| 227 | set type [$dataobj hints type] |
|---|
| 228 | set mode "xy" |
|---|
| 229 | if { $type == "bars" } { |
|---|
| 230 | if {![info exists _mode2widget($mode)]} { |
|---|
| 231 | set w $itk_interior.xy |
|---|
| 232 | Rappture::BarResult $w |
|---|
| 233 | set _mode2widget($mode) $w |
|---|
| 234 | } |
|---|
| 235 | } else { |
|---|
| 236 | if {![info exists _mode2widget($mode)]} { |
|---|
| 237 | set w $itk_interior.xy |
|---|
| 238 | Rappture::XyResult $w |
|---|
| 239 | set _mode2widget($mode) $w |
|---|
| 240 | } |
|---|
| 241 | } |
|---|
| 242 | } |
|---|
| 243 | ::Rappture::Field { |
|---|
| 244 | set dims [lindex [lsort [$dataobj components -dimensions]] end] |
|---|
| 245 | switch -- $dims { |
|---|
| 246 | 1D { |
|---|
| 247 | set mode "xy" |
|---|
| 248 | if {![info exists _mode2widget($mode)]} { |
|---|
| 249 | set w $itk_interior.xy |
|---|
| 250 | Rappture::XyResult $w |
|---|
| 251 | set _mode2widget($mode) $w |
|---|
| 252 | } |
|---|
| 253 | } |
|---|
| 254 | 2D { |
|---|
| 255 | set mode "contour" |
|---|
| 256 | if {![info exists _mode2widget($mode)]} { |
|---|
| 257 | if { [$dataobj isunirect2d] } { |
|---|
| 258 | set resultMode "heightmap" |
|---|
| 259 | } else { |
|---|
| 260 | set resultMode "vtk" |
|---|
| 261 | } |
|---|
| 262 | set extents [$dataobj extents] |
|---|
| 263 | if { $extents > 1 } { |
|---|
| 264 | set resultMode "flowvis" |
|---|
| 265 | } |
|---|
| 266 | set w $itk_interior.contour |
|---|
| 267 | if { ![winfo exists $w] } { |
|---|
| 268 | Rappture::Field2DResult $w -mode $resultMode |
|---|
| 269 | } |
|---|
| 270 | set _mode2widget($mode) $w |
|---|
| 271 | } |
|---|
| 272 | } |
|---|
| 273 | 3D { |
|---|
| 274 | set mode "field3D" |
|---|
| 275 | if {![info exists _mode2widget($mode)]} { |
|---|
| 276 | set mesh [$dataobj mesh] |
|---|
| 277 | set fmt [expr {("" != $mesh) ? "vtk" : "nanovis"}] |
|---|
| 278 | set extents [$dataobj extents] |
|---|
| 279 | if { $extents > 1 } { |
|---|
| 280 | set fmt "flowvis" |
|---|
| 281 | } |
|---|
| 282 | set w $itk_interior.field3D |
|---|
| 283 | Rappture::Field3DResult $w -mode $fmt |
|---|
| 284 | set _mode2widget($mode) $w |
|---|
| 285 | } |
|---|
| 286 | } |
|---|
| 287 | default { |
|---|
| 288 | error "can't handle [$dataobj components -dimensions] field" |
|---|
| 289 | } |
|---|
| 290 | } |
|---|
| 291 | } |
|---|
| 292 | ::Rappture::Mesh { |
|---|
| 293 | switch -- [$dataobj dimensions] { |
|---|
| 294 | 2 { |
|---|
| 295 | set mode "mesh" |
|---|
| 296 | if {![info exists _mode2widget($mode)]} { |
|---|
| 297 | set w $itk_interior.mesh |
|---|
| 298 | Rappture::MeshResult $w |
|---|
| 299 | set _mode2widget($mode) $w |
|---|
| 300 | } |
|---|
| 301 | } |
|---|
| 302 | default { |
|---|
| 303 | error "can't handle [$dataobj dimensions]D field" |
|---|
| 304 | } |
|---|
| 305 | } |
|---|
| 306 | } |
|---|
| 307 | ::Rappture::Table { |
|---|
| 308 | set cols [Rappture::EnergyLevels::columns $dataobj] |
|---|
| 309 | if {"" != $cols} { |
|---|
| 310 | set mode "energies" |
|---|
| 311 | if {![info exists _mode2widget($mode)]} { |
|---|
| 312 | set w $itk_interior.energies |
|---|
| 313 | Rappture::EnergyLevels $w |
|---|
| 314 | set _mode2widget($mode) $w |
|---|
| 315 | } |
|---|
| 316 | } |
|---|
| 317 | } |
|---|
| 318 | ::Rappture::LibraryObj { |
|---|
| 319 | switch -- [$dataobj element -as type] { |
|---|
| 320 | string - log { |
|---|
| 321 | set mode "log" |
|---|
| 322 | if {![info exists _mode2widget($mode)]} { |
|---|
| 323 | set w $itk_interior.log |
|---|
| 324 | Rappture::TextResult $w |
|---|
| 325 | set _mode2widget($mode) $w |
|---|
| 326 | } |
|---|
| 327 | } |
|---|
| 328 | structure { |
|---|
| 329 | set mode "structure" |
|---|
| 330 | if {![info exists _mode2widget($mode)]} { |
|---|
| 331 | set w $itk_interior.struct |
|---|
| 332 | Rappture::DeviceResult $w |
|---|
| 333 | set _mode2widget($mode) $w |
|---|
| 334 | } |
|---|
| 335 | } |
|---|
| 336 | number - integer { |
|---|
| 337 | set mode "number" |
|---|
| 338 | if {![info exists _mode2widget($mode)]} { |
|---|
| 339 | set w $itk_interior.number |
|---|
| 340 | Rappture::NumberResult $w |
|---|
| 341 | set _mode2widget($mode) $w |
|---|
| 342 | } |
|---|
| 343 | } |
|---|
| 344 | boolean - choice { |
|---|
| 345 | set mode "value" |
|---|
| 346 | if {![info exists _mode2widget($mode)]} { |
|---|
| 347 | set w $itk_interior.value |
|---|
| 348 | Rappture::ValueResult $w |
|---|
| 349 | set _mode2widget($mode) $w |
|---|
| 350 | } |
|---|
| 351 | } |
|---|
| 352 | } |
|---|
| 353 | } |
|---|
| 354 | ::Rappture::Image { |
|---|
| 355 | set mode "image" |
|---|
| 356 | if {![info exists _mode2widget($mode)]} { |
|---|
| 357 | set w $itk_interior.image |
|---|
| 358 | Rappture::ImageResult $w |
|---|
| 359 | set _mode2widget($mode) $w |
|---|
| 360 | } |
|---|
| 361 | } |
|---|
| 362 | ::Rappture::Sequence { |
|---|
| 363 | set mode "sequence" |
|---|
| 364 | if {![info exists _mode2widget($mode)]} { |
|---|
| 365 | set w $itk_interior.image |
|---|
| 366 | Rappture::SequenceResult $w |
|---|
| 367 | set _mode2widget($mode) $w |
|---|
| 368 | } |
|---|
| 369 | } |
|---|
| 370 | default { |
|---|
| 371 | error "don't know how to plot <$type> data" |
|---|
| 372 | } |
|---|
| 373 | } |
|---|
| 374 | |
|---|
| 375 | if {$mode != $_mode && $_mode != ""} { |
|---|
| 376 | set nactive [llength [$_mode2widget($_mode) get]] |
|---|
| 377 | if {$nactive > 0} { |
|---|
| 378 | return ;# mixing data that doesn't mix -- ignore it! |
|---|
| 379 | } |
|---|
| 380 | } |
|---|
| 381 | |
|---|
| 382 | # are we plotting in a new mode? then change widgets |
|---|
| 383 | if {$_mode2widget($mode) != [pack slaves $itk_interior]} { |
|---|
| 384 | # remove any current window |
|---|
| 385 | foreach w [pack slaves $itk_interior] { |
|---|
| 386 | pack forget $w |
|---|
| 387 | } |
|---|
| 388 | pack $_mode2widget($mode) -expand yes -fill both |
|---|
| 389 | |
|---|
| 390 | set _mode $mode |
|---|
| 391 | $_dispatcher event -idle !scale |
|---|
| 392 | } |
|---|
| 393 | $_mode2widget($mode) add $dataobj $settings |
|---|
| 394 | } |
|---|
| 395 | |
|---|
| 396 | # ---------------------------------------------------------------------- |
|---|
| 397 | # USAGE: _fixScale ?<eventArgs>...? |
|---|
| 398 | # |
|---|
| 399 | # Invoked automatically whenever a new dataset is added to fix the |
|---|
| 400 | # overall scales of the viewer. This makes the visualizer consistent |
|---|
| 401 | # across all <dataobj> in this widget, so that it can plot all |
|---|
| 402 | # available data. |
|---|
| 403 | # ---------------------------------------------------------------------- |
|---|
| 404 | itcl::body Rappture::ResultViewer::_fixScale {args} { |
|---|
| 405 | if {"" != $_mode} { |
|---|
| 406 | set dlist "" |
|---|
| 407 | foreach slot $_dataslots { |
|---|
| 408 | foreach dobj $slot { |
|---|
| 409 | lappend dlist $dobj |
|---|
| 410 | } |
|---|
| 411 | } |
|---|
| 412 | eval $_mode2widget($_mode) scale $dlist |
|---|
| 413 | } |
|---|
| 414 | } |
|---|
| 415 | |
|---|
| 416 | # ---------------------------------------------------------------------- |
|---|
| 417 | # USAGE: download coming |
|---|
| 418 | # USAGE: download controls <downloadCommand> |
|---|
| 419 | # USAGE: download now |
|---|
| 420 | # |
|---|
| 421 | # Clients use this method to create a downloadable representation |
|---|
| 422 | # of the plot. Returns a list of the form {ext string}, where |
|---|
| 423 | # "ext" is the file extension (indicating the type of data) and |
|---|
| 424 | # "string" is the data itself. |
|---|
| 425 | # ---------------------------------------------------------------------- |
|---|
| 426 | itcl::body Rappture::ResultViewer::download {option args} { |
|---|
| 427 | if {"" == $_mode} { |
|---|
| 428 | return "" |
|---|
| 429 | } |
|---|
| 430 | return [eval $_mode2widget($_mode) download $option $args] |
|---|
| 431 | } |
|---|
| 432 | |
|---|
| 433 | # ---------------------------------------------------------------------- |
|---|
| 434 | # USAGE: _xml2data <xmlobj> <path> |
|---|
| 435 | # |
|---|
| 436 | # Used internally to create a data object for the data at the |
|---|
| 437 | # specified <path> in the <xmlobj>. |
|---|
| 438 | # ---------------------------------------------------------------------- |
|---|
| 439 | itcl::body Rappture::ResultViewer::_xml2data {xmlobj path} { |
|---|
| 440 | set type [$xmlobj element -as type $path] |
|---|
| 441 | switch -- $type { |
|---|
| 442 | curve { |
|---|
| 443 | return [Rappture::Curve ::#auto $xmlobj $path] |
|---|
| 444 | } |
|---|
| 445 | histogram { |
|---|
| 446 | return [Rappture::Histogram ::#auto $xmlobj $path] |
|---|
| 447 | } |
|---|
| 448 | field { |
|---|
| 449 | return [Rappture::Field ::#auto $xmlobj $path] |
|---|
| 450 | } |
|---|
| 451 | mesh { |
|---|
| 452 | return [Rappture::Mesh ::#auto $xmlobj $path] |
|---|
| 453 | } |
|---|
| 454 | table { |
|---|
| 455 | return [Rappture::Table ::#auto $xmlobj $path] |
|---|
| 456 | } |
|---|
| 457 | image { |
|---|
| 458 | return [Rappture::Image ::#auto $xmlobj $path] |
|---|
| 459 | } |
|---|
| 460 | sequence { |
|---|
| 461 | return [Rappture::Sequence ::#auto $xmlobj $path] |
|---|
| 462 | } |
|---|
| 463 | string - log { |
|---|
| 464 | return [$xmlobj element -as object $path] |
|---|
| 465 | } |
|---|
| 466 | structure { |
|---|
| 467 | return [$xmlobj element -as object $path] |
|---|
| 468 | } |
|---|
| 469 | number - integer - boolean - choice { |
|---|
| 470 | return [$xmlobj element -as object $path] |
|---|
| 471 | } |
|---|
| 472 | drawing3d { |
|---|
| 473 | return [Rappture::Drawing3d ::#auto $xmlobj $path] |
|---|
| 474 | } |
|---|
| 475 | time - status { |
|---|
| 476 | return "" |
|---|
| 477 | } |
|---|
| 478 | } |
|---|
| 479 | error "don't know how to plot <$type> data" |
|---|
| 480 | } |
|---|
| 481 | |
|---|
| 482 | # ---------------------------------------------------------------------- |
|---|
| 483 | # CONFIGURATION OPTION: -width |
|---|
| 484 | # ---------------------------------------------------------------------- |
|---|
| 485 | itcl::configbody Rappture::ResultViewer::width { |
|---|
| 486 | set w [winfo pixels $itk_component(hull) $itk_option(-width)] |
|---|
| 487 | set h [winfo pixels $itk_component(hull) $itk_option(-height)] |
|---|
| 488 | if {$w == 0 || $h == 0} { |
|---|
| 489 | pack propagate $itk_component(hull) yes |
|---|
| 490 | } else { |
|---|
| 491 | component hull configure -width $w -height $h |
|---|
| 492 | pack propagate $itk_component(hull) no |
|---|
| 493 | } |
|---|
| 494 | } |
|---|
| 495 | |
|---|
| 496 | # ---------------------------------------------------------------------- |
|---|
| 497 | # CONFIGURATION OPTION: -height |
|---|
| 498 | # ---------------------------------------------------------------------- |
|---|
| 499 | itcl::configbody Rappture::ResultViewer::height { |
|---|
| 500 | set h [winfo pixels $itk_component(hull) $itk_option(-height)] |
|---|
| 501 | set w [winfo pixels $itk_component(hull) $itk_option(-width)] |
|---|
| 502 | if {$w == 0 || $h == 0} { |
|---|
| 503 | pack propagate $itk_component(hull) yes |
|---|
| 504 | } else { |
|---|
| 505 | component hull configure -width $w -height $h |
|---|
| 506 | pack propagate $itk_component(hull) no |
|---|
| 507 | } |
|---|
| 508 | } |
|---|
