source: trunk/gui/scripts/gauge.tcl @ 578

Last change on this file since 578 was 578, checked in by dkearney, 17 years ago

added code to normalize the units entered by the user
File size: 24.6 KB
Line 
1# ----------------------------------------------------------------------
2#  COMPONENT: gauge - compact readout for real values
3#
4#  This widget is a readout for a real value.  It has a little glyph
5#  filled with color according to the value, followed by a numeric
6#  representation of the value itself.  The value can be edited, and
7#  a list of predefined values can be associated with a menu that
8#  drops down from the value.
9# ======================================================================
10#  AUTHOR:  Michael McLennan, Purdue University
11#  Copyright (c) 2004-2005  Purdue Research Foundation
12#
13#  See the file "license.terms" for information on usage and
14#  redistribution of this file, and for a DISCLAIMER OF ALL WARRANTIES.
15# ======================================================================
16package require Itk
17package require BLT
18
19option add *Gauge.sampleWidth 30 widgetDefault
20option add *Gauge.sampleHeight 20 widgetDefault
21option add *Gauge.valuePosition "right" widgetDefault
22option add *Gauge.textBackground #cccccc widgetDefault
23option add *Gauge.editable yes widgetDefault
24
25itcl::class Rappture::Gauge {
26    inherit itk::Widget
27
28    itk_option define -editable editable Editable ""
29    itk_option define -state state State "normal"
30    itk_option define -spectrum spectrum Spectrum ""
31    itk_option define -type type Type "real"
32    itk_option define -units units Units ""
33    itk_option define -minvalue minValue MinValue ""
34    itk_option define -maxvalue maxValue MaxValue ""
35    itk_option define -presets presets Presets ""
36    itk_option define -valueposition valuePosition ValuePosition ""
37    itk_option define -image image Image ""
38    itk_option define -samplewidth sampleWidth SampleWidth 0
39    itk_option define -sampleheight sampleHeight SampleHeight 0
40
41    constructor {args} { # defined below }
42
43    public method value {args}
44    public method edit {option}
45    public method bump {delta}
46
47    protected method _redraw {}
48    protected method _resize {}
49    protected method _hilite {comp state}
50    protected method _editor {option args}
51    protected method _presets {option}
52    protected method _layout {}
53
54    private variable _value 0  ;# value for this widget
55
56    blt::bitmap define GaugeArrow-up {
57        #define up_width 8
58        #define up_height 4
59        static unsigned char up_bits[] = {
60           0x10, 0x38, 0x7c, 0xfe};
61    }
62    blt::bitmap define GaugeArrow-down {
63        #define arrow_width 8
64        #define arrow_height 4
65        static unsigned char arrow_bits[] = {
66           0xfe, 0x7c, 0x38, 0x10};
67    }
68
69    blt::bitmap define GaugeArrow {
70        #define arrow_width 9
71        #define arrow_height 4
72        static unsigned char arrow_bits[] = {
73           0x7f, 0x00, 0x3e, 0x00, 0x1c, 0x00, 0x08, 0x00};
74    }
75}
76                                                                               
77itk::usual Gauge {
78    keep -cursor -font -foreground -background
79    keep -selectbackground -selectforeground -selectborderwidth
80}
81
82# ----------------------------------------------------------------------
83# CONSTRUCTOR
84# ----------------------------------------------------------------------
85itcl::body Rappture::Gauge::constructor {args} {
86    itk_component add icon {
87        canvas $itk_interior.icon -width 1 -height 1 \
88            -borderwidth 0 -highlightthickness 0
89    } {
90        usual
91        ignore -highlightthickness -highlightbackground -highlightcolor
92    }
93    pack $itk_component(icon) -side left
94    bind $itk_component(icon) <Configure> [itcl::code $this _redraw]
95
96    itk_component add -protected vframe {
97        frame $itk_interior.vframe
98    }
99
100    itk_component add value {
101        label $itk_component(vframe).value -borderwidth 1 -width 7 \
102            -textvariable [itcl::scope _value]
103    } {
104        rename -background -textbackground textBackground Background
105    }
106    pack $itk_component(value) -side left -expand yes -fill both
107
108    bind $itk_component(value) <Enter> [itcl::code $this _hilite value on]
109    bind $itk_component(value) <Leave> [itcl::code $this _hilite value off]
110
111    bind $itk_component(value) <<Cut>> [itcl::code $this edit cut]
112    bind $itk_component(value) <<Copy>> [itcl::code $this edit copy]
113    bind $itk_component(value) <<Paste>> [itcl::code $this edit paste]
114
115    itk_component add emenu {
116        menu $itk_component(value).menu -tearoff 0
117    } {
118        usual
119        ignore -tearoff
120    }
121    $itk_component(emenu) add command -label "Cut" -accelerator "^X" \
122        -command [list event generate $itk_component(value) <<Cut>>]
123    $itk_component(emenu) add command -label "Copy" -accelerator "^C" \
124        -command [list event generate $itk_component(value) <<Copy>>]
125    $itk_component(emenu) add command -label "Paste" -accelerator "^V" \
126        -command [list event generate $itk_component(value) <<Paste>>]
127    bind $itk_component(value) <<PopupMenu>> \
128        [itcl::code $this _editor menu]
129
130    itk_component add editor {
131        Rappture::Editor $itk_interior.editor \
132            -activatecommand [itcl::code $this _editor activate] \
133            -validatecommand [itcl::code $this _editor validate] \
134            -applycommand [itcl::code $this _editor apply]
135    }
136    bind $itk_component(value) <ButtonPress> \
137        [itcl::code $this _editor popup]
138
139
140    itk_component add spinner {
141        frame $itk_component(vframe).spinner
142    }
143
144    itk_component add spinup {
145        button $itk_component(spinner).up -bitmap GaugeArrow-up \
146            -borderwidth 1 -relief raised -highlightthickness 0 \
147            -command [itcl::code $this bump 1]
148    } {
149        usual
150        ignore -borderwidth -highlightthickness
151    }
152    pack $itk_component(spinup) -side top -expand yes -fill both
153
154    itk_component add spindn {
155        button $itk_component(spinner).down -bitmap GaugeArrow-down \
156            -borderwidth 1 -relief raised -highlightthickness 0 \
157            -command [itcl::code $this bump -1]
158    } {
159        usual
160        ignore -borderwidth -highlightthickness
161    }
162    pack $itk_component(spindn) -side bottom -expand yes -fill both
163
164
165    itk_component add presets {
166        button $itk_component(vframe).psbtn -bitmap GaugeArrow \
167            -borderwidth 1 -highlightthickness 0 -relief flat
168    } {
169        usual
170        ignore -borderwidth -relief -highlightthickness
171        rename -background -textbackground textBackground Background
172    }
173
174    bind $itk_component(presets) <Enter> [itcl::code $this _hilite presets on]
175    bind $itk_component(presets) <Leave> [itcl::code $this _hilite presets off]
176
177    itk_component add presetlist {
178        Rappture::Dropdownlist $itk_component(presets).plist \
179            -postcommand [itcl::code $this _presets post] \
180            -unpostcommand [itcl::code $this _presets unpost] \
181    }
182
183    bind $itk_component(presetlist) <<DropdownlistSelect>> \
184        [itcl::code $this _presets select]
185
186    $itk_component(presets) configure -command \
187        [list $itk_component(presetlist) post $itk_component(vframe) left]
188
189    eval itk_initialize $args
190}
191
192# ----------------------------------------------------------------------
193# USAGE: value ?-check? ?<newval>?
194#
195# Clients use this to query/set the value for this widget.  With
196# no args, it returns the current value for the widget.  If the
197# <newval> is specified, it sets the value of the widget and
198# sends a <<Value>> event.  If the -check flag is included, the
199# new value is not actually applied, but just checked for correctness.
200# ----------------------------------------------------------------------
201itcl::body Rappture::Gauge::value {args} {
202    set onlycheck 0
203    set i [lsearch -exact $args -check]
204    if {$i >= 0} {
205        set onlycheck 1
206        set args [lreplace $args $i $i]
207    }
208
209    if {[llength $args] == 1} {
210        #
211        # If this gauge has -units, try to convert the incoming
212        # value to that system of units.  Also, make sure that
213        # the value is bound by any min/max value constraints.
214        #
215        # Keep track of the inputted units so we can give a
216        # response about min and max values in familiar units.
217        #
218        set newval [set nv [lindex $args 0]]
219        set units $itk_option(-units)
220        if {"" != $units} {
221            set newval [Rappture::Units::convert $newval -context $units]
222            set nvUnits [Rappture::Units::Search::for $newval]
223            if { "" == $nvUnits} {
224                set msg [Rappture::Units::description $units]
225                error "Unrecognized units: $newval\nEnter value with units of $msg"
226            }
227            set nv [Rappture::Units::convert $nv \
228                -context $units -to $units -units off]
229
230            # Normalize the units name
231            set newval [Rappture::Units::convert $newval -units off]$nvUnits
232        }
233
234        switch -- $itk_option(-type) {
235            integer {
236                if {![string is integer -strict $nv]} {
237                    error "Should be an integer value"
238                }
239            }
240            real {
241                if {![string is double -strict $nv]} {
242                    error "Should be a real number"
243                }
244            }
245        }
246
247        if {"" != $itk_option(-minvalue)} {
248            set convMinVal [set minv $itk_option(-minvalue)]
249            if {"" != $units} {
250                set minv [Rappture::Units::convert $minv \
251                    -context $units -to $units -units off]
252                set convMinVal [Rappture::Units::convert \
253                    $itk_option(-minvalue) -context $units -to $nvUnits]
254            } else {
255                set newval [format "%g" $newval]
256            }
257
258            # fix for the case when the user tries to
259            # compare values like minv=-500 nv=-0600
260            set nv [format "%g" $nv]
261            set minv [format "%g" $minv]
262
263            if {$nv < $minv} {
264                error "minimum value allowed here is $convMinVal"
265            }
266        }
267
268        if {"" != $itk_option(-maxvalue)} {
269            set convMaxVal [set maxv $itk_option(-maxvalue)]
270            if {"" != $units} {
271                set maxv [Rappture::Units::convert $maxv \
272                    -context $units -to $units -units off]
273                set convMaxVal [Rappture::Units::convert \
274                    $itk_option(-maxvalue) -context $units -to $nvUnits]
275            } else {
276                set newval [format "%g" $newval]
277            }
278
279            # fix for the case when the user tries to
280            # compare values like maxv=500 nv=0600
281            set nv [format "%g" $nv]
282            set maxv [format "%g" $maxv]
283
284            if {$nv > $maxv} {
285                error "maximum value allowed here is $convMaxVal"
286            }
287        }
288
289        if {$onlycheck} {
290            return
291        }
292
293        set _value $newval
294
295        _redraw
296        event generate $itk_component(hull) <<Value>>
297
298    } elseif {[llength $args] != 0} {
299        error "wrong # args: should be \"value ?-check? ?newval?\""
300    }
301    return $_value
302}
303
304# ----------------------------------------------------------------------
305# USAGE: edit cut
306# USAGE: edit copy
307# USAGE: edit paste
308#
309# Used internally to handle cut/copy/paste operations for the current
310# value.  Usually invoked by <<Cut>>, <<Copy>>, <<Paste>> events, but
311# can also be called directly through this method.
312# ----------------------------------------------------------------------
313itcl::body Rappture::Gauge::edit {option} {
314    if {$itk_option(-state) == "disabled"} {
315        return  ;# disabled? then bail out here!
316    }
317    switch -- $option {
318        cut {
319            edit copy
320            _editor popup
321            $itk_component(editor) value ""
322            $itk_component(editor) deactivate
323        }
324        copy {
325            clipboard clear
326            clipboard append $_value
327        }
328        paste {
329            _editor popup
330            $itk_component(editor) value [clipboard get]
331            $itk_component(editor) deactivate
332        }
333        default {
334            error "bad option \"$option\": should be cut, copy, paste"
335        }
336    }
337}
338
339# ----------------------------------------------------------------------
340# USAGE: bump <delta>
341#
342# Changes the current value up/down by the <delta> value.  Used
343# internally by the up/down spinner buttons when the value is
344# -type integer.
345# ----------------------------------------------------------------------
346itcl::body Rappture::Gauge::bump {delta} {
347    set val $_value
348    if {$val == ""} {
349        set val 0
350    }
351    if {[catch {value [expr {$val+$delta}]} result]} {
352        if {[regexp {allowed here is (.+)} $result match newval]} {
353            set _value $newval
354            $itk_component(value) configure -text $newval
355        }
356        if {[regexp {^bad.*: +(.)(.+)} $result match first tail]
357              || [regexp {(.)(.+)} $result match first tail]} {
358            set result "[string toupper $first]$tail"
359        }
360        bell
361        Rappture::Tooltip::cue $itk_component(value) $result
362        return 0
363    }
364}
365
366# ----------------------------------------------------------------------
367# USAGE: _redraw
368#
369# Used internally to redraw the gauge on the internal canvas based
370# on the current value and the size of the widget.  In this simple
371# base class, the gauge is drawn as a colored block, with an optional
372# image in the middle of it.
373# ----------------------------------------------------------------------
374itcl::body Rappture::Gauge::_redraw {} {
375    set c $itk_component(icon)
376    set w [winfo width $c]
377    set h [winfo height $c]
378
379    if {"" == [$c find all]} {
380        # first time around, create the items
381        $c create rectangle 0 0 1 1 -outline black -tags block
382        $c create image 0 0 -anchor center -image "" -tags bimage
383        $c create rectangle 0 0 1 1 -outline "" -fill "" -stipple gray50 -tags screen
384    }
385
386    if {"" != $itk_option(-spectrum)} {
387        set color [$itk_option(-spectrum) get $_value]
388    } else {
389        set color ""
390    }
391
392    # update the items based on current values
393    $c coords block 0 0 [expr {$w-1}] [expr {$h-1}]
394    $c coords screen 0 0 $w $h
395    $c itemconfigure block -fill $color
396
397    $c coords bimage [expr {0.5*$w}] [expr {0.5*$h}]
398
399    if {$itk_option(-state) == "disabled"} {
400        $c itemconfigure screen -fill white
401    } else {
402        $c itemconfigure screen -fill ""
403    }
404}
405
406# ----------------------------------------------------------------------
407# USAGE: _resize
408#
409# Used internally to resize the internal canvas based on the -image
410# option or the size of the text.
411# ----------------------------------------------------------------------
412itcl::body Rappture::Gauge::_resize {} {
413    set w 0
414    set h 0
415
416    if {"" != $itk_option(-image) || "" != $itk_option(-spectrum)} {
417        if {$itk_option(-samplewidth) > 0} {
418            set w $itk_option(-samplewidth)
419        } else {
420            if {$itk_option(-image) != ""} {
421                set w [expr {[image width $itk_option(-image)]+4}]
422            } else {
423                set w [winfo reqheight $itk_component(value)]
424            }
425        }
426
427        if {$itk_option(-sampleheight) > 0} {
428            set h $itk_option(-sampleheight)
429        } else {
430            if {$itk_option(-image) != ""} {
431                set h [expr {[image height $itk_option(-image)]+4}]
432            } else {
433                set h [winfo reqheight $itk_component(value)]
434            }
435        }
436    }
437
438    if {$w > 0 && $h > 0} {
439        $itk_component(icon) configure -width $w -height $h
440    }
441}
442
443# ----------------------------------------------------------------------
444# USAGE: _hilite <component> <state>
445#
446# Used internally to resize the internal canvas based on the -image
447# option or the size of the text.
448# ----------------------------------------------------------------------
449itcl::body Rappture::Gauge::_hilite {comp state} {
450    if {$itk_option(-state) == "disabled"} {
451        set state 0  ;# disabled? then don't hilite
452    }
453    if {$comp == "value" && !$itk_option(-editable)} {
454        $itk_component(value) configure -relief flat
455        return
456    }
457
458    if {$state} {
459        $itk_component($comp) configure -relief solid
460    } else {
461        $itk_component($comp) configure -relief flat
462    }
463}
464
465# ----------------------------------------------------------------------
466# USAGE: _editor popup
467# USAGE: _editor activate
468# USAGE: _editor validate <value>
469# USAGE: _editor apply <value>
470# USAGE: _editor menu <rootx> <rooty>
471#
472# Used internally to handle the various functions of the pop-up
473# editor for the value of this gauge.
474# ----------------------------------------------------------------------
475itcl::body Rappture::Gauge::_editor {option args} {
476    if {$itk_option(-state) == "disabled"} {
477        return  ;# disabled? then bail out here!
478    }
479    switch -- $option {
480        popup {
481            if {$itk_option(-editable)} {
482                $itk_component(editor) activate
483            }
484        }
485        activate {
486            return [list text $_value \
487                x [winfo rootx $itk_component(value)] \
488                y [winfo rooty $itk_component(value)] \
489                w [winfo width $itk_component(value)] \
490                h [winfo height $itk_component(value)]]
491        }
492        validate {
493            if {[llength $args] != 1} {
494                error "wrong # args: should be \"_editor validate val\""
495            }
496            set val [lindex $args 0]
497
498            if {[catch {value -check $val} result]} {
499                if {[regexp {allowed here is (.+)} $result match newval]} {
500                    $itk_component(editor) value $newval
501                }
502                if {[regexp {^bad.*: +(.)(.+)} $result match first tail]
503                      || [regexp {(.)(.+)} $result match first tail]} {
504                    set result "[string toupper $first]$tail"
505                }
506                bell
507                Rappture::Tooltip::cue $itk_component(editor) $result
508                return 0
509            }
510        }
511        apply {
512            if {[llength $args] != 1} {
513                error "wrong # args: should be \"_editor apply val\""
514            }
515            value [lindex $args 0]
516        }
517        menu {
518            eval tk_popup $itk_component(emenu) $args
519        }
520        default {
521            error "bad option \"$option\": should be popup, activate, validate, apply, and menu"
522        }
523    }
524}
525
526# ----------------------------------------------------------------------
527# USAGE: _presets post
528# USAGE: _presets unpost
529# USAGE: _presets select
530#
531# Used internally to handle the list of presets for this gauge.  The
532# post/unpost options are invoked when the list is posted or unposted
533# to manage the relief of the controlling button.  The select option
534# is invoked whenever there is a selection from the list, to assign
535# the value back to the gauge.
536# ----------------------------------------------------------------------
537itcl::body Rappture::Gauge::_presets {option} {
538    switch -- $option {
539        post {
540            set i [$itk_component(presetlist) index $_value]
541            if {$i >= 0} {
542                $itk_component(presetlist) select clear 0 end
543                $itk_component(presetlist) select set $i
544            }
545            after 10 [list $itk_component(presets) configure -relief sunken]
546        }
547        unpost {
548            $itk_component(presets) configure -relief flat
549        }
550        select {
551            set val [$itk_component(presetlist) current]
552            if {"" != $val} {
553                value $val
554            }
555        }
556        default {
557            error "bad option \"$option\": should be post, unpost, select"
558        }
559    }
560}
561
562# ----------------------------------------------------------------------
563# USAGE: _layout
564#
565# Used internally to fix the layout of widgets whenever there is a
566# change in the options that affect layout.  Puts the value in the
567# proper position according to the -valueposition option.  Also,
568# adds or removes the icon if it needs to be shown.
569# ----------------------------------------------------------------------
570itcl::body Rappture::Gauge::_layout {} {
571    foreach w [pack slaves $itk_component(hull)] {
572        pack forget $w
573    }
574
575    array set side2anchor {
576        left   e
577        right  w
578        top    s
579        bottom n
580    }
581    set pos $itk_option(-valueposition)
582    pack $itk_component(vframe) -side $pos \
583        -expand yes -fill both -ipadx 2
584    $itk_component(value) configure -anchor $side2anchor($pos)
585
586    if {"" != $itk_option(-image) || "" != $itk_option(-spectrum)} {
587        pack $itk_component(icon) -side $pos
588    }
589}
590
591# ----------------------------------------------------------------------
592# CONFIGURATION OPTION: -editable
593# ----------------------------------------------------------------------
594itcl::configbody Rappture::Gauge::editable {
595    if {![string is boolean -strict $itk_option(-editable)]} {
596        error "bad value \"$itk_option(-editable)\": should be boolean"
597    }
598    if {!$itk_option(-editable) && [winfo ismapped $itk_component(editor)]} {
599        $itk_component(editor) deactivate -abort
600    }
601}
602
603# ----------------------------------------------------------------------
604# CONFIGURATION OPTION: -state
605# ----------------------------------------------------------------------
606itcl::configbody Rappture::Gauge::state {
607    set valid {normal disabled}
608    if {[lsearch -exact $valid $itk_option(-state)] < 0} {
609        error "bad value \"$itk_option(-state)\": should be [join $valid {, }]"
610    }
611    $itk_component(value) configure -state $itk_option(-state)
612    $itk_component(spinup) configure -state $itk_option(-state)
613    $itk_component(spindn) configure -state $itk_option(-state)
614    $itk_component(presets) configure -state $itk_option(-state)
615    _redraw  ;# fix gauge
616}
617
618# ----------------------------------------------------------------------
619# CONFIGURATION OPTION: -spectrum
620# ----------------------------------------------------------------------
621itcl::configbody Rappture::Gauge::spectrum {
622    if {$itk_option(-spectrum) != ""
623          && ([catch {$itk_option(-spectrum) isa ::Rappture::Spectrum} valid]
624               || !$valid)} {
625        error "bad option \"$itk_option(-spectrum)\": should be Rappture::Spectrum object"
626    }
627    _resize
628    _layout
629    _redraw
630}
631
632# ----------------------------------------------------------------------
633# CONFIGURATION OPTION: -image
634# ----------------------------------------------------------------------
635itcl::configbody Rappture::Gauge::image {
636    if {$itk_option(-image) != ""
637          && [catch {image width $itk_option(-image)}]} {
638        error "bad value \"$itk_option(-image)\": should be Tk image"
639    }
640    _resize
641    _layout
642    $itk_component(icon) itemconfigure bimage -image $itk_option(-image)
643}
644
645# ----------------------------------------------------------------------
646# CONFIGURATION OPTION: -units
647# ----------------------------------------------------------------------
648itcl::configbody Rappture::Gauge::units {
649    if {$itk_option(-units) != ""
650          && [::Rappture::Units::System::for $itk_option(-units)] == ""} {
651        error "unrecognized system of units \"$itk_option(-units)\""
652    }
653}
654
655# ----------------------------------------------------------------------
656# CONFIGURATION OPTION: -valueposition
657# ----------------------------------------------------------------------
658itcl::configbody Rappture::Gauge::valueposition {
659    set pos $itk_option(-valueposition)
660    set opts {left right top bottom}
661    if {[lsearch -exact $opts $pos] < 0} {
662        error "bad value \"$pos\": should be [join $opts {, }]"
663    }
664    _layout
665}
666
667# ----------------------------------------------------------------------
668# CONFIGURATION OPTION: -presets
669# ----------------------------------------------------------------------
670itcl::configbody Rappture::Gauge::presets {
671    if {"" == $itk_option(-presets)} {
672        pack forget $itk_component(presets)
673    } else {
674        if {$itk_option(-valueposition) == "left"} {
675            set s "left"
676        } else {
677            set s "right"
678        }
679        set first [lindex [pack slaves $itk_component(vframe)] 0]
680        pack $itk_component(presets) -before $first -side $s -fill y
681
682        $itk_component(presetlist) delete 0 end
683        $itk_component(presetlist) insert end $itk_option(-presets)
684    }
685}
686
687# ----------------------------------------------------------------------
688# CONFIGURATION OPTION: -type
689# ----------------------------------------------------------------------
690itcl::configbody Rappture::Gauge::type {
691    switch -- $itk_option(-type) {
692        integer {
693            set first [lindex [pack slaves $itk_component(vframe)] 0]
694            if {$first == $itk_component(presets)} {
695                pack $itk_component(spinner) -after $first -side left -fill y
696            } else {
697                pack $itk_component(spinner) -before $first -side right -fill y
698            }
699        }
700        real {
701            pack forget $itk_component(spinner)
702        }
703        default {
704            error "bad number type \"$itk_option(-type)\": should be integer or real"
705        }
706    }
707}
Note: See TracBrowser for help on using the repository browser.