source: trunk/gui/configure.in @ 708

#!/bin/bash -norc
dnl     This file is an input file used by the GNU "autoconf" program to
dnl     generate the file "configure", which is run during Tcl installation
dnl     to configure the system for the local environment.
#
# RCS: @(#) $Id: configure.in,v 1.46 2006/01/23 19:18:55 hobbs Exp $

#-----------------------------------------------------------------------
# Sample configure.in for Tcl Extensions.  The only places you should
# need to modify this file are marked by the string __CHANGE__
#-----------------------------------------------------------------------

#-----------------------------------------------------------------------
# __CHANGE__
# Set your package name and version numbers here.
#
# This initializes the environment with PACKAGE_NAME and PACKAGE_VERSION
# set as provided.  These will also be added as -D defs in your Makefile
# so you can encode the package version directly into the source files.
#-----------------------------------------------------------------------

AC_INIT([RapptureGUI], [1.0])

PACKAGE=RapptureGUI

MAJOR_VERSION=1
MINOR_VERSION=0
VERSION=${MAJOR_VERSION}.${MINOR_VERSION}

#--------------------------------------------------------------------
# Call TEA_INIT as the first TEA_ macro to set up initial vars.
# This will define a ${TEA_PLATFORM} variable == "unix" or "windows"
# as well as PKG_LIB_FILE and PKG_STUB_LIB_FILE.
#--------------------------------------------------------------------

TEA_INIT([3.5])

AC_CONFIG_AUX_DIR(tclconfig)

#--------------------------------------------------------------------
# Extra build options
#--------------------------------------------------------------------
AC_ARG_WITH(blt, [  --with-blt=DIR          Find bltInt.h in DIR],
  blt_source_dir=$withval)

#--------------------------------------------------------------------
# Load the tclConfig.sh file
#--------------------------------------------------------------------

TEA_PATH_TCLCONFIG
TEA_LOAD_TCLCONFIG

#--------------------------------------------------------------------
# Load the tkConfig.sh file if necessary (Tk extension)
#--------------------------------------------------------------------

#TEA_PATH_TKCONFIG
#TEA_LOAD_TKCONFIG

#-----------------------------------------------------------------------
# Handle the --prefix=... option by defaulting to what Tcl gave.
# Must be called after TEA_LOAD_TCLCONFIG and before TEA_SETUP_COMPILER.
#-----------------------------------------------------------------------

TEA_PREFIX

#-----------------------------------------------------------------------
# Standard compiler checks.
# This sets up CC by using the CC env var, or looks for gcc otherwise.
# This also calls AC_PROG_CC, AC_PROG_INSTALL and a few others to create
# the basic setup necessary to compile executables.
#-----------------------------------------------------------------------

TEA_SETUP_COMPILER

#-----------------------------------------------------------------------
# __CHANGE__
# Specify the C source files to compile in TEA_ADD_SOURCES,
# public headers that need to be installed in TEA_ADD_HEADERS,
# stub library C source files to compile in TEA_ADD_STUB_SOURCES,
# and runtime Tcl library files in TEA_ADD_TCL_SOURCES.
# This defines PKG(_STUB)_SOURCES, PKG(_STUB)_OBJECTS, PKG_HEADERS
# and PKG_TCL_SOURCES.
#-----------------------------------------------------------------------

TEA_ADD_SOURCES([RpInit.c RpRlimit.c RpRusage.c RpSignal.c RpDaemon.c])
TEA_ADD_HEADERS([])
TEA_ADD_INCLUDES([])
TEA_ADD_CFLAGS([])
TEA_ADD_STUB_SOURCES([])
TEA_ADD_TCL_SOURCES([scripts/analyzer.tcl scripts/animover.tcl])
TEA_ADD_TCL_SOURCES([scripts/balloon.tcl scripts/booleanentry.tcl])
TEA_ADD_TCL_SOURCES([scripts/bugreport.tcl scripts/choiceentry.tcl])
TEA_ADD_TCL_SOURCES([scripts/cloud.tcl scripts/color.tcl])
TEA_ADD_TCL_SOURCES([scripts/combobox.tcl scripts/contourresult.tcl])
TEA_ADD_TCL_SOURCES([scripts/controlOwner.tcl scripts/controls.tcl])
TEA_ADD_TCL_SOURCES([scripts/curve.tcl scripts/deviceEditor.tcl])
TEA_ADD_TCL_SOURCES([scripts/deviceLayout1D.tcl scripts/deviceViewer1D.tcl])
TEA_ADD_TCL_SOURCES([scripts/deviceresult.tcl scripts/dispatcher.tcl])
TEA_ADD_TCL_SOURCES([scripts/dropdown.tcl scripts/dropdownlist.tcl])
TEA_ADD_TCL_SOURCES([scripts/editor.tcl scripts/energyLevels.tcl])
TEA_ADD_TCL_SOURCES([scripts/field.tcl scripts/field3dresult.tcl])
TEA_ADD_TCL_SOURCES([scripts/filexfer.tcl scripts/gauge.tcl])
TEA_ADD_TCL_SOURCES([scripts/getopts.tcl scripts/grab.tcl])
TEA_ADD_TCL_SOURCES([scripts/groupentry.tcl scripts/icons.tcl])
TEA_ADD_TCL_SOURCES([scripts/image.tcl scripts/imageentry.tcl])
TEA_ADD_TCL_SOURCES([scripts/imageresult.tcl])
TEA_ADD_TCL_SOURCES([scripts/integerentry.tcl scripts/loader.tcl])
TEA_ADD_TCL_SOURCES([scripts/mainwin.tcl scripts/mesh.tcl])
TEA_ADD_TCL_SOURCES([scripts/molvisviewer.tcl])
TEA_ADD_TCL_SOURCES([scripts/meshresult.tcl scripts/moleculeViewer.tcl])
TEA_ADD_TCL_SOURCES([scripts/nanovisviewer.tcl scripts/notebook.tcl])
TEA_ADD_TCL_SOURCES([scripts/numberentry.tcl scripts/page.tcl])
TEA_ADD_TCL_SOURCES([scripts/pager.tcl scripts/panes.tcl])
TEA_ADD_TCL_SOURCES([scripts/postern.tcl scripts/progress.tcl])
TEA_ADD_TCL_SOURCES([scripts/radiodial.tcl scripts/resources.tcl])
TEA_ADD_TCL_SOURCES([scripts/resultset.tcl scripts/resultviewer.tcl])
TEA_ADD_TCL_SOURCES([scripts/scroller.tcl scripts/sequence.tcl])
TEA_ADD_TCL_SOURCES([scripts/sequenceresult.tcl scripts/service.tcl])
TEA_ADD_TCL_SOURCES([scripts/spectrum.tcl scripts/spinint.tcl])
TEA_ADD_TCL_SOURCES([scripts/switch.tcl scripts/table.tcl])
TEA_ADD_TCL_SOURCES([scripts/tempgauge.tcl scripts/textentry.tcl])
TEA_ADD_TCL_SOURCES([scripts/textresult.tcl scripts/tool.tcl])
TEA_ADD_TCL_SOURCES([scripts/tooltip.tcl scripts/tuples.tcl])
TEA_ADD_TCL_SOURCES([scripts/units.tcl scripts/valueresult.tcl])
TEA_ADD_TCL_SOURCES([scripts/xyresult.tcl])

#--------------------------------------------------------------------
# __CHANGE__
# A few miscellaneous platform-specific items:
#
# Define a special symbol for Windows (BUILD_Rappture in this case) so
# that we create the export library with the dll.
#
# Windows creates a few extra files that need to be cleaned up.
# You can add more files to clean if your extension creates any extra
# files.
#
# TEA_ADD_* any platform specific compiler/build info here.
#--------------------------------------------------------------------

if test "${TEA_PLATFORM}" = "windows" ; then
    AC_DEFINE(BUILD_Rappture, 1, [Build windows export dll])
    CLEANFILES="*.lib *.dll *.exp *.ilk *.pdb vc*.pch *.manifest"
    TEA_ADD_SOURCES([RpWinResource.c])
    TEA_ADD_LIBS([-LIBPATH:${TCL_EXEC_PREFIX}/lib])
    TEA_ADD_LIBS([BLTlite24.LIB])
    TEA_ADD_LIBS([psapi.lib])
    TEA_ADD_CFLAGS([-D_CRT_SECURE_NO_DEPRECATE -wd4996])
else
    CLEANFILES=""
    TEA_ADD_LIBS([-L${TCL_EXEC_PREFIX}/lib])
    TEA_ADD_LIBS([-lBLTlite24])
fi
AC_SUBST(CLEANFILES)

#--------------------------------------------------------------------
# __CHANGE__
# Choose which headers you need.  Extension authors should try very
# hard to only rely on the Tcl public header files.  Internal headers
# contain private data structures and are subject to change without
# notice.
# This MUST be called after TEA_LOAD_TCLCONFIG / TEA_LOAD_TKCONFIG
#--------------------------------------------------------------------

TEA_PUBLIC_TCL_HEADERS
#TEA_PRIVATE_TCL_HEADERS

TEA_PUBLIC_TK_HEADERS
#TEA_PRIVATE_TK_HEADERS
#TEA_PATH_X

#--------------------------------------------------------------------
# Check whether --enable-threads or --disable-threads was given.
# This auto-enables if Tcl was compiled threaded.
#--------------------------------------------------------------------

TEA_ENABLE_THREADS

#--------------------------------------------------------------------
# The statement below defines a collection of symbols related to
# building as a shared library instead of a static library.
#--------------------------------------------------------------------

TEA_ENABLE_SHARED

#--------------------------------------------------------------------
# This macro figures out what flags to use with the compiler/linker
# when building shared/static debug/optimized objects.  This information
# can be taken from the tclConfig.sh file, but this figures it all out.
#--------------------------------------------------------------------

TEA_CONFIG_CFLAGS

#--------------------------------------------------------------------
# Set the default compiler switches based on the --enable-symbols option.
#--------------------------------------------------------------------

TEA_ENABLE_SYMBOLS

#--------------------------------------------------------------------
# Everyone should be linking against the Tcl stub library.  If you
# can't for some reason, remove this definition.  If you aren't using
# stubs, you also need to modify the SHLIB_LD_LIBS setting below to
# link against the non-stubbed Tcl library.  Add Tk too if necessary.
#--------------------------------------------------------------------

AC_DEFINE(USE_TCL_STUBS, 1, [Use Tcl stubs])
#AC_DEFINE(USE_TK_STUBS, 1, [Use Tk stubs])

#--------------------------------------------------------------------
# This macro generates a line to use when building a library.  It
# depends on values set by the TEA_ENABLE_SHARED, TEA_ENABLE_SYMBOLS,
# and TEA_LOAD_TCLCONFIG macros above.
#--------------------------------------------------------------------

TEA_MAKE_LIB

#--------------------------------------------------------------------
# Determine the name of the tclsh and/or wish executables in the
# Tcl and Tk build directories or the location they were installed
# into. These paths are used to support running test cases only,
# the Makefile should not be making use of these paths to generate
# a pkgIndex.tcl file or anything else at extension build time.
#--------------------------------------------------------------------

TEA_PROG_TCLSH
#TEA_PROG_WISH


#--------------------------------------------------------------------
# Look for bltInt.h on the normal include path.  If not found, look
# for it in the --with-blt directory.
#--------------------------------------------------------------------
AC_MSG_CHECKING([for bltInt.h])
BLT_SRC_DIR=""
if test "x$blt_source_dir" != "x" ; then
  #
  # Verify that a tclConfig.sh file exists in the directory specified
  # by --with-blt.
  #
  if test -r "$blt_source_dir/bltInt.h" ; then
    BLT_SRC_DIR="$blt_source_dir"
  elif test -r "$blt_source_dir/src/bltInt.h" ; then
    BLT_SRC_DIR="$blt_source_dir/src"
  fi
else
  #
  # Otherwise, search for the bltInt.h include file...
  # 1. Search previously named locations.
  #
  for dir in \
   $prefix \
   $exec_prefix
  do
    if test -r "$dir/bltInt.h" ; then
      BLT_SRC_DIR="$dir"
      break
    elif test -r "$dir/include/bltInt.h" ; then
      BLT_SRC_DIR="$dir/include"
      break
    fi
  done
  #
  #  2. Search source directories.
  #
  if test "x$BLT_SRC_DIR" = "x" ; then
    for dir in \
     `ls -dr ../blt[[2-3]].[[0-9]]* 2>/dev/null` \
     ../blt \
     `ls -dr ../../blt[[2-3]].[[0-9]]* 2>/dev/null` \
     ../../blt \
     `ls -dr ../../../blt[[2-3]].[[0-9]]* 2>/dev/null` \
     ../../../blt \
     `ls -dr c:/opt/blt[[2-3]].[[0-9]]* 2>/dev/null` \
     c\:/opt/blt
    do
      if test -r "$dir/src/bltInt.h" ; then
        BLT_SRC_DIR="$dir/src"
        break
      fi
    done
  fi
fi
AC_MSG_RESULT([${BLT_SRC_DIR}])

if test "x$BLT_SRC_DIR" = "x" ; then
  echo "can't find BLT include file \"bltInt.h\""
  echo "use --with-blt=DIR to specify the location of the BLT sources"
  exit 1
fi

AC_SUBST(BLT_SRC_DIR)

PATCHLEVEL=`${TCLSH_PROG} tclconfig/patchlevel.tcl`
EXACT_VERSION=${MAJOR_VERSION}.${MINOR_VERSION}-${PATCHLEVEL}
NODOT_VERSION=${MAJOR_VERSION}${MINOR_VERSION}

AC_SUBST(PACKAGE)
AC_SUBST(VERSION)
AC_SUBST(PATCHLEVEL)
AC_SUBST(EXACT_VERSION)
AC_SUBST(NODOT_VERSION)


#--------------------------------------------------------------------
# Finally, substitute all of the various values into the Makefile.
# You may alternatively have a special pkgIndex.tcl.in or other files
# which require substituting th AC variables in.  Include these here.
#--------------------------------------------------------------------

AC_CONFIG_SUBDIRS( vizservers )
AC_OUTPUT([Makefile pkgIndex.tcl init.tcl])