source: branches/blt4_geovis/gui/test/geomaplayer.test @ 5994

# Commands covered:
#   Rappture::GeoMapLayer
#
# This file contains a collection of tests for one of the Rappture Tcl
# commands.  Sourcing this file into Tcl runs the tests and
# generates output for errors.  No output means no errors were found.
#
# ======================================================================
# AUTHOR:  Derrick Kearney, Purdue University
# Copyright (c) 2004-2015  HUBzero Foundation, LLC
#
# See the file "license.terms" for information on usage and redistribution
# of this file, and for a DISCLAIMER OF ALL WARRANTIES.


if {[lsearch [namespace children] ::tcltest] == -1} {
    package require tcltest
    package require RapptureGUI
    namespace import -force ::tcltest::*
}
catch {unset lib}

proc check {var size} {
    set l [llength $var]
    if {$l != $size} {
        return "length mismatch: should have been $size, was $l"
    }
    for {set i 0} {$i < $size} {set i [expr $i+1]} {
        set j [lindex $var $i]
        if {$j != "item $i"} {
            return "element $i should have been \"item $i\", was \"$j\""
        }
    }
    return ok
}

set provider [Rappture::GeoMapDataProviderXYZ #auto {http://myurl.com/}]

#----------------------------------------------------------
#----------------------------------------------------------
# constructor command
# Rappture::GeoMapLayer <name> <provider> \
#   ?-label <label>? \
#   ?-description <desc>? \
#   ?-attribution <attrib>? \
#   ?-visibility <visibility>? \
#   ?-opacity <opacity>? \
#   ?-placardattributes <attributes>? \
#   ?-placardstyle <style>? \
#   ?-placardpadding <padding>?
#----------------------------------------------------------
test geomaplayer-1.1 {Rappture::GeoMapLayer, 0 arguments} {
    list [catch {Rappture::GeoMapLayer} msg] $msg
} {0 {}}

test geomaplayer-1.2 {Rappture::GeoMapLayer, 1 arguments} {
    list [catch {Rappture::GeoMapLayer name $provider} msg] $msg
} {0 name}


#----------------------------------------------------------
# export command
#----------------------------------------------------------

set l1 [Rappture::GeoMapLayer #auto $provider]

test geomaplayer-11.0 {Rappture::GeoMapLayer, export (default format)} {
    set t [$l1 export]
    list [catch {lindex [$t dump 0] 3} msg] $msg
} {0 {type image driver xyz cache true attribution {} xyz.url http://myurl.com/ label {} description {} visible true opacity 1.0 placard {attrlist {} style {fill: #B6B6B688; text-fill: #000000; text-size: 12.0;} padding 5}}}

test geomaplayer-11.1 {Rappture::GeoMapLayer, export bad format} {
    list [catch {$l1 export -format blahh} msg] $msg
} {1 {bad format "blahh": should be one of blt_tree}}

test geomaplayer-11.2 {Rappture::GeoMapLayer, export -format blt_tree} {
    set t [$l1 export -format blt_tree]
    list [catch {lindex [$t dump 0] 3} msg] $msg
} {0 {type image driver xyz cache true attribution {} xyz.url http://myurl.com/ label {} description {} visible true opacity 1.0 placard {attrlist {} style {fill: #B6B6B688; text-fill: #000000; text-size: 12.0;} padding 5}}}


#----------------------------------------------------------
# -placardattributes flag validation
#----------------------------------------------------------

set l2 [Rappture::GeoMapLayer #auto $provider]

test geomaplayer-12.1 {-placardattributes string} {
    set err [catch {$l2 configure -placardattributes {name Name aland "Land Area"}} msg]
    catch {$l2 cget -placardattributes} stored
    list $err $msg $stored
} {0 {} {name Name aland "Land Area"}}

test geomaplayer-12.2 {-placardattributes string with extra spaces} {
    set err [catch {$l2 configure -placardattributes "name Name\naland LandArea"} msg]
    catch {$l2 cget -placardattributes} stored
    list $err $msg $stored
} {0 {} {name Name aland LandArea}}



#----------------------------------------------------------
# -placardstyle flag validation
#----------------------------------------------------------

test geomaplayer-13.1 {-placardstyle string} {
    set err [catch {$l2 configure -placardstyle {fill: #00FF0088;}} msg]
    catch {$l2 cget -placardstyle} stored
    list $err $msg $stored
} {0 {} {fill: #00FF0088;}}

test geomaplayer-13.2 {-placardstyle string with extra spaces} {
    set err [catch {$l2 configure -placardstyle "fill:\t#00FF0088;"} msg]
    catch {$l2 cget -placardstyle} stored
    list $err $msg $stored
} {0 {} {fill: #00FF0088;}}

test geomaplayer-13.3 {-placardstyle empty string sets widget default} {
    set err [catch {$l2 configure -placardstyle ""} msg]
    catch {$l2 cget -placardstyle} stored
    list $err $msg $stored
} {0 {} {fill: #B6B6B688; text-fill: #000000; text-size: 12.0;}}


#----------------------------------------------------------
# -placardpadding flag validation
#----------------------------------------------------------

test geomaplayer-14.1 {-placardpadding integer} {
    set err [catch {$l2 configure -placardpadding 7} msg]
    catch {$l2 cget -placardpadding} stored
    list $err $msg $stored
} {0 {} 7}

test geomaplayer-14.2 {-placardpadding double} {
    list [catch {$l2 configure -placardpadding 8.0} msg] $msg
} {1 {bad value "8.0": placardpadding should be a positive integer}}

test geomaplayer-14.3 {-placardpadding negative integer} {
    list [catch {$l2 configure -placardpadding -5} msg] $msg
} {1 {bad value "-5": placardpadding should be a positive integer}}




# TODO:

::tcltest::cleanupTests
return