source: trunk/gui/scripts/gauge.tcl @ 1555

Last change on this file since 1555 was 1483, checked in by gah, 15 years ago

fix newlines when sending data to pymolproxy
File size: 22.3 KB
Line 
1# ----------------------------------------------------------------------
2#  COMPONENT: gauge - compact readout for real values
3#
4#  This widget is a readout for a real value.  It has a little glyph
5#  filled with color according to the value, followed by a numeric
6#  representation of the value itself.  The value can be edited, and
7#  a list of predefined values can be associated with a menu that
8#  drops down from the value.
9# ======================================================================
10#  AUTHOR:  Michael McLennan, Purdue University
11#  Copyright (c) 2004-2005  Purdue Research Foundation
12#
13#  See the file "license.terms" for information on usage and
14#  redistribution of this file, and for a DISCLAIMER OF ALL WARRANTIES.
15# ======================================================================
16package require Itk
17package require BLT
18
19option add *Gauge.sampleWidth 30 widgetDefault
20option add *Gauge.sampleHeight 20 widgetDefault
21option add *Gauge.valuePosition "right" widgetDefault
22option add *Gauge.textBackground #cccccc widgetDefault
23option add *Gauge.editable yes widgetDefault
24
25itcl::class Rappture::Gauge {
26    inherit itk::Widget
27
28    itk_option define -editable editable Editable ""
29    itk_option define -state state State "normal"
30    itk_option define -spectrum spectrum Spectrum ""
31    itk_option define -type type Type "real"
32    itk_option define -units units Units ""
33    itk_option define -minvalue minValue MinValue ""
34    itk_option define -maxvalue maxValue MaxValue ""
35    itk_option define -presets presets Presets ""
36    itk_option define -valueposition valuePosition ValuePosition ""
37    itk_option define -image image Image ""
38    itk_option define -samplewidth sampleWidth SampleWidth 0
39    itk_option define -sampleheight sampleHeight SampleHeight 0
40
41    constructor {args} { # defined below }
42
43    public method value {args}
44    public method edit {option}
45    public method bump {delta}
46
47    protected method _redraw {}
48    protected method _resize {}
49    protected method _hilite {comp state}
50    protected method _editor {option args}
51    protected method _presets {option}
52    protected method _layout {}
53
54    private variable _value 0  ;# value for this widget
55
56    blt::bitmap define GaugeArrow-up {
57        #define up_width 8
58        #define up_height 4
59        static unsigned char up_bits[] = {
60           0x10, 0x38, 0x7c, 0xfe};
61    }
62    blt::bitmap define GaugeArrow-down {
63        #define arrow_width 8
64        #define arrow_height 4
65        static unsigned char arrow_bits[] = {
66           0xfe, 0x7c, 0x38, 0x10};
67    }
68
69    blt::bitmap define GaugeArrow {
70        #define arrow_width 9
71        #define arrow_height 4
72        static unsigned char arrow_bits[] = {
73           0x7f, 0x00, 0x3e, 0x00, 0x1c, 0x00, 0x08, 0x00};
74    }
75}
76                                                                               
77itk::usual Gauge {
78    keep -cursor -font -foreground -background
79    keep -selectbackground -selectforeground -selectborderwidth
80}
81
82# ----------------------------------------------------------------------
83# CONSTRUCTOR
84# ----------------------------------------------------------------------
85itcl::body Rappture::Gauge::constructor {args} {
86    itk_component add icon {
87        canvas $itk_interior.icon -width 1 -height 1 \
88            -borderwidth 0 -highlightthickness 0
89    } {
90        usual
91        ignore -highlightthickness -highlightbackground -highlightcolor
92    }
93    pack $itk_component(icon) -side left
94    bind $itk_component(icon) <Configure> [itcl::code $this _redraw]
95
96    itk_component add -protected vframe {
97        frame $itk_interior.vframe
98    }
99
100    itk_component add value {
101        label $itk_component(vframe).value -borderwidth 1 -width 7 \
102            -textvariable [itcl::scope _value]
103    } {
104        rename -background -textbackground textBackground Background
105    }
106    pack $itk_component(value) -side left -expand yes -fill both
107
108    bind $itk_component(value) <Enter> [itcl::code $this _hilite value on]
109    bind $itk_component(value) <Leave> [itcl::code $this _hilite value off]
110
111    bind $itk_component(value) <<Cut>> [itcl::code $this edit cut]
112    bind $itk_component(value) <<Copy>> [itcl::code $this edit copy]
113    bind $itk_component(value) <<Paste>> [itcl::code $this edit paste]
114
115    itk_component add emenu {
116        menu $itk_component(value).menu -tearoff 0
117    } {
118        usual
119        ignore -tearoff
120    }
121    $itk_component(emenu) add command -label "Cut" -accelerator "^X" \
122        -command [list event generate $itk_component(value) <<Cut>>]
123    $itk_component(emenu) add command -label "Copy" -accelerator "^C" \
124        -command [list event generate $itk_component(value) <<Copy>>]
125    $itk_component(emenu) add command -label "Paste" -accelerator "^V" \
126        -command [list event generate $itk_component(value) <<Paste>>]
127    bind $itk_component(value) <<PopupMenu>> \
128        [itcl::code $this _editor menu %X %Y]
129
130    itk_component add editor {
131        Rappture::Editor $itk_interior.editor \
132            -activatecommand [itcl::code $this _editor activate] \
133            -validatecommand [itcl::code $this _editor validate] \
134            -applycommand [itcl::code $this _editor apply]
135    }
136    bind $itk_component(value) <ButtonPress> \
137        [itcl::code $this _editor popup]
138
139
140    itk_component add spinner {
141        frame $itk_component(vframe).spinner
142    }
143
144    itk_component add spinup {
145        button $itk_component(spinner).up -bitmap GaugeArrow-up \
146            -borderwidth 1 -relief raised -highlightthickness 0 \
147            -command [itcl::code $this bump 1]
148    } {
149        usual
150        ignore -borderwidth -highlightthickness
151    }
152    pack $itk_component(spinup) -side top -expand yes -fill both
153
154    itk_component add spindn {
155        button $itk_component(spinner).down -bitmap GaugeArrow-down \
156            -borderwidth 1 -relief raised -highlightthickness 0 \
157            -command [itcl::code $this bump -1]
158    } {
159        usual
160        ignore -borderwidth -highlightthickness
161    }
162    pack $itk_component(spindn) -side bottom -expand yes -fill both
163
164
165    itk_component add presets {
166        button $itk_component(vframe).psbtn -bitmap GaugeArrow \
167            -borderwidth 1 -highlightthickness 0 -relief flat
168    } {
169        usual
170        ignore -borderwidth -relief -highlightthickness
171        rename -background -textbackground textBackground Background
172    }
173
174    bind $itk_component(presets) <Enter> [itcl::code $this _hilite presets on]
175    bind $itk_component(presets) <Leave> [itcl::code $this _hilite presets off]
176
177    itk_component add presetlist {
178        Rappture::Dropdownlist $itk_component(presets).plist \
179            -postcommand [itcl::code $this _presets post] \
180            -unpostcommand [itcl::code $this _presets unpost] \
181    }
182
183    bind $itk_component(presetlist) <<DropdownlistSelect>> \
184        [itcl::code $this _presets select]
185
186    $itk_component(presets) configure -command \
187        [list $itk_component(presetlist) post $itk_component(vframe) left]
188
189    eval itk_initialize $args
190}
191
192# ----------------------------------------------------------------------
193# USAGE: value ?-check? ?<newval>?
194#
195# Clients use this to query/set the value for this widget.  With
196# no args, it returns the current value for the widget.  If the
197# <newval> is specified, it sets the value of the widget and
198# sends a <<Value>> event.  If the -check flag is included, the
199# new value is not actually applied, but just checked for correctness.
200# ----------------------------------------------------------------------
201itcl::body Rappture::Gauge::value {args} {
202    set onlycheck 0
203    set i [lsearch -exact $args -check]
204    if {$i >= 0} {
205        set onlycheck 1
206        set args [lreplace $args $i $i]
207    }
208
209    if {[llength $args] == 1} {
210        #
211        # If this gauge has -units, try to convert the incoming
212        # value to that system of units.  Also, make sure that
213        # the value is bound by any min/max value constraints.
214        #
215        # Keep track of the inputted units so we can give a
216        # response about min and max values in familiar units.
217        #
218        set newval [set nv [lindex $args 0]]
219        set units $itk_option(-units)
220        if {"" != $units} {
221            set newval [Rappture::Units::convert $newval -context $units]
222            set nvUnits [Rappture::Units::Search::for $newval]
223            if { "" == $nvUnits} {
224                set msg [Rappture::Units::description $units]
225                error "Unrecognized units: $newval\nEnter value with units of $msg"
226            }
227            set nv [Rappture::Units::convert $nv \
228                -context $units -to $units -units off]
229
230            # Normalize the units name
231            set newval [Rappture::Units::convert $newval -units off]$nvUnits
232        }
233
234        switch -- $itk_option(-type) {
235            integer {
236                if { [scan $nv "%g" value] != 1 || int($nv) != $value } {
237                    error "bad value \"$nv\": should be an integer value"
238                }
239            }
240            real {
241                if {[string length $nv] <= 0
242                      || ![string is double $nv]
243                      || [regexp -nocase {^(inf|nan)$} $nv]} {
244                    error "bad value \"$nv\": should be a real number"
245                }
246            }
247        }
248
249        if {"" != $itk_option(-minvalue)} {
250            set convMinVal [set minv $itk_option(-minvalue)]
251            if {"" != $units} {
252                set minv [Rappture::Units::convert $minv \
253                    -context $units -to $units -units off]
254                set convMinVal [Rappture::Units::convert \
255                    $itk_option(-minvalue) -context $units -to $nvUnits]
256            } else {
257                set newval [format "%g" $newval]
258            }
259
260            # fix for the case when the user tries to
261            # compare values like minv=-500 nv=-0600
262            set nv [format "%g" $nv]
263            set minv [format "%g" $minv]
264
265            if {$nv < $minv} {
266                error "minimum value allowed here is $convMinVal"
267            }
268        }
269
270        if {"" != $itk_option(-maxvalue)} {
271            set convMaxVal [set maxv $itk_option(-maxvalue)]
272            if {"" != $units} {
273                set maxv [Rappture::Units::convert $maxv \
274                    -context $units -to $units -units off]
275                set convMaxVal [Rappture::Units::convert \
276                    $itk_option(-maxvalue) -context $units -to $nvUnits]
277            } else {
278                set newval [format "%g" $newval]
279            }
280
281            # fix for the case when the user tries to
282            # compare values like maxv=500 nv=0600
283            set nv [format "%g" $nv]
284            set maxv [format "%g" $maxv]
285
286            if {$nv > $maxv} {
287                error "maximum value allowed here is $convMaxVal"
288            }
289        }
290
291        if {$onlycheck} {
292            return
293        }
294
295        set _value $newval
296
297        _redraw
298        event generate $itk_component(hull) <<Value>>
299
300    } elseif {[llength $args] != 0} {
301        error "wrong # args: should be \"value ?-check? ?newval?\""
302    }
303    return $_value
304}
305
306# ----------------------------------------------------------------------
307# USAGE: edit cut
308# USAGE: edit copy
309# USAGE: edit paste
310#
311# Used internally to handle cut/copy/paste operations for the current
312# value.  Usually invoked by <<Cut>>, <<Copy>>, <<Paste>> events, but
313# can also be called directly through this method.
314# ----------------------------------------------------------------------
315itcl::body Rappture::Gauge::edit {option} {
316    if {$itk_option(-state) == "disabled"} {
317        return  ;# disabled? then bail out here!
318    }
319    switch -- $option {
320        cut {
321            edit copy
322            _editor popup
323            $itk_component(editor) value ""
324            $itk_component(editor) deactivate
325        }
326        copy {
327            clipboard clear
328            clipboard append $_value
329        }
330        paste {
331            _editor popup
332            $itk_component(editor) value [clipboard get]
333            $itk_component(editor) deactivate
334        }
335        default {
336            error "bad option \"$option\": should be cut, copy, paste"
337        }
338    }
339}
340
341# ----------------------------------------------------------------------
342# USAGE: bump <delta>
343#
344# Changes the current value up/down by the <delta> value.  Used
345# internally by the up/down spinner buttons when the value is
346# -type integer.
347# ----------------------------------------------------------------------
348itcl::body Rappture::Gauge::bump {delta} {
349    set val $_value
350    if {$val == ""} {
351        set val 0
352    }
353    if {[catch {value [expr {$val+$delta}]} result]} {
354        if {[regexp {allowed here is (.+)} $result match newval]} {
355            set _value $newval
356            $itk_component(value) configure -text $newval
357        }
358        if {[regexp {^bad.*: +(.)(.+)} $result match first tail]
359              || [regexp {(.)(.+)} $result match first tail]} {
360            set result "[string toupper $first]$tail"
361        }
362        bell
363        Rappture::Tooltip::cue $itk_component(value) $result
364        return 0
365    }
366}
367
368# ----------------------------------------------------------------------
369# USAGE: _redraw
370#
371# Used internally to redraw the gauge on the internal canvas based
372# on the current value and the size of the widget.  In this simple
373# base class, the gauge is drawn as a colored block, with an optional
374# image in the middle of it.
375# ----------------------------------------------------------------------
376itcl::body Rappture::Gauge::_redraw {} {
377    set c $itk_component(icon)
378    set w [winfo width $c]
379    set h [winfo height $c]
380
381    if {"" == [$c find all]} {
382        # first time around, create the items
383        $c create rectangle 0 0 1 1 -outline black -tags block
384        $c create image 0 0 -anchor center -image "" -tags bimage
385        $c create rectangle 0 0 1 1 -outline "" -fill "" -stipple gray50 -tags screen
386    }
387
388    if {"" != $itk_option(-spectrum)} {
389        set color [$itk_option(-spectrum) get $_value]
390    } else {
391        set color ""
392    }
393
394    # update the items based on current values
395    $c coords block 0 0 [expr {$w-1}] [expr {$h-1}]
396    $c coords screen 0 0 $w $h
397    $c itemconfigure block -fill $color
398
399    $c coords bimage [expr {0.5*$w}] [expr {0.5*$h}]
400
401    if {$itk_option(-state) == "disabled"} {
402        $c itemconfigure screen -fill white
403    } else {
404        $c itemconfigure screen -fill ""
405    }
406}
407
408# ----------------------------------------------------------------------
409# USAGE: _resize
410#
411# Used internally to resize the internal canvas based on the -image
412# option or the size of the text.
413# ----------------------------------------------------------------------
414itcl::body Rappture::Gauge::_resize {} {
415    set w 0
416    set h 0
417
418    if {"" != $itk_option(-image) || "" != $itk_option(-spectrum)} {
419        if {$itk_option(-samplewidth) > 0} {
420            set w $itk_option(-samplewidth)
421        } else {
422            if {$itk_option(-image) != ""} {
423                set w [expr {[image width $itk_option(-image)]+4}]
424            } else {
425                set w [winfo reqheight $itk_component(value)]
426            }
427        }
428
429        if {$itk_option(-sampleheight) > 0} {
430            set h $itk_option(-sampleheight)
431        } else {
432            if {$itk_option(-image) != ""} {
433                set h [expr {[image height $itk_option(-image)]+4}]
434            } else {
435                set h [winfo reqheight $itk_component(value)]
436            }
437        }
438    }
439
440    if {$w > 0 && $h > 0} {
441        $itk_component(icon) configure -width $w -height $h
442    }
443}
444
445# ----------------------------------------------------------------------
446# USAGE: _hilite <component> <state>
447#
448# Used internally to resize the internal canvas based on the -image
449# option or the size of the text.
450# ----------------------------------------------------------------------
451itcl::body Rappture::Gauge::_hilite {comp state} {
452    if {$itk_option(-state) == "disabled"} {
453        set state 0  ;# disabled? then don't hilite
454    }
455    if {$comp == "value" && !$itk_option(-editable)} {
456        $itk_component(value) configure -relief flat
457        return
458    }
459
460    if {$state} {
461        $itk_component($comp) configure -relief solid
462    } else {
463        $itk_component($comp) configure -relief flat
464    }
465}
466
467# ----------------------------------------------------------------------
468# USAGE: _editor popup
469# USAGE: _editor activate
470# USAGE: _editor validate <value>
471# USAGE: _editor apply <value>
472# USAGE: _editor menu <rootx> <rooty>
473#
474# Used internally to handle the various functions of the pop-up
475# editor for the value of this gauge.
476# ----------------------------------------------------------------------
477itcl::body Rappture::Gauge::_editor {option args} {
478    if {$itk_option(-state) == "disabled"} {
479        return  ;# disabled? then bail out here!
480    }
481    switch -- $option {
482        popup {
483            if {$itk_option(-editable)} {
484                $itk_component(editor) activate
485            }
486        }
487        activate {
488            return [list text $_value \
489                x [winfo rootx $itk_component(value)] \
490                y [winfo rooty $itk_component(value)] \
491                w [winfo width $itk_component(value)] \
492                h [winfo height $itk_component(value)]]
493        }
494        validate {
495            if {[llength $args] != 1} {
496                error "wrong # args: should be \"_editor validate val\""
497            }
498            set val [lindex $args 0]
499
500            if {[catch {value -check $val} result]} {
501                if {[regexp {allowed here is (.+)} $result match newval]} {
502                    $itk_component(editor) value $newval
503                }
504                if {[regexp {^bad.*: +(.)(.+)} $result match first tail]
505                      || [regexp {(.)(.+)} $result match first tail]} {
506                    set result "[string toupper $first]$tail"
507                }
508                bell
509                Rappture::Tooltip::cue $itk_component(editor) $result
510                return 0
511            }
512        }
513        apply {
514            if {[llength $args] != 1} {
515                error "wrong # args: should be \"_editor apply val\""
516            }
517            value [lindex $args 0]
518        }
519        menu {
520            eval tk_popup $itk_component(emenu) $args
521        }
522        default {
523            error "bad option \"$option\": should be popup, activate, validate, apply, and menu"
524        }
525    }
526}
527
528# ----------------------------------------------------------------------
529# USAGE: _presets post
530# USAGE: _presets unpost
531# USAGE: _presets select
532#
533# Used internally to handle the list of presets for this gauge.  The
534# post/unpost options are invoked when the list is posted or unposted
535# to manage the relief of the controlling button.  The select option
536# is invoked whenever there is a selection from the list, to assign
537# the value back to the gauge.
538# ----------------------------------------------------------------------
539itcl::body Rappture::Gauge::_presets {option} {
540    switch -- $option {
541        post {
542            set i [$itk_component(presetlist) index $_value]
543            if {$i >= 0} {
544                $itk_component(presetlist) select clear 0 end
545                $itk_component(presetlist) select set $i
546            }
547            after 10 [list $itk_component(presets) configure -relief sunken]
548        }
549        unpost {
550            $itk_component(presets) configure -relief flat
551        }
552        select {
553            set val [$itk_component(presetlist) current]
554            if {"" != $val} {
555                value $val
556            }
557        }
558        default {
559            error "bad option \"$option\": should be post, unpost, select"
560        }
561    }
562}
563
564# ----------------------------------------------------------------------
565# USAGE: _layout
566#
567# Used internally to fix the layout of widgets whenever there is a
568# change in the options that affect layout.  Puts the value in the
569# proper position according to the -valueposition option.  Also,
570# adds or removes the icon if it needs to be shown.
571# ----------------------------------------------------------------------
572itcl::body Rappture::Gauge::_layout {} {
573    foreach w [pack slaves $itk_component(hull)] {
574        pack forget $w
575    }
576
577    array set side2anchor {
578        left   e
579        right  w
580        top    s
581        bottom n
582    }
583    set pos $itk_option(-valueposition)
584    pack $itk_component(vframe) -side $pos \
585        -expand yes -fill both -ipadx 2
586    $itk_component(value) configure -anchor $side2anchor($pos)
587
588    if {"" != $itk_option(-image) || "" != $itk_option(-spectrum)} {
589        pack $itk_component(icon) -side $pos
590    }
591}
592
593# ----------------------------------------------------------------------
594# CONFIGURATION OPTION: -editable
595# ----------------------------------------------------------------------
596itcl::configbody Rappture::Gauge::editable {
597    if {![string is boolean -strict $itk_option(-editable)]} {
598        error "bad value \"$itk_option(-editable)\": should be boolean"
599    }
600    if {!$itk_option(-editable) && [winfo ismapped $itk_component(editor)]} {
601        $itk_component(editor) deactivate -abort
602    }
603}
604
605# ----------------------------------------------------------------------
606# CONFIGURATION OPTION: -state
607# ----------------------------------------------------------------------
608itcl::configbody Rappture::Gauge::state {
609    set valid {normal disabled}
610    if {[lsearch -exact $valid $itk_option(-state)] < 0} {
611        error "bad value \"$itk_option(-state)\": should be [join $valid {, }]"
612    }
613    $itk_component(value) configure -state $itk_option(-state)
614    $itk_component(spinup) configure -state $itk_option(-state)
615    $itk_component(spindn) configure -state $itk_option(-state)
616    $itk_component(presets) configure -state $itk_option(-state)
617    _redraw  ;# fix gauge
618}
619
620# ----------------------------------------------------------------------
621# CONFIGURATION OPTION: -spectrum
622# ----------------------------------------------------------------------
623itcl::configbody Rappture::Gauge::spectrum {
624    if {$itk_option(-spectrum) != ""
625          && ([catch {$itk_option(-spectrum) isa ::Rappture::Spectrum} valid]
626               || !$valid)} {
627        error "bad option \"$itk_option(-spectrum)\": should be Rappture::Spectrum object"
628    }
629    _resize
630    _layout
631    _redraw
632}
633
634# ----------------------------------------------------------------------
635# CONFIGURATION OPTION: -image
636# ----------------------------------------------------------------------
637itcl::configbody Rappture::Gauge::image {
638    if {$itk_option(-image) != ""
639          && [catch {image width $itk_option(-image)}]} {
640        error "bad value \"$itk_option(-image)\": should be Tk image"
641    }
642    _resize
643    _layout
644    $itk_component(icon) itemconfigure bimage -image $itk_option(-image)
645}
646
647# ----------------------------------------------------------------------
648# CONFIGURATION OPTION: -units
649# ----------------------------------------------------------------------
650itcl::configbody Rappture::Gauge::units {
651    if {$itk_option(-units) != ""
652          && [::Rappture::Units::System::for $itk_option(-units)] == ""} {
653        error "unrecognized system of units \"$itk_option(-units)\""
654    }
655}
656
657# ----------------------------------------------------------------------
658# CONFIGURATION OPTION: -valueposition
659# ----------------------------------------------------------------------
660itcl::configbody Rappture::Gauge::valueposition {
661    set pos $itk_option(-valueposition)
662    set opts {left right top bottom}
663    if {[lsearch -exact $opts $pos] < 0} {
664        error "bad value \"$pos\": should be [join $opts {, }]"
665    }
666    _layout
667}
668
669# ----------------------------------------------------------------------
670# CONFIGURATION OPTION: -presets
671# ----------------------------------------------------------------------
672itcl::configbody Rappture::Gauge::presets {
673    if {"" == $itk_option(-presets)} {
674        pack forget $itk_component(presets)
675    } else {
676        if {$itk_option(-valueposition) == "left"} {
677            set s "left"
678        } else {
679            set s "right"
680        }
681        set first [lindex [pack slaves $itk_component(vframe)] 0]
682        pack $itk_component(presets) -before $first -side $s -fill y
683
684        $itk_component(presetlist) delete 0 end
685        $itk_component(presetlist) insert end $itk_option(-presets)
686    }
687}
688
689# ----------------------------------------------------------------------
690# CONFIGURATION OPTION: -type
691# ----------------------------------------------------------------------
692itcl::configbody Rappture::Gauge::type {
693    switch -- $itk_option(-type) {
694        integer {
695            set first [lindex [pack slaves $itk_component(vframe)] 0]
696            if {$first == $itk_component(presets)} {
697                pack $itk_component(spinner) -after $first -side left -fill y
698            } else {
699                pack $itk_component(spinner) -before $first -side right -fill y
700            }
701        }
702        real {
703            pack forget $itk_component(spinner)
704        }
705        default {
706            error "bad number type \"$itk_option(-type)\": should be integer or real"
707        }
708    }
709}
Note: See TracBrowser for help on using the repository browser.