| 1 | # ---------------------------------------------------------------------- |
|---|
| 2 | # COMPONENT: ResultViewer - plots a collection of related results |
|---|
| 3 | # |
|---|
| 4 | # This widget plots a collection of results that all represent |
|---|
| 5 | # the same quantity, but for various ranges of input values. It |
|---|
| 6 | # is normally used as part of an Analyzer, to plot the various |
|---|
| 7 | # results selected by a ResultSet. |
|---|
| 8 | # ====================================================================== |
|---|
| 9 | # AUTHOR: Michael McLennan, Purdue University |
|---|
| 10 | # Copyright (c) 2004-2005 Purdue Research Foundation |
|---|
| 11 | # |
|---|
| 12 | # See the file "license.terms" for information on usage and |
|---|
| 13 | # redistribution of this file, and for a DISCLAIMER OF ALL WARRANTIES. |
|---|
| 14 | # ====================================================================== |
|---|
| 15 | package require Itk |
|---|
| 16 | |
|---|
| 17 | itcl::class Rappture::ResultViewer { |
|---|
| 18 | inherit itk::Widget |
|---|
| 19 | |
|---|
| 20 | itk_option define -width width Width 4i |
|---|
| 21 | itk_option define -height height Height 4i |
|---|
| 22 | itk_option define -colors colors Colors "" |
|---|
| 23 | itk_option define -clearcommand clearCommand ClearCommand "" |
|---|
| 24 | itk_option define -simulatecommand simulateCommand SimulateCommand "" |
|---|
| 25 | |
|---|
| 26 | constructor {args} { # defined below } |
|---|
| 27 | destructor { # defined below } |
|---|
| 28 | |
|---|
| 29 | public method add {index xmlobj path} |
|---|
| 30 | public method clear {{index ""}} |
|---|
| 31 | public method value {xmlobj} |
|---|
| 32 | |
|---|
| 33 | public method plot {option args} |
|---|
| 34 | public method download {option args} |
|---|
| 35 | |
|---|
| 36 | protected method _plotAdd {xmlobj {settings ""}} |
|---|
| 37 | protected method _fixScale {args} |
|---|
| 38 | protected proc _xml2data {xmlobj path} |
|---|
| 39 | |
|---|
| 40 | private variable _dispatcher "" ;# dispatchers for !events |
|---|
| 41 | private variable _mode "" ;# current plotting mode (xy, etc.) |
|---|
| 42 | private variable _mode2widget ;# maps plotting mode => widget |
|---|
| 43 | private variable _dataslots "" ;# list of all data objects in this widget |
|---|
| 44 | } |
|---|
| 45 | |
|---|
| 46 | itk::usual ResultViewer { |
|---|
| 47 | keep -background -foreground -cursor -font |
|---|
| 48 | } |
|---|
| 49 | |
|---|
| 50 | # ---------------------------------------------------------------------- |
|---|
| 51 | # CONSTRUCTOR |
|---|
| 52 | # ---------------------------------------------------------------------- |
|---|
| 53 | itcl::body Rappture::ResultViewer::constructor {args} { |
|---|
| 54 | # create a dispatcher for events |
|---|
| 55 | Rappture::dispatcher _dispatcher |
|---|
| 56 | $_dispatcher register !scale |
|---|
| 57 | $_dispatcher dispatch $this !scale \ |
|---|
| 58 | [itcl::code $this _fixScale] |
|---|
| 59 | |
|---|
| 60 | eval itk_initialize $args |
|---|
| 61 | } |
|---|
| 62 | |
|---|
| 63 | # ---------------------------------------------------------------------- |
|---|
| 64 | # DESTRUCTOR |
|---|
| 65 | # ---------------------------------------------------------------------- |
|---|
| 66 | itcl::body Rappture::ResultViewer::destructor {} { |
|---|
| 67 | foreach slot $_dataslots { |
|---|
| 68 | foreach obj $slot { |
|---|
| 69 | itcl::delete object $obj |
|---|
| 70 | } |
|---|
| 71 | } |
|---|
| 72 | } |
|---|
| 73 | |
|---|
| 74 | # ---------------------------------------------------------------------- |
|---|
| 75 | # USAGE: add <index> <xmlobj> <path> |
|---|
| 76 | # |
|---|
| 77 | # Adds a new result to this result viewer at the specified <index>. |
|---|
| 78 | # Data is taken from the <xmlobj> object at the <path>. |
|---|
| 79 | # ---------------------------------------------------------------------- |
|---|
| 80 | itcl::body Rappture::ResultViewer::add {index xmlobj path} { |
|---|
| 81 | set dobj [_xml2data $xmlobj $path] |
|---|
| 82 | |
|---|
| 83 | # |
|---|
| 84 | # If the index doesn't exist, then fill in empty slots and |
|---|
| 85 | # make it exist. |
|---|
| 86 | # |
|---|
| 87 | for {set i [llength $_dataslots]} {$i <= $index} {incr i} { |
|---|
| 88 | lappend _dataslots "" |
|---|
| 89 | } |
|---|
| 90 | set slot [lindex $_dataslots $index] |
|---|
| 91 | lappend slot $dobj |
|---|
| 92 | set _dataslots [lreplace $_dataslots $index $index $slot] |
|---|
| 93 | |
|---|
| 94 | $_dispatcher event -idle !scale |
|---|
| 95 | } |
|---|
| 96 | |
|---|
| 97 | # ---------------------------------------------------------------------- |
|---|
| 98 | # USAGE: clear ?<index>? |
|---|
| 99 | # |
|---|
| 100 | # Clears one or all results in this result viewer. |
|---|
| 101 | # ---------------------------------------------------------------------- |
|---|
| 102 | itcl::body Rappture::ResultViewer::clear {{index ""}} { |
|---|
| 103 | if {"" != $index} { |
|---|
| 104 | # clear one result |
|---|
| 105 | if {$index >= 0 && $index < [llength $_dataslots]} { |
|---|
| 106 | set slot [lindex $_dataslots $index] |
|---|
| 107 | foreach dobj $slot { |
|---|
| 108 | itcl::delete object $dobj |
|---|
| 109 | } |
|---|
| 110 | set _dataslots [lreplace $_dataslots $index $index ""] |
|---|
| 111 | } |
|---|
| 112 | } else { |
|---|
| 113 | # clear all results |
|---|
| 114 | plot clear |
|---|
| 115 | foreach slot $_dataslots { |
|---|
| 116 | foreach dobj $slot { |
|---|
| 117 | itcl::delete object $dobj |
|---|
| 118 | } |
|---|
| 119 | } |
|---|
| 120 | set _dataslots "" |
|---|
| 121 | } |
|---|
| 122 | } |
|---|
| 123 | |
|---|
| 124 | # ---------------------------------------------------------------------- |
|---|
| 125 | # USAGE: value <xmlobj> |
|---|
| 126 | # |
|---|
| 127 | # Convenience method for showing a single value. Loads the value |
|---|
| 128 | # into the widget via add/clear, then immediately plots the value. |
|---|
| 129 | # This makes the widget consistent with other widgets, such as |
|---|
| 130 | # the DeviceEditor, etc. |
|---|
| 131 | # ---------------------------------------------------------------------- |
|---|
| 132 | itcl::body Rappture::ResultViewer::value {xmlobj} { |
|---|
| 133 | clear |
|---|
| 134 | if {"" != $xmlobj} { |
|---|
| 135 | add 0 $xmlobj "" |
|---|
| 136 | plot add 0 "" |
|---|
| 137 | } |
|---|
| 138 | } |
|---|
| 139 | |
|---|
| 140 | # ---------------------------------------------------------------------- |
|---|
| 141 | # USAGE: plot add ?<index> <settings> <index> <settings> ...? |
|---|
| 142 | # USAGE: plot clear |
|---|
| 143 | # |
|---|
| 144 | # Used to manipulate the contents of this viewer. The "plot clear" |
|---|
| 145 | # command clears the current viewer. Data is still stored in the |
|---|
| 146 | # widget, but the results are not shown on screen. The "plot add" |
|---|
| 147 | # command adds the data at the specified <index> to the plot. If |
|---|
| 148 | # the optional <settings> are specified, then they are applied |
|---|
| 149 | # to the plot; otherwise, default settings are used. |
|---|
| 150 | # ---------------------------------------------------------------------- |
|---|
| 151 | itcl::body Rappture::ResultViewer::plot {option args} { |
|---|
| 152 | switch -- $option { |
|---|
| 153 | add { |
|---|
| 154 | set params "" |
|---|
| 155 | foreach {index opts} $args { |
|---|
| 156 | if {$index == "params"} { |
|---|
| 157 | set params $opts |
|---|
| 158 | continue |
|---|
| 159 | } |
|---|
| 160 | set reset "-color autoreset" |
|---|
| 161 | set slot [lindex $_dataslots $index] |
|---|
| 162 | foreach dobj $slot { |
|---|
| 163 | set settings "" |
|---|
| 164 | # start with color reset, only for first object in series |
|---|
| 165 | if {"" != $reset} { |
|---|
| 166 | set settings $reset |
|---|
| 167 | set reset "" |
|---|
| 168 | } |
|---|
| 169 | # add default settings from data object |
|---|
| 170 | if {[catch {$dobj hints style} style] == 0} { |
|---|
| 171 | eval lappend settings $style |
|---|
| 172 | } |
|---|
| 173 | if {[catch {$dobj hints type} type] == 0} { |
|---|
| 174 | if {"" != $type} { |
|---|
| 175 | eval lappend settings "-type $type" |
|---|
| 176 | } |
|---|
| 177 | } |
|---|
| 178 | # add override settings passed in here |
|---|
| 179 | eval lappend settings $opts |
|---|
| 180 | _plotAdd $dobj $settings |
|---|
| 181 | } |
|---|
| 182 | } |
|---|
| 183 | if {"" != $params && "" != $_mode} { |
|---|
| 184 | eval $_mode2widget($_mode) parameters $params |
|---|
| 185 | } |
|---|
| 186 | } |
|---|
| 187 | clear { |
|---|
| 188 | # clear the contents of the current mode |
|---|
| 189 | if {"" != $_mode} { |
|---|
| 190 | $_mode2widget($_mode) delete |
|---|
| 191 | } |
|---|
| 192 | } |
|---|
| 193 | default { |
|---|
| 194 | error "bad option \"$option\": should be add or clear" |
|---|
| 195 | } |
|---|
| 196 | } |
|---|
| 197 | } |
|---|
| 198 | |
|---|
| 199 | # ---------------------------------------------------------------------- |
|---|
| 200 | # USAGE: _plotAdd <dataobj> <settings> |
|---|
| 201 | # |
|---|
| 202 | # Used internally to add a <dataobj> representing some data to |
|---|
| 203 | # the plot at the top of this widget. The data is added to the |
|---|
| 204 | # current plot. Use the "clear" function to clear before adding |
|---|
| 205 | # new data. |
|---|
| 206 | # ---------------------------------------------------------------------- |
|---|
| 207 | itcl::body Rappture::ResultViewer::_plotAdd {dataobj {settings ""}} { |
|---|
| 208 | switch -- [$dataobj info class] { |
|---|
| 209 | ::Rappture::DataTable { |
|---|
| 210 | set mode "datatable" |
|---|
| 211 | if {![info exists _mode2widget($mode)]} { |
|---|
| 212 | set w $itk_interior.datatable |
|---|
| 213 | Rappture::DataTableResult $w |
|---|
| 214 | set _mode2widget($mode) $w |
|---|
| 215 | } |
|---|
| 216 | } |
|---|
| 217 | ::Rappture::Drawing { |
|---|
| 218 | set mode "vtkviewer" |
|---|
| 219 | if {![info exists _mode2widget($mode)]} { |
|---|
| 220 | set servers [Rappture::VisViewer::GetServerList "vtkvis"] |
|---|
| 221 | set w $itk_interior.vtkviewer |
|---|
| 222 | catch { Rappture::VtkViewer $w $servers } errs |
|---|
| 223 | puts stderr errs=$errs |
|---|
| 224 | set _mode2widget($mode) $w |
|---|
| 225 | } |
|---|
| 226 | } |
|---|
| 227 | ::Rappture::Histogram { |
|---|
| 228 | set mode "histogram" |
|---|
| 229 | if {![info exists _mode2widget($mode)]} { |
|---|
| 230 | set w $itk_interior.histogram |
|---|
| 231 | Rappture::HistogramResult $w |
|---|
| 232 | set _mode2widget($mode) $w |
|---|
| 233 | } |
|---|
| 234 | } |
|---|
| 235 | ::Rappture::Curve { |
|---|
| 236 | set type [$dataobj hints type] |
|---|
| 237 | set mode "xy" |
|---|
| 238 | if { $type == "bars" } { |
|---|
| 239 | if {![info exists _mode2widget($mode)]} { |
|---|
| 240 | set w $itk_interior.xy |
|---|
| 241 | Rappture::BarchartResult $w |
|---|
| 242 | set _mode2widget($mode) $w |
|---|
| 243 | } |
|---|
| 244 | } else { |
|---|
| 245 | if {![info exists _mode2widget($mode)]} { |
|---|
| 246 | set w $itk_interior.xy |
|---|
| 247 | Rappture::XyResult $w |
|---|
| 248 | set _mode2widget($mode) $w |
|---|
| 249 | } |
|---|
| 250 | } |
|---|
| 251 | } |
|---|
| 252 | ::Rappture::Field { |
|---|
| 253 | set dims [lindex [lsort [$dataobj components -dimensions]] end] |
|---|
| 254 | switch -- $dims { |
|---|
| 255 | 1D { |
|---|
| 256 | set mode "xy" |
|---|
| 257 | if {![info exists _mode2widget($mode)]} { |
|---|
| 258 | set w $itk_interior.xy |
|---|
| 259 | Rappture::XyResult $w |
|---|
| 260 | set _mode2widget($mode) $w |
|---|
| 261 | } |
|---|
| 262 | } |
|---|
| 263 | 2D { |
|---|
| 264 | set mode "contour" |
|---|
| 265 | if {![info exists _mode2widget($mode)]} { |
|---|
| 266 | if { [$dataobj isunirect2d] } { |
|---|
| 267 | if { [$dataobj hints type] == "contour" } { |
|---|
| 268 | set resultMode "vtkcontour" |
|---|
| 269 | } else { |
|---|
| 270 | set resultMode "heightmap" |
|---|
| 271 | } |
|---|
| 272 | } else { |
|---|
| 273 | set resultMode "vtk" |
|---|
| 274 | } |
|---|
| 275 | set extents [$dataobj extents] |
|---|
| 276 | if { $extents > 1 } { |
|---|
| 277 | set resultMode "flowvis" |
|---|
| 278 | } |
|---|
| 279 | set w $itk_interior.contour |
|---|
| 280 | if { ![winfo exists $w] } { |
|---|
| 281 | Rappture::Field2DResult $w -mode $resultMode |
|---|
| 282 | } |
|---|
| 283 | set _mode2widget($mode) $w |
|---|
| 284 | } |
|---|
| 285 | } |
|---|
| 286 | 3D { |
|---|
| 287 | set mode "field3D" |
|---|
| 288 | if {![info exists _mode2widget($mode)]} { |
|---|
| 289 | switch -- [$dataobj type] { |
|---|
| 290 | "vtk" { |
|---|
| 291 | set fmt "vtk" |
|---|
| 292 | } |
|---|
| 293 | "opendx" - "dx" - "points-on-mesh" { |
|---|
| 294 | set fmt "nanovis" |
|---|
| 295 | set extents [$dataobj extents] |
|---|
| 296 | if { $extents > 1 } { |
|---|
| 297 | set fmt "flowvis" |
|---|
| 298 | } |
|---|
| 299 | } |
|---|
| 300 | "vtkstreamlines" { |
|---|
| 301 | set fmt "vtkstreamlines" |
|---|
| 302 | } |
|---|
| 303 | } |
|---|
| 304 | set w $itk_interior.field3D |
|---|
| 305 | Rappture::Field3DResult $w -mode $fmt |
|---|
| 306 | set _mode2widget($mode) $w |
|---|
| 307 | } |
|---|
| 308 | } |
|---|
| 309 | default { |
|---|
| 310 | error "can't handle \"$dims\" dimension field" |
|---|
| 311 | } |
|---|
| 312 | } |
|---|
| 313 | } |
|---|
| 314 | ::Rappture::Mesh { |
|---|
| 315 | switch -- [$dataobj dimensions] { |
|---|
| 316 | 2 { |
|---|
| 317 | set mode "mesh" |
|---|
| 318 | if {![info exists _mode2widget($mode)]} { |
|---|
| 319 | set w $itk_interior.mesh |
|---|
| 320 | Rappture::MeshResult $w |
|---|
| 321 | set _mode2widget($mode) $w |
|---|
| 322 | } |
|---|
| 323 | } |
|---|
| 324 | default { |
|---|
| 325 | error "can't handle [$dataobj dimensions]D field" |
|---|
| 326 | } |
|---|
| 327 | } |
|---|
| 328 | } |
|---|
| 329 | ::Rappture::Table { |
|---|
| 330 | set cols [Rappture::EnergyLevels::columns $dataobj] |
|---|
| 331 | if {"" != $cols} { |
|---|
| 332 | set mode "energies" |
|---|
| 333 | if {![info exists _mode2widget($mode)]} { |
|---|
| 334 | set w $itk_interior.energies |
|---|
| 335 | Rappture::EnergyLevels $w |
|---|
| 336 | set _mode2widget($mode) $w |
|---|
| 337 | } |
|---|
| 338 | } |
|---|
| 339 | } |
|---|
| 340 | ::Rappture::LibraryObj { |
|---|
| 341 | switch -- [$dataobj element -as type] { |
|---|
| 342 | string - log { |
|---|
| 343 | set mode "log" |
|---|
| 344 | if {![info exists _mode2widget($mode)]} { |
|---|
| 345 | set w $itk_interior.log |
|---|
| 346 | Rappture::TextResult $w |
|---|
| 347 | set _mode2widget($mode) $w |
|---|
| 348 | } |
|---|
| 349 | } |
|---|
| 350 | structure { |
|---|
| 351 | set mode "structure" |
|---|
| 352 | if {![info exists _mode2widget($mode)]} { |
|---|
| 353 | set w $itk_interior.struct |
|---|
| 354 | Rappture::DeviceResult $w |
|---|
| 355 | set _mode2widget($mode) $w |
|---|
| 356 | } |
|---|
| 357 | } |
|---|
| 358 | number - integer { |
|---|
| 359 | set mode "number" |
|---|
| 360 | if {![info exists _mode2widget($mode)]} { |
|---|
| 361 | set w $itk_interior.number |
|---|
| 362 | Rappture::NumberResult $w |
|---|
| 363 | set _mode2widget($mode) $w |
|---|
| 364 | } |
|---|
| 365 | } |
|---|
| 366 | boolean - choice { |
|---|
| 367 | set mode "value" |
|---|
| 368 | if {![info exists _mode2widget($mode)]} { |
|---|
| 369 | set w $itk_interior.value |
|---|
| 370 | Rappture::ValueResult $w |
|---|
| 371 | set _mode2widget($mode) $w |
|---|
| 372 | } |
|---|
| 373 | } |
|---|
| 374 | } |
|---|
| 375 | } |
|---|
| 376 | ::Rappture::Image { |
|---|
| 377 | set mode "image" |
|---|
| 378 | if {![info exists _mode2widget($mode)]} { |
|---|
| 379 | set w $itk_interior.image |
|---|
| 380 | Rappture::ImageResult $w |
|---|
| 381 | set _mode2widget($mode) $w |
|---|
| 382 | } |
|---|
| 383 | } |
|---|
| 384 | ::Rappture::Sequence { |
|---|
| 385 | set mode "sequence" |
|---|
| 386 | if {![info exists _mode2widget($mode)]} { |
|---|
| 387 | set w $itk_interior.image |
|---|
| 388 | Rappture::SequenceResult $w |
|---|
| 389 | set _mode2widget($mode) $w |
|---|
| 390 | } |
|---|
| 391 | } |
|---|
| 392 | default { |
|---|
| 393 | error "don't know how to plot <$type> data [$dataobj info class]" |
|---|
| 394 | } |
|---|
| 395 | } |
|---|
| 396 | |
|---|
| 397 | if {$mode != $_mode && $_mode != ""} { |
|---|
| 398 | set nactive [llength [$_mode2widget($_mode) get]] |
|---|
| 399 | if {$nactive > 0} { |
|---|
| 400 | return ;# mixing data that doesn't mix -- ignore it! |
|---|
| 401 | } |
|---|
| 402 | } |
|---|
| 403 | |
|---|
| 404 | # Are we plotting in a new mode? then change widgets |
|---|
| 405 | if {$_mode2widget($mode) != [pack slaves $itk_interior]} { |
|---|
| 406 | # remove any current window |
|---|
| 407 | foreach w [pack slaves $itk_interior] { |
|---|
| 408 | pack forget $w |
|---|
| 409 | } |
|---|
| 410 | pack $_mode2widget($mode) -expand yes -fill both |
|---|
| 411 | |
|---|
| 412 | set _mode $mode |
|---|
| 413 | $_dispatcher event -idle !scale |
|---|
| 414 | } |
|---|
| 415 | $_mode2widget($mode) add $dataobj $settings |
|---|
| 416 | } |
|---|
| 417 | |
|---|
| 418 | # ---------------------------------------------------------------------- |
|---|
| 419 | # USAGE: _fixScale ?<eventArgs>...? |
|---|
| 420 | # |
|---|
| 421 | # Invoked automatically whenever a new dataset is added to fix the |
|---|
| 422 | # overall scales of the viewer. This makes the visualizer consistent |
|---|
| 423 | # across all <dataobj> in this widget, so that it can plot all |
|---|
| 424 | # available data. |
|---|
| 425 | # ---------------------------------------------------------------------- |
|---|
| 426 | itcl::body Rappture::ResultViewer::_fixScale {args} { |
|---|
| 427 | if {"" != $_mode} { |
|---|
| 428 | set dlist "" |
|---|
| 429 | foreach slot $_dataslots { |
|---|
| 430 | foreach dobj $slot { |
|---|
| 431 | lappend dlist $dobj |
|---|
| 432 | } |
|---|
| 433 | } |
|---|
| 434 | eval $_mode2widget($_mode) scale $dlist |
|---|
| 435 | } |
|---|
| 436 | } |
|---|
| 437 | |
|---|
| 438 | # ---------------------------------------------------------------------- |
|---|
| 439 | # USAGE: download coming |
|---|
| 440 | # USAGE: download controls <downloadCommand> |
|---|
| 441 | # USAGE: download now |
|---|
| 442 | # |
|---|
| 443 | # Clients use this method to create a downloadable representation |
|---|
| 444 | # of the plot. Returns a list of the form {ext string}, where |
|---|
| 445 | # "ext" is the file extension (indicating the type of data) and |
|---|
| 446 | # "string" is the data itself. |
|---|
| 447 | # ---------------------------------------------------------------------- |
|---|
| 448 | itcl::body Rappture::ResultViewer::download {option args} { |
|---|
| 449 | if {"" == $_mode} { |
|---|
| 450 | return "" |
|---|
| 451 | } |
|---|
| 452 | return [eval $_mode2widget($_mode) download $option $args] |
|---|
| 453 | } |
|---|
| 454 | |
|---|
| 455 | # ---------------------------------------------------------------------- |
|---|
| 456 | # USAGE: _xml2data <xmlobj> <path> |
|---|
| 457 | # |
|---|
| 458 | # Used internally to create a data object for the data at the |
|---|
| 459 | # specified <path> in the <xmlobj>. |
|---|
| 460 | # ---------------------------------------------------------------------- |
|---|
| 461 | itcl::body Rappture::ResultViewer::_xml2data {xmlobj path} { |
|---|
| 462 | set type [$xmlobj element -as type $path] |
|---|
| 463 | switch -- $type { |
|---|
| 464 | curve { |
|---|
| 465 | return [Rappture::Curve ::#auto $xmlobj $path] |
|---|
| 466 | } |
|---|
| 467 | datatable { |
|---|
| 468 | return [Rappture::DataTable ::#auto $xmlobj $path] |
|---|
| 469 | } |
|---|
| 470 | histogram { |
|---|
| 471 | return [Rappture::Histogram ::#auto $xmlobj $path] |
|---|
| 472 | } |
|---|
| 473 | field { |
|---|
| 474 | return [Rappture::Field ::#auto $xmlobj $path] |
|---|
| 475 | } |
|---|
| 476 | mesh { |
|---|
| 477 | return [Rappture::Mesh ::#auto $xmlobj $path] |
|---|
| 478 | } |
|---|
| 479 | table { |
|---|
| 480 | return [Rappture::Table ::#auto $xmlobj $path] |
|---|
| 481 | } |
|---|
| 482 | image { |
|---|
| 483 | return [Rappture::Image ::#auto $xmlobj $path] |
|---|
| 484 | } |
|---|
| 485 | sequence { |
|---|
| 486 | return [Rappture::Sequence ::#auto $xmlobj $path] |
|---|
| 487 | } |
|---|
| 488 | string - log { |
|---|
| 489 | return [$xmlobj element -as object $path] |
|---|
| 490 | } |
|---|
| 491 | structure { |
|---|
| 492 | return [$xmlobj element -as object $path] |
|---|
| 493 | } |
|---|
| 494 | number - integer - boolean - choice { |
|---|
| 495 | return [$xmlobj element -as object $path] |
|---|
| 496 | } |
|---|
| 497 | drawing3d - drawing { |
|---|
| 498 | return [Rappture::Drawing ::#auto $xmlobj $path] |
|---|
| 499 | } |
|---|
| 500 | time - status { |
|---|
| 501 | return "" |
|---|
| 502 | } |
|---|
| 503 | } |
|---|
| 504 | error "don't know how to plot <$type> data path=$path" |
|---|
| 505 | } |
|---|
| 506 | |
|---|
| 507 | # ---------------------------------------------------------------------- |
|---|
| 508 | # CONFIGURATION OPTION: -width |
|---|
| 509 | # ---------------------------------------------------------------------- |
|---|
| 510 | itcl::configbody Rappture::ResultViewer::width { |
|---|
| 511 | set w [winfo pixels $itk_component(hull) $itk_option(-width)] |
|---|
| 512 | set h [winfo pixels $itk_component(hull) $itk_option(-height)] |
|---|
| 513 | if {$w == 0 || $h == 0} { |
|---|
| 514 | pack propagate $itk_component(hull) yes |
|---|
| 515 | } else { |
|---|
| 516 | component hull configure -width $w -height $h |
|---|
| 517 | pack propagate $itk_component(hull) no |
|---|
| 518 | } |
|---|
| 519 | } |
|---|
| 520 | |
|---|
| 521 | # ---------------------------------------------------------------------- |
|---|
| 522 | # CONFIGURATION OPTION: -height |
|---|
| 523 | # ---------------------------------------------------------------------- |
|---|
| 524 | itcl::configbody Rappture::ResultViewer::height { |
|---|
| 525 | set h [winfo pixels $itk_component(hull) $itk_option(-height)] |
|---|
| 526 | set w [winfo pixels $itk_component(hull) $itk_option(-width)] |
|---|
| 527 | if {$w == 0 || $h == 0} { |
|---|
| 528 | pack propagate $itk_component(hull) yes |
|---|
| 529 | } else { |
|---|
| 530 | component hull configure -width $w -height $h |
|---|
| 531 | pack propagate $itk_component(hull) no |
|---|
| 532 | } |
|---|
| 533 | } |
|---|
