source: tags/1.3.5/gui/scripts/vtkheightmapviewer.tcl @ 4753

Last change on this file since 4753 was 4753, checked in by ldelgass, 7 years ago

merge r4749 from trunk

File size: 87.9 KB
Line 
1# -*- mode: tcl; indent-tabs-mode: nil -*-
2# ----------------------------------------------------------------------
3#  COMPONENT: vtkheightmapviewer - Vtk heightmap viewer
4#
5#  It connects to the Vtk server running on a rendering farm,
6#  transmits data, and displays the results.
7# ======================================================================
8#  AUTHOR:  Michael McLennan, Purdue University
9#  Copyright (c) 2004-2012  HUBzero Foundation, LLC
10#
11#  See the file "license.terms" for information on usage and
12#  redistribution of this file, and for a DISCLAIMER OF ALL WARRANTIES.
13# ======================================================================
14package require Itk
15package require BLT
16#package require Img
17
18option add *VtkHeightmapViewer.width 4i widgetDefault
19option add *VtkHeightmapViewer*cursor crosshair widgetDefault
20option add *VtkHeightmapViewer.height 4i widgetDefault
21option add *VtkHeightmapViewer.foreground black widgetDefault
22option add *VtkHeightmapViewer.controlBackground gray widgetDefault
23option add *VtkHeightmapViewer.controlDarkBackground #999999 widgetDefault
24option add *VtkHeightmapViewer.plotBackground black widgetDefault
25option add *VtkHeightmapViewer.plotForeground white widgetDefault
26option add *VtkHeightmapViewer.font \
27    -*-helvetica-medium-r-normal-*-12-* widgetDefault
28
29# must use this name -- plugs into Rappture::resources::load
30proc VtkHeightmapViewer_init_resources {} {
31    Rappture::resources::register \
32        vtkvis_server Rappture::VtkHeightmapViewer::SetServerList
33}
34
35itcl::class Rappture::VtkHeightmapViewer {
36    inherit Rappture::VisViewer
37
38    itk_option define -plotforeground plotForeground Foreground ""
39    itk_option define -plotbackground plotBackground Background ""
40    itk_option define -mode mode Mode "contour"
41
42    constructor { hostlist args } {
43        Rappture::VisViewer::constructor $hostlist
44    } {
45        # defined below
46    }
47    destructor {
48        # defined below
49    }
50    public proc SetServerList { namelist } {
51        Rappture::VisViewer::SetServerList "vtkvis" $namelist
52    }
53    public method add {dataobj {settings ""}}
54    public method camera {option args}
55    public method delete {args}
56    public method disconnect {}
57    public method download {option args}
58    public method get {args}
59    public method isconnected {}
60    public method limits3 { dataobj }
61    public method parameters {title args} {
62        # do nothing
63    }
64    public method scale {args}
65
66    protected method CameraReset {}
67    protected method Connect {}
68    protected method CurrentDatasets {args}
69    protected method Disconnect {}
70    protected method DoResize {}
71    protected method DoRotate {}
72    protected method AdjustSetting {what {value ""}}
73    protected method AdjustMode {}
74    protected method InitSettings { args  }
75    protected method Pan {option x y}
76    protected method Pick {x y}
77    protected method Rebuild {}
78    protected method ReceiveDataset { args }
79    protected method ReceiveImage { args }
80    protected method ReceiveLegend { colormap title min max size }
81    protected method Rotate {option x y}
82    protected method Zoom {option}
83
84    # The following methods are only used by this class.
85    private method BuildAxisTab {}
86    private method BuildCameraTab {}
87    private method BuildColormap { name }
88    private method BuildContourTab {}
89    private method BuildDownloadPopup { widget command }
90    private method Combo { option }
91    private method DrawLegend {}
92    private method EnterLegend { x y }
93    private method EventuallyRequestLegend {}
94    private method EventuallyResize { w h }
95    private method EventuallyRotate { q }
96    private method GetImage { args }
97    private method GetVtkData { args }
98    private method IsValidObject { dataobj }
99    private method LeaveLegend {}
100    private method MotionLegend { x y }
101    private method PanCamera {}
102    private method RequestLegend {}
103    private method SetCurrentColormap { color }
104    private method SetLegendTip { x y }
105    private method SetObjectStyle { dataobj comp }
106    private method GetHeightmapScale {}
107    private method ResetAxes {}
108    private method SetOrientation { side }
109    private method UpdateContourList {}
110
111    private variable _arcball ""
112    private variable _dlist ""     ;    # list of data objects
113    private variable _obj2datasets
114    private variable _obj2ovride   ;    # maps dataobj => style override
115    private variable _comp2scale;       # maps dataset to the heightmap scale.
116    private variable _datasets     ;    # contains all the dataobj-component
117                                   ;    # datasets in the server
118    private variable _colormaps    ;    # contains all the colormaps
119                                   ;    # in the server.
120
121    # The name of the current colormap used.  The colormap is global to all
122    # heightmaps displayed.
123    private variable _currentColormap ""
124    private variable _currentNumIsolines -1
125    private variable _currentOpacity ""
126
127    private variable _maxScale 100;     # This is the # of times the x-axis
128                                        # and y-axis ranges can differ before
129                                        # automatically turning on
130                                        # -stretchtofit
131
132    private variable _click        ;    # info used for rotate operations
133    private variable _limits       ;    # Holds overall limits for all dataobjs
134                                        # using the viewer.
135    private variable _view         ;    # view params for 3D view
136    private variable _settings
137    private variable _changed
138    private variable _initialStyle "";  # First found style in dataobjects.
139    private variable _reset 1;          # Indicates if camera needs to be reset
140                                        # to starting position.
141    private variable _beforeConnect 1;  # Indicates if camera needs to be reset
142                                        # to starting position.
143
144    private variable _first ""     ;    # This is the topmost dataset.
145    private variable _start 0
146    private variable _isolines
147    private variable _contourList ""
148
149    common _downloadPopup;              # download options from popup
150    private common _hardcopy
151    private variable _width 0
152    private variable _height 0
153    private variable _legendWidth 0
154    private variable _legendHeight 0
155    private variable _resizePending 0
156    private variable _rotatePending 0
157    private variable _legendPending 0
158    private variable _fieldNames {}
159    private variable _fields
160    private variable _curFldName ""
161    private variable _curFldLabel ""
162    private variable _colorMode "scalar";#  Mode of colormap (vmag or scalar)
163}
164
165itk::usual VtkHeightmapViewer {
166    keep -background -foreground -cursor -font
167    keep -plotbackground -plotforeground -mode
168}
169
170# ----------------------------------------------------------------------
171# CONSTRUCTOR
172# ----------------------------------------------------------------------
173itcl::body Rappture::VtkHeightmapViewer::constructor {hostlist args} {
174    set _serverType "vtkvis"
175
176    EnableWaitDialog 900
177    # Rebuild event
178    $_dispatcher register !rebuild
179    $_dispatcher dispatch $this !rebuild "[itcl::code $this Rebuild]; list"
180
181    # Resize event
182    $_dispatcher register !resize
183    $_dispatcher dispatch $this !resize "[itcl::code $this DoResize]; list"
184
185    # Rotate event
186    $_dispatcher register !rotate
187    $_dispatcher dispatch $this !rotate "[itcl::code $this DoRotate]; list"
188
189    # Legend event
190    $_dispatcher register !legend
191    $_dispatcher dispatch $this !legend "[itcl::code $this RequestLegend]; list"
192
193    #
194    # Populate parser with commands handle incoming requests
195    #
196    $_parser alias image [itcl::code $this ReceiveImage]
197    $_parser alias dataset [itcl::code $this ReceiveDataset]
198    $_parser alias legend [itcl::code $this ReceiveLegend]
199
200    # Create image for legend colorbar.
201    set _image(legend) [image create photo]
202
203    # Initialize the view to some default parameters.
204    array set _view {
205        qw      0.36
206        qx      0.25
207        qy      0.50
208        qz      0.70
209        zoom    1.0
210        xpan    0
211        ypan    0
212        ortho   0
213    }
214    set _arcball [blt::arcball create 100 100]
215    set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
216    $_arcball quaternion $q
217
218    array set _settings {
219        axisFlymode             "static"
220        axisMinorTicks          1
221        stretchToFit            0
222        axisLabels              1
223        axisVisible             1
224        axisXGrid               0
225        axisYGrid               0
226        axisZGrid               0
227        colormapVisible         1
228        colormapDiscrete        0
229        edges                   0
230        field                   "Default"
231        heightmapScale          50
232        isHeightmap             0
233        isolineColor            black
234        isolinesVisible         1
235        legendVisible           1
236        lighting                1
237        saveLighting            1
238        numIsolines             10
239        opacity                 100
240        outline                 0
241        wireframe               0
242        saveOpacity             100
243        saveOutline             0
244    }
245    array set _changed {
246        opacity                 0
247        colormap                0
248        numIsolines             0
249    }
250    itk_component add view {
251        canvas $itk_component(plotarea).view \
252            -highlightthickness 0 -borderwidth 0
253    } {
254        usual
255        ignore -highlightthickness -borderwidth -background
256    }
257
258    itk_component add fieldmenu {
259        menu $itk_component(plotarea).menu \
260            -relief flat \
261            -tearoff no
262    } {
263        usual
264        ignore -background -foreground -relief -tearoff
265    }
266    set c $itk_component(view)
267    bind $c <Configure> [itcl::code $this EventuallyResize %w %h]
268    bind $c <4> [itcl::code $this Zoom in 0.25]
269    bind $c <5> [itcl::code $this Zoom out 0.25]
270    bind $c <KeyPress-Left>  [list %W xview scroll 10 units]
271    bind $c <KeyPress-Right> [list %W xview scroll -10 units]
272    bind $c <KeyPress-Up>    [list %W yview scroll 10 units]
273    bind $c <KeyPress-Down>  [list %W yview scroll -10 units]
274    bind $c <Enter> "focus %W"
275    bind $c <Control-F1> [itcl::code $this ToggleConsole]
276
277    # Fix the scrollregion in case we go off screen
278    $c configure -scrollregion [$c bbox all]
279
280    set _map(id) [$c create image 0 0 -anchor nw -image $_image(plot)]
281    set _map(cwidth) -1
282    set _map(cheight) -1
283    set _map(zoom) 1.0
284    set _map(original) ""
285
286    set f [$itk_component(main) component controls]
287    itk_component add reset {
288        button $f.reset -borderwidth 1 -padx 1 -pady 1 \
289            -highlightthickness 0 \
290            -image [Rappture::icon reset-view] \
291            -command [itcl::code $this CameraReset]
292    } {
293        usual
294        ignore -highlightthickness
295    }
296    pack $itk_component(reset) -side top -padx 2 -pady { 2 0 }
297    Rappture::Tooltip::for $itk_component(reset) "Reset the view to the default zoom level"
298
299    itk_component add zoomin {
300        button $f.zin -borderwidth 1 -padx 1 -pady 1 \
301            -highlightthickness 0 \
302            -image [Rappture::icon zoom-in] \
303            -command [itcl::code $this Zoom in]
304    } {
305        usual
306        ignore -highlightthickness
307    }
308    pack $itk_component(zoomin) -side top -padx 2 -pady { 2 0 }
309    Rappture::Tooltip::for $itk_component(zoomin) "Zoom in"
310
311    itk_component add zoomout {
312        button $f.zout -borderwidth 1 -padx 1 -pady 1 \
313            -highlightthickness 0 \
314            -image [Rappture::icon zoom-out] \
315            -command [itcl::code $this Zoom out]
316    } {
317        usual
318        ignore -highlightthickness
319    }
320    pack $itk_component(zoomout) -side top -padx 2 -pady { 2 0 }
321    Rappture::Tooltip::for $itk_component(zoomout) "Zoom out"
322
323    itk_component add mode {
324        Rappture::PushButton $f.mode \
325            -onimage [Rappture::icon surface] \
326            -offimage [Rappture::icon surface] \
327            -variable [itcl::scope _settings(isHeightmap)] \
328            -command [itcl::code $this AdjustSetting isHeightmap] \
329    }
330    Rappture::Tooltip::for $itk_component(mode) \
331        "Toggle the surface/contour on/off"
332    pack $itk_component(mode) -padx 2 -pady { 2 0 }
333
334    itk_component add stretchtofit {
335        Rappture::PushButton $f.stretchtofit \
336            -onimage [Rappture::icon stretchtofit] \
337            -offimage [Rappture::icon stretchtofit] \
338            -variable [itcl::scope _settings(stretchToFit)] \
339            -command [itcl::code $this AdjustSetting stretchToFit] \
340    }
341    Rappture::Tooltip::for $itk_component(stretchtofit) \
342        "Stretch plot to fit window on/off"
343    pack $itk_component(stretchtofit) -padx 2 -pady 2
344
345    if { [catch {
346        BuildContourTab
347        BuildAxisTab
348        BuildCameraTab
349    } errs] != 0 } {
350        global errorInfo
351        puts stderr "errs=$errs errorInfo=$errorInfo"
352    }
353
354    # Hack around the Tk panewindow.  The problem is that the requested
355    # size of the 3d view isn't set until an image is retrieved from
356    # the server.  So the panewindow uses the tiny size.
357    set w 10000
358    pack forget $itk_component(view)
359    blt::table $itk_component(plotarea) \
360        0,0 $itk_component(view) -fill both -reqwidth $w
361    blt::table configure $itk_component(plotarea) c1 -resize none
362
363    # Bindings for panning via mouse
364    bind $itk_component(view) <ButtonPress-2> \
365        [itcl::code $this Pan click %x %y]
366    bind $itk_component(view) <B2-Motion> \
367        [itcl::code $this Pan drag %x %y]
368    bind $itk_component(view) <ButtonRelease-2> \
369        [itcl::code $this Pan release %x %y]
370
371    #bind $itk_component(view) <ButtonRelease-3> \
372    #    [itcl::code $this Pick %x %y]
373
374    # Bindings for panning via keyboard
375    bind $itk_component(view) <KeyPress-Left> \
376        [itcl::code $this Pan set -10 0]
377    bind $itk_component(view) <KeyPress-Right> \
378        [itcl::code $this Pan set 10 0]
379    bind $itk_component(view) <KeyPress-Up> \
380        [itcl::code $this Pan set 0 -10]
381    bind $itk_component(view) <KeyPress-Down> \
382        [itcl::code $this Pan set 0 10]
383    bind $itk_component(view) <Shift-KeyPress-Left> \
384        [itcl::code $this Pan set -2 0]
385    bind $itk_component(view) <Shift-KeyPress-Right> \
386        [itcl::code $this Pan set 2 0]
387    bind $itk_component(view) <Shift-KeyPress-Up> \
388        [itcl::code $this Pan set 0 -2]
389    bind $itk_component(view) <Shift-KeyPress-Down> \
390        [itcl::code $this Pan set 0 2]
391
392    # Bindings for zoom via keyboard
393    bind $itk_component(view) <KeyPress-Prior> \
394        [itcl::code $this Zoom out]
395    bind $itk_component(view) <KeyPress-Next> \
396        [itcl::code $this Zoom in]
397
398    bind $itk_component(view) <Enter> "focus $itk_component(view)"
399
400    if {[string equal "x11" [tk windowingsystem]]} {
401        # Bindings for zoom via mouse
402        bind $itk_component(view) <4> [itcl::code $this Zoom out]
403        bind $itk_component(view) <5> [itcl::code $this Zoom in]
404    }
405
406    set _image(download) [image create photo]
407    eval itk_initialize $args
408    Connect
409    set _beforeConnect 0
410}
411
412# ----------------------------------------------------------------------
413# DESTRUCTOR
414# ----------------------------------------------------------------------
415itcl::body Rappture::VtkHeightmapViewer::destructor {} {
416    Disconnect
417    image delete $_image(plot)
418    image delete $_image(download)
419    catch { blt::arcball destroy $_arcball }
420}
421
422itcl::body Rappture::VtkHeightmapViewer::DoResize {} {
423    if { $_width < 2 } {
424        set _width 500
425    }
426    if { $_height < 2 } {
427        set _height 500
428    }
429    set _start [clock clicks -milliseconds]
430    SendCmd "screen size [expr $_width - 20] $_height"
431
432    set font "Arial 8"
433    set lh [font metrics $font -linespace]
434    set h [expr {$_height - 2 * ($lh + 2)}]
435    if { $h != $_legendHeight } {
436        EventuallyRequestLegend
437    } else {
438        DrawLegend
439    }
440    set _resizePending 0
441}
442
443itcl::body Rappture::VtkHeightmapViewer::DoRotate {} {
444    set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
445    SendCmd "camera orient $q"
446    set _rotatePending 0
447}
448
449itcl::body Rappture::VtkHeightmapViewer::EventuallyRequestLegend {} {
450    if { !$_legendPending } {
451        set _legendPending 1
452        $_dispatcher event -idle !legend
453    }
454}
455
456itcl::body Rappture::VtkHeightmapViewer::EventuallyResize { w h } {
457    set _width $w
458    set _height $h
459    $_arcball resize $w $h
460    if { !$_resizePending } {
461        set _resizePending 1
462        $_dispatcher event -after 250 !resize
463    }
464}
465
466set rotate_delay 100
467
468itcl::body Rappture::VtkHeightmapViewer::EventuallyRotate { q } {
469    foreach { _view(qw) _view(qx) _view(qy) _view(qz) } $q break
470    if { !$_rotatePending } {
471        set _rotatePending 1
472        global rotate_delay
473        $_dispatcher event -after $rotate_delay !rotate
474    }
475}
476
477# ----------------------------------------------------------------------
478# USAGE: add <dataobj> ?<settings>?
479#
480# Clients use this to add a data object to the plot.  The optional
481# <settings> are used to configure the plot.  Allowed settings are
482# -color, -brightness, -width, -linestyle, and -raise.
483# ----------------------------------------------------------------------
484itcl::body Rappture::VtkHeightmapViewer::add {dataobj {settings ""}} {
485    if { ![$dataobj isvalid] } {
486        return;                         # Object doesn't contain valid data.
487    }
488    array set params {
489        -color auto
490        -width 1
491        -linestyle solid
492        -brightness 0
493        -raise 0
494        -description ""
495        -param ""
496        -type ""
497    }
498    array set params $settings
499    set params(-description) ""
500    set params(-param) ""
501    array set params $settings
502
503    if {$params(-color) == "auto" || $params(-color) == "autoreset"} {
504        # can't handle -autocolors yet
505        set params(-color) white
506    }
507    set pos [lsearch -exact $_dlist $dataobj]
508    if {$pos < 0} {
509        lappend _dlist $dataobj
510    }
511    set _obj2ovride($dataobj-color) $params(-color)
512    set _obj2ovride($dataobj-width) $params(-width)
513    set _obj2ovride($dataobj-raise) $params(-raise)
514    $_dispatcher event -idle !rebuild
515}
516
517
518# ----------------------------------------------------------------------
519# USAGE: delete ?<dataobj1> <dataobj2> ...?
520#
521#       Clients use this to delete a dataobj from the plot.  If no dataobjs
522#       are specified, then all dataobjs are deleted.  No data objects are
523#       deleted.  They are only removed from the display list.
524#
525# ----------------------------------------------------------------------
526itcl::body Rappture::VtkHeightmapViewer::delete {args} {
527    if { [llength $args] == 0} {
528        set args $_dlist
529    }
530    # Delete all specified dataobjs
531    set changed 0
532    foreach dataobj $args {
533        set pos [lsearch -exact $_dlist $dataobj]
534        if { $pos < 0 } {
535            continue;                   # Don't know anything about it.
536        }
537        # Remove it from the dataobj list.
538        set _dlist [lreplace $_dlist $pos $pos]
539        array unset _obj2ovride $dataobj-*
540        array unset _settings $dataobj-*
541        set changed 1
542    }
543    # If anything changed, then rebuild the plot
544    if { $changed } {
545        $_dispatcher event -idle !rebuild
546    }
547}
548
549# ----------------------------------------------------------------------
550# USAGE: get ?-objects?
551# USAGE: get ?-visible?
552# USAGE: get ?-image view?
553#
554# Clients use this to query the list of objects being plotted, in
555# order from bottom to top of this result.  The optional "-image"
556# flag can also request the internal images being shown.
557# ----------------------------------------------------------------------
558itcl::body Rappture::VtkHeightmapViewer::get {args} {
559    if {[llength $args] == 0} {
560        set args "-objects"
561    }
562    set op [lindex $args 0]
563    switch -- $op {
564        "-objects" {
565            # put the dataobj list in order according to -raise options
566            set dlist {}
567            foreach dataobj $_dlist {
568                if { ![IsValidObject $dataobj] } {
569                    continue
570                }
571                if {[info exists _obj2ovride($dataobj-raise)] &&
572                    $_obj2ovride($dataobj-raise)} {
573                    set dlist [linsert $dlist 0 $dataobj]
574                } else {
575                    lappend dlist $dataobj
576                }
577            }
578            return $dlist
579        }
580        "-visible" {
581            set dlist {}
582            foreach dataobj $_dlist {
583                if { ![IsValidObject $dataobj] } {
584                    continue
585                }
586                if { ![info exists _obj2ovride($dataobj-raise)] } {
587                    # No setting indicates that the object isn't visible.
588                    continue
589                }
590                # Otherwise use the -raise parameter to put the object to
591                # the front of the list.
592                if { $_obj2ovride($dataobj-raise) } {
593                    set dlist [linsert $dlist 0 $dataobj]
594                } else {
595                    lappend dlist $dataobj
596                }
597            }
598            return $dlist
599        }           
600        -image {
601            if {[llength $args] != 2} {
602                error "wrong # args: should be \"get -image view\""
603            }
604            switch -- [lindex $args end] {
605                view {
606                    return $_image(plot)
607                }
608                default {
609                    error "bad image name \"[lindex $args end]\": should be view"
610                }
611            }
612        }
613        default {
614            error "bad option \"$op\": should be -objects or -image"
615        }
616    }
617}
618
619#
620# scale  --
621#
622#       This gets called either incrementally as new simulations are
623#       added or all at once as a sequence of heightmaps.
624#       This  accounts for all objects--even those not showing on the
625#       screen.  Because of this, the limits are appropriate for all
626#       objects as the user scans through data in the ResultSet viewer.
627#
628itcl::body Rappture::VtkHeightmapViewer::scale {args} {
629    foreach dataobj $args {
630        if { ![$dataobj isvalid] } {
631            continue;                   # Object doesn't contain valid data.
632        }
633        foreach axis { x y } {
634            set lim [$dataobj limits $axis]
635            if { ![info exists _limits($axis)] } {
636                set _limits($axis) $lim
637                continue
638            }
639            foreach {min max} $lim break
640            foreach {amin amax} $_limits($axis) break
641            if { $amin > $min } {
642                set amin $min
643            }
644            if { $amax < $max } {
645                set amax $max
646            }
647            set _limits($axis) [list $amin $amax]
648            set units [$dataobj hints ${axis}units]
649            set found($units) 1
650        }
651        foreach { fname lim } [$dataobj fieldlimits] {
652            if { ![info exists _limits($fname)] } {
653                set _limits($fname) $lim
654                continue
655            }
656            foreach {min max} $lim break
657            foreach {fmin fmax} $_limits($fname) break
658            if { $fmin > $min } {
659                set fmin $min
660            }
661            if { $fmax < $max } {
662                set fmax $max
663            }
664            set _limits($fname) [list $fmin $fmax]
665        }
666    }
667    if { [array size found] > 1 } {
668        set _settings(stretchToFit) 1
669    } else {
670        # Check if the range of the x and y axes requires that we stretch
671        # the contour to fit the plotting area.  This can happen when the
672        # x and y scales differ greatly (> 100x)
673        foreach {xmin xmax} $_limits(x) break
674        foreach {ymin ymax} $_limits(y) break
675        if { (($xmax - $xmin) > (($ymax -$ymin) * $_maxScale)) ||
676             ((($xmax - $xmin) * $_maxScale) < ($ymax -$ymin)) } {
677            set _settings(stretchToFit) 1
678        }
679    }
680}
681
682# ----------------------------------------------------------------------
683# USAGE: download coming
684# USAGE: download controls <downloadCommand>
685# USAGE: download now
686#
687# Clients use this method to create a downloadable representation
688# of the plot.  Returns a list of the form {ext string}, where
689# "ext" is the file extension (indicating the type of data) and
690# "string" is the data itself.
691# ----------------------------------------------------------------------
692itcl::body Rappture::VtkHeightmapViewer::download {option args} {
693    switch $option {
694        coming {
695            if {[catch {
696                blt::winop snap $itk_component(plotarea) $_image(download)
697            }]} {
698                $_image(download) configure -width 1 -height 1
699                $_image(download) put #000000
700            }
701        }
702        controls {
703            set popup .vtkviewerdownload
704            if { ![winfo exists .vtkviewerdownload] } {
705                set inner [BuildDownloadPopup $popup [lindex $args 0]]
706            } else {
707                set inner [$popup component inner]
708            }
709            set _downloadPopup(image_controls) $inner.image_frame
710            set num [llength [get]]
711            set num [expr {($num == 1) ? "1 result" : "$num results"}]
712            set word [Rappture::filexfer::label downloadWord]
713            $inner.summary configure -text "$word $num in the following format:"
714            update idletasks            ;# Fix initial sizes
715            return $popup
716        }
717        now {
718            set popup .vtkviewerdownload
719            if {[winfo exists .vtkviewerdownload]} {
720                $popup deactivate
721            }
722            switch -- $_downloadPopup(format) {
723                "image" {
724                    return [$this GetImage [lindex $args 0]]
725                }
726                "vtk" {
727                    return [$this GetVtkData [lindex $args 0]]
728                }
729            }
730            return ""
731        }
732        default {
733            error "bad option \"$option\": should be coming, controls, now"
734        }
735    }
736}
737
738# ----------------------------------------------------------------------
739# USAGE: Connect ?<host:port>,<host:port>...?
740#
741# Clients use this method to establish a connection to a new
742# server, or to reestablish a connection to the previous server.
743# Any existing connection is automatically closed.
744# ----------------------------------------------------------------------
745itcl::body Rappture::VtkHeightmapViewer::Connect {} {
746    global readyForNextFrame
747    set readyForNextFrame 1
748    set _reset 1
749    set _hosts [GetServerList "vtkvis"]
750    if { "" == $_hosts } {
751        return 0
752    }
753    set result [VisViewer::Connect $_hosts]
754    if { $result } {
755        if { $_reportClientInfo }  {
756            # Tell the server the viewer, hub, user and session.
757            # Do this immediately on connect before buffering any commands
758            global env
759
760            set info {}
761            set user "???"
762            if { [info exists env(USER)] } {
763                set user $env(USER)
764            }
765            set session "???"
766            if { [info exists env(SESSION)] } {
767                set session $env(SESSION)
768            }
769            lappend info "hub" [exec hostname]
770            lappend info "client" "vtkheightmapviewer"
771            lappend info "user" $user
772            lappend info "session" $session
773            SendCmd "clientinfo [list $info]"
774        }
775        set w [winfo width $itk_component(view)]
776        set h [winfo height $itk_component(view)]
777        EventuallyResize $w $h
778    }
779    return $result
780}
781
782#
783# isconnected --
784#
785#       Indicates if we are currently connected to the visualization server.
786#
787itcl::body Rappture::VtkHeightmapViewer::isconnected {} {
788    return [VisViewer::IsConnected]
789}
790
791#
792# disconnect --
793#
794itcl::body Rappture::VtkHeightmapViewer::disconnect {} {
795    Disconnect
796    set _reset 1
797}
798
799#
800# Disconnect --
801#
802#       Clients use this method to disconnect from the current rendering
803#       server.
804#
805itcl::body Rappture::VtkHeightmapViewer::Disconnect {} {
806    VisViewer::Disconnect
807
808    $_dispatcher cancel !rebuild
809    $_dispatcher cancel !resize
810    $_dispatcher cancel !rotate
811    $_dispatcher cancel !legend
812    # disconnected -- no more data sitting on server
813    array unset _datasets
814    array unset _data
815    array unset _colormaps
816    array unset _obj2datasets
817    global readyForNextFrame
818    set readyForNextFrame 1
819}
820
821# ----------------------------------------------------------------------
822# USAGE: ReceiveImage -bytes <size> -type <type> -token <token>
823#
824# Invoked automatically whenever the "image" command comes in from
825# the rendering server.  Indicates that binary image data with the
826# specified <size> will follow.
827# ----------------------------------------------------------------------
828itcl::body Rappture::VtkHeightmapViewer::ReceiveImage { args } {
829    global readyForNextFrame
830    set readyForNextFrame 1
831    array set info {
832        -token "???"
833        -bytes 0
834        -type image
835    }
836    array set info $args
837    set bytes [ReceiveBytes $info(-bytes)]
838    if { $info(-type) == "image" } {
839        if 0 {
840            set f [open "last.ppm" "w"]
841            puts $f $bytes
842            close $f
843        }
844        $_image(plot) configure -data $bytes
845        set time [clock seconds]
846        set date [clock format $time]
847        #puts stderr "$date: received image [image width $_image(plot)]x[image height $_image(plot)] image>"       
848        if { $_start > 0 } {
849            set finish [clock clicks -milliseconds]
850            #puts stderr "round trip time [expr $finish -$_start] milliseconds"
851            set _start 0
852        }
853    } elseif { $info(type) == "print" } {
854        set tag $this-print-$info(-token)
855        set _hardcopy($tag) $bytes
856    }
857}
858
859#
860# ReceiveDataset --
861#
862itcl::body Rappture::VtkHeightmapViewer::ReceiveDataset { args } {
863    if { ![isconnected] } {
864        return
865    }
866    set option [lindex $args 0]
867    switch -- $option {
868        "scalar" {
869            set option [lindex $args 1]
870            switch -- $option {
871                "world" {
872                    foreach { x y z value tag } [lrange $args 2 end] break
873                }
874                "pixel" {
875                    foreach { x y value tag } [lrange $args 2 end] break
876                }
877            }
878        }
879        "vector" {
880            set option [lindex $args 1]
881            switch -- $option {
882                "world" {
883                    foreach { x y z vx vy vz tag } [lrange $args 2 end] break
884                }
885                "pixel" {
886                    foreach { x y vx vy vz tag } [lrange $args 2 end] break
887                }
888            }
889        }
890        "names" {
891            foreach { name } [lindex $args 1] {
892                #puts stderr "Dataset: $name"
893            }
894        }
895        default {
896            error "unknown dataset option \"$option\" from server"
897        }
898    }
899}
900
901# ----------------------------------------------------------------------
902# USAGE: Rebuild
903#
904# Called automatically whenever something changes that affects the
905# data in the widget.  Clears any existing data and rebuilds the
906# widget to display new data.
907# ----------------------------------------------------------------------
908itcl::body Rappture::VtkHeightmapViewer::Rebuild {} {
909    set w [winfo width $itk_component(view)]
910    set h [winfo height $itk_component(view)]
911    if { $w < 2 || $h < 2 } {
912        $_dispatcher event -idle !rebuild
913        return
914    }
915
916    # Turn on buffering of commands to the server.  We don't want to
917    # be preempted by a server disconnect/reconnect (which automatically
918    # generates a new call to Rebuild).   
919    StartBufferingCommands
920
921    if { $_width != $w || $_height != $h || $_reset } {
922        set _width $w
923        set _height $h
924        $_arcball resize $w $h
925        DoResize
926        if { $_settings(stretchToFit) } {
927            AdjustSetting stretchToFit
928        }
929    }
930    if { $_reset } {
931        #
932        # Reset the camera and other view parameters
933        #
934        InitSettings isHeightmap background
935
936        # Let's see how this goes.  I think it's preferable to overloading the
937        # axis title with the exponent.
938        SendCmd "axis exp 0 0 0 1"
939
940        SendCmd "axis lrot z 90"
941        set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
942        $_arcball quaternion $q
943        if {$_settings(isHeightmap) } {
944            if { $_view(ortho)} {
945                SendCmd "camera mode ortho"
946            } else {
947                SendCmd "camera mode persp"
948            }
949            DoRotate
950            SendCmd "camera reset"
951        }
952        PanCamera
953        StopBufferingCommands
954        SendCmd "imgflush"
955        StartBufferingCommands
956    }
957
958    set _first ""
959    # Start off with no datasets are visible.
960    SendCmd "dataset visible 0"
961    set scale [GetHeightmapScale]
962    foreach dataobj [get -objects] {
963        if { [info exists _obj2ovride($dataobj-raise)] &&  $_first == "" } {
964            set _first $dataobj
965        }
966        set _obj2datasets($dataobj) ""
967        foreach comp [$dataobj components] {
968            set tag $dataobj-$comp
969            if { ![info exists _datasets($tag)] } {
970                set bytes [$dataobj vtkdata $comp]
971                if 0 {
972                    set f [open /tmp/vtkheightmap.vtk "w"]
973                    puts $f $bytes
974                    close $f
975                }
976                set length [string length $bytes]
977                if { $_reportClientInfo }  {
978                    set info {}
979                    lappend info "tool_id"       [$dataobj hints toolid]
980                    lappend info "tool_name"     [$dataobj hints toolname]
981                    lappend info "tool_title"    [$dataobj hints tooltitle]
982                    lappend info "tool_command"  [$dataobj hints toolcommand]
983                    lappend info "tool_revision" [$dataobj hints toolrevision]
984                    lappend info "dataset_label" [$dataobj hints label]
985                    lappend info "dataset_size"  $length
986                    lappend info "dataset_tag"   $tag
987                    SendCmd [list "clientinfo" $info]
988                }
989                SendCmd "dataset add $tag data follows $length"
990                append _outbuf $bytes
991                set _datasets($tag) 1
992                SetObjectStyle $dataobj $comp
993            }
994            lappend _obj2datasets($dataobj) $tag
995            if { [info exists _obj2ovride($dataobj-raise)] } {
996                # Setting dataset visible enables outline
997                # and heightmap
998                SendCmd "dataset visible 1 $tag"
999            }
1000            if { ![info exists _comp2scale($tag)] ||
1001                 $_comp2scale($tag) != $scale } {
1002                SendCmd "heightmap heightscale $scale $tag"
1003                set _comp2scale($tag) $scale
1004            }
1005        }
1006    }
1007    if { $_first != ""  } {
1008        $itk_component(field) choices delete 0 end
1009        $itk_component(fieldmenu) delete 0 end
1010        array unset _fields
1011        set _curFldName ""
1012        foreach cname [$_first components] {
1013            foreach fname [$_first fieldnames $cname] {
1014                if { [info exists _fields($fname)] } {
1015                    continue
1016                }
1017                foreach { label units components } \
1018                    [$_first fieldinfo $fname] break
1019                $itk_component(field) choices insert end "$fname" "$label"
1020                $itk_component(fieldmenu) add radiobutton -label "$label" \
1021                    -value $label -variable [itcl::scope _curFldLabel] \
1022                    -selectcolor red \
1023                    -activebackground $itk_option(-plotbackground) \
1024                    -activeforeground $itk_option(-plotforeground) \
1025                    -font "Arial 8" \
1026                    -command [itcl::code $this Combo invoke]
1027                set _fields($fname) [list $label $units $components]
1028                if { $_curFldName == "" } {
1029                    set _curFldName $fname
1030                    set _curFldLabel $label
1031                }
1032            }
1033        }
1034        $itk_component(field) value $_curFldLabel
1035    }
1036    InitSettings stretchToFit outline
1037
1038    if { $_reset } {
1039        SendCmd "axis tickpos outside"
1040        foreach axis { x y z } {
1041            SendCmd "axis lformat $axis %g"
1042        }
1043       
1044        foreach axis { x y z } {
1045            if { $axis == "z" } {
1046                set label [$_first hints label]
1047            } else {
1048                set label [$_first hints ${axis}label]
1049            }
1050            if { $label == "" } {
1051                if {$axis == "z"} {
1052                    if { [string match "component*" $_curFldName] } {
1053                        set label [string toupper $axis]
1054                    } else {
1055                        set label $_curFldLabel
1056                    }
1057                } else {
1058                    set label [string toupper $axis]
1059                }
1060            }
1061            # May be a space in the axis label.
1062            SendCmd [list axis name $axis $label]
1063
1064            if {$axis == "z" && [$_first hints ${axis}units] == ""} {
1065                set units [lindex $_fields($_curFldName) 1]
1066            } else {
1067                set units [$_first hints ${axis}units]
1068            }
1069            if { $units != "" } {
1070                # May be a space in the axis units.
1071                SendCmd [list axis units $axis $units]
1072            }
1073        }
1074        #
1075        # Reset the camera and other view parameters
1076        #
1077        ResetAxes
1078        set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
1079        $_arcball quaternion $q
1080        if {$_settings(isHeightmap) } {
1081            if { $_view(ortho)} {
1082                SendCmd "camera mode ortho"
1083            } else {
1084                SendCmd "camera mode persp"
1085            }
1086            DoRotate
1087            SendCmd "camera reset"
1088        }
1089        PanCamera
1090        InitSettings axisXGrid axisYGrid axisZGrid \
1091            axisVisible axisLabels heightmapScale field isHeightmap \
1092            numIsolines
1093        if { [array size _fields] < 2 } {
1094            blt::table forget $itk_component(field) $itk_component(field_l)
1095        }
1096        RequestLegend
1097        set _reset 0
1098    }
1099    global readyForNextFrame
1100    set readyForNextFrame 0;            # Don't advance to the next frame
1101
1102    # Actually write the commands to the server socket.  If it fails, we don't
1103    # care.  We're finished here.
1104    blt::busy hold $itk_component(hull)
1105    StopBufferingCommands
1106    blt::busy release $itk_component(hull)
1107}
1108
1109# ----------------------------------------------------------------------
1110# USAGE: CurrentDatasets ?-all -visible? ?dataobjs?
1111#
1112# Returns a list of server IDs for the current datasets being displayed.  This
1113# is normally a single ID, but it might be a list of IDs if the current data
1114# object has multiple components.
1115# ----------------------------------------------------------------------
1116itcl::body Rappture::VtkHeightmapViewer::CurrentDatasets {args} {
1117    set flag [lindex $args 0]
1118    switch -- $flag {
1119        "-all" {
1120            if { [llength $args] > 1 } {
1121                error "CurrentDatasets: can't specify dataobj after \"-all\""
1122            }
1123            set dlist [get -objects]
1124        }
1125        "-visible" {
1126            if { [llength $args] > 1 } {
1127                set dlist {}
1128                set args [lrange $args 1 end]
1129                foreach dataobj $args {
1130                    if { [info exists _obj2ovride($dataobj-raise)] } {
1131                        lappend dlist $dataobj
1132                    }
1133                }
1134            } else {
1135                set dlist [get -visible]
1136            }
1137        }           
1138        default {
1139            set dlist $args
1140        }
1141    }
1142    set rlist ""
1143    foreach dataobj $dlist {
1144        foreach comp [$dataobj components] {
1145            set tag $dataobj-$comp
1146            if { [info exists _datasets($tag)] && $_datasets($tag) } {
1147                lappend rlist $tag
1148            }
1149        }
1150    }
1151    return $rlist
1152}
1153
1154itcl::body Rappture::VtkHeightmapViewer::CameraReset {} {
1155    array set _view {
1156        qw      0.36
1157        qx      0.25
1158        qy      0.50
1159        qz      0.70
1160        zoom    1.0
1161        xpan    0
1162        ypan    0
1163    }
1164    if { $_first != "" } {
1165        set location [$_first hints camera]
1166        if { $location != "" } {
1167            array set _view $location
1168        }
1169    }
1170    set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
1171    $_arcball quaternion $q
1172    if {$_settings(isHeightmap) } {
1173        DoRotate
1174    }
1175    SendCmd "camera reset"
1176}
1177
1178# ----------------------------------------------------------------------
1179# USAGE: Zoom in
1180# USAGE: Zoom out
1181# USAGE: Zoom reset
1182#
1183# Called automatically when the user clicks on one of the zoom
1184# controls for this widget.  Changes the zoom for the current view.
1185# ----------------------------------------------------------------------
1186itcl::body Rappture::VtkHeightmapViewer::Zoom {option} {
1187    switch -- $option {
1188        "in" {
1189            set _view(zoom) [expr {$_view(zoom)*1.25}]
1190            SendCmd "camera zoom $_view(zoom)"
1191        }
1192        "out" {
1193            set _view(zoom) [expr {$_view(zoom)*0.8}]
1194            SendCmd "camera zoom $_view(zoom)"
1195        }
1196        "reset" {
1197            array set _view {
1198                zoom    1.0
1199                xpan    0
1200                ypan    0
1201            }
1202            SendCmd "camera reset"
1203        }
1204    }
1205}
1206
1207itcl::body Rappture::VtkHeightmapViewer::PanCamera {} {
1208    set x $_view(xpan)
1209    set y $_view(ypan)
1210    SendCmd "camera pan $x $y"
1211}
1212
1213
1214# ----------------------------------------------------------------------
1215# USAGE: Rotate click <x> <y>
1216# USAGE: Rotate drag <x> <y>
1217# USAGE: Rotate release <x> <y>
1218#
1219# Called automatically when the user clicks/drags/releases in the
1220# plot area.  Moves the plot according to the user's actions.
1221# ----------------------------------------------------------------------
1222itcl::body Rappture::VtkHeightmapViewer::Rotate {option x y} {
1223    switch -- $option {
1224        "click" {
1225            $itk_component(view) configure -cursor fleur
1226            set _click(x) $x
1227            set _click(y) $y
1228        }
1229        "drag" {
1230            if {[array size _click] == 0} {
1231                Rotate click $x $y
1232            } else {
1233                set w [winfo width $itk_component(view)]
1234                set h [winfo height $itk_component(view)]
1235                if {$w <= 0 || $h <= 0} {
1236                    return
1237                }
1238
1239                if {[catch {
1240                    # this fails sometimes for no apparent reason
1241                    set dx [expr {double($x-$_click(x))/$w}]
1242                    set dy [expr {double($y-$_click(y))/$h}]
1243                }]} {
1244                    return
1245                }
1246                if { $dx == 0 && $dy == 0 } {
1247                    return
1248                }
1249                set q [$_arcball rotate $x $y $_click(x) $_click(y)]
1250                EventuallyRotate $q
1251                set _click(x) $x
1252                set _click(y) $y
1253            }
1254        }
1255        "release" {
1256            Rotate drag $x $y
1257            $itk_component(view) configure -cursor ""
1258            catch {unset _click}
1259        }
1260        default {
1261            error "bad option \"$option\": should be click, drag, release"
1262        }
1263    }
1264}
1265
1266itcl::body Rappture::VtkHeightmapViewer::Pick {x y} {
1267    foreach tag [CurrentDatasets -visible] {
1268        SendCmd "dataset getscalar pixel $x $y $tag"
1269    }
1270}
1271
1272# ----------------------------------------------------------------------
1273# USAGE: $this Pan click x y
1274#        $this Pan drag x y
1275#        $this Pan release x y
1276#
1277# Called automatically when the user clicks on one of the zoom
1278# controls for this widget.  Changes the zoom for the current view.
1279# ----------------------------------------------------------------------
1280itcl::body Rappture::VtkHeightmapViewer::Pan {option x y} {
1281    switch -- $option {
1282        "set" {
1283            set w [winfo width $itk_component(view)]
1284            set h [winfo height $itk_component(view)]
1285            set x [expr $x / double($w)]
1286            set y [expr $y / double($h)]
1287            set _view(xpan) [expr $_view(xpan) + $x]
1288            set _view(ypan) [expr $_view(ypan) + $y]
1289            PanCamera
1290            return
1291        }
1292        "click" {
1293            set _click(x) $x
1294            set _click(y) $y
1295            $itk_component(view) configure -cursor hand1
1296        }
1297        "drag" {
1298            if { ![info exists _click(x)] } {
1299                set _click(x) $x
1300            }
1301            if { ![info exists _click(y)] } {
1302                set _click(y) $y
1303            }
1304            set w [winfo width $itk_component(view)]
1305            set h [winfo height $itk_component(view)]
1306            set dx [expr ($_click(x) - $x)/double($w)]
1307            set dy [expr ($_click(y) - $y)/double($h)]
1308            set _click(x) $x
1309            set _click(y) $y
1310            set _view(xpan) [expr $_view(xpan) - $dx]
1311            set _view(ypan) [expr $_view(ypan) - $dy]
1312            PanCamera
1313        }
1314        "release" {
1315            Pan drag $x $y
1316            $itk_component(view) configure -cursor ""
1317        }
1318        default {
1319            error "unknown option \"$option\": should set, click, drag, or release"
1320        }
1321    }
1322}
1323
1324# ----------------------------------------------------------------------
1325# USAGE: InitSettings <what> ?<value>?
1326#
1327# Used internally to update rendering settings whenever parameters
1328# change in the popup settings panel.  Sends the new settings off
1329# to the back end.
1330# ----------------------------------------------------------------------
1331itcl::body Rappture::VtkHeightmapViewer::InitSettings { args } {
1332    foreach spec $args {
1333        if { [info exists _settings($_first-$spec)] } {
1334            # Reset global setting with dataobj specific setting
1335            set _settings($spec) $_settings($_first-$spec)
1336        }
1337        AdjustSetting $spec
1338    }
1339}
1340
1341#
1342# AdjustSetting --
1343#
1344#       Changes/updates a specific setting in the widget.  There are
1345#       usually user-setable option.  Commands are sent to the render
1346#       server.
1347#
1348itcl::body Rappture::VtkHeightmapViewer::AdjustSetting {what {value ""}} {
1349    if { $_beforeConnect } {
1350        return
1351    }
1352    switch -- $what {
1353        "axisFlymode" {
1354            set mode [$itk_component(axisflymode) value]
1355            set mode [$itk_component(axisflymode) translate $mode]
1356            set _settings($what) $mode
1357            SendCmd "axis flymode $mode"
1358        }
1359        "axisLabels" {
1360            set bool $_settings(axisLabels)
1361            SendCmd "axis labels all $bool"
1362        }
1363        "axisMinorTicks" {
1364            set bool $_settings(axisMinorTicks)
1365            foreach axis { x y z } {
1366                SendCmd "axis minticks ${axis} $bool"
1367            }
1368        }
1369        "axisVisible" {
1370            set bool $_settings(axisVisible)
1371            SendCmd "axis visible all $bool"
1372        }
1373        "axisXGrid" - "axisYGrid" - "axisZGrid" {
1374            set axis [string tolower [string range $what 4 4]]
1375            set bool $_settings($what)
1376            SendCmd "axis grid $axis $bool"
1377        }
1378        "background" {
1379            set bg [$itk_component(background) value]
1380            array set fgcolors {
1381                "black" "white"
1382                "white" "black"
1383                "grey"  "black"
1384            }
1385            set fg $fgcolors($bg)
1386            configure -plotbackground $bg -plotforeground $fg
1387            $itk_component(view) delete "legend"
1388            SendCmd "screen bgcolor [Color2RGB $bg]"
1389            SendCmd "outline color [Color2RGB $fg]"
1390            SendCmd "axis color all [Color2RGB $fg]"
1391            DrawLegend
1392        }
1393        "colormap" {
1394            set _changed(colormap) 1
1395            StartBufferingCommands
1396            set color [$itk_component(colormap) value]
1397            set _settings(colormap) $color
1398            if { $color == "none" } {
1399                if { $_settings(colormapVisible) } {
1400                    SendCmd "heightmap surface 0"
1401                    set _settings(colormapVisible) 0
1402                }
1403            } else {
1404                if { !$_settings(colormapVisible) } {
1405                    SendCmd "heightmap surface 1"
1406                    set _settings(colormapVisible) 1
1407                }
1408                SetCurrentColormap $color
1409                if {$_settings(colormapDiscrete)} {
1410                    set numColors [expr $_settings(numIsolines) + 1]
1411                    SendCmd "colormap res $numColors $color"
1412                }
1413            }
1414            StopBufferingCommands
1415            EventuallyRequestLegend
1416        }
1417        "colormapVisible" {
1418            set bool $_settings($what)
1419            SendCmd "heightmap surface $bool"
1420        }
1421        "colormapDiscrete" {
1422            set bool $_settings($what)
1423            set numColors [expr $_settings(numIsolines) + 1]
1424            StartBufferingCommands
1425            if {$bool} {
1426                SendCmd "colormap res $numColors"
1427                # Discrete colormap requires preinterp on
1428                SendCmd "heightmap preinterp on"
1429            } else {
1430                SendCmd "colormap res default"
1431                # FIXME: add setting for preinterp (default on)
1432                SendCmd "heightmap preinterp on"
1433            }
1434            StopBufferingCommands
1435            EventuallyRequestLegend
1436        }
1437        "edges" {
1438            set bool $_settings(edges)
1439            SendCmd "heightmap edges $bool"
1440        }
1441        "field" {
1442            set label [$itk_component(field) value]
1443            set fname [$itk_component(field) translate $label]
1444            set _settings(field) $fname
1445            if { [info exists _fields($fname)] } {
1446                foreach { label units components } $_fields($fname) break
1447                if { $components > 1 } {
1448                    set _colorMode vmag
1449                } else {
1450                    set _colorMode scalar
1451                }
1452                set _curFldName $fname
1453                set _curFldLabel $label
1454            } else {
1455                puts stderr "unknown field \"$fname\""
1456                return
1457            }
1458            set label [$_first hints label]
1459            if { $label == "" } {
1460                if { [string match "component*" $_curFldName] } {
1461                    set label Z
1462                } else {
1463                    set label $_curFldLabel
1464                }
1465            }
1466            # May be a space in the axis label.
1467            SendCmd [list axis name z $label]
1468
1469            if { [$_first hints zunits] == "" } {
1470                set units [lindex $_fields($_curFldName) 1]
1471            } else {
1472                set units [$_first hints zunits]
1473            }
1474            if { $units != "" } {
1475                # May be a space in the axis units.
1476                SendCmd [list axis units z $units]
1477            }
1478            # Get the new limits because the field changed.
1479            ResetAxes
1480            SendCmd "dataset scalar $_curFldName"
1481            SendCmd "heightmap colormode scalar $_curFldName"
1482            Zoom reset
1483            UpdateContourList
1484            DrawLegend
1485        }
1486        "heightmapScale" {
1487            if { $_settings(isHeightmap) } {
1488                set scale [GetHeightmapScale]
1489                # Have to set the datasets individually because we are
1490                # tracking them in _comp2scale.
1491                foreach dataset [CurrentDatasets -all] {
1492                    SendCmd "heightmap heightscale $scale $dataset"
1493                    set _comp2scale($dataset) $scale
1494                }
1495                ResetAxes
1496            }
1497        }
1498        "isHeightmap" {
1499            set bool $_settings(isHeightmap)
1500            set c $itk_component(view)
1501            StartBufferingCommands
1502            # Fix heightmap scale: 0 for contours, 1 for heightmaps.
1503            if { $bool } {
1504                set _settings(heightmapScale) 50
1505                set _settings(opacity) $_settings(saveOpacity)
1506                set _settings(lighting) $_settings(saveLighting)
1507                set _settings(outline) 0
1508            } else {
1509                set _settings(heightmapScale) 0
1510                set _settings(lighting) 0
1511                set _settings(opacity) 100
1512                set _settings(outline)  $_settings(saveOutline)
1513            }
1514            AdjustSetting lighting
1515            AdjustSetting opacity
1516            AdjustSetting outline
1517            set scale [GetHeightmapScale]
1518            # Have to set the datasets individually because we are
1519            # tracking them in _comp2scale.
1520            foreach dataset [CurrentDatasets -all] {
1521                SendCmd "heightmap heightscale $scale $dataset"
1522                set _comp2scale($dataset) $scale
1523            }
1524            if { $bool } {
1525                $itk_component(lighting) configure -state normal
1526                $itk_component(opacity) configure -state normal
1527                $itk_component(scale) configure -state normal
1528                $itk_component(opacity_l) configure -state normal
1529                $itk_component(scale_l) configure -state normal
1530                $itk_component(outline) configure -state disabled
1531                if {$_view(ortho)} {
1532                    SendCmd "camera mode ortho"
1533                } else {
1534                    SendCmd "camera mode persp"
1535                }
1536            } else {
1537                $itk_component(lighting) configure -state disabled
1538                $itk_component(opacity) configure -state disabled
1539                $itk_component(scale) configure -state disabled
1540                $itk_component(opacity_l) configure -state disabled
1541                $itk_component(scale_l) configure -state disabled
1542                $itk_component(outline) configure -state normal
1543                SendCmd "camera mode image"
1544            }
1545            if {$_settings(stretchToFit)} {
1546                if {$scale == 0} {
1547                    SendCmd "camera aspect window"
1548                } else {
1549                    SendCmd "camera aspect square"
1550                }
1551            }
1552            ResetAxes
1553            if { $bool } {
1554                set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
1555                $_arcball quaternion $q
1556                SendCmd "camera orient $q"
1557            } else {
1558                bind $c <ButtonPress-1> {}
1559                bind $c <B1-Motion> {}
1560                bind $c <ButtonRelease-1> {}
1561            }
1562            Zoom reset
1563            # Fix the mouse bindings for rotation/panning and the
1564            # camera mode. Ideally we'd create a bindtag for these.
1565            if { $bool } {
1566                # Bindings for rotation via mouse
1567                bind $c <ButtonPress-1> \
1568                    [itcl::code $this Rotate click %x %y]
1569                bind $c <B1-Motion> \
1570                    [itcl::code $this Rotate drag %x %y]
1571                bind $c <ButtonRelease-1> \
1572                    [itcl::code $this Rotate release %x %y]
1573            }
1574            StopBufferingCommands
1575        }
1576        "isolineColor" {
1577            set color [$itk_component(isolinecolor) value]
1578            if { $color == "none" } {
1579                if { $_settings(isolinesVisible) } {
1580                    SendCmd "heightmap isolines 0"
1581                    set _settings(isolinesVisible) 0
1582                }
1583            } else {
1584                if { !$_settings(isolinesVisible) } {
1585                    SendCmd "heightmap isolines 1"
1586                    set _settings(isolinesVisible) 1
1587                }
1588                SendCmd "heightmap isolinecolor [Color2RGB $color]"
1589            }
1590            DrawLegend
1591        }
1592        "isolinesVisible" {
1593            set bool $_settings($what)
1594            SendCmd "heightmap isolines $bool"
1595            DrawLegend
1596        }
1597        "legendVisible" {
1598            if { !$_settings($what) } {
1599                $itk_component(view) delete legend
1600            }
1601            DrawLegend
1602        }
1603        "lighting" {
1604            if { $_settings(isHeightmap) } {
1605                set _settings(saveLighting) $_settings(lighting)
1606                set bool $_settings($what)
1607                SendCmd "heightmap lighting $bool"
1608            } else {
1609                SendCmd "heightmap lighting 0"
1610            }
1611        }
1612        "numIsolines" {
1613            set _settings(numIsolines) [$itk_component(numisolines) value]
1614            set _currentNumIsolines $_settings(numIsolines)
1615            UpdateContourList
1616            set _changed(numIsolines) 1
1617            SendCmd "heightmap contourlist [list $_contourList]"
1618            if {$_settings(colormapDiscrete)} {
1619                set numColors [expr $_settings(numIsolines) + 1]
1620                SendCmd "colormap res $numColors"
1621                EventuallyRequestLegend
1622            } else {
1623                DrawLegend
1624            }
1625        }
1626        "opacity" {
1627            set _changed(opacity) 1
1628            if { $_settings(isHeightmap) } {
1629                set _settings(saveOpacity) $_settings(opacity)
1630                set val $_settings(opacity)
1631                set sval [expr { 0.01 * double($val) }]
1632                SendCmd "heightmap opacity $sval"
1633            } else {
1634                SendCmd "heightmap opacity 1"
1635            }
1636        }
1637        "outline" {
1638            if { $_settings(isHeightmap) } {
1639                SendCmd "outline visible 0"
1640            } else {
1641                set _settings(saveOutline) $_settings(outline)
1642                set bool $_settings(outline)
1643                SendCmd "outline visible $bool"
1644            }
1645        }
1646        "stretchToFit" {
1647            set bool $_settings($what)
1648            if { $bool } {
1649                set heightScale [GetHeightmapScale]
1650                if {$heightScale == 0} {
1651                    SendCmd "camera aspect window"
1652                } else {
1653                    SendCmd "camera aspect square"
1654                }
1655            } else {
1656                SendCmd "camera aspect native"
1657            }
1658            Zoom reset
1659        }
1660        "wireframe" {
1661            set bool $_settings($what)
1662            SendCmd "heightmap wireframe $bool"
1663        }
1664        default {
1665            error "don't know how to fix $what"
1666        }
1667    }
1668}
1669
1670#
1671# RequestLegend --
1672#
1673#       Request a new legend from the server.  The size of the legend
1674#       is determined from the height of the canvas. 
1675#
1676# This should be called when
1677#       1.  A new current colormap is set.
1678#       2.  Window is resized.
1679#       3.  The limits of the data have changed.  (Just need a redraw).
1680#       4.  Number of isolines have changed. (Just need a redraw).
1681#       5.  Legend becomes visible (Just need a redraw).
1682#
1683itcl::body Rappture::VtkHeightmapViewer::RequestLegend {} {
1684    set _legendPending 0
1685    set font "Arial 8"
1686    set w 12
1687    set lineht [font metrics $font -linespace]
1688    # color ramp height = (canvas height) - (min and max value lines) - 2
1689    set h [expr {$_height - 2 * ($lineht + 2)}]
1690    set _legendHeight $h
1691
1692    set fname $_curFldName
1693    if { [string match "component*" $fname] } {
1694        set title ""
1695    } else {
1696        if { [info exists _fields($fname)] } {
1697            foreach { title units } $_fields($fname) break
1698            if { $units != "" } {
1699                set title [format "%s (%s)" $title $units]
1700            }
1701        } else {
1702            set title $fname
1703        }
1704    }
1705    # If there's a title too, substract one more line
1706    if { $title != "" } {
1707        incr h -$lineht
1708    }
1709    if { $h < 1 } {
1710        return
1711    }
1712    # Set the legend on the first heightmap dataset.
1713    if { $_currentColormap != ""  } {
1714        set cmap $_currentColormap
1715        SendCmd "legend $cmap scalar $_curFldName {} $w $h 0"
1716    }
1717}
1718
1719#
1720# ResetAxes --
1721#
1722#       Set axis z bounds and range
1723#
1724itcl::body Rappture::VtkHeightmapViewer::ResetAxes {} {
1725    if { ![info exists _limits($_curFldName)]} {
1726        SendCmd "dataset maprange all"
1727        SendCmd "axis autorange z on"
1728        SendCmd "axis autobounds z on"
1729        return
1730    }
1731    foreach { xmin xmax } $_limits(x) break
1732    foreach { ymin ymax } $_limits(y) break
1733    foreach { vmin vmax } $_limits($_curFldName) break
1734
1735    global tcl_precision
1736    set tcl_precision 17
1737    set xr [expr $xmax - $xmin]
1738    set yr [expr $ymax - $ymin]
1739    set vr [expr $vmax - $vmin]
1740    set r  [expr ($yr > $xr) ? $yr : $xr]
1741    if { $vr < 1.0e-17 } {
1742        set dataScale 1.0
1743    } else {
1744        set dataScale [expr $r / $vr]
1745    }
1746    set heightScale [GetHeightmapScale]
1747    set bmin [expr $heightScale * $dataScale * $vmin]
1748    set bmax [expr $heightScale * $dataScale * $vmax]
1749    if {$heightScale > 0} {
1750        set zpos [expr - $bmin]
1751        SendCmd "heightmap pos 0 0 $zpos"
1752    } else {
1753        SendCmd "heightmap pos 0 0 0"
1754    }
1755    set bmax [expr $bmax - $bmin]
1756    set bmin 0
1757    SendCmd "dataset maprange explicit $_limits($_curFldName) $_curFldName"
1758    SendCmd "axis bounds z $bmin $bmax"
1759    SendCmd "axis range z $_limits($_curFldName)"
1760}
1761
1762#
1763# SetCurrentColormap --
1764#
1765itcl::body Rappture::VtkHeightmapViewer::SetCurrentColormap { name } {
1766    # Keep track of the colormaps that we build.
1767    if { $name != "none" && ![info exists _colormaps($name)] } {
1768        BuildColormap $name
1769        set _colormaps($name) 1
1770    }
1771    set _currentColormap $name
1772    SendCmd "heightmap colormap $_currentColormap"
1773}
1774
1775
1776#
1777# BuildColormap --
1778#
1779#       Build the designated colormap on the server.
1780#
1781itcl::body Rappture::VtkHeightmapViewer::BuildColormap { name } {
1782    set cmap [ColorsToColormap $name]
1783    if { [llength $cmap] == 0 } {
1784        set cmap "0.0 0.0 0.0 0.0 1.0 1.0 1.0 1.0"
1785    }
1786    set wmap "0.0 1.0 1.0 1.0"
1787    SendCmd "colormap add $name { $cmap } { $wmap }"
1788}
1789
1790# ----------------------------------------------------------------------
1791# CONFIGURATION OPTION: -mode
1792# ----------------------------------------------------------------------
1793itcl::configbody Rappture::VtkHeightmapViewer::mode {
1794    switch -- $itk_option(-mode) {
1795        "heightmap" {
1796            set _settings(isHeightmap) 1
1797        }
1798        "contour" {
1799            set _settings(isHeightmap) 0
1800        }
1801        default {
1802            error "unknown mode settings \"$itk_option(-mode)\""
1803        }
1804    }
1805    if { !$_reset } {
1806        AdjustSetting isHeightmap
1807    }
1808}
1809
1810# ----------------------------------------------------------------------
1811# CONFIGURATION OPTION: -plotbackground
1812# ----------------------------------------------------------------------
1813itcl::configbody Rappture::VtkHeightmapViewer::plotbackground {
1814    if { [isconnected] } {
1815        set rgb [Color2RGB $itk_option(-plotbackground)]
1816        if { !$_reset } {
1817            SendCmd "screen bgcolor $rgb"
1818        }
1819        $itk_component(view) configure -background $itk_option(-plotbackground)
1820    }
1821}
1822
1823# ----------------------------------------------------------------------
1824# CONFIGURATION OPTION: -plotforeground
1825# ----------------------------------------------------------------------
1826itcl::configbody Rappture::VtkHeightmapViewer::plotforeground {
1827    if { [isconnected] } {
1828        set rgb [Color2RGB $itk_option(-plotforeground)]
1829        if { !$_reset } {
1830            SendCmd "outline color $rgb"
1831            SendCmd "axis color all $rgb"
1832        }
1833    }
1834}
1835
1836itcl::body Rappture::VtkHeightmapViewer::limits3 { dataobj } {
1837    lappend limits x [$dataobj limits x]
1838    lappend limits y [$dataobj limits y]
1839    if { [catch { $dataobj limits $_curFldName } vlim] != 0 } {
1840        set vlim [$dataobj limits v]
1841    }
1842    lappend limits v $vlim
1843    return $limits
1844}
1845
1846itcl::body Rappture::VtkHeightmapViewer::BuildContourTab {} {
1847
1848    set fg [option get $itk_component(hull) font Font]
1849    #set bfg [option get $itk_component(hull) boldFont Font]
1850
1851    set inner [$itk_component(main) insert end \
1852        -title "Contour/Surface Settings" \
1853        -icon [Rappture::icon contour2]]
1854    $inner configure -borderwidth 4
1855
1856    checkbutton $inner.legend \
1857        -text "Legend" \
1858        -variable [itcl::scope _settings(legendVisible)] \
1859        -command [itcl::code $this AdjustSetting legendVisible] \
1860        -font "Arial 9"
1861
1862    checkbutton $inner.wireframe \
1863        -text "Wireframe" \
1864        -variable [itcl::scope _settings(wireframe)] \
1865        -command [itcl::code $this AdjustSetting wireframe] \
1866        -font "Arial 9"
1867
1868    itk_component add lighting {
1869        checkbutton $inner.lighting \
1870            -text "Enable Lighting" \
1871            -variable [itcl::scope _settings(lighting)] \
1872            -command [itcl::code $this AdjustSetting lighting] \
1873            -font "Arial 9"
1874    } {
1875        ignore -font
1876    }
1877    checkbutton $inner.edges \
1878        -text "Edges" \
1879        -variable [itcl::scope _settings(edges)] \
1880        -command [itcl::code $this AdjustSetting edges] \
1881        -font "Arial 9"
1882
1883    itk_component add outline {
1884        checkbutton $inner.outline \
1885            -text "Outline" \
1886            -variable [itcl::scope _settings(outline)] \
1887            -command [itcl::code $this AdjustSetting outline] \
1888            -font "Arial 9"
1889    } {
1890        ignore -font
1891    }
1892    checkbutton $inner.stretch \
1893        -text "Stretch to fit" \
1894        -variable [itcl::scope _settings(stretchToFit)] \
1895        -command [itcl::code $this AdjustSetting stretchToFit] \
1896        -font "Arial 9"
1897
1898    checkbutton $inner.isolines \
1899        -text "Isolines" \
1900        -variable [itcl::scope _settings(isolinesVisible)] \
1901        -command [itcl::code $this AdjustSetting isolinesVisible] \
1902        -font "Arial 9"
1903
1904    checkbutton $inner.colormapDiscrete \
1905        -text "Discrete Colormap" \
1906        -variable [itcl::scope _settings(colormapDiscrete)] \
1907        -command [itcl::code $this AdjustSetting colormapDiscrete] \
1908        -font "Arial 9"
1909
1910    itk_component add field_l {
1911        label $inner.field_l -text "Field" -font "Arial 9"
1912    } {
1913        ignore -font
1914    }
1915    itk_component add field {
1916        Rappture::Combobox $inner.field -width 10 -editable no
1917    }
1918    bind $inner.field <<Value>> \
1919        [itcl::code $this AdjustSetting field]
1920
1921    label $inner.colormap_l -text "Colormap" -font "Arial 9"
1922    itk_component add colormap {
1923        Rappture::Combobox $inner.colormap -width 10 -editable no
1924    }
1925    $inner.colormap choices insert end \
1926        "BCGYR"              "BCGYR"            \
1927        "BGYOR"              "BGYOR"            \
1928        "blue"               "blue"             \
1929        "blue-to-brown"      "blue-to-brown"    \
1930        "blue-to-orange"     "blue-to-orange"   \
1931        "blue-to-grey"       "blue-to-grey"     \
1932        "green-to-magenta"   "green-to-magenta" \
1933        "greyscale"          "greyscale"        \
1934        "nanohub"            "nanohub"          \
1935        "rainbow"            "rainbow"          \
1936        "spectral"           "spectral"         \
1937        "ROYGB"              "ROYGB"            \
1938        "RYGCB"              "RYGCB"            \
1939        "brown-to-blue"      "brown-to-blue"    \
1940        "grey-to-blue"       "grey-to-blue"     \
1941        "orange-to-blue"     "orange-to-blue"   \
1942        "none"               "none"
1943
1944    $itk_component(colormap) value "BCGYR"
1945    bind $inner.colormap <<Value>> \
1946        [itcl::code $this AdjustSetting colormap]
1947
1948    label $inner.isolinecolor_l -text "Isolines Color" -font "Arial 9"
1949    itk_component add isolinecolor {
1950        Rappture::Combobox $inner.isolinecolor -width 10 -editable no
1951    }
1952    $inner.isolinecolor choices insert end \
1953        "black"              "black"            \
1954        "blue"               "blue"             \
1955        "cyan"               "cyan"             \
1956        "green"              "green"            \
1957        "grey"               "grey"             \
1958        "magenta"            "magenta"          \
1959        "orange"             "orange"           \
1960        "red"                "red"              \
1961        "white"              "white"            \
1962        "none"               "none"
1963
1964    $itk_component(isolinecolor) value "black"
1965    bind $inner.isolinecolor <<Value>> \
1966        [itcl::code $this AdjustSetting isolineColor]
1967
1968    label $inner.background_l -text "Background Color" -font "Arial 9"
1969    itk_component add background {
1970        Rappture::Combobox $inner.background -width 10 -editable no
1971    }
1972    $inner.background choices insert end \
1973        "black"              "black"            \
1974        "white"              "white"            \
1975        "grey"               "grey"             
1976
1977    $itk_component(background) value "white"
1978    bind $inner.background <<Value>> [itcl::code $this AdjustSetting background]
1979
1980    itk_component add opacity_l {
1981        label $inner.opacity_l -text "Opacity" -font "Arial 9"
1982    } {
1983        ignore -font
1984    }
1985    itk_component add opacity {
1986        ::scale $inner.opacity -from 0 -to 100 -orient horizontal \
1987            -variable [itcl::scope _settings(opacity)] \
1988            -showvalue off \
1989            -command [itcl::code $this AdjustSetting opacity]
1990    }
1991    itk_component add scale_l {
1992        label $inner.scale_l -text "Scale" -font "Arial 9"
1993    } {
1994        ignore -font
1995    }
1996    itk_component add scale {
1997        ::scale $inner.scale -from 0 -to 100 -orient horizontal \
1998            -variable [itcl::scope _settings(heightmapScale)] \
1999            -showvalue off \
2000            -command [itcl::code $this AdjustSetting heightmapScale]
2001    }
2002    label $inner.numisolines_l -text "Number of Isolines" -font "Arial 9"
2003    itk_component add numisolines {
2004        Rappture::Spinint $inner.numisolines \
2005            -min 0 -max 50 -font "arial 9"
2006    }
2007    $itk_component(numisolines) value $_settings(numIsolines)
2008    bind $itk_component(numisolines) <<Value>> \
2009        [itcl::code $this AdjustSetting numIsolines]
2010
2011    frame $inner.separator1 -height 2 -relief sunken -bd 1
2012    frame $inner.separator2 -height 2 -relief sunken -bd 1
2013
2014    blt::table $inner \
2015        0,0 $inner.field_l -anchor w -pady 2 \
2016        0,1 $inner.field -anchor w -pady 2 -fill x \
2017        1,0 $inner.colormap_l -anchor w -pady 2  \
2018        1,1 $inner.colormap   -anchor w -pady 2 -fill x  \
2019        2,0 $inner.isolinecolor_l  -anchor w -pady 2  \
2020        2,1 $inner.isolinecolor    -anchor w -pady 2 -fill x  \
2021        3,0 $inner.background_l -anchor w -pady 2 \
2022        3,1 $inner.background -anchor w -pady 2  -fill x \
2023        4,0 $inner.numisolines_l -anchor w -pady 2 \
2024        4,1 $inner.numisolines -anchor w -pady 2 \
2025        5,0 $inner.stretch    -anchor w -pady 2 -cspan 2 \
2026        6,0 $inner.edges      -anchor w -pady 2 -cspan 2 \
2027        7,0 $inner.legend     -anchor w -pady 2 -cspan 2 \
2028        8,0 $inner.colormapDiscrete -anchor w -pady 2 -cspan 2 \
2029        9,0 $inner.wireframe  -anchor w -pady 2 -cspan 2\
2030        10,0 $inner.isolines   -anchor w -pady 2 -cspan 2 \
2031        11,0 $inner.separator1 -padx 2 -fill x -cspan 2 \
2032        12,0 $inner.outline    -anchor w -pady 2 -cspan 2 \
2033        13,0 $inner.separator2 -padx 2 -fill x -cspan 2 \
2034        14,0 $inner.lighting   -anchor w -pady 2 -cspan 2 \
2035        15,0 $inner.opacity_l -anchor w -pady 2 \
2036        15,1 $inner.opacity   -fill x   -pady 2 \
2037        16,0 $inner.scale_l   -anchor w -pady 2 -cspan 2 \
2038        16,1 $inner.scale     -fill x   -pady 2 -cspan 2 \
2039
2040    blt::table configure $inner r* c* -resize none
2041    blt::table configure $inner r17 c1 -resize expand
2042}
2043
2044itcl::body Rappture::VtkHeightmapViewer::BuildAxisTab {} {
2045
2046    set fg [option get $itk_component(hull) font Font]
2047    #set bfg [option get $itk_component(hull) boldFont Font]
2048
2049    set inner [$itk_component(main) insert end \
2050        -title "Axis Settings" \
2051        -icon [Rappture::icon axis2]]
2052    $inner configure -borderwidth 4
2053
2054    checkbutton $inner.visible \
2055        -text "Axes" \
2056        -variable [itcl::scope _settings(axisVisible)] \
2057        -command [itcl::code $this AdjustSetting axisVisible] \
2058        -font "Arial 9"
2059    checkbutton $inner.labels \
2060        -text "Axis Labels" \
2061        -variable [itcl::scope _settings(axisLabels)] \
2062        -command [itcl::code $this AdjustSetting axisLabels] \
2063        -font "Arial 9"
2064    label $inner.grid_l -text "Grid" -font "Arial 9"
2065    checkbutton $inner.xgrid \
2066        -text "X" \
2067        -variable [itcl::scope _settings(axisXGrid)] \
2068        -command [itcl::code $this AdjustSetting axisXGrid] \
2069        -font "Arial 9"
2070    checkbutton $inner.ygrid \
2071        -text "Y" \
2072        -variable [itcl::scope _settings(axisYGrid)] \
2073        -command [itcl::code $this AdjustSetting axisYGrid] \
2074        -font "Arial 9"
2075    checkbutton $inner.zgrid \
2076        -text "Z" \
2077        -variable [itcl::scope _settings(axisZGrid)] \
2078        -command [itcl::code $this AdjustSetting axisZGrid] \
2079        -font "Arial 9"
2080    checkbutton $inner.minorticks \
2081        -text "Minor Ticks" \
2082        -variable [itcl::scope _settings(axisMinorTicks)] \
2083        -command [itcl::code $this AdjustSetting axisMinorTicks] \
2084        -font "Arial 9"
2085
2086
2087    label $inner.mode_l -text "Mode" -font "Arial 9"
2088
2089    itk_component add axisflymode {
2090        Rappture::Combobox $inner.mode -width 10 -editable no
2091    }
2092    $inner.mode choices insert end \
2093        "static_triad"    "static" \
2094        "closest_triad"   "closest" \
2095        "furthest_triad"  "farthest" \
2096        "outer_edges"     "outer"         
2097    $itk_component(axisflymode) value "static"
2098    bind $inner.mode <<Value>> [itcl::code $this AdjustSetting axisFlymode]
2099
2100    blt::table $inner \
2101        0,0 $inner.visible -anchor w -cspan 4 \
2102        1,0 $inner.labels  -anchor w -cspan 4 \
2103        2,0 $inner.minorticks  -anchor w -cspan 4 \
2104        4,0 $inner.grid_l  -anchor w \
2105        4,1 $inner.xgrid   -anchor w \
2106        4,2 $inner.ygrid   -anchor w \
2107        4,3 $inner.zgrid   -anchor w \
2108        5,0 $inner.mode_l  -anchor w -padx { 2 0 } \
2109        5,1 $inner.mode    -fill x -cspan 3
2110
2111    blt::table configure $inner r* c* -resize none
2112    blt::table configure $inner r7 c6 -resize expand
2113    blt::table configure $inner r3 -height 0.125i
2114}
2115
2116
2117itcl::body Rappture::VtkHeightmapViewer::BuildCameraTab {} {
2118    set inner [$itk_component(main) insert end \
2119        -title "Camera Settings" \
2120        -icon [Rappture::icon camera]]
2121    $inner configure -borderwidth 4
2122
2123    label $inner.view_l -text "view" -font "Arial 9"
2124    set f [frame $inner.view]
2125    foreach side { front back left right top bottom } {
2126        button $f.$side  -image [Rappture::icon view$side] \
2127            -command [itcl::code $this SetOrientation $side]
2128        Rappture::Tooltip::for $f.$side "Change the view to $side"
2129        pack $f.$side -side left
2130    }
2131
2132    blt::table $inner \
2133        0,0 $inner.view_l -anchor e -pady 2 \
2134        0,1 $inner.view -anchor w -pady 2
2135
2136    set labels { qx qy qz qw xpan ypan zoom }
2137    set row 1
2138    foreach tag $labels {
2139        label $inner.${tag}label -text $tag -font "Arial 9"
2140        entry $inner.${tag} -font "Arial 9"  -bg white \
2141            -textvariable [itcl::scope _view($tag)]
2142        bind $inner.${tag} <Return> \
2143            [itcl::code $this camera set ${tag}]
2144        bind $inner.${tag} <KP_Enter> \
2145            [itcl::code $this camera set ${tag}]
2146        blt::table $inner \
2147            $row,0 $inner.${tag}label -anchor e -pady 2 \
2148            $row,1 $inner.${tag} -anchor w -pady 2
2149        blt::table configure $inner r$row -resize none
2150        incr row
2151    }
2152    checkbutton $inner.ortho \
2153        -text "Orthographic Projection" \
2154        -variable [itcl::scope _view(ortho)] \
2155        -command [itcl::code $this camera set ortho] \
2156        -font "Arial 9"
2157    blt::table $inner \
2158            $row,0 $inner.ortho -cspan 2 -anchor w -pady 2
2159    blt::table configure $inner r$row -resize none
2160    incr row
2161
2162    blt::table configure $inner c* r* -resize none
2163    blt::table configure $inner c2 -resize expand
2164    blt::table configure $inner r$row -resize expand
2165}
2166
2167#
2168#  camera --
2169#
2170itcl::body Rappture::VtkHeightmapViewer::camera {option args} {
2171    switch -- $option {
2172        "show" {
2173            puts [array get _view]
2174        }
2175        "set" {
2176            set who [lindex $args 0]
2177            set x $_view($who)
2178            set code [catch { string is double $x } result]
2179            if { $code != 0 || !$result } {
2180                return
2181            }
2182            switch -- $who {
2183                "ortho" {
2184                    if {$_view(ortho)} {
2185                        SendCmd "camera mode ortho"
2186                    } else {
2187                        SendCmd "camera mode persp"
2188                    }
2189                }
2190                "xpan" - "ypan" {
2191                    PanCamera
2192                }
2193                "qx" - "qy" - "qz" - "qw" {
2194                    set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
2195                    $_arcball quaternion $q
2196                    EventuallyRotate $q
2197                }
2198                "zoom" {
2199                    SendCmd "camera zoom $_view(zoom)"
2200                }
2201            }
2202        }
2203    }
2204}
2205
2206itcl::body Rappture::VtkHeightmapViewer::GetVtkData { args } {
2207    set bytes ""
2208    foreach dataobj [get] {
2209        foreach comp [$dataobj components] {
2210            set tag $dataobj-$comp
2211            set contents [$dataobj vtkdata $comp]
2212            append bytes "$contents\n"
2213        }
2214    }
2215    return [list .vtk $bytes]
2216}
2217
2218itcl::body Rappture::VtkHeightmapViewer::GetImage { args } {
2219    if { [image width $_image(download)] > 0 &&
2220         [image height $_image(download)] > 0 } {
2221        set bytes [$_image(download) data -format "jpeg -quality 100"]
2222        set bytes [Rappture::encoding::decode -as b64 $bytes]
2223        return [list .jpg $bytes]
2224    }
2225    return ""
2226}
2227
2228itcl::body Rappture::VtkHeightmapViewer::BuildDownloadPopup { popup command } {
2229    Rappture::Balloon $popup \
2230        -title "[Rappture::filexfer::label downloadWord] as..."
2231    set inner [$popup component inner]
2232    label $inner.summary -text "" -anchor w
2233    radiobutton $inner.vtk_button -text "VTK data file" \
2234        -variable [itcl::scope _downloadPopup(format)] \
2235        -font "Arial 9 " \
2236        -value vtk 
2237    Rappture::Tooltip::for $inner.vtk_button "Save as VTK data file."
2238    radiobutton $inner.image_button -text "Image File" \
2239        -variable [itcl::scope _downloadPopup(format)] \
2240        -font "Arial 9 " \
2241        -value image
2242    Rappture::Tooltip::for $inner.image_button \
2243        "Save as digital image."
2244
2245    button $inner.ok -text "Save" \
2246        -highlightthickness 0 -pady 2 -padx 3 \
2247        -command $command \
2248        -compound left \
2249        -image [Rappture::icon download]
2250
2251    button $inner.cancel -text "Cancel" \
2252        -highlightthickness 0 -pady 2 -padx 3 \
2253        -command [list $popup deactivate] \
2254        -compound left \
2255        -image [Rappture::icon cancel]
2256
2257    blt::table $inner \
2258        0,0 $inner.summary -cspan 2  \
2259        1,0 $inner.vtk_button -anchor w -cspan 2 -padx { 4 0 } \
2260        2,0 $inner.image_button -anchor w -cspan 2 -padx { 4 0 } \
2261        4,1 $inner.cancel -width .9i -fill y \
2262        4,0 $inner.ok -padx 2 -width .9i -fill y
2263    blt::table configure $inner r3 -height 4
2264    blt::table configure $inner r4 -pady 4
2265    raise $inner.image_button
2266    $inner.vtk_button invoke
2267    return $inner
2268}
2269
2270#
2271# SetObjectStyle --
2272#
2273#       Set the style of the heightmap/contour object.  This gets calls
2274#       for each dataset once as it is loaded.  It can overridden by
2275#       the user controls.
2276#
2277#
2278itcl::body Rappture::VtkHeightmapViewer::SetObjectStyle { dataobj comp } {
2279    # Parse style string.
2280    set tag $dataobj-$comp
2281    array set style {
2282        -color BCGYR
2283        -opacity 100
2284        -levels 10
2285    }
2286    set stylelist [$dataobj style $comp]
2287    if { $stylelist != "" } {
2288        array set style $stylelist
2289    }
2290    # This is too complicated.  We want to set the colormap, number of
2291    # isolines and opacity for the dataset.  They can be the default values,
2292    # the style hints loaded with the dataset, or set by user controls.  As
2293    # datasets get loaded, they first use the defaults that are overidden
2294    # by the style hints.  If the user changes the global controls, then that
2295    # overrides everything else.  I don't know what it means when global
2296    # controls are specified as style hints by each dataset.  It complicates
2297    # the code to handle aberrant cases.
2298
2299    if { $_changed(opacity) } {
2300        set style(-opacity) $_settings(opacity)
2301    }
2302    if { $_changed(numIsolines) } {
2303        set style(-levels) $_settings(numIsolines)
2304    }
2305    if { $_changed(colormap) } {
2306        set style(-color) $_settings(colormap)
2307    }
2308    if { $_currentColormap == "" } {
2309        $itk_component(colormap) value $style(-color)
2310    }
2311    if { [info exists style(-stretchtofit)] } {
2312        set _settings(stretchToFit) $style(-stretchtofit)
2313        AdjustSetting stretchToFit
2314    }
2315    set _currentOpacity $style(-opacity)
2316    if { $_currentNumIsolines != $style(-levels) } {
2317        set _currentNumIsolines $style(-levels)
2318        set _settings(numIsolines) $_currentNumIsolines
2319        $itk_component(numisolines) value $_currentNumIsolines
2320        UpdateContourList
2321        DrawLegend
2322    }
2323    SendCmd "outline add $tag"
2324    SendCmd "outline color [Color2RGB $itk_option(-plotforeground)] $tag"
2325    SendCmd "outline visible $_settings(outline) $tag"
2326    set scale [GetHeightmapScale]
2327    SendCmd "[list heightmap add contourlist $_contourList $scale $tag]"
2328    set _comp2scale($tag) $_settings(heightmapScale)
2329    SendCmd "heightmap edges $_settings(edges) $tag"
2330    SendCmd "heightmap wireframe $_settings(wireframe) $tag"
2331    SetCurrentColormap $style(-color)
2332    set color [$itk_component(isolinecolor) value]
2333    SendCmd "heightmap isolinecolor [Color2RGB $color] $tag"
2334    SendCmd "heightmap lighting $_settings(isHeightmap) $tag"
2335    SendCmd "heightmap isolines $_settings(isolinesVisible) $tag"
2336    SendCmd "heightmap surface $_settings(colormapVisible) $tag"
2337}
2338
2339itcl::body Rappture::VtkHeightmapViewer::IsValidObject { dataobj } {
2340    if {[catch {$dataobj isa Rappture::Field} valid] != 0 || !$valid} {
2341        return 0
2342    }
2343    return 1
2344}
2345
2346# ----------------------------------------------------------------------
2347# USAGE: ReceiveLegend <colormap> <title> <min> <max> <size>
2348#
2349# Invoked automatically whenever the "legend" command comes in from
2350# the rendering server.  Indicates that binary image data with the
2351# specified <size> will follow.
2352# ----------------------------------------------------------------------
2353itcl::body Rappture::VtkHeightmapViewer::ReceiveLegend { colormap title min max size } {
2354    #puts stderr "ReceiveLegend colormap=$colormap title=$title range=$min,$max size=$size"
2355    if { [isconnected] } {
2356        set bytes [ReceiveBytes $size]
2357        if { ![info exists _image(legend)] } {
2358            set _image(legend) [image create photo]
2359        }
2360        $_image(legend) configure -data $bytes
2361        #puts stderr "read $size bytes for [image width $_image(legend)]x[image height $_image(legend)] legend>"
2362        if { [catch {DrawLegend} errs] != 0 } {
2363            global errorInfo
2364            puts stderr "errs=$errs errorInfo=$errorInfo"
2365        }
2366    }
2367}
2368
2369#
2370# DrawLegend --
2371#
2372#       Draws the legend in the own canvas on the right side of the plot area.
2373#
2374itcl::body Rappture::VtkHeightmapViewer::DrawLegend {} {
2375    set fname $_curFldName
2376    set c $itk_component(view)
2377    set w [winfo width $c]
2378    set h [winfo height $c]
2379    set font "Arial 8"
2380    set lineht [font metrics $font -linespace]
2381   
2382    if { [string match "component*" $fname] } {
2383        set title ""
2384    } else {
2385        if { [info exists _fields($fname)] } {
2386            foreach { title units } $_fields($fname) break
2387            if { $units != "" } {
2388                set title [format "%s (%s)" $title $units]
2389            }
2390        } else {
2391            set title $fname
2392        }
2393    }
2394    set x [expr $w - 2]
2395    if { !$_settings(legendVisible) } {
2396        $c delete legend
2397        return
2398    }
2399    if { [$c find withtag "legend"] == "" } {
2400        set y 2
2401        # If there's a legend title, create a text item for the title.
2402        $c create text $x $y \
2403                -anchor ne \
2404                -fill $itk_option(-plotforeground) -tags "title legend" \
2405                -font $font
2406        $c create text $x $y \
2407            -anchor ne \
2408            -fill $itk_option(-plotforeground) -tags "vmax legend" \
2409            -font $font
2410        incr y $lineht
2411        $c create image $x $y \
2412            -anchor ne \
2413            -image $_image(legend) -tags "colormap legend"
2414        $c create rectangle $x $y 1 1 \
2415            -fill "" -outline "" -tags "sensor legend"
2416        $c create text $x [expr {$h-2}] \
2417            -anchor se \
2418            -fill $itk_option(-plotforeground) -tags "vmin legend" \
2419            -font $font
2420        $c bind sensor <Enter> [itcl::code $this EnterLegend %x %y]
2421        $c bind sensor <Leave> [itcl::code $this LeaveLegend]
2422        $c bind sensor <Motion> [itcl::code $this MotionLegend %x %y]
2423    }
2424    $c delete isoline
2425    set x2 $x
2426    set iw [image width $_image(legend)]
2427    set ih [image height $_image(legend)]
2428    set x1 [expr $x2 - ($iw*12)/10]
2429    set color [$itk_component(isolinecolor) value]
2430
2431    # Draw the isolines on the legend.
2432    array unset _isolines
2433    if { $color != "none"  && [info exists _limits($_curFldName)] &&
2434         $_settings(isolinesVisible) && $_currentNumIsolines > 0 } {
2435
2436        foreach { vmin vmax } $_limits($_curFldName) break
2437        set range [expr double($vmax - $vmin)]
2438        if { $range <= 0.0 } {
2439            set range 1.0;              # Min is greater or equal to max.
2440        }
2441        set tags "isoline legend"
2442        set offset [expr 2 + $lineht]
2443        if { $title != "" } {
2444            incr offset $lineht
2445        }
2446        foreach value $_contourList {
2447            set norm [expr 1.0 - (($value - $vmin) / $range)]
2448            set y1 [expr int(round(($norm * $ih) + $offset))]
2449            for { set off 0 } { $off < 3 } { incr off } {
2450                set _isolines([expr $y1 + $off]) $value
2451                set _isolines([expr $y1 - $off]) $value
2452            }
2453            $c create line $x1 $y1 $x2 $y1 -fill $color -tags $tags
2454        }
2455    }
2456
2457    $c bind title <ButtonPress> [itcl::code $this Combo post]
2458    $c bind title <Enter> [itcl::code $this Combo activate]
2459    $c bind title <Leave> [itcl::code $this Combo deactivate]
2460    # Reset the item coordinates according the current size of the plot.
2461    if { [info exists _limits($_curFldName)] } {
2462        foreach { vmin vmax } $_limits($_curFldName) break
2463        $c itemconfigure vmin -text [format %g $vmin]
2464        $c itemconfigure vmax -text [format %g $vmax]
2465    }
2466    set y 2
2467    # If there's a legend title, move the title to the correct position
2468    if { $title != "" } {
2469        $c itemconfigure title -text $title
2470        $c coords title $x $y
2471        incr y $lineht
2472    }
2473    $c coords vmax $x $y
2474    incr y $lineht
2475    $c coords colormap $x $y
2476    $c coords sensor [expr $x - $iw] $y $x [expr $y + $ih]
2477    $c raise sensor
2478    $c coords vmin $x [expr {$h - 2}]
2479}
2480
2481#
2482# EnterLegend --
2483#
2484itcl::body Rappture::VtkHeightmapViewer::EnterLegend { x y } {
2485    SetLegendTip $x $y
2486}
2487
2488#
2489# MotionLegend --
2490#
2491itcl::body Rappture::VtkHeightmapViewer::MotionLegend { x y } {
2492    Rappture::Tooltip::tooltip cancel
2493    set c $itk_component(view)
2494    set cw [winfo width $c]
2495    set ch [winfo height $c]
2496    if { $x >= 0 && $x < $cw && $y >= 0 && $y < $ch } {
2497        SetLegendTip $x $y
2498    }
2499}
2500
2501#
2502# LeaveLegend --
2503#
2504itcl::body Rappture::VtkHeightmapViewer::LeaveLegend { } {
2505    Rappture::Tooltip::tooltip cancel
2506    .rappturetooltip configure -icon ""
2507}
2508
2509#
2510# SetLegendTip --
2511#
2512itcl::body Rappture::VtkHeightmapViewer::SetLegendTip { x y } {
2513    set fname $_curFldName
2514    set c $itk_component(view)
2515    set w [winfo width $c]
2516    set h [winfo height $c]
2517    set font "Arial 8"
2518    set lineht [font metrics $font -linespace]
2519   
2520    set ih [image height $_image(legend)]
2521    # Subtract off the offset of the color ramp from the top of the canvas
2522    set iy [expr $y - ($lineht + 2)]
2523
2524    if { [string match "component*" $fname] } {
2525        set title ""
2526    } else {
2527        if { [info exists _fields($fname)] } {
2528            foreach { title units } $_fields($fname) break
2529            if { $units != "" } {
2530                set title [format "%s (%s)" $title $units]
2531            }
2532        } else {
2533            set title $fname
2534        }
2535    }
2536    # If there's a legend title, increase the offset by the line height.
2537    if { $title != "" } {
2538        incr iy -$lineht
2539    }
2540
2541    # Make a swatch of the selected color
2542    if { [catch { $_image(legend) get 10 $iy } pixel] != 0 } {
2543        return
2544    }
2545
2546    if { ![info exists _image(swatch)] } {
2547        set _image(swatch) [image create photo -width 24 -height 24]
2548    }
2549    set color [eval format "\#%02x%02x%02x" $pixel]
2550    $_image(swatch) put black  -to 0 0 23 23
2551    $_image(swatch) put $color -to 1 1 22 22
2552
2553    # Compute the value of the point
2554    if { [info exists _limits($fname)] } {
2555        foreach { vmin vmax } $_limits($fname) break
2556        set t [expr 1.0 - (double($iy) / double($ih-1))]
2557        set value [expr $t * ($vmax - $vmin) + $vmin]
2558    } else {
2559        set value 0.0
2560    }
2561    set tipx [expr $x + 15]
2562    set tipy [expr $y - 5]
2563    .rappturetooltip configure -icon $_image(swatch)
2564    if { [info exists _isolines($y)] } {
2565        Rappture::Tooltip::text $c [format "$title %g (isoline)" $_isolines($y)]
2566    } else {
2567        Rappture::Tooltip::text $c [format "$title %g" $value]
2568    }
2569    Rappture::Tooltip::tooltip show $c +$tipx,+$tipy   
2570}
2571
2572# ----------------------------------------------------------------------
2573# USAGE: _dropdown post
2574# USAGE: _dropdown unpost
2575# USAGE: _dropdown select
2576#
2577# Used internally to handle the dropdown list for this combobox.  The
2578# post/unpost options are invoked when the list is posted or unposted
2579# to manage the relief of the controlling button.  The select option
2580# is invoked whenever there is a selection from the list, to assign
2581# the value back to the gauge.
2582# ----------------------------------------------------------------------
2583itcl::body Rappture::VtkHeightmapViewer::Combo {option} {
2584    set c $itk_component(view)
2585    switch -- $option {
2586        post {
2587            foreach { x1 y1 x2 y2 } [$c bbox title] break
2588            set x1 [expr [winfo width $itk_component(view)] - [winfo reqwidth $itk_component(fieldmenu)]]
2589            set x [expr $x1 + [winfo rootx $itk_component(view)]]
2590            set y [expr $y2 + [winfo rooty $itk_component(view)]]
2591            tk_popup $itk_component(fieldmenu) $x $y
2592        }
2593        activate {
2594            $c itemconfigure title -fill red
2595        }
2596        deactivate {
2597            $c itemconfigure title -fill $itk_option(-plotforeground)
2598        }
2599        invoke {
2600            $itk_component(field) value $_curFldLabel
2601            AdjustSetting field
2602        }
2603        default {
2604            error "bad option \"$option\": should be post, unpost, select"
2605        }
2606    }
2607}
2608
2609itcl::body Rappture::VtkHeightmapViewer::GetHeightmapScale {} {
2610    if {  $_settings(isHeightmap) } {
2611        set val $_settings(heightmapScale)
2612        set sval [expr { $val >= 50 ? double($val)/50.0 : 1.0/(2.0-(double($val)/50.0)) }]
2613        return $sval
2614    }
2615    return 0
2616}
2617
2618itcl::body Rappture::VtkHeightmapViewer::SetOrientation { side } {
2619    array set positions {
2620        front  "0.707107 0.707107 0 0"
2621        back   "0 0 0.707107 0.707107"
2622        left   "0.5 0.5 -0.5 -0.5"
2623        right  "0.5 0.5 0.5 0.5"
2624        top    "1 0 0 0"
2625        bottom "0 1 0 0"
2626    }
2627    foreach name { qw qx qy qz } value $positions($side) {
2628        set _view($name) $value
2629    }
2630    set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
2631    $_arcball quaternion $q
2632    SendCmd "camera orient $q"
2633    SendCmd "camera reset"
2634    set _view(xpan) 0
2635    set _view(ypan) 0
2636    set _view(zoom) 1.0
2637}
2638
2639itcl::body Rappture::VtkHeightmapViewer::UpdateContourList {} {
2640    if {$_currentNumIsolines == 0} {
2641        set _contourList ""
2642        return
2643    }
2644    if { ![info exists _limits($_curFldName)] } {
2645        return
2646    }
2647    foreach { vmin vmax } $_limits($_curFldName) break
2648    set v [blt::vector create \#auto]
2649    $v seq $vmin $vmax [expr $_currentNumIsolines+2]
2650    $v delete end 0
2651    set _contourList [$v range 0 end]
2652    blt::vector destroy $v
2653}
Note: See TracBrowser for help on using the repository browser.