source: branches/r9/gui/scripts/vtkheightmapviewer.tcl @ 4919

Last change on this file since 4919 was 4919, checked in by gah, 6 years ago
File size: 87.9 KB
Line 
1# -*- mode: tcl; indent-tabs-mode: nil -*-
2# ----------------------------------------------------------------------
3#  COMPONENT: vtkheightmapviewer - Vtk heightmap viewer
4#
5#  It connects to the Vtk server running on a rendering farm,
6#  transmits data, and displays the results.
7# ======================================================================
8#  AUTHOR:  Michael McLennan, Purdue University
9#  Copyright (c) 2004-2014  HUBzero Foundation, LLC
10#
11#  See the file "license.terms" for information on usage and
12#  redistribution of this file, and for a DISCLAIMER OF ALL WARRANTIES.
13# ======================================================================
14package require Itk
15package require BLT
16#package require Img
17
18option add *VtkHeightmapViewer.width 4i widgetDefault
19option add *VtkHeightmapViewer*cursor crosshair widgetDefault
20option add *VtkHeightmapViewer.height 4i widgetDefault
21option add *VtkHeightmapViewer.foreground black widgetDefault
22option add *VtkHeightmapViewer.controlBackground gray widgetDefault
23option add *VtkHeightmapViewer.controlDarkBackground #999999 widgetDefault
24option add *VtkHeightmapViewer.plotBackground black widgetDefault
25option add *VtkHeightmapViewer.plotForeground white widgetDefault
26option add *VtkHeightmapViewer.font \
27    -*-helvetica-medium-r-normal-*-12-* widgetDefault
28
29# must use this name -- plugs into Rappture::resources::load
30proc VtkHeightmapViewer_init_resources {} {
31    Rappture::resources::register \
32        vtkvis_server Rappture::VtkHeightmapViewer::SetServerList
33}
34
35itcl::class Rappture::VtkHeightmapViewer {
36    inherit Rappture::VisViewer
37
38    itk_option define -plotforeground plotForeground Foreground ""
39    itk_option define -plotbackground plotBackground Background ""
40    itk_option define -mode mode Mode "contour"
41
42    constructor { hostlist args } {
43        Rappture::VisViewer::constructor $hostlist
44    } {
45        # defined below
46    }
47    destructor {
48        # defined below
49    }
50    public proc SetServerList { namelist } {
51        Rappture::VisViewer::SetServerList "vtkvis" $namelist
52    }
53    public method add {dataobj {settings ""}}
54    public method camera {option args}
55    public method delete {args}
56    public method disconnect {}
57    public method download {option args}
58    public method get {args}
59    public method isconnected {}
60    public method limits3 { dataobj }
61    public method parameters {title args} {
62        # do nothing
63    }
64    public method scale {args}
65
66    protected method CameraReset {}
67    protected method Connect {}
68    protected method CurrentDatasets {args}
69    protected method Disconnect {}
70    protected method DoResize {}
71    protected method DoRotate {}
72    protected method AdjustSetting {what {value ""}}
73    protected method AdjustMode {}
74    protected method InitSettings { args  }
75    protected method Pan {option x y}
76    protected method Pick {x y}
77    protected method Rebuild {}
78    protected method ReceiveDataset { args }
79    protected method ReceiveImage { args }
80    protected method ReceiveLegend { colormap title min max size }
81    protected method Rotate {option x y}
82    protected method Zoom {option}
83
84    # The following methods are only used by this class.
85    private method BuildAxisTab {}
86    private method BuildCameraTab {}
87    private method BuildColormap { name }
88    private method BuildContourTab {}
89    private method BuildDownloadPopup { widget command }
90    private method Combo { option }
91    private method DrawLegend {}
92    private method EnterLegend { x y }
93    private method EventuallyRequestLegend {}
94    private method EventuallyResize { w h }
95    private method EventuallyRotate { q }
96    private method GetImage { args }
97    private method GetVtkData { args }
98    private method IsValidObject { dataobj }
99    private method LeaveLegend {}
100    private method MotionLegend { x y }
101    private method PanCamera {}
102    private method RequestLegend {}
103    private method SetCurrentColormap { color }
104    private method SetLegendTip { x y }
105    private method SetObjectStyle { dataobj comp }
106    private method GetHeightmapScale {}
107    private method ResetAxes {}
108    private method SetOrientation { side }
109    private method UpdateContourList {}
110
111    private variable _arcball ""
112    private variable _dlist ""     ;    # list of data objects
113    private variable _obj2datasets
114    private variable _obj2ovride   ;    # maps dataobj => style override
115    private variable _comp2scale;       # maps dataset to the heightmap scale.
116    private variable _datasets     ;    # contains all the dataobj-component
117                                   ;    # datasets in the server
118    private variable _colormaps    ;    # contains all the colormaps
119                                   ;    # in the server.
120
121    # The name of the current colormap used.  The colormap is global to all
122    # heightmaps displayed.
123    private variable _currentColormap ""
124    private variable _currentNumIsolines -1
125
126    private variable _maxScale 100;     # This is the # of times the x-axis
127                                        # and y-axis ranges can differ before
128                                        # automatically turning on
129                                        # -stretchtofit
130
131    private variable _click        ;    # info used for rotate operations
132    private variable _limits       ;    # Holds overall limits for all dataobjs
133                                        # using the viewer.
134    private variable _view         ;    # view params for 3D view
135    private variable _settings
136    private variable _changed
137    private variable _initialStyle "";  # First found style in dataobjects.
138    private variable _reset 1;          # Indicates if camera needs to be reset
139                                        # to starting position.
140    private variable _beforeConnect 1;  # Indicates if camera needs to be reset
141                                        # to starting position.
142
143    private variable _first ""     ;    # This is the topmost dataset.
144    private variable _start 0
145    private variable _isolines
146    private variable _contourList ""
147
148    common _downloadPopup;              # download options from popup
149    private common _hardcopy
150    private variable _width 0
151    private variable _height 0
152    private variable _legendWidth 0
153    private variable _legendHeight 0
154    private variable _resizePending 0
155    private variable _rotatePending 0
156    private variable _legendPending 0
157    private variable _fieldNames {}
158    private variable _fields
159    private variable _curFldName ""
160    private variable _curFldLabel ""
161    private variable _colorMode "scalar";#  Mode of colormap (vmag or scalar)
162}
163
164itk::usual VtkHeightmapViewer {
165    keep -background -foreground -cursor -font
166    keep -plotbackground -plotforeground -mode
167}
168
169# ----------------------------------------------------------------------
170# CONSTRUCTOR
171# ----------------------------------------------------------------------
172itcl::body Rappture::VtkHeightmapViewer::constructor {hostlist args} {
173    set _serverType "vtkvis"
174
175    EnableWaitDialog 900
176    # Rebuild event
177    $_dispatcher register !rebuild
178    $_dispatcher dispatch $this !rebuild "[itcl::code $this Rebuild]; list"
179
180    # Resize event
181    $_dispatcher register !resize
182    $_dispatcher dispatch $this !resize "[itcl::code $this DoResize]; list"
183
184    # Rotate event
185    $_dispatcher register !rotate
186    $_dispatcher dispatch $this !rotate "[itcl::code $this DoRotate]; list"
187
188    # Legend event
189    $_dispatcher register !legend
190    $_dispatcher dispatch $this !legend "[itcl::code $this RequestLegend]; list"
191
192    #
193    # Populate parser with commands handle incoming requests
194    #
195    $_parser alias image [itcl::code $this ReceiveImage]
196    $_parser alias dataset [itcl::code $this ReceiveDataset]
197    $_parser alias legend [itcl::code $this ReceiveLegend]
198
199    # Create image for legend colorbar.
200    set _image(legend) [image create photo]
201
202    # Initialize the view to some default parameters.
203    array set _view {
204        qw      0.36
205        qx      0.25
206        qy      0.50
207        qz      0.70
208        zoom    1.0
209        xpan    0
210        ypan    0
211        ortho   0
212    }
213    set _arcball [blt::arcball create 100 100]
214    set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
215    $_arcball quaternion $q
216
217    array set _settings {
218        -axisflymode            "static"
219        -axislabels             1
220        -axisminorticks         1
221        -axisvisible            1
222        -colormap               BCGYR
223        -colormapdiscrete       0
224        -colormapvisible        1
225        -edges                  0
226        -field                  "Default"
227        -heightmapscale         50
228        -isheightmap            0
229        -isolinecolor           black
230        -isolinesvisible        1
231        -legendvisible          1
232        -lighting               1
233        -numisolines            10
234        -opacity                100
235        -outline                0
236        -savelighting           1
237        -saveopacity            100
238        -saveoutline            0
239        -stretchtofit           0
240        -wireframe              0
241        -xgrid                  0
242        -ygrid                  0
243        -zgrid                  0
244    }
245    array set _changed {
246        -colormap               0
247        -numisolines            0
248        -opacity                0
249    }
250    itk_component add view {
251        canvas $itk_component(plotarea).view \
252            -highlightthickness 0 -borderwidth 0
253    } {
254        usual
255        ignore -highlightthickness -borderwidth -background
256    }
257
258    itk_component add fieldmenu {
259        menu $itk_component(plotarea).menu \
260            -relief flat \
261            -tearoff no
262    } {
263        usual
264        ignore -background -foreground -relief -tearoff
265    }
266    set c $itk_component(view)
267    bind $c <Configure> [itcl::code $this EventuallyResize %w %h]
268    bind $c <4> [itcl::code $this Zoom in 0.25]
269    bind $c <5> [itcl::code $this Zoom out 0.25]
270    bind $c <KeyPress-Left>  [list %W xview scroll 10 units]
271    bind $c <KeyPress-Right> [list %W xview scroll -10 units]
272    bind $c <KeyPress-Up>    [list %W yview scroll 10 units]
273    bind $c <KeyPress-Down>  [list %W yview scroll -10 units]
274    bind $c <Enter> "focus %W"
275    bind $c <Control-F1> [itcl::code $this ToggleConsole]
276
277    # Fix the scrollregion in case we go off screen
278    $c configure -scrollregion [$c bbox all]
279
280    set _map(id) [$c create image 0 0 -anchor nw -image $_image(plot)]
281    set _map(cwidth) -1
282    set _map(cheight) -1
283    set _map(zoom) 1.0
284    set _map(original) ""
285
286    set f [$itk_component(main) component controls]
287    itk_component add reset {
288        button $f.reset -borderwidth 1 -padx 1 -pady 1 \
289            -highlightthickness 0 \
290            -image [Rappture::icon reset-view] \
291            -command [itcl::code $this CameraReset]
292    } {
293        usual
294        ignore -highlightthickness
295    }
296    pack $itk_component(reset) -side top -padx 2 -pady { 2 0 }
297    Rappture::Tooltip::for $itk_component(reset) "Reset the view to the default zoom level"
298
299    itk_component add zoomin {
300        button $f.zin -borderwidth 1 -padx 1 -pady 1 \
301            -highlightthickness 0 \
302            -image [Rappture::icon zoom-in] \
303            -command [itcl::code $this Zoom in]
304    } {
305        usual
306        ignore -highlightthickness
307    }
308    pack $itk_component(zoomin) -side top -padx 2 -pady { 2 0 }
309    Rappture::Tooltip::for $itk_component(zoomin) "Zoom in"
310
311    itk_component add zoomout {
312        button $f.zout -borderwidth 1 -padx 1 -pady 1 \
313            -highlightthickness 0 \
314            -image [Rappture::icon zoom-out] \
315            -command [itcl::code $this Zoom out]
316    } {
317        usual
318        ignore -highlightthickness
319    }
320    pack $itk_component(zoomout) -side top -padx 2 -pady { 2 0 }
321    Rappture::Tooltip::for $itk_component(zoomout) "Zoom out"
322
323    itk_component add mode {
324        Rappture::PushButton $f.mode \
325            -onimage [Rappture::icon surface] \
326            -offimage [Rappture::icon surface] \
327            -variable [itcl::scope _settings(-isheightmap)] \
328            -command [itcl::code $this AdjustSetting -isheightmap] \
329    }
330    Rappture::Tooltip::for $itk_component(mode) \
331        "Toggle the surface/contour on/off"
332    pack $itk_component(mode) -padx 2 -pady { 2 0 }
333
334    itk_component add stretchtofit {
335        Rappture::PushButton $f.stretchtofit \
336            -onimage [Rappture::icon stretchtofit] \
337            -offimage [Rappture::icon stretchtofit] \
338            -variable [itcl::scope _settings(-stretchtofit)] \
339            -command [itcl::code $this AdjustSetting -stretchtofit] \
340    }
341    Rappture::Tooltip::for $itk_component(stretchtofit) \
342        "Stretch plot to fit window on/off"
343    pack $itk_component(stretchtofit) -padx 2 -pady 2
344
345    if { [catch {
346        BuildContourTab
347        BuildAxisTab
348        BuildCameraTab
349    } errs] != 0 } {
350        global errorInfo
351        puts stderr "errs=$errs errorInfo=$errorInfo"
352    }
353
354    # Hack around the Tk panewindow.  The problem is that the requested
355    # size of the 3d view isn't set until an image is retrieved from
356    # the server.  So the panewindow uses the tiny size.
357    set w 10000
358    pack forget $itk_component(view)
359    blt::table $itk_component(plotarea) \
360        0,0 $itk_component(view) -fill both -reqwidth $w
361    blt::table configure $itk_component(plotarea) c1 -resize none
362
363    # Bindings for panning via mouse
364    bind $itk_component(view) <ButtonPress-2> \
365        [itcl::code $this Pan click %x %y]
366    bind $itk_component(view) <B2-Motion> \
367        [itcl::code $this Pan drag %x %y]
368    bind $itk_component(view) <ButtonRelease-2> \
369        [itcl::code $this Pan release %x %y]
370
371    #bind $itk_component(view) <ButtonRelease-3> \
372    #    [itcl::code $this Pick %x %y]
373
374    # Bindings for panning via keyboard
375    bind $itk_component(view) <KeyPress-Left> \
376        [itcl::code $this Pan set -10 0]
377    bind $itk_component(view) <KeyPress-Right> \
378        [itcl::code $this Pan set 10 0]
379    bind $itk_component(view) <KeyPress-Up> \
380        [itcl::code $this Pan set 0 -10]
381    bind $itk_component(view) <KeyPress-Down> \
382        [itcl::code $this Pan set 0 10]
383    bind $itk_component(view) <Shift-KeyPress-Left> \
384        [itcl::code $this Pan set -2 0]
385    bind $itk_component(view) <Shift-KeyPress-Right> \
386        [itcl::code $this Pan set 2 0]
387    bind $itk_component(view) <Shift-KeyPress-Up> \
388        [itcl::code $this Pan set 0 -2]
389    bind $itk_component(view) <Shift-KeyPress-Down> \
390        [itcl::code $this Pan set 0 2]
391
392    # Bindings for zoom via keyboard
393    bind $itk_component(view) <KeyPress-Prior> \
394        [itcl::code $this Zoom out]
395    bind $itk_component(view) <KeyPress-Next> \
396        [itcl::code $this Zoom in]
397
398    bind $itk_component(view) <Enter> "focus $itk_component(view)"
399
400    if {[string equal "x11" [tk windowingsystem]]} {
401        # Bindings for zoom via mouse
402        bind $itk_component(view) <4> [itcl::code $this Zoom out]
403        bind $itk_component(view) <5> [itcl::code $this Zoom in]
404    }
405
406    set _image(download) [image create photo]
407    eval itk_initialize $args
408    Connect
409    set _beforeConnect 0
410}
411
412# ----------------------------------------------------------------------
413# DESTRUCTOR
414# ----------------------------------------------------------------------
415itcl::body Rappture::VtkHeightmapViewer::destructor {} {
416    Disconnect
417    image delete $_image(plot)
418    image delete $_image(download)
419    catch { blt::arcball destroy $_arcball }
420}
421
422itcl::body Rappture::VtkHeightmapViewer::DoResize {} {
423    if { $_width < 2 } {
424        set _width 500
425    }
426    if { $_height < 2 } {
427        set _height 500
428    }
429    set _start [clock clicks -milliseconds]
430    SendCmd "screen size [expr $_width - 20] $_height"
431
432    set font "Arial 8"
433    set lh [font metrics $font -linespace]
434    set h [expr {$_height - 2 * ($lh + 2)}]
435    if { $h != $_legendHeight } {
436        EventuallyRequestLegend
437    } else {
438        DrawLegend
439    }
440    set _resizePending 0
441}
442
443itcl::body Rappture::VtkHeightmapViewer::DoRotate {} {
444    set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
445    SendCmd "camera orient $q"
446    set _rotatePending 0
447}
448
449itcl::body Rappture::VtkHeightmapViewer::EventuallyRequestLegend {} {
450    if { !$_legendPending } {
451        set _legendPending 1
452        $_dispatcher event -idle !legend
453    }
454}
455
456itcl::body Rappture::VtkHeightmapViewer::EventuallyResize { w h } {
457    set _width $w
458    set _height $h
459    $_arcball resize $w $h
460    if { !$_resizePending } {
461        set _resizePending 1
462        $_dispatcher event -after 250 !resize
463    }
464}
465
466set rotate_delay 100
467
468itcl::body Rappture::VtkHeightmapViewer::EventuallyRotate { q } {
469    foreach { _view(qw) _view(qx) _view(qy) _view(qz) } $q break
470    if { !$_rotatePending } {
471        set _rotatePending 1
472        global rotate_delay
473        $_dispatcher event -after $rotate_delay !rotate
474    }
475}
476
477# ----------------------------------------------------------------------
478# USAGE: add <dataobj> ?<settings>?
479#
480# Clients use this to add a data object to the plot.  The optional
481# <settings> are used to configure the plot.  Allowed settings are
482# -color, -brightness, -width, -linestyle, and -raise.
483# ----------------------------------------------------------------------
484itcl::body Rappture::VtkHeightmapViewer::add {dataobj {settings ""}} {
485    if { ![$dataobj isvalid] } {
486        return;                         # Object doesn't contain valid data.
487    }
488    array set params {
489        -color auto
490        -width 1
491        -linestyle solid
492        -brightness 0
493        -raise 0
494        -description ""
495        -param ""
496        -type ""
497    }
498    array set params $settings
499    set params(-description) ""
500    set params(-param) ""
501    array set params $settings
502
503    if {$params(-color) == "auto" || $params(-color) == "autoreset"} {
504        # can't handle -autocolors yet
505        set params(-color) white
506    }
507    set pos [lsearch -exact $_dlist $dataobj]
508    if {$pos < 0} {
509        lappend _dlist $dataobj
510    }
511    set _obj2ovride($dataobj-color) $params(-color)
512    set _obj2ovride($dataobj-width) $params(-width)
513    set _obj2ovride($dataobj-raise) $params(-raise)
514    $_dispatcher event -idle !rebuild
515}
516
517
518# ----------------------------------------------------------------------
519# USAGE: delete ?<dataobj1> <dataobj2> ...?
520#
521#       Clients use this to delete a dataobj from the plot.  If no dataobjs
522#       are specified, then all dataobjs are deleted.  No data objects are
523#       deleted.  They are only removed from the display list.
524#
525# ----------------------------------------------------------------------
526itcl::body Rappture::VtkHeightmapViewer::delete {args} {
527    if { [llength $args] == 0} {
528        set args $_dlist
529    }
530    # Delete all specified dataobjs
531    set changed 0
532    foreach dataobj $args {
533        set pos [lsearch -exact $_dlist $dataobj]
534        if { $pos < 0 } {
535            continue;                   # Don't know anything about it.
536        }
537        # Remove it from the dataobj list.
538        set _dlist [lreplace $_dlist $pos $pos]
539        array unset _obj2ovride $dataobj-*
540        array unset _settings $dataobj-*
541        set changed 1
542    }
543    # If anything changed, then rebuild the plot
544    if { $changed } {
545        $_dispatcher event -idle !rebuild
546    }
547}
548
549# ----------------------------------------------------------------------
550# USAGE: get ?-objects?
551# USAGE: get ?-visible?
552# USAGE: get ?-image view?
553#
554# Clients use this to query the list of objects being plotted, in
555# order from bottom to top of this result.  The optional "-image"
556# flag can also request the internal images being shown.
557# ----------------------------------------------------------------------
558itcl::body Rappture::VtkHeightmapViewer::get {args} {
559    if {[llength $args] == 0} {
560        set args "-objects"
561    }
562    set op [lindex $args 0]
563    switch -- $op {
564        "-objects" {
565            # put the dataobj list in order according to -raise options
566            set dlist {}
567            foreach dataobj $_dlist {
568                if { ![IsValidObject $dataobj] } {
569                    continue
570                }
571                if {[info exists _obj2ovride($dataobj-raise)] &&
572                    $_obj2ovride($dataobj-raise)} {
573                    set dlist [linsert $dlist 0 $dataobj]
574                } else {
575                    lappend dlist $dataobj
576                }
577            }
578            return $dlist
579        }
580        "-visible" {
581            set dlist {}
582            foreach dataobj $_dlist {
583                if { ![IsValidObject $dataobj] } {
584                    continue
585                }
586                if { ![info exists _obj2ovride($dataobj-raise)] } {
587                    # No setting indicates that the object isn't visible.
588                    continue
589                }
590                # Otherwise use the -raise parameter to put the object to
591                # the front of the list.
592                if { $_obj2ovride($dataobj-raise) } {
593                    set dlist [linsert $dlist 0 $dataobj]
594                } else {
595                    lappend dlist $dataobj
596                }
597            }
598            return $dlist
599        }           
600        -image {
601            if {[llength $args] != 2} {
602                error "wrong # args: should be \"get -image view\""
603            }
604            switch -- [lindex $args end] {
605                view {
606                    return $_image(plot)
607                }
608                default {
609                    error "bad image name \"[lindex $args end]\": should be view"
610                }
611            }
612        }
613        default {
614            error "bad option \"$op\": should be -objects or -image"
615        }
616    }
617}
618
619#
620# scale  --
621#
622#       This gets called either incrementally as new simulations are
623#       added or all at once as a sequence of heightmaps.
624#       This  accounts for all objects--even those not showing on the
625#       screen.  Because of this, the limits are appropriate for all
626#       objects as the user scans through data in the ResultSet viewer.
627#
628itcl::body Rappture::VtkHeightmapViewer::scale {args} {
629    foreach dataobj $args {
630        if { ![$dataobj isvalid] } {
631            continue;                   # Object doesn't contain valid data.
632        }
633        foreach axis { x y } {
634            set lim [$dataobj limits $axis]
635            if { ![info exists _limits($axis)] } {
636                set _limits($axis) $lim
637                continue
638            }
639            foreach {min max} $lim break
640            foreach {amin amax} $_limits($axis) break
641            if { $amin > $min } {
642                set amin $min
643            }
644            if { $amax < $max } {
645                set amax $max
646            }
647            set _limits($axis) [list $amin $amax]
648            set units [$dataobj hints ${axis}units]
649            set found($units) 1
650        }
651        foreach { fname lim } [$dataobj fieldlimits] {
652            if { ![info exists _limits($fname)] } {
653                set _limits($fname) $lim
654                continue
655            }
656            foreach {min max} $lim break
657            foreach {fmin fmax} $_limits($fname) break
658            if { $fmin > $min } {
659                set fmin $min
660            }
661            if { $fmax < $max } {
662                set fmax $max
663            }
664            set _limits($fname) [list $fmin $fmax]
665        }
666    }
667    if { [array size found] > 1 } {
668        set _settings(-stretchtofit) 1
669    } else {
670        # Check if the range of the x and y axes requires that we stretch
671        # the contour to fit the plotting area.  This can happen when the
672        # x and y scales differ greatly (> 100x)
673        foreach {xmin xmax} $_limits(x) break
674        foreach {ymin ymax} $_limits(y) break
675        if { (($xmax - $xmin) > (($ymax -$ymin) * $_maxScale)) ||
676             ((($xmax - $xmin) * $_maxScale) < ($ymax -$ymin)) } {
677            set _settings(-stretchtofit) 1
678        }
679    }
680}
681
682# ----------------------------------------------------------------------
683# USAGE: download coming
684# USAGE: download controls <downloadCommand>
685# USAGE: download now
686#
687# Clients use this method to create a downloadable representation
688# of the plot.  Returns a list of the form {ext string}, where
689# "ext" is the file extension (indicating the type of data) and
690# "string" is the data itself.
691# ----------------------------------------------------------------------
692itcl::body Rappture::VtkHeightmapViewer::download {option args} {
693    switch $option {
694        coming {
695            if {[catch {
696                blt::winop snap $itk_component(plotarea) $_image(download)
697            }]} {
698                $_image(download) configure -width 1 -height 1
699                $_image(download) put #000000
700            }
701        }
702        controls {
703            set popup .vtkviewerdownload
704            if { ![winfo exists .vtkviewerdownload] } {
705                set inner [BuildDownloadPopup $popup [lindex $args 0]]
706            } else {
707                set inner [$popup component inner]
708            }
709            set _downloadPopup(image_controls) $inner.image_frame
710            set num [llength [get]]
711            set num [expr {($num == 1) ? "1 result" : "$num results"}]
712            set word [Rappture::filexfer::label downloadWord]
713            $inner.summary configure -text "$word $num in the following format:"
714            update idletasks            ;# Fix initial sizes
715            return $popup
716        }
717        now {
718            set popup .vtkviewerdownload
719            if {[winfo exists .vtkviewerdownload]} {
720                $popup deactivate
721            }
722            switch -- $_downloadPopup(format) {
723                "image" {
724                    return [$this GetImage [lindex $args 0]]
725                }
726                "vtk" {
727                    return [$this GetVtkData [lindex $args 0]]
728                }
729            }
730            return ""
731        }
732        default {
733            error "bad option \"$option\": should be coming, controls, now"
734        }
735    }
736}
737
738# ----------------------------------------------------------------------
739# USAGE: Connect ?<host:port>,<host:port>...?
740#
741# Clients use this method to establish a connection to a new
742# server, or to reestablish a connection to the previous server.
743# Any existing connection is automatically closed.
744# ----------------------------------------------------------------------
745itcl::body Rappture::VtkHeightmapViewer::Connect {} {
746    global readyForNextFrame
747    set readyForNextFrame 1
748    set _reset 1
749    set _hosts [GetServerList "vtkvis"]
750    if { "" == $_hosts } {
751        return 0
752    }
753    set result [VisViewer::Connect $_hosts]
754    if { $result } {
755        if { $_reportClientInfo }  {
756            # Tell the server the viewer, hub, user and session.
757            # Do this immediately on connect before buffering any commands
758            global env
759
760            set info {}
761            set user "???"
762            if { [info exists env(USER)] } {
763                set user $env(USER)
764            }
765            set session "???"
766            if { [info exists env(SESSION)] } {
767                set session $env(SESSION)
768            }
769            lappend info "version" "$Rappture::version"
770            lappend info "build" "$Rappture::build"
771            lappend info "svnurl" "$Rappture::svnurl"
772            lappend info "installdir" "$Rappture::installdir"
773            lappend info "hub" [exec hostname]
774            lappend info "client" "vtkheightmapviewer"
775            lappend info "user" $user
776            lappend info "session" $session
777            SendCmd "clientinfo [list $info]"
778        }
779        set w [winfo width $itk_component(view)]
780        set h [winfo height $itk_component(view)]
781        EventuallyResize $w $h
782    }
783    return $result
784}
785
786#
787# isconnected --
788#
789#       Indicates if we are currently connected to the visualization server.
790#
791itcl::body Rappture::VtkHeightmapViewer::isconnected {} {
792    return [VisViewer::IsConnected]
793}
794
795#
796# disconnect --
797#
798itcl::body Rappture::VtkHeightmapViewer::disconnect {} {
799    Disconnect
800    set _reset 1
801}
802
803#
804# Disconnect --
805#
806#       Clients use this method to disconnect from the current rendering
807#       server.
808#
809itcl::body Rappture::VtkHeightmapViewer::Disconnect {} {
810    VisViewer::Disconnect
811
812    $_dispatcher cancel !rebuild
813    $_dispatcher cancel !resize
814    $_dispatcher cancel !rotate
815    $_dispatcher cancel !legend
816    # disconnected -- no more data sitting on server
817    array unset _datasets
818    array unset _data
819    array unset _colormaps
820    array unset _obj2datasets
821    global readyForNextFrame
822    set readyForNextFrame 1
823}
824
825# ----------------------------------------------------------------------
826# USAGE: ReceiveImage -bytes <size> -type <type> -token <token>
827#
828# Invoked automatically whenever the "image" command comes in from
829# the rendering server.  Indicates that binary image data with the
830# specified <size> will follow.
831# ----------------------------------------------------------------------
832itcl::body Rappture::VtkHeightmapViewer::ReceiveImage { args } {
833    global readyForNextFrame
834    set readyForNextFrame 1
835    array set info {
836        -token "???"
837        -bytes 0
838        -type image
839    }
840    array set info $args
841    set bytes [ReceiveBytes $info(-bytes)]
842    if { $info(-type) == "image" } {
843        if 0 {
844            set f [open "last.ppm" "w"]
845            puts $f $bytes
846            close $f
847        }
848        $_image(plot) configure -data $bytes
849        set time [clock seconds]
850        set date [clock format $time]
851        #puts stderr "$date: received image [image width $_image(plot)]x[image height $_image(plot)] image>"       
852        if { $_start > 0 } {
853            set finish [clock clicks -milliseconds]
854            #puts stderr "round trip time [expr $finish -$_start] milliseconds"
855            set _start 0
856        }
857    } elseif { $info(type) == "print" } {
858        set tag $this-print-$info(-token)
859        set _hardcopy($tag) $bytes
860    }
861}
862
863#
864# ReceiveDataset --
865#
866itcl::body Rappture::VtkHeightmapViewer::ReceiveDataset { args } {
867    if { ![isconnected] } {
868        return
869    }
870    set option [lindex $args 0]
871    switch -- $option {
872        "scalar" {
873            set option [lindex $args 1]
874            switch -- $option {
875                "world" {
876                    foreach { x y z value tag } [lrange $args 2 end] break
877                }
878                "pixel" {
879                    foreach { x y value tag } [lrange $args 2 end] break
880                }
881            }
882        }
883        "vector" {
884            set option [lindex $args 1]
885            switch -- $option {
886                "world" {
887                    foreach { x y z vx vy vz tag } [lrange $args 2 end] break
888                }
889                "pixel" {
890                    foreach { x y vx vy vz tag } [lrange $args 2 end] break
891                }
892            }
893        }
894        "names" {
895            foreach { name } [lindex $args 1] {
896                #puts stderr "Dataset: $name"
897            }
898        }
899        default {
900            error "unknown dataset option \"$option\" from server"
901        }
902    }
903}
904
905# ----------------------------------------------------------------------
906# USAGE: Rebuild
907#
908# Called automatically whenever something changes that affects the
909# data in the widget.  Clears any existing data and rebuilds the
910# widget to display new data.
911# ----------------------------------------------------------------------
912itcl::body Rappture::VtkHeightmapViewer::Rebuild {} {
913    set w [winfo width $itk_component(view)]
914    set h [winfo height $itk_component(view)]
915    if { $w < 2 || $h < 2 } {
916        $_dispatcher event -idle !rebuild
917        return
918    }
919
920    # Turn on buffering of commands to the server.  We don't want to
921    # be preempted by a server disconnect/reconnect (which automatically
922    # generates a new call to Rebuild).   
923    StartBufferingCommands
924
925    if { $_width != $w || $_height != $h || $_reset } {
926        set _width $w
927        set _height $h
928        $_arcball resize $w $h
929        DoResize
930        if { $_settings(-stretchtofit) } {
931            AdjustSetting -stretchtofit
932        }
933    }
934    if { $_reset } {
935        #
936        # Reset the camera and other view parameters
937        #
938        InitSettings -isheightmap -background
939
940        # Setting a custom exponent and label format for axes is causing
941        # a problem with rounding.  Near zero ticks aren't rounded by
942        # the %g format.  The VTK CubeAxes seem to currently work best
943        # when allowed to automatically set the exponent and precision
944        # based on the axis ranges.  This does tend to result in less
945        # visual clutter, so I think it is best to use the automatic
946        # settings by default.  We can test more fine-grained
947        # controls on the axis settings tab if necessary.
948        # -Leif
949        #SendCmd "axis exp 0 0 0 1"
950
951        SendCmd "axis lrot z 90"
952        set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
953        $_arcball quaternion $q
954        if {$_settings(-isheightmap) } {
955            if { $_view(ortho)} {
956                SendCmd "camera mode ortho"
957            } else {
958                SendCmd "camera mode persp"
959            }
960            DoRotate
961            SendCmd "camera reset"
962        }
963        PanCamera
964        StopBufferingCommands
965        SendCmd "imgflush"
966        StartBufferingCommands
967    }
968
969    set _first ""
970    # Start off with no datasets are visible.
971    SendCmd "dataset visible 0"
972    set scale [GetHeightmapScale]
973    foreach dataobj [get -objects] {
974        if { [info exists _obj2ovride($dataobj-raise)] &&  $_first == "" } {
975            set _first $dataobj
976        }
977        set _obj2datasets($dataobj) ""
978        foreach comp [$dataobj components] {
979            set tag $dataobj-$comp
980            if { ![info exists _datasets($tag)] } {
981                set bytes [$dataobj vtkdata $comp]
982                if 0 {
983                    set f [open /tmp/vtkheightmap.vtk "w"]
984                    puts $f $bytes
985                    close $f
986                }
987                set length [string length $bytes]
988                if { $_reportClientInfo }  {
989                    set info {}
990                    lappend info "tool_id"       [$dataobj hints toolId]
991                    lappend info "tool_name"     [$dataobj hints toolName]
992                    lappend info "tool_version"  [$dataobj hints toolRevision]
993                    lappend info "tool_title"    [$dataobj hints toolTitle]
994                    lappend info "dataset_label" [$dataobj hints label]
995                    lappend info "dataset_size"  $length
996                    lappend info "dataset_tag"   $tag
997                    SendCmd [list "clientinfo" $info]
998                }
999                SendCmd "dataset add $tag data follows $length"
1000                append _outbuf $bytes
1001                set _datasets($tag) 1
1002                SetObjectStyle $dataobj $comp
1003            }
1004            lappend _obj2datasets($dataobj) $tag
1005            if { [info exists _obj2ovride($dataobj-raise)] } {
1006                # Setting dataset visible enables outline
1007                # and heightmap
1008                SendCmd "dataset visible 1 $tag"
1009            }
1010            if { ![info exists _comp2scale($tag)] ||
1011                 $_comp2scale($tag) != $scale } {
1012                SendCmd "heightmap heightscale $scale $tag"
1013                set _comp2scale($tag) $scale
1014            }
1015        }
1016    }
1017    if { $_first != ""  } {
1018        $itk_component(field) choices delete 0 end
1019        $itk_component(fieldmenu) delete 0 end
1020        array unset _fields
1021        set _curFldName ""
1022        foreach cname [$_first components] {
1023            foreach fname [$_first fieldnames $cname] {
1024                if { [info exists _fields($fname)] } {
1025                    continue
1026                }
1027                foreach { label units components } \
1028                    [$_first fieldinfo $fname] break
1029                $itk_component(field) choices insert end "$fname" "$label"
1030                $itk_component(fieldmenu) add radiobutton -label "$label" \
1031                    -value $label -variable [itcl::scope _curFldLabel] \
1032                    -selectcolor red \
1033                    -activebackground $itk_option(-plotbackground) \
1034                    -activeforeground $itk_option(-plotforeground) \
1035                    -font "Arial 8" \
1036                    -command [itcl::code $this Combo invoke]
1037                set _fields($fname) [list $label $units $components]
1038                if { $_curFldName == "" } {
1039                    set _curFldName $fname
1040                    set _curFldLabel $label
1041                }
1042            }
1043        }
1044        $itk_component(field) value $_curFldLabel
1045    }
1046    InitSettings -stretchtofit -outline
1047
1048    if { $_reset } {
1049        SendCmd "axis tickpos outside"
1050        foreach axis { x y z } {
1051            SendCmd "axis lformat $axis %g"
1052        }
1053       
1054        foreach axis { x y z } {
1055            if { $axis == "z" } {
1056                set label [$_first hints label]
1057            } else {
1058                set label [$_first hints ${axis}label]
1059            }
1060            if { $label == "" } {
1061                if {$axis == "z"} {
1062                    if { [string match "component*" $_curFldName] } {
1063                        set label [string toupper $axis]
1064                    } else {
1065                        set label $_curFldLabel
1066                    }
1067                } else {
1068                    set label [string toupper $axis]
1069                }
1070            }
1071            # May be a space in the axis label.
1072            SendCmd [list axis name $axis $label]
1073
1074            if {$axis == "z" && [$_first hints ${axis}units] == ""} {
1075                set units [lindex $_fields($_curFldName) 1]
1076            } else {
1077                set units [$_first hints ${axis}units]
1078            }
1079            if { $units != "" } {
1080                # May be a space in the axis units.
1081                SendCmd [list axis units $axis $units]
1082            }
1083        }
1084        #
1085        # Reset the camera and other view parameters
1086        #
1087        ResetAxes
1088        set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
1089        $_arcball quaternion $q
1090        if {$_settings(-isheightmap) } {
1091            if { $_view(ortho)} {
1092                SendCmd "camera mode ortho"
1093            } else {
1094                SendCmd "camera mode persp"
1095            }
1096            DoRotate
1097            SendCmd "camera reset"
1098        }
1099        PanCamera
1100        InitSettings -xgrid -ygrid -zgrid \
1101            -axisvisible -axislabels -heightmapscale -field -isheightmap \
1102            -numisolines
1103        if { [array size _fields] < 2 } {
1104            catch {
1105                blt::table forget $itk_component(field) $itk_component(field_l)
1106            }
1107        }
1108        RequestLegend
1109        set _reset 0
1110    }
1111    global readyForNextFrame
1112    set readyForNextFrame 0;            # Don't advance to the next frame
1113
1114    # Actually write the commands to the server socket.  If it fails, we don't
1115    # care.  We're finished here.
1116    blt::busy hold $itk_component(hull)
1117    StopBufferingCommands
1118    blt::busy release $itk_component(hull)
1119}
1120
1121# ----------------------------------------------------------------------
1122# USAGE: CurrentDatasets ?-all -visible? ?dataobjs?
1123#
1124# Returns a list of server IDs for the current datasets being displayed.  This
1125# is normally a single ID, but it might be a list of IDs if the current data
1126# object has multiple components.
1127# ----------------------------------------------------------------------
1128itcl::body Rappture::VtkHeightmapViewer::CurrentDatasets {args} {
1129    set flag [lindex $args 0]
1130    switch -- $flag {
1131        "-all" {
1132            if { [llength $args] > 1 } {
1133                error "CurrentDatasets: can't specify dataobj after \"-all\""
1134            }
1135            set dlist [get -objects]
1136        }
1137        "-visible" {
1138            if { [llength $args] > 1 } {
1139                set dlist {}
1140                set args [lrange $args 1 end]
1141                foreach dataobj $args {
1142                    if { [info exists _obj2ovride($dataobj-raise)] } {
1143                        lappend dlist $dataobj
1144                    }
1145                }
1146            } else {
1147                set dlist [get -visible]
1148            }
1149        }           
1150        default {
1151            set dlist $args
1152        }
1153    }
1154    set rlist ""
1155    foreach dataobj $dlist {
1156        foreach comp [$dataobj components] {
1157            set tag $dataobj-$comp
1158            if { [info exists _datasets($tag)] && $_datasets($tag) } {
1159                lappend rlist $tag
1160            }
1161        }
1162    }
1163    return $rlist
1164}
1165
1166itcl::body Rappture::VtkHeightmapViewer::CameraReset {} {
1167    array set _view {
1168        qw      0.36
1169        qx      0.25
1170        qy      0.50
1171        qz      0.70
1172        zoom    1.0
1173        xpan    0
1174        ypan    0
1175    }
1176    if { $_first != "" } {
1177        set location [$_first hints camera]
1178        if { $location != "" } {
1179            array set _view $location
1180        }
1181    }
1182    set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
1183    $_arcball quaternion $q
1184    if {$_settings(-isheightmap) } {
1185        DoRotate
1186    }
1187    SendCmd "camera reset"
1188}
1189
1190# ----------------------------------------------------------------------
1191# USAGE: Zoom in
1192# USAGE: Zoom out
1193# USAGE: Zoom reset
1194#
1195# Called automatically when the user clicks on one of the zoom
1196# controls for this widget.  Changes the zoom for the current view.
1197# ----------------------------------------------------------------------
1198itcl::body Rappture::VtkHeightmapViewer::Zoom {option} {
1199    switch -- $option {
1200        "in" {
1201            set _view(zoom) [expr {$_view(zoom)*1.25}]
1202            SendCmd "camera zoom $_view(zoom)"
1203        }
1204        "out" {
1205            set _view(zoom) [expr {$_view(zoom)*0.8}]
1206            SendCmd "camera zoom $_view(zoom)"
1207        }
1208        "reset" {
1209            array set _view {
1210                zoom    1.0
1211                xpan    0
1212                ypan    0
1213            }
1214            SendCmd "camera reset"
1215        }
1216    }
1217}
1218
1219itcl::body Rappture::VtkHeightmapViewer::PanCamera {} {
1220    set x $_view(xpan)
1221    set y $_view(ypan)
1222    SendCmd "camera pan $x $y"
1223}
1224
1225
1226# ----------------------------------------------------------------------
1227# USAGE: Rotate click <x> <y>
1228# USAGE: Rotate drag <x> <y>
1229# USAGE: Rotate release <x> <y>
1230#
1231# Called automatically when the user clicks/drags/releases in the
1232# plot area.  Moves the plot according to the user's actions.
1233# ----------------------------------------------------------------------
1234itcl::body Rappture::VtkHeightmapViewer::Rotate {option x y} {
1235    switch -- $option {
1236        "click" {
1237            $itk_component(view) configure -cursor fleur
1238            set _click(x) $x
1239            set _click(y) $y
1240        }
1241        "drag" {
1242            if {[array size _click] == 0} {
1243                Rotate click $x $y
1244            } else {
1245                set w [winfo width $itk_component(view)]
1246                set h [winfo height $itk_component(view)]
1247                if {$w <= 0 || $h <= 0} {
1248                    return
1249                }
1250
1251                if {[catch {
1252                    # this fails sometimes for no apparent reason
1253                    set dx [expr {double($x-$_click(x))/$w}]
1254                    set dy [expr {double($y-$_click(y))/$h}]
1255                }]} {
1256                    return
1257                }
1258                if { $dx == 0 && $dy == 0 } {
1259                    return
1260                }
1261                set q [$_arcball rotate $x $y $_click(x) $_click(y)]
1262                EventuallyRotate $q
1263                set _click(x) $x
1264                set _click(y) $y
1265            }
1266        }
1267        "release" {
1268            Rotate drag $x $y
1269            $itk_component(view) configure -cursor ""
1270            catch {unset _click}
1271        }
1272        default {
1273            error "bad option \"$option\": should be click, drag, release"
1274        }
1275    }
1276}
1277
1278itcl::body Rappture::VtkHeightmapViewer::Pick {x y} {
1279    foreach tag [CurrentDatasets -visible] {
1280        SendCmd "dataset getscalar pixel $x $y $tag"
1281    }
1282}
1283
1284# ----------------------------------------------------------------------
1285# USAGE: $this Pan click x y
1286#        $this Pan drag x y
1287#        $this Pan release x y
1288#
1289# Called automatically when the user clicks on one of the zoom
1290# controls for this widget.  Changes the zoom for the current view.
1291# ----------------------------------------------------------------------
1292itcl::body Rappture::VtkHeightmapViewer::Pan {option x y} {
1293    switch -- $option {
1294        "set" {
1295            set w [winfo width $itk_component(view)]
1296            set h [winfo height $itk_component(view)]
1297            set x [expr $x / double($w)]
1298            set y [expr $y / double($h)]
1299            set _view(xpan) [expr $_view(xpan) + $x]
1300            set _view(ypan) [expr $_view(ypan) + $y]
1301            PanCamera
1302            return
1303        }
1304        "click" {
1305            set _click(x) $x
1306            set _click(y) $y
1307            $itk_component(view) configure -cursor hand1
1308        }
1309        "drag" {
1310            if { ![info exists _click(x)] } {
1311                set _click(x) $x
1312            }
1313            if { ![info exists _click(y)] } {
1314                set _click(y) $y
1315            }
1316            set w [winfo width $itk_component(view)]
1317            set h [winfo height $itk_component(view)]
1318            set dx [expr ($_click(x) - $x)/double($w)]
1319            set dy [expr ($_click(y) - $y)/double($h)]
1320            set _click(x) $x
1321            set _click(y) $y
1322            set _view(xpan) [expr $_view(xpan) - $dx]
1323            set _view(ypan) [expr $_view(ypan) - $dy]
1324            PanCamera
1325        }
1326        "release" {
1327            Pan drag $x $y
1328            $itk_component(view) configure -cursor ""
1329        }
1330        default {
1331            error "unknown option \"$option\": should set, click, drag, or release"
1332        }
1333    }
1334}
1335
1336# ----------------------------------------------------------------------
1337# USAGE: InitSettings <what> ?<value>?
1338#
1339# Used internally to update rendering settings whenever parameters
1340# change in the popup settings panel.  Sends the new settings off
1341# to the back end.
1342# ----------------------------------------------------------------------
1343itcl::body Rappture::VtkHeightmapViewer::InitSettings { args } {
1344    foreach spec $args {
1345        if { [info exists _settings($_first${spec})] } {
1346            # Reset global setting with dataobj specific setting
1347            set _settings($spec) $_settings($_first${spec})
1348        }
1349        AdjustSetting $spec
1350    }
1351}
1352
1353#
1354# AdjustSetting --
1355#
1356#       Changes/updates a specific setting in the widget.  There are
1357#       usually user-setable option.  Commands are sent to the render
1358#       server.
1359#
1360itcl::body Rappture::VtkHeightmapViewer::AdjustSetting {what {value ""}} {
1361    if { $_beforeConnect } {
1362        return
1363    }
1364    switch -- $what {
1365        "-axisflymode" {
1366            set mode [$itk_component(axisflymode) value]
1367            set mode [$itk_component(axisflymode) translate $mode]
1368            set _settings($what) $mode
1369            SendCmd "axis flymode $mode"
1370        }
1371        "-axislabels" {
1372            set bool $_settings($what)
1373            SendCmd "axis labels all $bool"
1374        }
1375        "-axisminorticks" {
1376            set bool $_settings($what)
1377            SendCmd "axis minticks all $bool"
1378        }
1379        "-axisvisible" {
1380            set bool $_settings($what)
1381            SendCmd "axis visible all $bool"
1382        }
1383        "-xgrid" - "-ygrid" - "-zgrid" {
1384            set axis [string tolower [string range $what 1 1]]
1385            set bool $_settings($what)
1386            SendCmd "axis grid $axis $bool"
1387        }
1388        "-background" {
1389            set bg [$itk_component(background) value]
1390            array set fgcolors {
1391                "black" "white"
1392                "white" "black"
1393                "grey"  "black"
1394            }
1395            set fg $fgcolors($bg)
1396            configure -plotbackground $bg -plotforeground $fg
1397            $itk_component(view) delete "legend"
1398            SendCmd "screen bgcolor [Color2RGB $bg]"
1399            SendCmd "outline color [Color2RGB $fg]"
1400            SendCmd "axis color all [Color2RGB $fg]"
1401            DrawLegend
1402        }
1403        "-colormap" {
1404            set _changed($what) 1
1405            StartBufferingCommands
1406            set color [$itk_component(colormap) value]
1407            set _settings($what) $color
1408            if { $color == "none" } {
1409                if { $_settings(-colormapvisible) } {
1410                    SendCmd "heightmap surface 0"
1411                    set _settings(-colormapvisible) 0
1412                }
1413            } else {
1414                if { !$_settings(-colormapvisible) } {
1415                    SendCmd "heightmap surface 1"
1416                    set _settings(-colormapvisible) 1
1417                }
1418                SetCurrentColormap $color
1419                if {$_settings(-colormapdiscrete)} {
1420                    set numColors [expr $_settings(-numisolines) + 1]
1421                    SendCmd "colormap res $numColors $color"
1422                }
1423            }
1424            StopBufferingCommands
1425            EventuallyRequestLegend
1426        }
1427        "-colormapvisible" {
1428            set bool $_settings($what)
1429            SendCmd "heightmap surface $bool"
1430        }
1431        "-colormapdiscrete" {
1432            set bool $_settings($what)
1433            set numColors [expr $_settings(-numisolines) + 1]
1434            StartBufferingCommands
1435            if {$bool} {
1436                SendCmd "colormap res $numColors"
1437                # Discrete colormap requires preinterp on
1438                SendCmd "heightmap preinterp on"
1439            } else {
1440                SendCmd "colormap res default"
1441                # FIXME: add setting for preinterp (default on)
1442                SendCmd "heightmap preinterp on"
1443            }
1444            StopBufferingCommands
1445            EventuallyRequestLegend
1446        }
1447        "-edges" {
1448            set bool $_settings($what)
1449            SendCmd "heightmap edges $bool"
1450        }
1451        "-field" {
1452            set label [$itk_component(field) value]
1453            set fname [$itk_component(field) translate $label]
1454            set _settings($what) $fname
1455            if { [info exists _fields($fname)] } {
1456                foreach { label units components } $_fields($fname) break
1457                if { $components > 1 } {
1458                    set _colorMode vmag
1459                } else {
1460                    set _colorMode scalar
1461                }
1462                set _curFldName $fname
1463                set _curFldLabel $label
1464            } else {
1465                puts stderr "unknown field \"$fname\""
1466                return
1467            }
1468            set label [$_first hints label]
1469            if { $label == "" } {
1470                if { [string match "component*" $_curFldName] } {
1471                    set label Z
1472                } else {
1473                    set label $_curFldLabel
1474                }
1475            }
1476            # May be a space in the axis label.
1477            SendCmd [list axis name z $label]
1478
1479            if { [$_first hints zunits] == "" } {
1480                set units [lindex $_fields($_curFldName) 1]
1481            } else {
1482                set units [$_first hints zunits]
1483            }
1484            if { $units != "" } {
1485                # May be a space in the axis units.
1486                SendCmd [list axis units z $units]
1487            }
1488            # Get the new limits because the field changed.
1489            ResetAxes
1490            SendCmd "dataset scalar $_curFldName"
1491            SendCmd "heightmap colormode scalar $_curFldName"
1492            Zoom reset
1493            UpdateContourList
1494            DrawLegend
1495        }
1496        "-heightmapscale" {
1497            if { $_settings(-isheightmap) } {
1498                set scale [GetHeightmapScale]
1499                # Have to set the datasets individually because we are
1500                # tracking them in _comp2scale.
1501                foreach dataset [CurrentDatasets -all] {
1502                    SendCmd "heightmap heightscale $scale $dataset"
1503                    set _comp2scale($dataset) $scale
1504                }
1505                ResetAxes
1506            }
1507        }
1508        "-isheightmap" {
1509            set bool $_settings($what)
1510            set c $itk_component(view)
1511            StartBufferingCommands
1512            # Fix heightmap scale: 0 for contours, 1 for heightmaps.
1513            if { $bool } {
1514                set _settings(-heightmapscale) 50
1515                set _settings(-opacity) $_settings(-saveopacity)
1516                set _settings(-lighting) $_settings(-savelighting)
1517                set _settings(-outline) 0
1518            } else {
1519                set _settings(-heightmapscale) 0
1520                set _settings(-lighting) 0
1521                set _settings(-opacity) 100
1522                set _settings(-outline)  $_settings(-saveoutline)
1523            }
1524            InitSettings -lighting -opacity -outline
1525            set scale [GetHeightmapScale]
1526            # Have to set the datasets individually because we are
1527            # tracking them in _comp2scale.
1528            foreach dataset [CurrentDatasets -all] {
1529                SendCmd "heightmap heightscale $scale $dataset"
1530                set _comp2scale($dataset) $scale
1531            }
1532            if { $bool } {
1533                $itk_component(lighting) configure -state normal
1534                $itk_component(opacity) configure -state normal
1535                $itk_component(scale) configure -state normal
1536                $itk_component(opacity_l) configure -state normal
1537                $itk_component(scale_l) configure -state normal
1538                $itk_component(outline) configure -state disabled
1539                if {$_view(ortho)} {
1540                    SendCmd "camera mode ortho"
1541                } else {
1542                    SendCmd "camera mode persp"
1543                }
1544            } else {
1545                $itk_component(lighting) configure -state disabled
1546                $itk_component(opacity) configure -state disabled
1547                $itk_component(scale) configure -state disabled
1548                $itk_component(opacity_l) configure -state disabled
1549                $itk_component(scale_l) configure -state disabled
1550                $itk_component(outline) configure -state normal
1551                SendCmd "camera mode image"
1552            }
1553            if {$_settings(-stretchtofit)} {
1554                if {$scale == 0} {
1555                    SendCmd "camera aspect window"
1556                } else {
1557                    SendCmd "camera aspect square"
1558                }
1559            }
1560            ResetAxes
1561            if { $bool } {
1562                set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
1563                $_arcball quaternion $q
1564                SendCmd "camera orient $q"
1565            } else {
1566                bind $c <ButtonPress-1> {}
1567                bind $c <B1-Motion> {}
1568                bind $c <ButtonRelease-1> {}
1569            }
1570            Zoom reset
1571            # Fix the mouse bindings for rotation/panning and the
1572            # camera mode. Ideally we'd create a bindtag for these.
1573            if { $bool } {
1574                # Bindings for rotation via mouse
1575                bind $c <ButtonPress-1> \
1576                    [itcl::code $this Rotate click %x %y]
1577                bind $c <B1-Motion> \
1578                    [itcl::code $this Rotate drag %x %y]
1579                bind $c <ButtonRelease-1> \
1580                    [itcl::code $this Rotate release %x %y]
1581            }
1582            StopBufferingCommands
1583        }
1584        "-isolinecolor" {
1585            set color [$itk_component(isolinecolor) value]
1586            if { $color == "none" } {
1587                if { $_settings(-isolinesvisible) } {
1588                    SendCmd "heightmap isolines 0"
1589                    set _settings(-isolinesvisible) 0
1590                }
1591            } else {
1592                if { !$_settings(-isolinesvisible) } {
1593                    SendCmd "heightmap isolines 1"
1594                    set _settings(-isolinesvisible) 1
1595                }
1596                SendCmd "heightmap isolinecolor [Color2RGB $color]"
1597            }
1598            DrawLegend
1599        }
1600        "-isolinesvisible" {
1601            set bool $_settings($what)
1602            SendCmd "heightmap isolines $bool"
1603            DrawLegend
1604        }
1605        "-legendvisible" {
1606            if { !$_settings($what) } {
1607                $itk_component(view) delete legend
1608            }
1609            DrawLegend
1610        }
1611        "-lighting" {
1612            if { $_settings(-isheightmap) } {
1613                set _settings(-savelighting) $_settings($what)
1614                set bool $_settings($what)
1615                SendCmd "heightmap lighting $bool"
1616            } else {
1617                SendCmd "heightmap lighting 0"
1618            }
1619        }
1620        "-numisolines" {
1621            set _settings($what) [$itk_component(numisolines) value]
1622            set _currentNumIsolines $_settings($what)
1623            UpdateContourList
1624            set _changed($what) 1
1625            SendCmd "heightmap contourlist [list $_contourList]"
1626            if {$_settings(-colormapdiscrete)} {
1627                set numColors [expr $_settings($what) + 1]
1628                SendCmd "colormap res $numColors"
1629                EventuallyRequestLegend
1630            } else {
1631                DrawLegend
1632            }
1633        }
1634        "-opacity" {
1635            set _changed($what) 1
1636            set val [expr $_settings($what) * 0.01]
1637            if { $_settings(-isheightmap) } {
1638                set _settings(-saveopacity) $_settings($what)
1639                SendCmd "heightmap opacity $val"
1640            } else {
1641                SendCmd "heightmap opacity 1.0"
1642            }
1643        }
1644        "-outline" {
1645            if { $_settings(-isheightmap) } {
1646                SendCmd "outline visible 0"
1647            } else {
1648                set _settings(-saveoutline) $_settings($what)
1649                set bool $_settings($what)
1650                SendCmd "outline visible $bool"
1651            }
1652        }
1653        "-stretchtofit" {
1654            set bool $_settings($what)
1655            if { $bool } {
1656                set heightScale [GetHeightmapScale]
1657                if {$heightScale == 0} {
1658                    SendCmd "camera aspect window"
1659                } else {
1660                    SendCmd "camera aspect square"
1661                }
1662            } else {
1663                SendCmd "camera aspect native"
1664            }
1665            Zoom reset
1666        }
1667        "-wireframe" {
1668            set bool $_settings($what)
1669            SendCmd "heightmap wireframe $bool"
1670        }
1671        default {
1672            error "don't know how to fix $what"
1673        }
1674    }
1675}
1676
1677#
1678# RequestLegend --
1679#
1680#       Request a new legend from the server.  The size of the legend
1681#       is determined from the height of the canvas. 
1682#
1683# This should be called when
1684#       1.  A new current colormap is set.
1685#       2.  Window is resized.
1686#       3.  The limits of the data have changed.  (Just need a redraw).
1687#       4.  Number of isolines have changed. (Just need a redraw).
1688#       5.  Legend becomes visible (Just need a redraw).
1689#
1690itcl::body Rappture::VtkHeightmapViewer::RequestLegend {} {
1691    set _legendPending 0
1692    set font "Arial 8"
1693    set w 12
1694    set lineht [font metrics $font -linespace]
1695    # color ramp height = (canvas height) - (min and max value lines) - 2
1696    set h [expr {$_height - 2 * ($lineht + 2)}]
1697    set _legendHeight $h
1698
1699    set fname $_curFldName
1700    if { [string match "component*" $fname] } {
1701        set title ""
1702    } else {
1703        if { [info exists _fields($fname)] } {
1704            foreach { title units } $_fields($fname) break
1705            if { $units != "" } {
1706                set title [format "%s (%s)" $title $units]
1707            }
1708        } else {
1709            set title $fname
1710        }
1711    }
1712    # If there's a title too, substract one more line
1713    if { $title != "" } {
1714        incr h -$lineht
1715    }
1716    if { $h < 1 } {
1717        return
1718    }
1719    # Set the legend on the first heightmap dataset.
1720    if { $_currentColormap != ""  } {
1721        set cmap $_currentColormap
1722        SendCmd "legend $cmap scalar $_curFldName {} $w $h 0"
1723    }
1724}
1725
1726#
1727# ResetAxes --
1728#
1729#       Set axis z bounds and range
1730#
1731itcl::body Rappture::VtkHeightmapViewer::ResetAxes {} {
1732    if { ![info exists _limits($_curFldName)]} {
1733        SendCmd "dataset maprange all"
1734        SendCmd "axis autorange z on"
1735        SendCmd "axis autobounds z on"
1736        return
1737    }
1738    foreach { xmin xmax } $_limits(x) break
1739    foreach { ymin ymax } $_limits(y) break
1740    foreach { vmin vmax } $_limits($_curFldName) break
1741
1742    global tcl_precision
1743    set tcl_precision 17
1744    set xr [expr $xmax - $xmin]
1745    set yr [expr $ymax - $ymin]
1746    set vr [expr $vmax - $vmin]
1747    set r  [expr ($yr > $xr) ? $yr : $xr]
1748    if { $vr < 1.0e-17 } {
1749        set dataScale 1.0
1750    } else {
1751        set dataScale [expr $r / $vr]
1752    }
1753    set heightScale [GetHeightmapScale]
1754    set bmin [expr $heightScale * $dataScale * $vmin]
1755    set bmax [expr $heightScale * $dataScale * $vmax]
1756    if {$heightScale > 0} {
1757        set zpos [expr - $bmin]
1758        SendCmd "heightmap pos 0 0 $zpos"
1759    } else {
1760        SendCmd "heightmap pos 0 0 0"
1761    }
1762    set bmax [expr $bmax - $bmin]
1763    set bmin 0
1764    SendCmd "dataset maprange explicit $_limits($_curFldName) $_curFldName"
1765    SendCmd "axis bounds z $bmin $bmax"
1766    SendCmd "axis range z $_limits($_curFldName)"
1767}
1768
1769#
1770# SetCurrentColormap --
1771#
1772itcl::body Rappture::VtkHeightmapViewer::SetCurrentColormap { name } {
1773    # Keep track of the colormaps that we build.
1774    if { $name != "none" && ![info exists _colormaps($name)] } {
1775        BuildColormap $name
1776        set _colormaps($name) 1
1777    }
1778    set _currentColormap $name
1779    SendCmd "heightmap colormap $_currentColormap"
1780}
1781
1782
1783#
1784# BuildColormap --
1785#
1786#       Build the designated colormap on the server.
1787#
1788itcl::body Rappture::VtkHeightmapViewer::BuildColormap { name } {
1789    set cmap [ColorsToColormap $name]
1790    if { [llength $cmap] == 0 } {
1791        set cmap "0.0 0.0 0.0 0.0 1.0 1.0 1.0 1.0"
1792    }
1793    set wmap "0.0 1.0 1.0 1.0"
1794    SendCmd "colormap add $name { $cmap } { $wmap }"
1795}
1796
1797# ----------------------------------------------------------------------
1798# CONFIGURATION OPTION: -mode
1799# ----------------------------------------------------------------------
1800itcl::configbody Rappture::VtkHeightmapViewer::mode {
1801    switch -- $itk_option(-mode) {
1802        "heightmap" {
1803            set _settings(-isheightmap) 1
1804        }
1805        "contour" {
1806            set _settings(-isheightmap) 0
1807        }
1808        default {
1809            error "unknown mode settings \"$itk_option(-mode)\""
1810        }
1811    }
1812    if { !$_reset } {
1813        AdjustSetting -isheightmap
1814    }
1815}
1816
1817# ----------------------------------------------------------------------
1818# CONFIGURATION OPTION: -plotbackground
1819# ----------------------------------------------------------------------
1820itcl::configbody Rappture::VtkHeightmapViewer::plotbackground {
1821    if { [isconnected] } {
1822        set rgb [Color2RGB $itk_option(-plotbackground)]
1823        if { !$_reset } {
1824            SendCmd "screen bgcolor $rgb"
1825        }
1826        $itk_component(view) configure -background $itk_option(-plotbackground)
1827    }
1828}
1829
1830# ----------------------------------------------------------------------
1831# CONFIGURATION OPTION: -plotforeground
1832# ----------------------------------------------------------------------
1833itcl::configbody Rappture::VtkHeightmapViewer::plotforeground {
1834    if { [isconnected] } {
1835        set rgb [Color2RGB $itk_option(-plotforeground)]
1836        if { !$_reset } {
1837            SendCmd "outline color $rgb"
1838            SendCmd "axis color all $rgb"
1839        }
1840    }
1841}
1842
1843itcl::body Rappture::VtkHeightmapViewer::limits3 { dataobj } {
1844    lappend limits x [$dataobj limits x]
1845    lappend limits y [$dataobj limits y]
1846    if { [catch { $dataobj limits $_curFldName } vlim] != 0 } {
1847        set vlim [$dataobj limits v]
1848    }
1849    lappend limits v $vlim
1850    return $limits
1851}
1852
1853itcl::body Rappture::VtkHeightmapViewer::BuildContourTab {} {
1854
1855    set fg [option get $itk_component(hull) font Font]
1856    #set bfg [option get $itk_component(hull) boldFont Font]
1857
1858    set inner [$itk_component(main) insert end \
1859        -title "Contour/Surface Settings" \
1860        -icon [Rappture::icon contour2]]
1861    $inner configure -borderwidth 4
1862
1863    checkbutton $inner.legend \
1864        -text "Legend" \
1865        -variable [itcl::scope _settings(-legendvisible)] \
1866        -command [itcl::code $this AdjustSetting -legendvisible] \
1867        -font "Arial 9"
1868
1869    checkbutton $inner.wireframe \
1870        -text "Wireframe" \
1871        -variable [itcl::scope _settings(-wireframe)] \
1872        -command [itcl::code $this AdjustSetting -wireframe] \
1873        -font "Arial 9"
1874
1875    itk_component add lighting {
1876        checkbutton $inner.lighting \
1877            -text "Enable Lighting" \
1878            -variable [itcl::scope _settings(-lighting)] \
1879            -command [itcl::code $this AdjustSetting -lighting] \
1880            -font "Arial 9"
1881    } {
1882        ignore -font
1883    }
1884    checkbutton $inner.edges \
1885        -text "Edges" \
1886        -variable [itcl::scope _settings(-edges)] \
1887        -command [itcl::code $this AdjustSetting -edges] \
1888        -font "Arial 9"
1889
1890    itk_component add outline {
1891        checkbutton $inner.outline \
1892            -text "Outline" \
1893            -variable [itcl::scope _settings(-outline)] \
1894            -command [itcl::code $this AdjustSetting -outline] \
1895            -font "Arial 9"
1896    } {
1897        ignore -font
1898    }
1899    checkbutton $inner.stretch \
1900        -text "Stretch to fit" \
1901        -variable [itcl::scope _settings(-stretchtofit)] \
1902        -command [itcl::code $this AdjustSetting -stretchtofit] \
1903        -font "Arial 9"
1904
1905    checkbutton $inner.isolines \
1906        -text "Isolines" \
1907        -variable [itcl::scope _settings(-isolinesvisible)] \
1908        -command [itcl::code $this AdjustSetting -isolinesvisible] \
1909        -font "Arial 9"
1910
1911    checkbutton $inner.colormapDiscrete \
1912        -text "Discrete Colormap" \
1913        -variable [itcl::scope _settings(-colormapdiscrete)] \
1914        -command [itcl::code $this AdjustSetting -colormapdiscrete] \
1915        -font "Arial 9"
1916
1917    itk_component add field_l {
1918        label $inner.field_l -text "Field" -font "Arial 9"
1919    } {
1920        ignore -font
1921    }
1922    itk_component add field {
1923        Rappture::Combobox $inner.field -width 10 -editable no
1924    }
1925    bind $inner.field <<Value>> \
1926        [itcl::code $this AdjustSetting -field]
1927
1928    label $inner.colormap_l -text "Colormap" -font "Arial 9"
1929    itk_component add colormap {
1930        Rappture::Combobox $inner.colormap -width 10 -editable no
1931    }
1932    $inner.colormap choices insert end [GetColormapList -includeNone]
1933    $itk_component(colormap) value $_settings(-colormap)
1934    bind $inner.colormap <<Value>> \
1935        [itcl::code $this AdjustSetting -colormap]
1936
1937    label $inner.isolinecolor_l -text "Isolines Color" -font "Arial 9"
1938    itk_component add isolinecolor {
1939        Rappture::Combobox $inner.isolinecolor -width 10 -editable no
1940    }
1941    $inner.isolinecolor choices insert end \
1942        "black"              "black"            \
1943        "blue"               "blue"             \
1944        "cyan"               "cyan"             \
1945        "green"              "green"            \
1946        "grey"               "grey"             \
1947        "magenta"            "magenta"          \
1948        "orange"             "orange"           \
1949        "red"                "red"              \
1950        "white"              "white"            \
1951        "none"               "none"
1952
1953    $itk_component(isolinecolor) value $_settings(-isolinecolor)
1954    bind $inner.isolinecolor <<Value>> \
1955        [itcl::code $this AdjustSetting -isolinecolor]
1956
1957    label $inner.background_l -text "Background Color" -font "Arial 9"
1958    itk_component add background {
1959        Rappture::Combobox $inner.background -width 10 -editable no
1960    }
1961    $inner.background choices insert end \
1962        "black"              "black"            \
1963        "white"              "white"            \
1964        "grey"               "grey"             
1965
1966    $itk_component(background) value "white"
1967    bind $inner.background <<Value>> \
1968        [itcl::code $this AdjustSetting -background]
1969
1970    itk_component add opacity_l {
1971        label $inner.opacity_l -text "Opacity" -font "Arial 9"
1972    } {
1973        ignore -font
1974    }
1975    itk_component add opacity {
1976        ::scale $inner.opacity -from 0 -to 100 -orient horizontal \
1977            -variable [itcl::scope _settings(-opacity)] \
1978            -showvalue off \
1979            -command [itcl::code $this AdjustSetting -opacity]
1980    }
1981    itk_component add scale_l {
1982        label $inner.scale_l -text "Scale" -font "Arial 9"
1983    } {
1984        ignore -font
1985    }
1986    itk_component add scale {
1987        ::scale $inner.scale -from 0 -to 100 -orient horizontal \
1988            -variable [itcl::scope _settings(-heightmapscale)] \
1989            -showvalue off \
1990            -command [itcl::code $this AdjustSetting -heightmapscale]
1991    }
1992    label $inner.numisolines_l -text "Number of Isolines" -font "Arial 9"
1993    itk_component add numisolines {
1994        Rappture::Spinint $inner.numisolines \
1995            -min 0 -max 50 -font "arial 9"
1996    }
1997    $itk_component(numisolines) value $_settings(-numisolines)
1998    bind $itk_component(numisolines) <<Value>> \
1999        [itcl::code $this AdjustSetting -numisolines]
2000
2001    frame $inner.separator1 -height 2 -relief sunken -bd 1
2002    frame $inner.separator2 -height 2 -relief sunken -bd 1
2003
2004    blt::table $inner \
2005        0,0 $inner.field_l -anchor w -pady 2 \
2006        0,1 $inner.field -anchor w -pady 2 -fill x \
2007        1,0 $inner.colormap_l -anchor w -pady 2  \
2008        1,1 $inner.colormap   -anchor w -pady 2 -fill x  \
2009        2,0 $inner.isolinecolor_l  -anchor w -pady 2  \
2010        2,1 $inner.isolinecolor    -anchor w -pady 2 -fill x  \
2011        3,0 $inner.background_l -anchor w -pady 2 \
2012        3,1 $inner.background -anchor w -pady 2  -fill x \
2013        4,0 $inner.numisolines_l -anchor w -pady 2 \
2014        4,1 $inner.numisolines -anchor w -pady 2 \
2015        5,0 $inner.stretch    -anchor w -pady 2 -cspan 2 \
2016        6,0 $inner.edges      -anchor w -pady 2 -cspan 2 \
2017        7,0 $inner.legend     -anchor w -pady 2 -cspan 2 \
2018        8,0 $inner.colormapDiscrete -anchor w -pady 2 -cspan 2 \
2019        9,0 $inner.wireframe  -anchor w -pady 2 -cspan 2\
2020        10,0 $inner.isolines   -anchor w -pady 2 -cspan 2 \
2021        11,0 $inner.separator1 -padx 2 -fill x -cspan 2 \
2022        12,0 $inner.outline    -anchor w -pady 2 -cspan 2 \
2023        13,0 $inner.separator2 -padx 2 -fill x -cspan 2 \
2024        14,0 $inner.lighting   -anchor w -pady 2 -cspan 2 \
2025        15,0 $inner.opacity_l -anchor w -pady 2 \
2026        15,1 $inner.opacity   -fill x   -pady 2 \
2027        16,0 $inner.scale_l   -anchor w -pady 2 -cspan 2 \
2028        16,1 $inner.scale     -fill x   -pady 2 -cspan 2 \
2029
2030    blt::table configure $inner r* c* -resize none
2031    blt::table configure $inner r17 c1 -resize expand
2032}
2033
2034itcl::body Rappture::VtkHeightmapViewer::BuildAxisTab {} {
2035
2036    set fg [option get $itk_component(hull) font Font]
2037    #set bfg [option get $itk_component(hull) boldFont Font]
2038
2039    set inner [$itk_component(main) insert end \
2040        -title "Axis Settings" \
2041        -icon [Rappture::icon axis2]]
2042    $inner configure -borderwidth 4
2043
2044    checkbutton $inner.visible \
2045        -text "Axes" \
2046        -variable [itcl::scope _settings(-axisvisible)] \
2047        -command [itcl::code $this AdjustSetting -axisvisible] \
2048        -font "Arial 9"
2049    checkbutton $inner.labels \
2050        -text "Axis Labels" \
2051        -variable [itcl::scope _settings(-axislabels)] \
2052        -command [itcl::code $this AdjustSetting -axislabels] \
2053        -font "Arial 9"
2054    label $inner.grid_l -text "Grid" -font "Arial 9"
2055    checkbutton $inner.xgrid \
2056        -text "X" \
2057        -variable [itcl::scope _settings(-xgrid)] \
2058        -command [itcl::code $this AdjustSetting -xgrid] \
2059        -font "Arial 9"
2060    checkbutton $inner.ygrid \
2061        -text "Y" \
2062        -variable [itcl::scope _settings(-ygrid)] \
2063        -command [itcl::code $this AdjustSetting -ygrid] \
2064        -font "Arial 9"
2065    checkbutton $inner.zgrid \
2066        -text "Z" \
2067        -variable [itcl::scope _settings(-zgrid)] \
2068        -command [itcl::code $this AdjustSetting -zgrid] \
2069        -font "Arial 9"
2070    checkbutton $inner.minorticks \
2071        -text "Minor Ticks" \
2072        -variable [itcl::scope _settings(-axisminorticks)] \
2073        -command [itcl::code $this AdjustSetting -axisminorticks] \
2074        -font "Arial 9"
2075
2076    label $inner.mode_l -text "Mode" -font "Arial 9"
2077
2078    itk_component add axisflymode {
2079        Rappture::Combobox $inner.mode -width 10 -editable no
2080    }
2081    $inner.mode choices insert end \
2082        "static_triad"    "static" \
2083        "closest_triad"   "closest" \
2084        "furthest_triad"  "farthest" \
2085        "outer_edges"     "outer"         
2086    $itk_component(axisflymode) value $_settings(-axisflymode)
2087    bind $inner.mode <<Value>> [itcl::code $this AdjustSetting -axisflymode]
2088
2089    blt::table $inner \
2090        0,0 $inner.visible -anchor w -cspan 4 \
2091        1,0 $inner.labels  -anchor w -cspan 4 \
2092        2,0 $inner.minorticks  -anchor w -cspan 4 \
2093        4,0 $inner.grid_l  -anchor w \
2094        4,1 $inner.xgrid   -anchor w \
2095        4,2 $inner.ygrid   -anchor w \
2096        4,3 $inner.zgrid   -anchor w \
2097        5,0 $inner.mode_l  -anchor w -padx { 2 0 } \
2098        5,1 $inner.mode    -fill x -cspan 3
2099
2100    blt::table configure $inner r* c* -resize none
2101    blt::table configure $inner r7 c6 -resize expand
2102    blt::table configure $inner r3 -height 0.125i
2103}
2104
2105
2106itcl::body Rappture::VtkHeightmapViewer::BuildCameraTab {} {
2107    set inner [$itk_component(main) insert end \
2108        -title "Camera Settings" \
2109        -icon [Rappture::icon camera]]
2110    $inner configure -borderwidth 4
2111
2112    label $inner.view_l -text "view" -font "Arial 9"
2113    set f [frame $inner.view]
2114    foreach side { front back left right top bottom } {
2115        button $f.$side  -image [Rappture::icon view$side] \
2116            -command [itcl::code $this SetOrientation $side]
2117        Rappture::Tooltip::for $f.$side "Change the view to $side"
2118        pack $f.$side -side left
2119    }
2120
2121    blt::table $inner \
2122        0,0 $inner.view_l -anchor e -pady 2 \
2123        0,1 $inner.view -anchor w -pady 2
2124
2125    set labels { qx qy qz qw xpan ypan zoom }
2126    set row 1
2127    foreach tag $labels {
2128        label $inner.${tag}label -text $tag -font "Arial 9"
2129        entry $inner.${tag} -font "Arial 9"  -bg white \
2130            -textvariable [itcl::scope _view($tag)]
2131        bind $inner.${tag} <Return> \
2132            [itcl::code $this camera set ${tag}]
2133        bind $inner.${tag} <KP_Enter> \
2134            [itcl::code $this camera set ${tag}]
2135        blt::table $inner \
2136            $row,0 $inner.${tag}label -anchor e -pady 2 \
2137            $row,1 $inner.${tag} -anchor w -pady 2
2138        blt::table configure $inner r$row -resize none
2139        incr row
2140    }
2141    checkbutton $inner.ortho \
2142        -text "Orthographic Projection" \
2143        -variable [itcl::scope _view(ortho)] \
2144        -command [itcl::code $this camera set ortho] \
2145        -font "Arial 9"
2146    blt::table $inner \
2147            $row,0 $inner.ortho -cspan 2 -anchor w -pady 2
2148    blt::table configure $inner r$row -resize none
2149    incr row
2150
2151    blt::table configure $inner c* r* -resize none
2152    blt::table configure $inner c2 -resize expand
2153    blt::table configure $inner r$row -resize expand
2154}
2155
2156#
2157#  camera --
2158#
2159itcl::body Rappture::VtkHeightmapViewer::camera {option args} {
2160    switch -- $option {
2161        "show" {
2162            puts [array get _view]
2163        }
2164        "set" {
2165            set who [lindex $args 0]
2166            set x $_view($who)
2167            set code [catch { string is double $x } result]
2168            if { $code != 0 || !$result } {
2169                return
2170            }
2171            switch -- $who {
2172                "ortho" {
2173                    if {$_view(ortho)} {
2174                        SendCmd "camera mode ortho"
2175                    } else {
2176                        SendCmd "camera mode persp"
2177                    }
2178                }
2179                "xpan" - "ypan" {
2180                    PanCamera
2181                }
2182                "qx" - "qy" - "qz" - "qw" {
2183                    set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
2184                    $_arcball quaternion $q
2185                    EventuallyRotate $q
2186                }
2187                "zoom" {
2188                    SendCmd "camera zoom $_view(zoom)"
2189                }
2190            }
2191        }
2192    }
2193}
2194
2195itcl::body Rappture::VtkHeightmapViewer::GetVtkData { args } {
2196    set bytes ""
2197    foreach dataobj [get] {
2198        foreach comp [$dataobj components] {
2199            set tag $dataobj-$comp
2200            set contents [$dataobj vtkdata $comp]
2201            append bytes "$contents\n"
2202        }
2203    }
2204    return [list .vtk $bytes]
2205}
2206
2207itcl::body Rappture::VtkHeightmapViewer::GetImage { args } {
2208    if { [image width $_image(download)] > 0 &&
2209         [image height $_image(download)] > 0 } {
2210        set bytes [$_image(download) data -format "jpeg -quality 100"]
2211        set bytes [Rappture::encoding::decode -as b64 $bytes]
2212        return [list .jpg $bytes]
2213    }
2214    return ""
2215}
2216
2217itcl::body Rappture::VtkHeightmapViewer::BuildDownloadPopup { popup command } {
2218    Rappture::Balloon $popup \
2219        -title "[Rappture::filexfer::label downloadWord] as..."
2220    set inner [$popup component inner]
2221    label $inner.summary -text "" -anchor w
2222    radiobutton $inner.vtk_button -text "VTK data file" \
2223        -variable [itcl::scope _downloadPopup(format)] \
2224        -font "Arial 9 " \
2225        -value vtk 
2226    Rappture::Tooltip::for $inner.vtk_button "Save as VTK data file."
2227    radiobutton $inner.image_button -text "Image File" \
2228        -variable [itcl::scope _downloadPopup(format)] \
2229        -font "Arial 9 " \
2230        -value image
2231    Rappture::Tooltip::for $inner.image_button \
2232        "Save as digital image."
2233
2234    button $inner.ok -text "Save" \
2235        -highlightthickness 0 -pady 2 -padx 3 \
2236        -command $command \
2237        -compound left \
2238        -image [Rappture::icon download]
2239
2240    button $inner.cancel -text "Cancel" \
2241        -highlightthickness 0 -pady 2 -padx 3 \
2242        -command [list $popup deactivate] \
2243        -compound left \
2244        -image [Rappture::icon cancel]
2245
2246    blt::table $inner \
2247        0,0 $inner.summary -cspan 2  \
2248        1,0 $inner.vtk_button -anchor w -cspan 2 -padx { 4 0 } \
2249        2,0 $inner.image_button -anchor w -cspan 2 -padx { 4 0 } \
2250        4,1 $inner.cancel -width .9i -fill y \
2251        4,0 $inner.ok -padx 2 -width .9i -fill y
2252    blt::table configure $inner r3 -height 4
2253    blt::table configure $inner r4 -pady 4
2254    raise $inner.image_button
2255    $inner.vtk_button invoke
2256    return $inner
2257}
2258
2259#
2260# SetObjectStyle --
2261#
2262#       Set the style of the heightmap/contour object.  This gets calls
2263#       for each dataset once as it is loaded.  It can overridden by
2264#       the user controls.
2265#
2266#
2267itcl::body Rappture::VtkHeightmapViewer::SetObjectStyle { dataobj comp } {
2268    # Parse style string.
2269    set tag $dataobj-$comp
2270    array set style {
2271        -color BCGYR
2272        -levels 10
2273        -opacity 1.0
2274    }
2275    set stylelist [$dataobj style $comp]
2276    if { $stylelist != "" } {
2277        array set style $stylelist
2278    }
2279    # This is too complicated.  We want to set the colormap, number of
2280    # isolines and opacity for the dataset.  They can be the default values,
2281    # the style hints loaded with the dataset, or set by user controls.  As
2282    # datasets get loaded, they first use the defaults that are overidden
2283    # by the style hints.  If the user changes the global controls, then that
2284    # overrides everything else.  I don't know what it means when global
2285    # controls are specified as style hints by each dataset.  It complicates
2286    # the code to handle aberrant cases.
2287
2288    if { $_changed(-opacity) } {
2289        set style(-opacity) [expr $_settings(-opacity) * 0.01]
2290    }
2291    if { $_changed(-numisolines) } {
2292        set style(-levels) $_settings(-numisolines)
2293    }
2294    if { $_changed(-colormap) } {
2295        set style(-color) $_settings(-colormap)
2296    }
2297    if { $_currentColormap == "" } {
2298        $itk_component(colormap) value $style(-color)
2299    }
2300    if { [info exists style(-stretchtofit)] } {
2301        set _settings(-stretchtofit) $style(-stretchtofit)
2302        AdjustSetting -stretchtofit
2303    }
2304    if { $_currentNumIsolines != $style(-levels) } {
2305        set _currentNumIsolines $style(-levels)
2306        set _settings(-numisolines) $_currentNumIsolines
2307        $itk_component(numisolines) value $_currentNumIsolines
2308        UpdateContourList
2309        DrawLegend
2310    }
2311    SendCmd "outline add $tag"
2312    SendCmd "outline color [Color2RGB $itk_option(-plotforeground)] $tag"
2313    SendCmd "outline visible $_settings(-outline) $tag"
2314    set scale [GetHeightmapScale]
2315    SendCmd "[list heightmap add contourlist $_contourList $scale $tag]"
2316    set _comp2scale($tag) $_settings(-heightmapscale)
2317    SendCmd "heightmap edges $_settings(-edges) $tag"
2318    SendCmd "heightmap wireframe $_settings(-wireframe) $tag"
2319    SetCurrentColormap $style(-color)
2320    set color [$itk_component(isolinecolor) value]
2321    SendCmd "heightmap isolinecolor [Color2RGB $color] $tag"
2322    SendCmd "heightmap lighting $_settings(-isheightmap) $tag"
2323    SendCmd "heightmap isolines $_settings(-isolinesvisible) $tag"
2324    SendCmd "heightmap surface $_settings(-colormapvisible) $tag"
2325    SendCmd "heightmap opacity $style(-opacity) $tag"
2326    set _settings(-opacity) [expr $style(-opacity) * 100.0]
2327}
2328
2329itcl::body Rappture::VtkHeightmapViewer::IsValidObject { dataobj } {
2330    if {[catch {$dataobj isa Rappture::Field} valid] != 0 || !$valid} {
2331        return 0
2332    }
2333    return 1
2334}
2335
2336# ----------------------------------------------------------------------
2337# USAGE: ReceiveLegend <colormap> <title> <min> <max> <size>
2338#
2339# Invoked automatically whenever the "legend" command comes in from
2340# the rendering server.  Indicates that binary image data with the
2341# specified <size> will follow.
2342# ----------------------------------------------------------------------
2343itcl::body Rappture::VtkHeightmapViewer::ReceiveLegend { colormap title min max size } {
2344    #puts stderr "ReceiveLegend colormap=$colormap title=$title range=$min,$max size=$size"
2345    if { [isconnected] } {
2346        set bytes [ReceiveBytes $size]
2347        if { ![info exists _image(legend)] } {
2348            set _image(legend) [image create photo]
2349        }
2350        $_image(legend) configure -data $bytes
2351        #puts stderr "read $size bytes for [image width $_image(legend)]x[image height $_image(legend)] legend>"
2352        if { [catch {DrawLegend} errs] != 0 } {
2353            global errorInfo
2354            puts stderr "errs=$errs errorInfo=$errorInfo"
2355        }
2356    }
2357}
2358
2359#
2360# DrawLegend --
2361#
2362#       Draws the legend in the own canvas on the right side of the plot area.
2363#
2364itcl::body Rappture::VtkHeightmapViewer::DrawLegend {} {
2365    set fname $_curFldName
2366    set c $itk_component(view)
2367    set w [winfo width $c]
2368    set h [winfo height $c]
2369    set font "Arial 8"
2370    set lineht [font metrics $font -linespace]
2371   
2372    if { [string match "component*" $fname] } {
2373        set title ""
2374    } else {
2375        if { [info exists _fields($fname)] } {
2376            foreach { title units } $_fields($fname) break
2377            if { $units != "" } {
2378                set title [format "%s (%s)" $title $units]
2379            }
2380        } else {
2381            set title $fname
2382        }
2383    }
2384    set x [expr $w - 2]
2385    if { !$_settings(-legendvisible) } {
2386        $c delete legend
2387        return
2388    }
2389    if { [$c find withtag "legend"] == "" } {
2390        set y 2
2391        # If there's a legend title, create a text item for the title.
2392        $c create text $x $y \
2393            -anchor ne \
2394            -fill $itk_option(-plotforeground) -tags "title legend" \
2395            -font $font
2396        if { $title != "" } {
2397            incr y $lineht
2398        }
2399        $c create text $x $y \
2400            -anchor ne \
2401            -fill $itk_option(-plotforeground) -tags "vmax legend" \
2402            -font $font
2403        incr y $lineht
2404        $c create image $x $y \
2405            -anchor ne \
2406            -image $_image(legend) -tags "colormap legend"
2407        $c create rectangle $x $y 1 1 \
2408            -fill "" -outline "" -tags "sensor legend"
2409        $c create text $x [expr {$h-2}] \
2410            -anchor se \
2411            -fill $itk_option(-plotforeground) -tags "vmin legend" \
2412            -font $font
2413        $c bind sensor <Enter> [itcl::code $this EnterLegend %x %y]
2414        $c bind sensor <Leave> [itcl::code $this LeaveLegend]
2415        $c bind sensor <Motion> [itcl::code $this MotionLegend %x %y]
2416    }
2417    $c delete isoline
2418    set x2 $x
2419    set iw [image width $_image(legend)]
2420    set ih [image height $_image(legend)]
2421    set x1 [expr $x2 - ($iw*12)/10]
2422    set color [$itk_component(isolinecolor) value]
2423
2424    # Draw the isolines on the legend.
2425    array unset _isolines
2426    if { $color != "none"  && [info exists _limits($_curFldName)] &&
2427         $_settings(-isolinesvisible) && $_currentNumIsolines > 0 } {
2428
2429        foreach { vmin vmax } $_limits($_curFldName) break
2430        set range [expr double($vmax - $vmin)]
2431        if { $range <= 0.0 } {
2432            set range 1.0;              # Min is greater or equal to max.
2433        }
2434        set tags "isoline legend"
2435        set offset [expr 2 + $lineht]
2436        if { $title != "" } {
2437            incr offset $lineht
2438        }
2439        foreach value $_contourList {
2440            set norm [expr 1.0 - (($value - $vmin) / $range)]
2441            set y1 [expr int(round(($norm * $ih) + $offset))]
2442            for { set off 0 } { $off < 3 } { incr off } {
2443                set _isolines([expr $y1 + $off]) $value
2444                set _isolines([expr $y1 - $off]) $value
2445            }
2446            $c create line $x1 $y1 $x2 $y1 -fill $color -tags $tags
2447        }
2448    }
2449
2450    $c bind title <ButtonPress> [itcl::code $this Combo post]
2451    $c bind title <Enter> [itcl::code $this Combo activate]
2452    $c bind title <Leave> [itcl::code $this Combo deactivate]
2453    # Reset the item coordinates according the current size of the plot.
2454    if { [info exists _limits($_curFldName)] } {
2455        foreach { vmin vmax } $_limits($_curFldName) break
2456        $c itemconfigure vmin -text [format %g $vmin]
2457        $c itemconfigure vmax -text [format %g $vmax]
2458    }
2459    set y 2
2460    # If there's a legend title, move the title to the correct position
2461    if { $title != "" } {
2462        $c itemconfigure title -text $title
2463        $c coords title $x $y
2464        incr y $lineht
2465    }
2466    $c coords vmax $x $y
2467    incr y $lineht
2468    $c coords colormap $x $y
2469    $c coords sensor [expr $x - $iw] $y $x [expr $y + $ih]
2470    $c raise sensor
2471    $c coords vmin $x [expr {$h - 2}]
2472}
2473
2474#
2475# EnterLegend --
2476#
2477itcl::body Rappture::VtkHeightmapViewer::EnterLegend { x y } {
2478    SetLegendTip $x $y
2479}
2480
2481#
2482# MotionLegend --
2483#
2484itcl::body Rappture::VtkHeightmapViewer::MotionLegend { x y } {
2485    Rappture::Tooltip::tooltip cancel
2486    set c $itk_component(view)
2487    set cw [winfo width $c]
2488    set ch [winfo height $c]
2489    if { $x >= 0 && $x < $cw && $y >= 0 && $y < $ch } {
2490        SetLegendTip $x $y
2491    }
2492}
2493
2494#
2495# LeaveLegend --
2496#
2497itcl::body Rappture::VtkHeightmapViewer::LeaveLegend { } {
2498    Rappture::Tooltip::tooltip cancel
2499    .rappturetooltip configure -icon ""
2500}
2501
2502#
2503# SetLegendTip --
2504#
2505itcl::body Rappture::VtkHeightmapViewer::SetLegendTip { x y } {
2506    set fname $_curFldName
2507    set c $itk_component(view)
2508    set w [winfo width $c]
2509    set h [winfo height $c]
2510    set font "Arial 8"
2511    set lineht [font metrics $font -linespace]
2512   
2513    set ih [image height $_image(legend)]
2514    # Subtract off the offset of the color ramp from the top of the canvas
2515    set iy [expr $y - ($lineht + 2)]
2516
2517    if { [string match "component*" $fname] } {
2518        set title ""
2519    } else {
2520        if { [info exists _fields($fname)] } {
2521            foreach { title units } $_fields($fname) break
2522            if { $units != "" } {
2523                set title [format "%s (%s)" $title $units]
2524            }
2525        } else {
2526            set title $fname
2527        }
2528    }
2529    # If there's a legend title, increase the offset by the line height.
2530    if { $title != "" } {
2531        incr iy -$lineht
2532    }
2533
2534    # Make a swatch of the selected color
2535    if { [catch { $_image(legend) get 10 $iy } pixel] != 0 } {
2536        return
2537    }
2538
2539    if { ![info exists _image(swatch)] } {
2540        set _image(swatch) [image create photo -width 24 -height 24]
2541    }
2542    set color [eval format "\#%02x%02x%02x" $pixel]
2543    $_image(swatch) put black  -to 0 0 23 23
2544    $_image(swatch) put $color -to 1 1 22 22
2545
2546    # Compute the value of the point
2547    if { [info exists _limits($fname)] } {
2548        foreach { vmin vmax } $_limits($fname) break
2549        set t [expr 1.0 - (double($iy) / double($ih-1))]
2550        set value [expr $t * ($vmax - $vmin) + $vmin]
2551    } else {
2552        set value 0.0
2553    }
2554    set tipx [expr $x + 15]
2555    set tipy [expr $y - 5]
2556    .rappturetooltip configure -icon $_image(swatch)
2557    if { [info exists _isolines($y)] } {
2558        Rappture::Tooltip::text $c [format "$title %g (isoline)" $_isolines($y)]
2559    } else {
2560        Rappture::Tooltip::text $c [format "$title %g" $value]
2561    }
2562    Rappture::Tooltip::tooltip show $c +$tipx,+$tipy   
2563}
2564
2565# ----------------------------------------------------------------------
2566# USAGE: _dropdown post
2567# USAGE: _dropdown unpost
2568# USAGE: _dropdown select
2569#
2570# Used internally to handle the dropdown list for this combobox.  The
2571# post/unpost options are invoked when the list is posted or unposted
2572# to manage the relief of the controlling button.  The select option
2573# is invoked whenever there is a selection from the list, to assign
2574# the value back to the gauge.
2575# ----------------------------------------------------------------------
2576itcl::body Rappture::VtkHeightmapViewer::Combo {option} {
2577    set c $itk_component(view)
2578    switch -- $option {
2579        post {
2580            foreach { x1 y1 x2 y2 } [$c bbox title] break
2581            set x1 [expr [winfo width $itk_component(view)] - [winfo reqwidth $itk_component(fieldmenu)]]
2582            set x [expr $x1 + [winfo rootx $itk_component(view)]]
2583            set y [expr $y2 + [winfo rooty $itk_component(view)]]
2584            tk_popup $itk_component(fieldmenu) $x $y
2585        }
2586        activate {
2587            $c itemconfigure title -fill red
2588        }
2589        deactivate {
2590            $c itemconfigure title -fill $itk_option(-plotforeground)
2591        }
2592        invoke {
2593            $itk_component(field) value $_curFldLabel
2594            AdjustSetting -field
2595        }
2596        default {
2597            error "bad option \"$option\": should be post, unpost, select"
2598        }
2599    }
2600}
2601
2602itcl::body Rappture::VtkHeightmapViewer::GetHeightmapScale {} {
2603    if {  $_settings(-isheightmap) } {
2604        set val $_settings(-heightmapscale)
2605        set sval [expr { $val >= 50 ? double($val)/50.0 : 1.0/(2.0-(double($val)/50.0)) }]
2606        return $sval
2607    }
2608    return 0
2609}
2610
2611itcl::body Rappture::VtkHeightmapViewer::SetOrientation { side } {
2612    array set positions {
2613        front  "0.707107 0.707107 0 0"
2614        back   "0 0 0.707107 0.707107"
2615        left   "0.5 0.5 -0.5 -0.5"
2616        right  "0.5 0.5 0.5 0.5"
2617        top    "1 0 0 0"
2618        bottom "0 1 0 0"
2619    }
2620    foreach name { qw qx qy qz } value $positions($side) {
2621        set _view($name) $value
2622    }
2623    set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
2624    $_arcball quaternion $q
2625    SendCmd "camera orient $q"
2626    SendCmd "camera reset"
2627    set _view(xpan) 0
2628    set _view(ypan) 0
2629    set _view(zoom) 1.0
2630}
2631
2632itcl::body Rappture::VtkHeightmapViewer::UpdateContourList {} {
2633    if {$_currentNumIsolines == 0} {
2634        set _contourList ""
2635        return
2636    }
2637    if { ![info exists _limits($_curFldName)] } {
2638        return
2639    }
2640    foreach { vmin vmax } $_limits($_curFldName) break
2641    set v [blt::vector create \#auto]
2642    $v seq $vmin $vmax [expr $_currentNumIsolines+2]
2643    $v delete end 0
2644    set _contourList [$v range 0 end]
2645    blt::vector destroy $v
2646}
Note: See TracBrowser for help on using the repository browser.