source: trunk/gui/scripts/vtkheightmapviewer.tcl @ 4381

Last change on this file since 4381 was 4381, checked in by ldelgass, 7 years ago

opacity style setting fixes for VTK viewers (expect vtkvolumeviewer which does
not yet support the style setting). Also note that nanovisviewer (and
flowvisviewer?) have a regression which changes the -opacity style to [0,100]
instead of [0,1]

File size: 87.1 KB
Line 
1# -*- mode: tcl; indent-tabs-mode: nil -*-
2# ----------------------------------------------------------------------
3#  COMPONENT: vtkheightmapviewer - Vtk heightmap viewer
4#
5#  It connects to the Vtk server running on a rendering farm,
6#  transmits data, and displays the results.
7# ======================================================================
8#  AUTHOR:  Michael McLennan, Purdue University
9#  Copyright (c) 2004-2014  HUBzero Foundation, LLC
10#
11#  See the file "license.terms" for information on usage and
12#  redistribution of this file, and for a DISCLAIMER OF ALL WARRANTIES.
13# ======================================================================
14package require Itk
15package require BLT
16#package require Img
17
18option add *VtkHeightmapViewer.width 4i widgetDefault
19option add *VtkHeightmapViewer*cursor crosshair widgetDefault
20option add *VtkHeightmapViewer.height 4i widgetDefault
21option add *VtkHeightmapViewer.foreground black widgetDefault
22option add *VtkHeightmapViewer.controlBackground gray widgetDefault
23option add *VtkHeightmapViewer.controlDarkBackground #999999 widgetDefault
24option add *VtkHeightmapViewer.plotBackground black widgetDefault
25option add *VtkHeightmapViewer.plotForeground white widgetDefault
26option add *VtkHeightmapViewer.font \
27    -*-helvetica-medium-r-normal-*-12-* widgetDefault
28
29# must use this name -- plugs into Rappture::resources::load
30proc VtkHeightmapViewer_init_resources {} {
31    Rappture::resources::register \
32        vtkvis_server Rappture::VtkHeightmapViewer::SetServerList
33}
34
35itcl::class Rappture::VtkHeightmapViewer {
36    inherit Rappture::VisViewer
37
38    itk_option define -plotforeground plotForeground Foreground ""
39    itk_option define -plotbackground plotBackground Background ""
40    itk_option define -mode mode Mode "contour"
41
42    constructor { hostlist args } {
43        Rappture::VisViewer::constructor $hostlist
44    } {
45        # defined below
46    }
47    destructor {
48        # defined below
49    }
50    public proc SetServerList { namelist } {
51        Rappture::VisViewer::SetServerList "vtkvis" $namelist
52    }
53    public method add {dataobj {settings ""}}
54    public method camera {option args}
55    public method delete {args}
56    public method disconnect {}
57    public method download {option args}
58    public method get {args}
59    public method isconnected {}
60    public method limits3 { dataobj }
61    public method parameters {title args} {
62        # do nothing
63    }
64    public method scale {args}
65
66    protected method CameraReset {}
67    protected method Connect {}
68    protected method CurrentDatasets {args}
69    protected method Disconnect {}
70    protected method DoResize {}
71    protected method DoRotate {}
72    protected method AdjustSetting {what {value ""}}
73    protected method AdjustMode {}
74    protected method InitSettings { args  }
75    protected method Pan {option x y}
76    protected method Pick {x y}
77    protected method Rebuild {}
78    protected method ReceiveDataset { args }
79    protected method ReceiveImage { args }
80    protected method ReceiveLegend { colormap title min max size }
81    protected method Rotate {option x y}
82    protected method Zoom {option}
83
84    # The following methods are only used by this class.
85    private method BuildAxisTab {}
86    private method BuildCameraTab {}
87    private method BuildColormap { name }
88    private method BuildContourTab {}
89    private method BuildDownloadPopup { widget command }
90    private method Combo { option }
91    private method DrawLegend {}
92    private method EnterLegend { x y }
93    private method EventuallyRequestLegend {}
94    private method EventuallyResize { w h }
95    private method EventuallyRotate { q }
96    private method GetImage { args }
97    private method GetVtkData { args }
98    private method IsValidObject { dataobj }
99    private method LeaveLegend {}
100    private method MotionLegend { x y }
101    private method PanCamera {}
102    private method RequestLegend {}
103    private method SetCurrentColormap { color }
104    private method SetLegendTip { x y }
105    private method SetObjectStyle { dataobj comp }
106    private method GetHeightmapScale {}
107    private method ResetAxes {}
108    private method SetOrientation { side }
109    private method UpdateContourList {}
110
111    private variable _arcball ""
112    private variable _dlist ""     ;    # list of data objects
113    private variable _obj2datasets
114    private variable _obj2ovride   ;    # maps dataobj => style override
115    private variable _comp2scale;       # maps dataset to the heightmap scale.
116    private variable _datasets     ;    # contains all the dataobj-component
117                                   ;    # datasets in the server
118    private variable _colormaps    ;    # contains all the colormaps
119                                   ;    # in the server.
120
121    # The name of the current colormap used.  The colormap is global to all
122    # heightmaps displayed.
123    private variable _currentColormap ""
124    private variable _currentNumIsolines -1
125
126    private variable _maxScale 100;     # This is the # of times the x-axis
127                                        # and y-axis ranges can differ before
128                                        # automatically turning on
129                                        # -stretchtofit
130
131    private variable _click        ;    # info used for rotate operations
132    private variable _limits       ;    # Holds overall limits for all dataobjs
133                                        # using the viewer.
134    private variable _view         ;    # view params for 3D view
135    private variable _settings
136    private variable _changed
137    private variable _initialStyle "";  # First found style in dataobjects.
138    private variable _reset 1;          # Indicates if camera needs to be reset
139                                        # to starting position.
140    private variable _beforeConnect 1;  # Indicates if camera needs to be reset
141                                        # to starting position.
142
143    private variable _first ""     ;    # This is the topmost dataset.
144    private variable _start 0
145    private variable _isolines
146    private variable _contourList ""
147
148    common _downloadPopup;              # download options from popup
149    private common _hardcopy
150    private variable _width 0
151    private variable _height 0
152    private variable _legendWidth 0
153    private variable _legendHeight 0
154    private variable _resizePending 0
155    private variable _rotatePending 0
156    private variable _legendPending 0
157    private variable _fieldNames {}
158    private variable _fields
159    private variable _curFldName ""
160    private variable _curFldLabel ""
161    private variable _colorMode "scalar";#  Mode of colormap (vmag or scalar)
162}
163
164itk::usual VtkHeightmapViewer {
165    keep -background -foreground -cursor -font
166    keep -plotbackground -plotforeground -mode
167}
168
169# ----------------------------------------------------------------------
170# CONSTRUCTOR
171# ----------------------------------------------------------------------
172itcl::body Rappture::VtkHeightmapViewer::constructor {hostlist args} {
173    set _serverType "vtkvis"
174
175    EnableWaitDialog 900
176    # Rebuild event
177    $_dispatcher register !rebuild
178    $_dispatcher dispatch $this !rebuild "[itcl::code $this Rebuild]; list"
179
180    # Resize event
181    $_dispatcher register !resize
182    $_dispatcher dispatch $this !resize "[itcl::code $this DoResize]; list"
183
184    # Rotate event
185    $_dispatcher register !rotate
186    $_dispatcher dispatch $this !rotate "[itcl::code $this DoRotate]; list"
187
188    # Legend event
189    $_dispatcher register !legend
190    $_dispatcher dispatch $this !legend "[itcl::code $this RequestLegend]; list"
191
192    #
193    # Populate parser with commands handle incoming requests
194    #
195    $_parser alias image [itcl::code $this ReceiveImage]
196    $_parser alias dataset [itcl::code $this ReceiveDataset]
197    $_parser alias legend [itcl::code $this ReceiveLegend]
198
199    # Create image for legend colorbar.
200    set _image(legend) [image create photo]
201
202    # Initialize the view to some default parameters.
203    array set _view {
204        qw      0.36
205        qx      0.25
206        qy      0.50
207        qz      0.70
208        zoom    1.0
209        xpan    0
210        ypan    0
211        ortho   0
212    }
213    set _arcball [blt::arcball create 100 100]
214    set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
215    $_arcball quaternion $q
216
217    array set _settings {
218        axisFlymode             "static"
219        axisMinorTicks          1
220        stretchToFit            0
221        axisLabels              1
222        axisVisible             1
223        axisXGrid               0
224        axisYGrid               0
225        axisZGrid               0
226        colormapVisible         1
227        colormapDiscrete        0
228        edges                   0
229        field                   "Default"
230        heightmapScale          50
231        isHeightmap             0
232        isolineColor            black
233        isolinesVisible         1
234        legendVisible           1
235        lighting                1
236        saveLighting            1
237        numIsolines             10
238        opacity                 100
239        outline                 0
240        wireframe               0
241        saveOpacity             100
242        saveOutline             0
243    }
244    array set _changed {
245        opacity                 0
246        colormap                0
247        numIsolines             0
248    }
249    itk_component add view {
250        canvas $itk_component(plotarea).view \
251            -highlightthickness 0 -borderwidth 0
252    } {
253        usual
254        ignore -highlightthickness -borderwidth -background
255    }
256
257    itk_component add fieldmenu {
258        menu $itk_component(plotarea).menu \
259            -relief flat \
260            -tearoff no
261    } {
262        usual
263        ignore -background -foreground -relief -tearoff
264    }
265    set c $itk_component(view)
266    bind $c <Configure> [itcl::code $this EventuallyResize %w %h]
267    bind $c <4> [itcl::code $this Zoom in 0.25]
268    bind $c <5> [itcl::code $this Zoom out 0.25]
269    bind $c <KeyPress-Left>  [list %W xview scroll 10 units]
270    bind $c <KeyPress-Right> [list %W xview scroll -10 units]
271    bind $c <KeyPress-Up>    [list %W yview scroll 10 units]
272    bind $c <KeyPress-Down>  [list %W yview scroll -10 units]
273    bind $c <Enter> "focus %W"
274    bind $c <Control-F1> [itcl::code $this ToggleConsole]
275
276    # Fix the scrollregion in case we go off screen
277    $c configure -scrollregion [$c bbox all]
278
279    set _map(id) [$c create image 0 0 -anchor nw -image $_image(plot)]
280    set _map(cwidth) -1
281    set _map(cheight) -1
282    set _map(zoom) 1.0
283    set _map(original) ""
284
285    set f [$itk_component(main) component controls]
286    itk_component add reset {
287        button $f.reset -borderwidth 1 -padx 1 -pady 1 \
288            -highlightthickness 0 \
289            -image [Rappture::icon reset-view] \
290            -command [itcl::code $this CameraReset]
291    } {
292        usual
293        ignore -highlightthickness
294    }
295    pack $itk_component(reset) -side top -padx 2 -pady { 2 0 }
296    Rappture::Tooltip::for $itk_component(reset) "Reset the view to the default zoom level"
297
298    itk_component add zoomin {
299        button $f.zin -borderwidth 1 -padx 1 -pady 1 \
300            -highlightthickness 0 \
301            -image [Rappture::icon zoom-in] \
302            -command [itcl::code $this Zoom in]
303    } {
304        usual
305        ignore -highlightthickness
306    }
307    pack $itk_component(zoomin) -side top -padx 2 -pady { 2 0 }
308    Rappture::Tooltip::for $itk_component(zoomin) "Zoom in"
309
310    itk_component add zoomout {
311        button $f.zout -borderwidth 1 -padx 1 -pady 1 \
312            -highlightthickness 0 \
313            -image [Rappture::icon zoom-out] \
314            -command [itcl::code $this Zoom out]
315    } {
316        usual
317        ignore -highlightthickness
318    }
319    pack $itk_component(zoomout) -side top -padx 2 -pady { 2 0 }
320    Rappture::Tooltip::for $itk_component(zoomout) "Zoom out"
321
322    itk_component add mode {
323        Rappture::PushButton $f.mode \
324            -onimage [Rappture::icon surface] \
325            -offimage [Rappture::icon surface] \
326            -variable [itcl::scope _settings(isHeightmap)] \
327            -command [itcl::code $this AdjustSetting isHeightmap] \
328    }
329    Rappture::Tooltip::for $itk_component(mode) \
330        "Toggle the surface/contour on/off"
331    pack $itk_component(mode) -padx 2 -pady { 2 0 }
332
333    itk_component add stretchtofit {
334        Rappture::PushButton $f.stretchtofit \
335            -onimage [Rappture::icon stretchtofit] \
336            -offimage [Rappture::icon stretchtofit] \
337            -variable [itcl::scope _settings(stretchToFit)] \
338            -command [itcl::code $this AdjustSetting stretchToFit] \
339    }
340    Rappture::Tooltip::for $itk_component(stretchtofit) \
341        "Stretch plot to fit window on/off"
342    pack $itk_component(stretchtofit) -padx 2 -pady 2
343
344    if { [catch {
345        BuildContourTab
346        BuildAxisTab
347        BuildCameraTab
348    } errs] != 0 } {
349        global errorInfo
350        puts stderr "errs=$errs errorInfo=$errorInfo"
351    }
352
353    # Hack around the Tk panewindow.  The problem is that the requested
354    # size of the 3d view isn't set until an image is retrieved from
355    # the server.  So the panewindow uses the tiny size.
356    set w 10000
357    pack forget $itk_component(view)
358    blt::table $itk_component(plotarea) \
359        0,0 $itk_component(view) -fill both -reqwidth $w
360    blt::table configure $itk_component(plotarea) c1 -resize none
361
362    # Bindings for panning via mouse
363    bind $itk_component(view) <ButtonPress-2> \
364        [itcl::code $this Pan click %x %y]
365    bind $itk_component(view) <B2-Motion> \
366        [itcl::code $this Pan drag %x %y]
367    bind $itk_component(view) <ButtonRelease-2> \
368        [itcl::code $this Pan release %x %y]
369
370    #bind $itk_component(view) <ButtonRelease-3> \
371    #    [itcl::code $this Pick %x %y]
372
373    # Bindings for panning via keyboard
374    bind $itk_component(view) <KeyPress-Left> \
375        [itcl::code $this Pan set -10 0]
376    bind $itk_component(view) <KeyPress-Right> \
377        [itcl::code $this Pan set 10 0]
378    bind $itk_component(view) <KeyPress-Up> \
379        [itcl::code $this Pan set 0 -10]
380    bind $itk_component(view) <KeyPress-Down> \
381        [itcl::code $this Pan set 0 10]
382    bind $itk_component(view) <Shift-KeyPress-Left> \
383        [itcl::code $this Pan set -2 0]
384    bind $itk_component(view) <Shift-KeyPress-Right> \
385        [itcl::code $this Pan set 2 0]
386    bind $itk_component(view) <Shift-KeyPress-Up> \
387        [itcl::code $this Pan set 0 -2]
388    bind $itk_component(view) <Shift-KeyPress-Down> \
389        [itcl::code $this Pan set 0 2]
390
391    # Bindings for zoom via keyboard
392    bind $itk_component(view) <KeyPress-Prior> \
393        [itcl::code $this Zoom out]
394    bind $itk_component(view) <KeyPress-Next> \
395        [itcl::code $this Zoom in]
396
397    bind $itk_component(view) <Enter> "focus $itk_component(view)"
398
399    if {[string equal "x11" [tk windowingsystem]]} {
400        # Bindings for zoom via mouse
401        bind $itk_component(view) <4> [itcl::code $this Zoom out]
402        bind $itk_component(view) <5> [itcl::code $this Zoom in]
403    }
404
405    set _image(download) [image create photo]
406    eval itk_initialize $args
407    Connect
408    set _beforeConnect 0
409}
410
411# ----------------------------------------------------------------------
412# DESTRUCTOR
413# ----------------------------------------------------------------------
414itcl::body Rappture::VtkHeightmapViewer::destructor {} {
415    Disconnect
416    image delete $_image(plot)
417    image delete $_image(download)
418    catch { blt::arcball destroy $_arcball }
419}
420
421itcl::body Rappture::VtkHeightmapViewer::DoResize {} {
422    if { $_width < 2 } {
423        set _width 500
424    }
425    if { $_height < 2 } {
426        set _height 500
427    }
428    set _start [clock clicks -milliseconds]
429    SendCmd "screen size [expr $_width - 20] $_height"
430
431    set font "Arial 8"
432    set lh [font metrics $font -linespace]
433    set h [expr {$_height - 2 * ($lh + 2)}]
434    if { $h != $_legendHeight } {
435        EventuallyRequestLegend
436    } else {
437        DrawLegend
438    }
439    set _resizePending 0
440}
441
442itcl::body Rappture::VtkHeightmapViewer::DoRotate {} {
443    set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
444    SendCmd "camera orient $q"
445    set _rotatePending 0
446}
447
448itcl::body Rappture::VtkHeightmapViewer::EventuallyRequestLegend {} {
449    if { !$_legendPending } {
450        set _legendPending 1
451        $_dispatcher event -idle !legend
452    }
453}
454
455itcl::body Rappture::VtkHeightmapViewer::EventuallyResize { w h } {
456    set _width $w
457    set _height $h
458    $_arcball resize $w $h
459    if { !$_resizePending } {
460        set _resizePending 1
461        $_dispatcher event -after 250 !resize
462    }
463}
464
465set rotate_delay 100
466
467itcl::body Rappture::VtkHeightmapViewer::EventuallyRotate { q } {
468    foreach { _view(qw) _view(qx) _view(qy) _view(qz) } $q break
469    if { !$_rotatePending } {
470        set _rotatePending 1
471        global rotate_delay
472        $_dispatcher event -after $rotate_delay !rotate
473    }
474}
475
476# ----------------------------------------------------------------------
477# USAGE: add <dataobj> ?<settings>?
478#
479# Clients use this to add a data object to the plot.  The optional
480# <settings> are used to configure the plot.  Allowed settings are
481# -color, -brightness, -width, -linestyle, and -raise.
482# ----------------------------------------------------------------------
483itcl::body Rappture::VtkHeightmapViewer::add {dataobj {settings ""}} {
484    if { ![$dataobj isvalid] } {
485        return;                         # Object doesn't contain valid data.
486    }
487    array set params {
488        -color auto
489        -width 1
490        -linestyle solid
491        -brightness 0
492        -raise 0
493        -description ""
494        -param ""
495        -type ""
496    }
497    array set params $settings
498    set params(-description) ""
499    set params(-param) ""
500    array set params $settings
501
502    if {$params(-color) == "auto" || $params(-color) == "autoreset"} {
503        # can't handle -autocolors yet
504        set params(-color) white
505    }
506    set pos [lsearch -exact $_dlist $dataobj]
507    if {$pos < 0} {
508        lappend _dlist $dataobj
509    }
510    set _obj2ovride($dataobj-color) $params(-color)
511    set _obj2ovride($dataobj-width) $params(-width)
512    set _obj2ovride($dataobj-raise) $params(-raise)
513    $_dispatcher event -idle !rebuild
514}
515
516
517# ----------------------------------------------------------------------
518# USAGE: delete ?<dataobj1> <dataobj2> ...?
519#
520#       Clients use this to delete a dataobj from the plot.  If no dataobjs
521#       are specified, then all dataobjs are deleted.  No data objects are
522#       deleted.  They are only removed from the display list.
523#
524# ----------------------------------------------------------------------
525itcl::body Rappture::VtkHeightmapViewer::delete {args} {
526    if { [llength $args] == 0} {
527        set args $_dlist
528    }
529    # Delete all specified dataobjs
530    set changed 0
531    foreach dataobj $args {
532        set pos [lsearch -exact $_dlist $dataobj]
533        if { $pos < 0 } {
534            continue;                   # Don't know anything about it.
535        }
536        # Remove it from the dataobj list.
537        set _dlist [lreplace $_dlist $pos $pos]
538        array unset _obj2ovride $dataobj-*
539        array unset _settings $dataobj-*
540        set changed 1
541    }
542    # If anything changed, then rebuild the plot
543    if { $changed } {
544        $_dispatcher event -idle !rebuild
545    }
546}
547
548# ----------------------------------------------------------------------
549# USAGE: get ?-objects?
550# USAGE: get ?-visible?
551# USAGE: get ?-image view?
552#
553# Clients use this to query the list of objects being plotted, in
554# order from bottom to top of this result.  The optional "-image"
555# flag can also request the internal images being shown.
556# ----------------------------------------------------------------------
557itcl::body Rappture::VtkHeightmapViewer::get {args} {
558    if {[llength $args] == 0} {
559        set args "-objects"
560    }
561    set op [lindex $args 0]
562    switch -- $op {
563        "-objects" {
564            # put the dataobj list in order according to -raise options
565            set dlist {}
566            foreach dataobj $_dlist {
567                if { ![IsValidObject $dataobj] } {
568                    continue
569                }
570                if {[info exists _obj2ovride($dataobj-raise)] &&
571                    $_obj2ovride($dataobj-raise)} {
572                    set dlist [linsert $dlist 0 $dataobj]
573                } else {
574                    lappend dlist $dataobj
575                }
576            }
577            return $dlist
578        }
579        "-visible" {
580            set dlist {}
581            foreach dataobj $_dlist {
582                if { ![IsValidObject $dataobj] } {
583                    continue
584                }
585                if { ![info exists _obj2ovride($dataobj-raise)] } {
586                    # No setting indicates that the object isn't visible.
587                    continue
588                }
589                # Otherwise use the -raise parameter to put the object to
590                # the front of the list.
591                if { $_obj2ovride($dataobj-raise) } {
592                    set dlist [linsert $dlist 0 $dataobj]
593                } else {
594                    lappend dlist $dataobj
595                }
596            }
597            return $dlist
598        }           
599        -image {
600            if {[llength $args] != 2} {
601                error "wrong # args: should be \"get -image view\""
602            }
603            switch -- [lindex $args end] {
604                view {
605                    return $_image(plot)
606                }
607                default {
608                    error "bad image name \"[lindex $args end]\": should be view"
609                }
610            }
611        }
612        default {
613            error "bad option \"$op\": should be -objects or -image"
614        }
615    }
616}
617
618#
619# scale  --
620#
621#       This gets called either incrementally as new simulations are
622#       added or all at once as a sequence of heightmaps.
623#       This  accounts for all objects--even those not showing on the
624#       screen.  Because of this, the limits are appropriate for all
625#       objects as the user scans through data in the ResultSet viewer.
626#
627itcl::body Rappture::VtkHeightmapViewer::scale {args} {
628    foreach dataobj $args {
629        if { ![$dataobj isvalid] } {
630            continue;                   # Object doesn't contain valid data.
631        }
632        foreach axis { x y } {
633            set lim [$dataobj limits $axis]
634            if { ![info exists _limits($axis)] } {
635                set _limits($axis) $lim
636                continue
637            }
638            foreach {min max} $lim break
639            foreach {amin amax} $_limits($axis) break
640            if { $amin > $min } {
641                set amin $min
642            }
643            if { $amax < $max } {
644                set amax $max
645            }
646            set _limits($axis) [list $amin $amax]
647            set units [$dataobj hints ${axis}units]
648            set found($units) 1
649        }
650        foreach { fname lim } [$dataobj fieldlimits] {
651            if { ![info exists _limits($fname)] } {
652                set _limits($fname) $lim
653                continue
654            }
655            foreach {min max} $lim break
656            foreach {fmin fmax} $_limits($fname) break
657            if { $fmin > $min } {
658                set fmin $min
659            }
660            if { $fmax < $max } {
661                set fmax $max
662            }
663            set _limits($fname) [list $fmin $fmax]
664        }
665    }
666    if { [array size found] > 1 } {
667        set _settings(stretchToFit) 1
668    } else {
669        # Check if the range of the x and y axes requires that we stretch
670        # the contour to fit the plotting area.  This can happen when the
671        # x and y scales differ greatly (> 100x)
672        foreach {xmin xmax} $_limits(x) break
673        foreach {ymin ymax} $_limits(y) break
674        if { (($xmax - $xmin) > (($ymax -$ymin) * $_maxScale)) ||
675             ((($xmax - $xmin) * $_maxScale) < ($ymax -$ymin)) } {
676            set _settings(stretchToFit) 1
677        }
678    }
679}
680
681# ----------------------------------------------------------------------
682# USAGE: download coming
683# USAGE: download controls <downloadCommand>
684# USAGE: download now
685#
686# Clients use this method to create a downloadable representation
687# of the plot.  Returns a list of the form {ext string}, where
688# "ext" is the file extension (indicating the type of data) and
689# "string" is the data itself.
690# ----------------------------------------------------------------------
691itcl::body Rappture::VtkHeightmapViewer::download {option args} {
692    switch $option {
693        coming {
694            if {[catch {
695                blt::winop snap $itk_component(plotarea) $_image(download)
696            }]} {
697                $_image(download) configure -width 1 -height 1
698                $_image(download) put #000000
699            }
700        }
701        controls {
702            set popup .vtkviewerdownload
703            if { ![winfo exists .vtkviewerdownload] } {
704                set inner [BuildDownloadPopup $popup [lindex $args 0]]
705            } else {
706                set inner [$popup component inner]
707            }
708            set _downloadPopup(image_controls) $inner.image_frame
709            set num [llength [get]]
710            set num [expr {($num == 1) ? "1 result" : "$num results"}]
711            set word [Rappture::filexfer::label downloadWord]
712            $inner.summary configure -text "$word $num in the following format:"
713            update idletasks            ;# Fix initial sizes
714            return $popup
715        }
716        now {
717            set popup .vtkviewerdownload
718            if {[winfo exists .vtkviewerdownload]} {
719                $popup deactivate
720            }
721            switch -- $_downloadPopup(format) {
722                "image" {
723                    return [$this GetImage [lindex $args 0]]
724                }
725                "vtk" {
726                    return [$this GetVtkData [lindex $args 0]]
727                }
728            }
729            return ""
730        }
731        default {
732            error "bad option \"$option\": should be coming, controls, now"
733        }
734    }
735}
736
737# ----------------------------------------------------------------------
738# USAGE: Connect ?<host:port>,<host:port>...?
739#
740# Clients use this method to establish a connection to a new
741# server, or to reestablish a connection to the previous server.
742# Any existing connection is automatically closed.
743# ----------------------------------------------------------------------
744itcl::body Rappture::VtkHeightmapViewer::Connect {} {
745    global readyForNextFrame
746    set readyForNextFrame 1
747    set _reset 1
748    set _hosts [GetServerList "vtkvis"]
749    if { "" == $_hosts } {
750        return 0
751    }
752    set result [VisViewer::Connect $_hosts]
753    if { $result } {
754        if { $_reportClientInfo }  {
755            # Tell the server the viewer, hub, user and session.
756            # Do this immediately on connect before buffering any commands
757            global env
758
759            set info {}
760            set user "???"
761            if { [info exists env(USER)] } {
762                set user $env(USER)
763            }
764            set session "???"
765            if { [info exists env(SESSION)] } {
766                set session $env(SESSION)
767            }
768            lappend info "hub" [exec hostname]
769            lappend info "client" "vtkheightmapviewer"
770            lappend info "user" $user
771            lappend info "session" $session
772            SendCmd "clientinfo [list $info]"
773        }
774        set w [winfo width $itk_component(view)]
775        set h [winfo height $itk_component(view)]
776        EventuallyResize $w $h
777    }
778    return $result
779}
780
781#
782# isconnected --
783#
784#       Indicates if we are currently connected to the visualization server.
785#
786itcl::body Rappture::VtkHeightmapViewer::isconnected {} {
787    return [VisViewer::IsConnected]
788}
789
790#
791# disconnect --
792#
793itcl::body Rappture::VtkHeightmapViewer::disconnect {} {
794    Disconnect
795    set _reset 1
796}
797
798#
799# Disconnect --
800#
801#       Clients use this method to disconnect from the current rendering
802#       server.
803#
804itcl::body Rappture::VtkHeightmapViewer::Disconnect {} {
805    VisViewer::Disconnect
806
807    $_dispatcher cancel !rebuild
808    $_dispatcher cancel !resize
809    $_dispatcher cancel !rotate
810    $_dispatcher cancel !legend
811    # disconnected -- no more data sitting on server
812    array unset _datasets
813    array unset _data
814    array unset _colormaps
815    array unset _obj2datasets
816    global readyForNextFrame
817    set readyForNextFrame 1
818}
819
820# ----------------------------------------------------------------------
821# USAGE: ReceiveImage -bytes <size> -type <type> -token <token>
822#
823# Invoked automatically whenever the "image" command comes in from
824# the rendering server.  Indicates that binary image data with the
825# specified <size> will follow.
826# ----------------------------------------------------------------------
827itcl::body Rappture::VtkHeightmapViewer::ReceiveImage { args } {
828    global readyForNextFrame
829    set readyForNextFrame 1
830    array set info {
831        -token "???"
832        -bytes 0
833        -type image
834    }
835    array set info $args
836    set bytes [ReceiveBytes $info(-bytes)]
837    if { $info(-type) == "image" } {
838        if 0 {
839            set f [open "last.ppm" "w"]
840            puts $f $bytes
841            close $f
842        }
843        $_image(plot) configure -data $bytes
844        set time [clock seconds]
845        set date [clock format $time]
846        #puts stderr "$date: received image [image width $_image(plot)]x[image height $_image(plot)] image>"       
847        if { $_start > 0 } {
848            set finish [clock clicks -milliseconds]
849            #puts stderr "round trip time [expr $finish -$_start] milliseconds"
850            set _start 0
851        }
852    } elseif { $info(type) == "print" } {
853        set tag $this-print-$info(-token)
854        set _hardcopy($tag) $bytes
855    }
856}
857
858#
859# ReceiveDataset --
860#
861itcl::body Rappture::VtkHeightmapViewer::ReceiveDataset { args } {
862    if { ![isconnected] } {
863        return
864    }
865    set option [lindex $args 0]
866    switch -- $option {
867        "scalar" {
868            set option [lindex $args 1]
869            switch -- $option {
870                "world" {
871                    foreach { x y z value tag } [lrange $args 2 end] break
872                }
873                "pixel" {
874                    foreach { x y value tag } [lrange $args 2 end] break
875                }
876            }
877        }
878        "vector" {
879            set option [lindex $args 1]
880            switch -- $option {
881                "world" {
882                    foreach { x y z vx vy vz tag } [lrange $args 2 end] break
883                }
884                "pixel" {
885                    foreach { x y vx vy vz tag } [lrange $args 2 end] break
886                }
887            }
888        }
889        "names" {
890            foreach { name } [lindex $args 1] {
891                #puts stderr "Dataset: $name"
892            }
893        }
894        default {
895            error "unknown dataset option \"$option\" from server"
896        }
897    }
898}
899
900# ----------------------------------------------------------------------
901# USAGE: Rebuild
902#
903# Called automatically whenever something changes that affects the
904# data in the widget.  Clears any existing data and rebuilds the
905# widget to display new data.
906# ----------------------------------------------------------------------
907itcl::body Rappture::VtkHeightmapViewer::Rebuild {} {
908    set w [winfo width $itk_component(view)]
909    set h [winfo height $itk_component(view)]
910    if { $w < 2 || $h < 2 } {
911        $_dispatcher event -idle !rebuild
912        return
913    }
914
915    # Turn on buffering of commands to the server.  We don't want to
916    # be preempted by a server disconnect/reconnect (which automatically
917    # generates a new call to Rebuild).   
918    StartBufferingCommands
919
920    if { $_width != $w || $_height != $h || $_reset } {
921        set _width $w
922        set _height $h
923        $_arcball resize $w $h
924        DoResize
925        if { $_settings(stretchToFit) } {
926            AdjustSetting stretchToFit
927        }
928    }
929    if { $_reset } {
930        #
931        # Reset the camera and other view parameters
932        #
933        InitSettings isHeightmap background
934
935        # Let's see how this goes.  I think it's preferable to overloading the
936        # axis title with the exponent.
937        SendCmd "axis exp 0 0 0 1"
938
939        SendCmd "axis lrot z 90"
940        set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
941        $_arcball quaternion $q
942        if {$_settings(isHeightmap) } {
943            if { $_view(ortho)} {
944                SendCmd "camera mode ortho"
945            } else {
946                SendCmd "camera mode persp"
947            }
948            DoRotate
949            SendCmd "camera reset"
950        }
951        PanCamera
952        StopBufferingCommands
953        SendCmd "imgflush"
954        StartBufferingCommands
955    }
956
957    set _first ""
958    # Start off with no datasets are visible.
959    SendCmd "dataset visible 0"
960    set scale [GetHeightmapScale]
961    foreach dataobj [get -objects] {
962        if { [info exists _obj2ovride($dataobj-raise)] &&  $_first == "" } {
963            set _first $dataobj
964        }
965        set _obj2datasets($dataobj) ""
966        foreach comp [$dataobj components] {
967            set tag $dataobj-$comp
968            if { ![info exists _datasets($tag)] } {
969                set bytes [$dataobj vtkdata $comp]
970                if 0 {
971                    set f [open /tmp/vtkheightmap.vtk "w"]
972                    puts $f $bytes
973                    close $f
974                }
975                set length [string length $bytes]
976                if { $_reportClientInfo }  {
977                    set info {}
978                    lappend info "tool_id"       [$dataobj hints toolId]
979                    lappend info "tool_name"     [$dataobj hints toolName]
980                    lappend info "tool_version"  [$dataobj hints toolRevision]
981                    lappend info "tool_title"    [$dataobj hints toolTitle]
982                    lappend info "dataset_label" [$dataobj hints label]
983                    lappend info "dataset_size"  $length
984                    lappend info "dataset_tag"   $tag
985                    SendCmd [list "clientinfo" $info]
986                }
987                SendCmd "dataset add $tag data follows $length"
988                append _outbuf $bytes
989                set _datasets($tag) 1
990                SetObjectStyle $dataobj $comp
991            }
992            lappend _obj2datasets($dataobj) $tag
993            if { [info exists _obj2ovride($dataobj-raise)] } {
994                # Setting dataset visible enables outline
995                # and heightmap
996                SendCmd "dataset visible 1 $tag"
997            }
998            if { ![info exists _comp2scale($tag)] ||
999                 $_comp2scale($tag) != $scale } {
1000                SendCmd "heightmap heightscale $scale $tag"
1001                set _comp2scale($tag) $scale
1002            }
1003        }
1004    }
1005    if { $_first != ""  } {
1006        $itk_component(field) choices delete 0 end
1007        $itk_component(fieldmenu) delete 0 end
1008        array unset _fields
1009        set _curFldName ""
1010        foreach cname [$_first components] {
1011            foreach fname [$_first fieldnames $cname] {
1012                if { [info exists _fields($fname)] } {
1013                    continue
1014                }
1015                foreach { label units components } \
1016                    [$_first fieldinfo $fname] break
1017                $itk_component(field) choices insert end "$fname" "$label"
1018                $itk_component(fieldmenu) add radiobutton -label "$label" \
1019                    -value $label -variable [itcl::scope _curFldLabel] \
1020                    -selectcolor red \
1021                    -activebackground $itk_option(-plotbackground) \
1022                    -activeforeground $itk_option(-plotforeground) \
1023                    -font "Arial 8" \
1024                    -command [itcl::code $this Combo invoke]
1025                set _fields($fname) [list $label $units $components]
1026                if { $_curFldName == "" } {
1027                    set _curFldName $fname
1028                    set _curFldLabel $label
1029                }
1030            }
1031        }
1032        $itk_component(field) value $_curFldLabel
1033    }
1034    InitSettings stretchToFit outline
1035
1036    if { $_reset } {
1037        SendCmd "axis tickpos outside"
1038        foreach axis { x y z } {
1039            SendCmd "axis lformat $axis %g"
1040        }
1041       
1042        foreach axis { x y z } {
1043            if { $axis == "z" } {
1044                set label [$_first hints label]
1045            } else {
1046                set label [$_first hints ${axis}label]
1047            }
1048            if { $label == "" } {
1049                if {$axis == "z"} {
1050                    if { [string match "component*" $_curFldName] } {
1051                        set label [string toupper $axis]
1052                    } else {
1053                        set label $_curFldLabel
1054                    }
1055                } else {
1056                    set label [string toupper $axis]
1057                }
1058            }
1059            # May be a space in the axis label.
1060            SendCmd [list axis name $axis $label]
1061
1062            if {$axis == "z" && [$_first hints ${axis}units] == ""} {
1063                set units [lindex $_fields($_curFldName) 1]
1064            } else {
1065                set units [$_first hints ${axis}units]
1066            }
1067            if { $units != "" } {
1068                # May be a space in the axis units.
1069                SendCmd [list axis units $axis $units]
1070            }
1071        }
1072        #
1073        # Reset the camera and other view parameters
1074        #
1075        ResetAxes
1076        set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
1077        $_arcball quaternion $q
1078        if {$_settings(isHeightmap) } {
1079            if { $_view(ortho)} {
1080                SendCmd "camera mode ortho"
1081            } else {
1082                SendCmd "camera mode persp"
1083            }
1084            DoRotate
1085            SendCmd "camera reset"
1086        }
1087        PanCamera
1088        InitSettings axisXGrid axisYGrid axisZGrid \
1089            axisVisible axisLabels heightmapScale field isHeightmap \
1090            numIsolines
1091        if { [array size _fields] < 2 } {
1092            blt::table forget $itk_component(field) $itk_component(field_l)
1093        }
1094        RequestLegend
1095        set _reset 0
1096    }
1097    global readyForNextFrame
1098    set readyForNextFrame 0;            # Don't advance to the next frame
1099
1100    # Actually write the commands to the server socket.  If it fails, we don't
1101    # care.  We're finished here.
1102    blt::busy hold $itk_component(hull)
1103    StopBufferingCommands
1104    blt::busy release $itk_component(hull)
1105}
1106
1107# ----------------------------------------------------------------------
1108# USAGE: CurrentDatasets ?-all -visible? ?dataobjs?
1109#
1110# Returns a list of server IDs for the current datasets being displayed.  This
1111# is normally a single ID, but it might be a list of IDs if the current data
1112# object has multiple components.
1113# ----------------------------------------------------------------------
1114itcl::body Rappture::VtkHeightmapViewer::CurrentDatasets {args} {
1115    set flag [lindex $args 0]
1116    switch -- $flag {
1117        "-all" {
1118            if { [llength $args] > 1 } {
1119                error "CurrentDatasets: can't specify dataobj after \"-all\""
1120            }
1121            set dlist [get -objects]
1122        }
1123        "-visible" {
1124            if { [llength $args] > 1 } {
1125                set dlist {}
1126                set args [lrange $args 1 end]
1127                foreach dataobj $args {
1128                    if { [info exists _obj2ovride($dataobj-raise)] } {
1129                        lappend dlist $dataobj
1130                    }
1131                }
1132            } else {
1133                set dlist [get -visible]
1134            }
1135        }           
1136        default {
1137            set dlist $args
1138        }
1139    }
1140    set rlist ""
1141    foreach dataobj $dlist {
1142        foreach comp [$dataobj components] {
1143            set tag $dataobj-$comp
1144            if { [info exists _datasets($tag)] && $_datasets($tag) } {
1145                lappend rlist $tag
1146            }
1147        }
1148    }
1149    return $rlist
1150}
1151
1152itcl::body Rappture::VtkHeightmapViewer::CameraReset {} {
1153    array set _view {
1154        qw      0.36
1155        qx      0.25
1156        qy      0.50
1157        qz      0.70
1158        zoom    1.0
1159        xpan    0
1160        ypan    0
1161    }
1162    if { $_first != "" } {
1163        set location [$_first hints camera]
1164        if { $location != "" } {
1165            array set _view $location
1166        }
1167    }
1168    set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
1169    $_arcball quaternion $q
1170    if {$_settings(isHeightmap) } {
1171        DoRotate
1172    }
1173    SendCmd "camera reset"
1174}
1175
1176# ----------------------------------------------------------------------
1177# USAGE: Zoom in
1178# USAGE: Zoom out
1179# USAGE: Zoom reset
1180#
1181# Called automatically when the user clicks on one of the zoom
1182# controls for this widget.  Changes the zoom for the current view.
1183# ----------------------------------------------------------------------
1184itcl::body Rappture::VtkHeightmapViewer::Zoom {option} {
1185    switch -- $option {
1186        "in" {
1187            set _view(zoom) [expr {$_view(zoom)*1.25}]
1188            SendCmd "camera zoom $_view(zoom)"
1189        }
1190        "out" {
1191            set _view(zoom) [expr {$_view(zoom)*0.8}]
1192            SendCmd "camera zoom $_view(zoom)"
1193        }
1194        "reset" {
1195            array set _view {
1196                zoom    1.0
1197                xpan    0
1198                ypan    0
1199            }
1200            SendCmd "camera reset"
1201        }
1202    }
1203}
1204
1205itcl::body Rappture::VtkHeightmapViewer::PanCamera {} {
1206    set x $_view(xpan)
1207    set y $_view(ypan)
1208    SendCmd "camera pan $x $y"
1209}
1210
1211
1212# ----------------------------------------------------------------------
1213# USAGE: Rotate click <x> <y>
1214# USAGE: Rotate drag <x> <y>
1215# USAGE: Rotate release <x> <y>
1216#
1217# Called automatically when the user clicks/drags/releases in the
1218# plot area.  Moves the plot according to the user's actions.
1219# ----------------------------------------------------------------------
1220itcl::body Rappture::VtkHeightmapViewer::Rotate {option x y} {
1221    switch -- $option {
1222        "click" {
1223            $itk_component(view) configure -cursor fleur
1224            set _click(x) $x
1225            set _click(y) $y
1226        }
1227        "drag" {
1228            if {[array size _click] == 0} {
1229                Rotate click $x $y
1230            } else {
1231                set w [winfo width $itk_component(view)]
1232                set h [winfo height $itk_component(view)]
1233                if {$w <= 0 || $h <= 0} {
1234                    return
1235                }
1236
1237                if {[catch {
1238                    # this fails sometimes for no apparent reason
1239                    set dx [expr {double($x-$_click(x))/$w}]
1240                    set dy [expr {double($y-$_click(y))/$h}]
1241                }]} {
1242                    return
1243                }
1244                if { $dx == 0 && $dy == 0 } {
1245                    return
1246                }
1247                set q [$_arcball rotate $x $y $_click(x) $_click(y)]
1248                EventuallyRotate $q
1249                set _click(x) $x
1250                set _click(y) $y
1251            }
1252        }
1253        "release" {
1254            Rotate drag $x $y
1255            $itk_component(view) configure -cursor ""
1256            catch {unset _click}
1257        }
1258        default {
1259            error "bad option \"$option\": should be click, drag, release"
1260        }
1261    }
1262}
1263
1264itcl::body Rappture::VtkHeightmapViewer::Pick {x y} {
1265    foreach tag [CurrentDatasets -visible] {
1266        SendCmd "dataset getscalar pixel $x $y $tag"
1267    }
1268}
1269
1270# ----------------------------------------------------------------------
1271# USAGE: $this Pan click x y
1272#        $this Pan drag x y
1273#        $this Pan release x y
1274#
1275# Called automatically when the user clicks on one of the zoom
1276# controls for this widget.  Changes the zoom for the current view.
1277# ----------------------------------------------------------------------
1278itcl::body Rappture::VtkHeightmapViewer::Pan {option x y} {
1279    switch -- $option {
1280        "set" {
1281            set w [winfo width $itk_component(view)]
1282            set h [winfo height $itk_component(view)]
1283            set x [expr $x / double($w)]
1284            set y [expr $y / double($h)]
1285            set _view(xpan) [expr $_view(xpan) + $x]
1286            set _view(ypan) [expr $_view(ypan) + $y]
1287            PanCamera
1288            return
1289        }
1290        "click" {
1291            set _click(x) $x
1292            set _click(y) $y
1293            $itk_component(view) configure -cursor hand1
1294        }
1295        "drag" {
1296            if { ![info exists _click(x)] } {
1297                set _click(x) $x
1298            }
1299            if { ![info exists _click(y)] } {
1300                set _click(y) $y
1301            }
1302            set w [winfo width $itk_component(view)]
1303            set h [winfo height $itk_component(view)]
1304            set dx [expr ($_click(x) - $x)/double($w)]
1305            set dy [expr ($_click(y) - $y)/double($h)]
1306            set _click(x) $x
1307            set _click(y) $y
1308            set _view(xpan) [expr $_view(xpan) - $dx]
1309            set _view(ypan) [expr $_view(ypan) - $dy]
1310            PanCamera
1311        }
1312        "release" {
1313            Pan drag $x $y
1314            $itk_component(view) configure -cursor ""
1315        }
1316        default {
1317            error "unknown option \"$option\": should set, click, drag, or release"
1318        }
1319    }
1320}
1321
1322# ----------------------------------------------------------------------
1323# USAGE: InitSettings <what> ?<value>?
1324#
1325# Used internally to update rendering settings whenever parameters
1326# change in the popup settings panel.  Sends the new settings off
1327# to the back end.
1328# ----------------------------------------------------------------------
1329itcl::body Rappture::VtkHeightmapViewer::InitSettings { args } {
1330    foreach spec $args {
1331        if { [info exists _settings($_first-$spec)] } {
1332            # Reset global setting with dataobj specific setting
1333            set _settings($spec) $_settings($_first-$spec)
1334        }
1335        AdjustSetting $spec
1336    }
1337}
1338
1339#
1340# AdjustSetting --
1341#
1342#       Changes/updates a specific setting in the widget.  There are
1343#       usually user-setable option.  Commands are sent to the render
1344#       server.
1345#
1346itcl::body Rappture::VtkHeightmapViewer::AdjustSetting {what {value ""}} {
1347    if { $_beforeConnect } {
1348        return
1349    }
1350    switch -- $what {
1351        "axisFlymode" {
1352            set mode [$itk_component(axisflymode) value]
1353            set mode [$itk_component(axisflymode) translate $mode]
1354            set _settings($what) $mode
1355            SendCmd "axis flymode $mode"
1356        }
1357        "axisLabels" {
1358            set bool $_settings($what)
1359            SendCmd "axis labels all $bool"
1360        }
1361        "axisMinorTicks" {
1362            set bool $_settings($what)
1363            foreach axis { x y z } {
1364                SendCmd "axis minticks ${axis} $bool"
1365            }
1366        }
1367        "axisVisible" {
1368            set bool $_settings($what)
1369            SendCmd "axis visible all $bool"
1370        }
1371        "axisXGrid" - "axisYGrid" - "axisZGrid" {
1372            set axis [string tolower [string range $what 4 4]]
1373            set bool $_settings($what)
1374            SendCmd "axis grid $axis $bool"
1375        }
1376        "background" {
1377            set bg [$itk_component(background) value]
1378            array set fgcolors {
1379                "black" "white"
1380                "white" "black"
1381                "grey"  "black"
1382            }
1383            set fg $fgcolors($bg)
1384            configure -plotbackground $bg -plotforeground $fg
1385            $itk_component(view) delete "legend"
1386            SendCmd "screen bgcolor [Color2RGB $bg]"
1387            SendCmd "outline color [Color2RGB $fg]"
1388            SendCmd "axis color all [Color2RGB $fg]"
1389            DrawLegend
1390        }
1391        "colormap" {
1392            set _changed($what) 1
1393            StartBufferingCommands
1394            set color [$itk_component(colormap) value]
1395            set _settings($what) $color
1396            if { $color == "none" } {
1397                if { $_settings(colormapVisible) } {
1398                    SendCmd "heightmap surface 0"
1399                    set _settings(colormapVisible) 0
1400                }
1401            } else {
1402                if { !$_settings(colormapVisible) } {
1403                    SendCmd "heightmap surface 1"
1404                    set _settings(colormapVisible) 1
1405                }
1406                SetCurrentColormap $color
1407                if {$_settings(colormapDiscrete)} {
1408                    set numColors [expr $_settings(numIsolines) + 1]
1409                    SendCmd "colormap res $numColors $color"
1410                }
1411            }
1412            StopBufferingCommands
1413            EventuallyRequestLegend
1414        }
1415        "colormapVisible" {
1416            set bool $_settings($what)
1417            SendCmd "heightmap surface $bool"
1418        }
1419        "colormapDiscrete" {
1420            set bool $_settings($what)
1421            set numColors [expr $_settings(numIsolines) + 1]
1422            StartBufferingCommands
1423            if {$bool} {
1424                SendCmd "colormap res $numColors"
1425                # Discrete colormap requires preinterp on
1426                SendCmd "heightmap preinterp on"
1427            } else {
1428                SendCmd "colormap res default"
1429                # FIXME: add setting for preinterp (default on)
1430                SendCmd "heightmap preinterp on"
1431            }
1432            StopBufferingCommands
1433            EventuallyRequestLegend
1434        }
1435        "edges" {
1436            set bool $_settings($what)
1437            SendCmd "heightmap edges $bool"
1438        }
1439        "field" {
1440            set label [$itk_component(field) value]
1441            set fname [$itk_component(field) translate $label]
1442            set _settings($what) $fname
1443            if { [info exists _fields($fname)] } {
1444                foreach { label units components } $_fields($fname) break
1445                if { $components > 1 } {
1446                    set _colorMode vmag
1447                } else {
1448                    set _colorMode scalar
1449                }
1450                set _curFldName $fname
1451                set _curFldLabel $label
1452            } else {
1453                puts stderr "unknown field \"$fname\""
1454                return
1455            }
1456            set label [$_first hints label]
1457            if { $label == "" } {
1458                if { [string match "component*" $_curFldName] } {
1459                    set label Z
1460                } else {
1461                    set label $_curFldLabel
1462                }
1463            }
1464            # May be a space in the axis label.
1465            SendCmd [list axis name z $label]
1466
1467            if { [$_first hints zunits] == "" } {
1468                set units [lindex $_fields($_curFldName) 1]
1469            } else {
1470                set units [$_first hints zunits]
1471            }
1472            if { $units != "" } {
1473                # May be a space in the axis units.
1474                SendCmd [list axis units z $units]
1475            }
1476            # Get the new limits because the field changed.
1477            ResetAxes
1478            SendCmd "dataset scalar $_curFldName"
1479            SendCmd "heightmap colormode scalar $_curFldName"
1480            Zoom reset
1481            UpdateContourList
1482            DrawLegend
1483        }
1484        "heightmapScale" {
1485            if { $_settings(isHeightmap) } {
1486                set scale [GetHeightmapScale]
1487                # Have to set the datasets individually because we are
1488                # tracking them in _comp2scale.
1489                foreach dataset [CurrentDatasets -all] {
1490                    SendCmd "heightmap heightscale $scale $dataset"
1491                    set _comp2scale($dataset) $scale
1492                }
1493                ResetAxes
1494            }
1495        }
1496        "isHeightmap" {
1497            set bool $_settings($what)
1498            set c $itk_component(view)
1499            StartBufferingCommands
1500            # Fix heightmap scale: 0 for contours, 1 for heightmaps.
1501            if { $bool } {
1502                set _settings(heightmapScale) 50
1503                set _settings(opacity) $_settings(saveOpacity)
1504                set _settings(lighting) $_settings(saveLighting)
1505                set _settings(outline) 0
1506            } else {
1507                set _settings(heightmapScale) 0
1508                set _settings(lighting) 0
1509                set _settings(opacity) 100
1510                set _settings(outline)  $_settings(saveOutline)
1511            }
1512            AdjustSetting lighting
1513            AdjustSetting opacity
1514            AdjustSetting outline
1515            set scale [GetHeightmapScale]
1516            # Have to set the datasets individually because we are
1517            # tracking them in _comp2scale.
1518            foreach dataset [CurrentDatasets -all] {
1519                SendCmd "heightmap heightscale $scale $dataset"
1520                set _comp2scale($dataset) $scale
1521            }
1522            if { $bool } {
1523                $itk_component(lighting) configure -state normal
1524                $itk_component(opacity) configure -state normal
1525                $itk_component(scale) configure -state normal
1526                $itk_component(opacity_l) configure -state normal
1527                $itk_component(scale_l) configure -state normal
1528                $itk_component(outline) configure -state disabled
1529                if {$_view(ortho)} {
1530                    SendCmd "camera mode ortho"
1531                } else {
1532                    SendCmd "camera mode persp"
1533                }
1534            } else {
1535                $itk_component(lighting) configure -state disabled
1536                $itk_component(opacity) configure -state disabled
1537                $itk_component(scale) configure -state disabled
1538                $itk_component(opacity_l) configure -state disabled
1539                $itk_component(scale_l) configure -state disabled
1540                $itk_component(outline) configure -state normal
1541                SendCmd "camera mode image"
1542            }
1543            if {$_settings(stretchToFit)} {
1544                if {$scale == 0} {
1545                    SendCmd "camera aspect window"
1546                } else {
1547                    SendCmd "camera aspect square"
1548                }
1549            }
1550            ResetAxes
1551            if { $bool } {
1552                set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
1553                $_arcball quaternion $q
1554                SendCmd "camera orient $q"
1555            } else {
1556                bind $c <ButtonPress-1> {}
1557                bind $c <B1-Motion> {}
1558                bind $c <ButtonRelease-1> {}
1559            }
1560            Zoom reset
1561            # Fix the mouse bindings for rotation/panning and the
1562            # camera mode. Ideally we'd create a bindtag for these.
1563            if { $bool } {
1564                # Bindings for rotation via mouse
1565                bind $c <ButtonPress-1> \
1566                    [itcl::code $this Rotate click %x %y]
1567                bind $c <B1-Motion> \
1568                    [itcl::code $this Rotate drag %x %y]
1569                bind $c <ButtonRelease-1> \
1570                    [itcl::code $this Rotate release %x %y]
1571            }
1572            StopBufferingCommands
1573        }
1574        "isolineColor" {
1575            set color [$itk_component(isolinecolor) value]
1576            if { $color == "none" } {
1577                if { $_settings(isolinesVisible) } {
1578                    SendCmd "heightmap isolines 0"
1579                    set _settings(isolinesVisible) 0
1580                }
1581            } else {
1582                if { !$_settings(isolinesVisible) } {
1583                    SendCmd "heightmap isolines 1"
1584                    set _settings(isolinesVisible) 1
1585                }
1586                SendCmd "heightmap isolinecolor [Color2RGB $color]"
1587            }
1588            DrawLegend
1589        }
1590        "isolinesVisible" {
1591            set bool $_settings($what)
1592            SendCmd "heightmap isolines $bool"
1593            DrawLegend
1594        }
1595        "legendVisible" {
1596            if { !$_settings($what) } {
1597                $itk_component(view) delete legend
1598            }
1599            DrawLegend
1600        }
1601        "lighting" {
1602            if { $_settings(isHeightmap) } {
1603                set _settings(saveLighting) $_settings($what)
1604                set bool $_settings($what)
1605                SendCmd "heightmap lighting $bool"
1606            } else {
1607                SendCmd "heightmap lighting 0"
1608            }
1609        }
1610        "numIsolines" {
1611            set _settings($what) [$itk_component(numisolines) value]
1612            set _currentNumIsolines $_settings($what)
1613            UpdateContourList
1614            set _changed($what) 1
1615            SendCmd "heightmap contourlist [list $_contourList]"
1616            if {$_settings(colormapDiscrete)} {
1617                set numColors [expr $_settings($what) + 1]
1618                SendCmd "colormap res $numColors"
1619                EventuallyRequestLegend
1620            } else {
1621                DrawLegend
1622            }
1623        }
1624        "opacity" {
1625            set _changed($what) 1
1626            if { $_settings(isHeightmap) } {
1627                set _settings(saveOpacity) $_settings($what)
1628                set val $_settings($what)
1629                set sval [expr { 0.01 * double($val) }]
1630                SendCmd "heightmap opacity $sval"
1631            } else {
1632                SendCmd "heightmap opacity 1"
1633            }
1634        }
1635        "outline" {
1636            if { $_settings(isHeightmap) } {
1637                SendCmd "outline visible 0"
1638            } else {
1639                set _settings(saveOutline) $_settings($what)
1640                set bool $_settings($what)
1641                SendCmd "outline visible $bool"
1642            }
1643        }
1644        "stretchToFit" {
1645            set bool $_settings($what)
1646            if { $bool } {
1647                set heightScale [GetHeightmapScale]
1648                if {$heightScale == 0} {
1649                    SendCmd "camera aspect window"
1650                } else {
1651                    SendCmd "camera aspect square"
1652                }
1653            } else {
1654                SendCmd "camera aspect native"
1655            }
1656            Zoom reset
1657        }
1658        "wireframe" {
1659            set bool $_settings($what)
1660            SendCmd "heightmap wireframe $bool"
1661        }
1662        default {
1663            error "don't know how to fix $what"
1664        }
1665    }
1666}
1667
1668#
1669# RequestLegend --
1670#
1671#       Request a new legend from the server.  The size of the legend
1672#       is determined from the height of the canvas. 
1673#
1674# This should be called when
1675#       1.  A new current colormap is set.
1676#       2.  Window is resized.
1677#       3.  The limits of the data have changed.  (Just need a redraw).
1678#       4.  Number of isolines have changed. (Just need a redraw).
1679#       5.  Legend becomes visible (Just need a redraw).
1680#
1681itcl::body Rappture::VtkHeightmapViewer::RequestLegend {} {
1682    set _legendPending 0
1683    set font "Arial 8"
1684    set w 12
1685    set lineht [font metrics $font -linespace]
1686    # color ramp height = (canvas height) - (min and max value lines) - 2
1687    set h [expr {$_height - 2 * ($lineht + 2)}]
1688    set _legendHeight $h
1689
1690    set fname $_curFldName
1691    if { [string match "component*" $fname] } {
1692        set title ""
1693    } else {
1694        if { [info exists _fields($fname)] } {
1695            foreach { title units } $_fields($fname) break
1696            if { $units != "" } {
1697                set title [format "%s (%s)" $title $units]
1698            }
1699        } else {
1700            set title $fname
1701        }
1702    }
1703    # If there's a title too, substract one more line
1704    if { $title != "" } {
1705        incr h -$lineht
1706    }
1707    if { $h < 1 } {
1708        return
1709    }
1710    # Set the legend on the first heightmap dataset.
1711    if { $_currentColormap != ""  } {
1712        set cmap $_currentColormap
1713        SendCmd "legend $cmap scalar $_curFldName {} $w $h 0"
1714    }
1715}
1716
1717#
1718# ResetAxes --
1719#
1720#       Set axis z bounds and range
1721#
1722itcl::body Rappture::VtkHeightmapViewer::ResetAxes {} {
1723    if { ![info exists _limits($_curFldName)]} {
1724        SendCmd "dataset maprange all"
1725        SendCmd "axis autorange z on"
1726        SendCmd "axis autobounds z on"
1727        return
1728    }
1729    foreach { xmin xmax } $_limits(x) break
1730    foreach { ymin ymax } $_limits(y) break
1731    foreach { vmin vmax } $_limits($_curFldName) break
1732
1733    global tcl_precision
1734    set tcl_precision 17
1735    set xr [expr $xmax - $xmin]
1736    set yr [expr $ymax - $ymin]
1737    set vr [expr $vmax - $vmin]
1738    set r  [expr ($yr > $xr) ? $yr : $xr]
1739    if { $vr < 1.0e-17 } {
1740        set dataScale 1.0
1741    } else {
1742        set dataScale [expr $r / $vr]
1743    }
1744    set heightScale [GetHeightmapScale]
1745    set bmin [expr $heightScale * $dataScale * $vmin]
1746    set bmax [expr $heightScale * $dataScale * $vmax]
1747    if {$heightScale > 0} {
1748        set zpos [expr - $bmin]
1749        SendCmd "heightmap pos 0 0 $zpos"
1750    } else {
1751        SendCmd "heightmap pos 0 0 0"
1752    }
1753    set bmax [expr $bmax - $bmin]
1754    set bmin 0
1755    SendCmd "dataset maprange explicit $_limits($_curFldName) $_curFldName"
1756    SendCmd "axis bounds z $bmin $bmax"
1757    SendCmd "axis range z $_limits($_curFldName)"
1758}
1759
1760#
1761# SetCurrentColormap --
1762#
1763itcl::body Rappture::VtkHeightmapViewer::SetCurrentColormap { name } {
1764    # Keep track of the colormaps that we build.
1765    if { $name != "none" && ![info exists _colormaps($name)] } {
1766        BuildColormap $name
1767        set _colormaps($name) 1
1768    }
1769    set _currentColormap $name
1770    SendCmd "heightmap colormap $_currentColormap"
1771}
1772
1773
1774#
1775# BuildColormap --
1776#
1777#       Build the designated colormap on the server.
1778#
1779itcl::body Rappture::VtkHeightmapViewer::BuildColormap { name } {
1780    set cmap [ColorsToColormap $name]
1781    if { [llength $cmap] == 0 } {
1782        set cmap "0.0 0.0 0.0 0.0 1.0 1.0 1.0 1.0"
1783    }
1784    set wmap "0.0 1.0 1.0 1.0"
1785    SendCmd "colormap add $name { $cmap } { $wmap }"
1786}
1787
1788# ----------------------------------------------------------------------
1789# CONFIGURATION OPTION: -mode
1790# ----------------------------------------------------------------------
1791itcl::configbody Rappture::VtkHeightmapViewer::mode {
1792    switch -- $itk_option(-mode) {
1793        "heightmap" {
1794            set _settings(isHeightmap) 1
1795        }
1796        "contour" {
1797            set _settings(isHeightmap) 0
1798        }
1799        default {
1800            error "unknown mode settings \"$itk_option(-mode)\""
1801        }
1802    }
1803    if { !$_reset } {
1804        AdjustSetting isHeightmap
1805    }
1806}
1807
1808# ----------------------------------------------------------------------
1809# CONFIGURATION OPTION: -plotbackground
1810# ----------------------------------------------------------------------
1811itcl::configbody Rappture::VtkHeightmapViewer::plotbackground {
1812    if { [isconnected] } {
1813        set rgb [Color2RGB $itk_option(-plotbackground)]
1814        if { !$_reset } {
1815            SendCmd "screen bgcolor $rgb"
1816        }
1817        $itk_component(view) configure -background $itk_option(-plotbackground)
1818    }
1819}
1820
1821# ----------------------------------------------------------------------
1822# CONFIGURATION OPTION: -plotforeground
1823# ----------------------------------------------------------------------
1824itcl::configbody Rappture::VtkHeightmapViewer::plotforeground {
1825    if { [isconnected] } {
1826        set rgb [Color2RGB $itk_option(-plotforeground)]
1827        if { !$_reset } {
1828            SendCmd "outline color $rgb"
1829            SendCmd "axis color all $rgb"
1830        }
1831    }
1832}
1833
1834itcl::body Rappture::VtkHeightmapViewer::limits3 { dataobj } {
1835    lappend limits x [$dataobj limits x]
1836    lappend limits y [$dataobj limits y]
1837    if { [catch { $dataobj limits $_curFldName } vlim] != 0 } {
1838        set vlim [$dataobj limits v]
1839    }
1840    lappend limits v $vlim
1841    return $limits
1842}
1843
1844itcl::body Rappture::VtkHeightmapViewer::BuildContourTab {} {
1845
1846    set fg [option get $itk_component(hull) font Font]
1847    #set bfg [option get $itk_component(hull) boldFont Font]
1848
1849    set inner [$itk_component(main) insert end \
1850        -title "Contour/Surface Settings" \
1851        -icon [Rappture::icon contour2]]
1852    $inner configure -borderwidth 4
1853
1854    checkbutton $inner.legend \
1855        -text "Legend" \
1856        -variable [itcl::scope _settings(legendVisible)] \
1857        -command [itcl::code $this AdjustSetting legendVisible] \
1858        -font "Arial 9"
1859
1860    checkbutton $inner.wireframe \
1861        -text "Wireframe" \
1862        -variable [itcl::scope _settings(wireframe)] \
1863        -command [itcl::code $this AdjustSetting wireframe] \
1864        -font "Arial 9"
1865
1866    itk_component add lighting {
1867        checkbutton $inner.lighting \
1868            -text "Enable Lighting" \
1869            -variable [itcl::scope _settings(lighting)] \
1870            -command [itcl::code $this AdjustSetting lighting] \
1871            -font "Arial 9"
1872    } {
1873        ignore -font
1874    }
1875    checkbutton $inner.edges \
1876        -text "Edges" \
1877        -variable [itcl::scope _settings(edges)] \
1878        -command [itcl::code $this AdjustSetting edges] \
1879        -font "Arial 9"
1880
1881    itk_component add outline {
1882        checkbutton $inner.outline \
1883            -text "Outline" \
1884            -variable [itcl::scope _settings(outline)] \
1885            -command [itcl::code $this AdjustSetting outline] \
1886            -font "Arial 9"
1887    } {
1888        ignore -font
1889    }
1890    checkbutton $inner.stretch \
1891        -text "Stretch to fit" \
1892        -variable [itcl::scope _settings(stretchToFit)] \
1893        -command [itcl::code $this AdjustSetting stretchToFit] \
1894        -font "Arial 9"
1895
1896    checkbutton $inner.isolines \
1897        -text "Isolines" \
1898        -variable [itcl::scope _settings(isolinesVisible)] \
1899        -command [itcl::code $this AdjustSetting isolinesVisible] \
1900        -font "Arial 9"
1901
1902    checkbutton $inner.colormapDiscrete \
1903        -text "Discrete Colormap" \
1904        -variable [itcl::scope _settings(colormapDiscrete)] \
1905        -command [itcl::code $this AdjustSetting colormapDiscrete] \
1906        -font "Arial 9"
1907
1908    itk_component add field_l {
1909        label $inner.field_l -text "Field" -font "Arial 9"
1910    } {
1911        ignore -font
1912    }
1913    itk_component add field {
1914        Rappture::Combobox $inner.field -width 10 -editable no
1915    }
1916    bind $inner.field <<Value>> \
1917        [itcl::code $this AdjustSetting field]
1918
1919    label $inner.colormap_l -text "Colormap" -font "Arial 9"
1920    itk_component add colormap {
1921        Rappture::Combobox $inner.colormap -width 10 -editable no
1922    }
1923    $inner.colormap choices insert end [GetColormapList -includeNone]
1924    $itk_component(colormap) value "BCGYR"
1925    bind $inner.colormap <<Value>> \
1926        [itcl::code $this AdjustSetting colormap]
1927
1928    label $inner.isolinecolor_l -text "Isolines Color" -font "Arial 9"
1929    itk_component add isolinecolor {
1930        Rappture::Combobox $inner.isolinecolor -width 10 -editable no
1931    }
1932    $inner.isolinecolor choices insert end \
1933        "black"              "black"            \
1934        "blue"               "blue"             \
1935        "cyan"               "cyan"             \
1936        "green"              "green"            \
1937        "grey"               "grey"             \
1938        "magenta"            "magenta"          \
1939        "orange"             "orange"           \
1940        "red"                "red"              \
1941        "white"              "white"            \
1942        "none"               "none"
1943
1944    $itk_component(isolinecolor) value "black"
1945    bind $inner.isolinecolor <<Value>> \
1946        [itcl::code $this AdjustSetting isolineColor]
1947
1948    label $inner.background_l -text "Background Color" -font "Arial 9"
1949    itk_component add background {
1950        Rappture::Combobox $inner.background -width 10 -editable no
1951    }
1952    $inner.background choices insert end \
1953        "black"              "black"            \
1954        "white"              "white"            \
1955        "grey"               "grey"             
1956
1957    $itk_component(background) value "white"
1958    bind $inner.background <<Value>> [itcl::code $this AdjustSetting background]
1959
1960    itk_component add opacity_l {
1961        label $inner.opacity_l -text "Opacity" -font "Arial 9"
1962    } {
1963        ignore -font
1964    }
1965    itk_component add opacity {
1966        ::scale $inner.opacity -from 0 -to 100 -orient horizontal \
1967            -variable [itcl::scope _settings(opacity)] \
1968            -showvalue off \
1969            -command [itcl::code $this AdjustSetting opacity]
1970    }
1971    itk_component add scale_l {
1972        label $inner.scale_l -text "Scale" -font "Arial 9"
1973    } {
1974        ignore -font
1975    }
1976    itk_component add scale {
1977        ::scale $inner.scale -from 0 -to 100 -orient horizontal \
1978            -variable [itcl::scope _settings(heightmapScale)] \
1979            -showvalue off \
1980            -command [itcl::code $this AdjustSetting heightmapScale]
1981    }
1982    label $inner.numisolines_l -text "Number of Isolines" -font "Arial 9"
1983    itk_component add numisolines {
1984        Rappture::Spinint $inner.numisolines \
1985            -min 0 -max 50 -font "arial 9"
1986    }
1987    $itk_component(numisolines) value $_settings(numIsolines)
1988    bind $itk_component(numisolines) <<Value>> \
1989        [itcl::code $this AdjustSetting numIsolines]
1990
1991    frame $inner.separator1 -height 2 -relief sunken -bd 1
1992    frame $inner.separator2 -height 2 -relief sunken -bd 1
1993
1994    blt::table $inner \
1995        0,0 $inner.field_l -anchor w -pady 2 \
1996        0,1 $inner.field -anchor w -pady 2 -fill x \
1997        1,0 $inner.colormap_l -anchor w -pady 2  \
1998        1,1 $inner.colormap   -anchor w -pady 2 -fill x  \
1999        2,0 $inner.isolinecolor_l  -anchor w -pady 2  \
2000        2,1 $inner.isolinecolor    -anchor w -pady 2 -fill x  \
2001        3,0 $inner.background_l -anchor w -pady 2 \
2002        3,1 $inner.background -anchor w -pady 2  -fill x \
2003        4,0 $inner.numisolines_l -anchor w -pady 2 \
2004        4,1 $inner.numisolines -anchor w -pady 2 \
2005        5,0 $inner.stretch    -anchor w -pady 2 -cspan 2 \
2006        6,0 $inner.edges      -anchor w -pady 2 -cspan 2 \
2007        7,0 $inner.legend     -anchor w -pady 2 -cspan 2 \
2008        8,0 $inner.colormapDiscrete -anchor w -pady 2 -cspan 2 \
2009        9,0 $inner.wireframe  -anchor w -pady 2 -cspan 2\
2010        10,0 $inner.isolines   -anchor w -pady 2 -cspan 2 \
2011        11,0 $inner.separator1 -padx 2 -fill x -cspan 2 \
2012        12,0 $inner.outline    -anchor w -pady 2 -cspan 2 \
2013        13,0 $inner.separator2 -padx 2 -fill x -cspan 2 \
2014        14,0 $inner.lighting   -anchor w -pady 2 -cspan 2 \
2015        15,0 $inner.opacity_l -anchor w -pady 2 \
2016        15,1 $inner.opacity   -fill x   -pady 2 \
2017        16,0 $inner.scale_l   -anchor w -pady 2 -cspan 2 \
2018        16,1 $inner.scale     -fill x   -pady 2 -cspan 2 \
2019
2020    blt::table configure $inner r* c* -resize none
2021    blt::table configure $inner r17 c1 -resize expand
2022}
2023
2024itcl::body Rappture::VtkHeightmapViewer::BuildAxisTab {} {
2025
2026    set fg [option get $itk_component(hull) font Font]
2027    #set bfg [option get $itk_component(hull) boldFont Font]
2028
2029    set inner [$itk_component(main) insert end \
2030        -title "Axis Settings" \
2031        -icon [Rappture::icon axis2]]
2032    $inner configure -borderwidth 4
2033
2034    checkbutton $inner.visible \
2035        -text "Axes" \
2036        -variable [itcl::scope _settings(axisVisible)] \
2037        -command [itcl::code $this AdjustSetting axisVisible] \
2038        -font "Arial 9"
2039    checkbutton $inner.labels \
2040        -text "Axis Labels" \
2041        -variable [itcl::scope _settings(axisLabels)] \
2042        -command [itcl::code $this AdjustSetting axisLabels] \
2043        -font "Arial 9"
2044    label $inner.grid_l -text "Grid" -font "Arial 9"
2045    checkbutton $inner.xgrid \
2046        -text "X" \
2047        -variable [itcl::scope _settings(axisXGrid)] \
2048        -command [itcl::code $this AdjustSetting axisXGrid] \
2049        -font "Arial 9"
2050    checkbutton $inner.ygrid \
2051        -text "Y" \
2052        -variable [itcl::scope _settings(axisYGrid)] \
2053        -command [itcl::code $this AdjustSetting axisYGrid] \
2054        -font "Arial 9"
2055    checkbutton $inner.zgrid \
2056        -text "Z" \
2057        -variable [itcl::scope _settings(axisZGrid)] \
2058        -command [itcl::code $this AdjustSetting axisZGrid] \
2059        -font "Arial 9"
2060    checkbutton $inner.minorticks \
2061        -text "Minor Ticks" \
2062        -variable [itcl::scope _settings(axisMinorTicks)] \
2063        -command [itcl::code $this AdjustSetting axisMinorTicks] \
2064        -font "Arial 9"
2065
2066
2067    label $inner.mode_l -text "Mode" -font "Arial 9"
2068
2069    itk_component add axisflymode {
2070        Rappture::Combobox $inner.mode -width 10 -editable no
2071    }
2072    $inner.mode choices insert end \
2073        "static_triad"    "static" \
2074        "closest_triad"   "closest" \
2075        "furthest_triad"  "farthest" \
2076        "outer_edges"     "outer"         
2077    $itk_component(axisflymode) value "static"
2078    bind $inner.mode <<Value>> [itcl::code $this AdjustSetting axisFlymode]
2079
2080    blt::table $inner \
2081        0,0 $inner.visible -anchor w -cspan 4 \
2082        1,0 $inner.labels  -anchor w -cspan 4 \
2083        2,0 $inner.minorticks  -anchor w -cspan 4 \
2084        4,0 $inner.grid_l  -anchor w \
2085        4,1 $inner.xgrid   -anchor w \
2086        4,2 $inner.ygrid   -anchor w \
2087        4,3 $inner.zgrid   -anchor w \
2088        5,0 $inner.mode_l  -anchor w -padx { 2 0 } \
2089        5,1 $inner.mode    -fill x -cspan 3
2090
2091    blt::table configure $inner r* c* -resize none
2092    blt::table configure $inner r7 c6 -resize expand
2093    blt::table configure $inner r3 -height 0.125i
2094}
2095
2096
2097itcl::body Rappture::VtkHeightmapViewer::BuildCameraTab {} {
2098    set inner [$itk_component(main) insert end \
2099        -title "Camera Settings" \
2100        -icon [Rappture::icon camera]]
2101    $inner configure -borderwidth 4
2102
2103    label $inner.view_l -text "view" -font "Arial 9"
2104    set f [frame $inner.view]
2105    foreach side { front back left right top bottom } {
2106        button $f.$side  -image [Rappture::icon view$side] \
2107            -command [itcl::code $this SetOrientation $side]
2108        Rappture::Tooltip::for $f.$side "Change the view to $side"
2109        pack $f.$side -side left
2110    }
2111
2112    blt::table $inner \
2113        0,0 $inner.view_l -anchor e -pady 2 \
2114        0,1 $inner.view -anchor w -pady 2
2115
2116    set labels { qx qy qz qw xpan ypan zoom }
2117    set row 1
2118    foreach tag $labels {
2119        label $inner.${tag}label -text $tag -font "Arial 9"
2120        entry $inner.${tag} -font "Arial 9"  -bg white \
2121            -textvariable [itcl::scope _view($tag)]
2122        bind $inner.${tag} <Return> \
2123            [itcl::code $this camera set ${tag}]
2124        bind $inner.${tag} <KP_Enter> \
2125            [itcl::code $this camera set ${tag}]
2126        blt::table $inner \
2127            $row,0 $inner.${tag}label -anchor e -pady 2 \
2128            $row,1 $inner.${tag} -anchor w -pady 2
2129        blt::table configure $inner r$row -resize none
2130        incr row
2131    }
2132    checkbutton $inner.ortho \
2133        -text "Orthographic Projection" \
2134        -variable [itcl::scope _view(ortho)] \
2135        -command [itcl::code $this camera set ortho] \
2136        -font "Arial 9"
2137    blt::table $inner \
2138            $row,0 $inner.ortho -cspan 2 -anchor w -pady 2
2139    blt::table configure $inner r$row -resize none
2140    incr row
2141
2142    blt::table configure $inner c* r* -resize none
2143    blt::table configure $inner c2 -resize expand
2144    blt::table configure $inner r$row -resize expand
2145}
2146
2147#
2148#  camera --
2149#
2150itcl::body Rappture::VtkHeightmapViewer::camera {option args} {
2151    switch -- $option {
2152        "show" {
2153            puts [array get _view]
2154        }
2155        "set" {
2156            set who [lindex $args 0]
2157            set x $_view($who)
2158            set code [catch { string is double $x } result]
2159            if { $code != 0 || !$result } {
2160                return
2161            }
2162            switch -- $who {
2163                "ortho" {
2164                    if {$_view(ortho)} {
2165                        SendCmd "camera mode ortho"
2166                    } else {
2167                        SendCmd "camera mode persp"
2168                    }
2169                }
2170                "xpan" - "ypan" {
2171                    PanCamera
2172                }
2173                "qx" - "qy" - "qz" - "qw" {
2174                    set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
2175                    $_arcball quaternion $q
2176                    EventuallyRotate $q
2177                }
2178                "zoom" {
2179                    SendCmd "camera zoom $_view(zoom)"
2180                }
2181            }
2182        }
2183    }
2184}
2185
2186itcl::body Rappture::VtkHeightmapViewer::GetVtkData { args } {
2187    set bytes ""
2188    foreach dataobj [get] {
2189        foreach comp [$dataobj components] {
2190            set tag $dataobj-$comp
2191            set contents [$dataobj vtkdata $comp]
2192            append bytes "$contents\n"
2193        }
2194    }
2195    return [list .vtk $bytes]
2196}
2197
2198itcl::body Rappture::VtkHeightmapViewer::GetImage { args } {
2199    if { [image width $_image(download)] > 0 &&
2200         [image height $_image(download)] > 0 } {
2201        set bytes [$_image(download) data -format "jpeg -quality 100"]
2202        set bytes [Rappture::encoding::decode -as b64 $bytes]
2203        return [list .jpg $bytes]
2204    }
2205    return ""
2206}
2207
2208itcl::body Rappture::VtkHeightmapViewer::BuildDownloadPopup { popup command } {
2209    Rappture::Balloon $popup \
2210        -title "[Rappture::filexfer::label downloadWord] as..."
2211    set inner [$popup component inner]
2212    label $inner.summary -text "" -anchor w
2213    radiobutton $inner.vtk_button -text "VTK data file" \
2214        -variable [itcl::scope _downloadPopup(format)] \
2215        -font "Arial 9 " \
2216        -value vtk 
2217    Rappture::Tooltip::for $inner.vtk_button "Save as VTK data file."
2218    radiobutton $inner.image_button -text "Image File" \
2219        -variable [itcl::scope _downloadPopup(format)] \
2220        -font "Arial 9 " \
2221        -value image
2222    Rappture::Tooltip::for $inner.image_button \
2223        "Save as digital image."
2224
2225    button $inner.ok -text "Save" \
2226        -highlightthickness 0 -pady 2 -padx 3 \
2227        -command $command \
2228        -compound left \
2229        -image [Rappture::icon download]
2230
2231    button $inner.cancel -text "Cancel" \
2232        -highlightthickness 0 -pady 2 -padx 3 \
2233        -command [list $popup deactivate] \
2234        -compound left \
2235        -image [Rappture::icon cancel]
2236
2237    blt::table $inner \
2238        0,0 $inner.summary -cspan 2  \
2239        1,0 $inner.vtk_button -anchor w -cspan 2 -padx { 4 0 } \
2240        2,0 $inner.image_button -anchor w -cspan 2 -padx { 4 0 } \
2241        4,1 $inner.cancel -width .9i -fill y \
2242        4,0 $inner.ok -padx 2 -width .9i -fill y
2243    blt::table configure $inner r3 -height 4
2244    blt::table configure $inner r4 -pady 4
2245    raise $inner.image_button
2246    $inner.vtk_button invoke
2247    return $inner
2248}
2249
2250#
2251# SetObjectStyle --
2252#
2253#       Set the style of the heightmap/contour object.  This gets calls
2254#       for each dataset once as it is loaded.  It can overridden by
2255#       the user controls.
2256#
2257#
2258itcl::body Rappture::VtkHeightmapViewer::SetObjectStyle { dataobj comp } {
2259    # Parse style string.
2260    set tag $dataobj-$comp
2261    array set style {
2262        -color BCGYR
2263        -levels 10
2264        -opacity 1.0
2265    }
2266    set stylelist [$dataobj style $comp]
2267    if { $stylelist != "" } {
2268        array set style $stylelist
2269    }
2270    # This is too complicated.  We want to set the colormap, number of
2271    # isolines and opacity for the dataset.  They can be the default values,
2272    # the style hints loaded with the dataset, or set by user controls.  As
2273    # datasets get loaded, they first use the defaults that are overidden
2274    # by the style hints.  If the user changes the global controls, then that
2275    # overrides everything else.  I don't know what it means when global
2276    # controls are specified as style hints by each dataset.  It complicates
2277    # the code to handle aberrant cases.
2278
2279    if { $_changed(opacity) } {
2280        set style(-opacity) [expr $_settings(opacity) * 0.01]
2281    }
2282    if { $_changed(numIsolines) } {
2283        set style(-levels) $_settings(numIsolines)
2284    }
2285    if { $_changed(colormap) } {
2286        set style(-color) $_settings(colormap)
2287    }
2288    if { $_currentColormap == "" } {
2289        $itk_component(colormap) value $style(-color)
2290    }
2291    if { [info exists style(-stretchtofit)] } {
2292        set _settings(stretchToFit) $style(-stretchtofit)
2293        AdjustSetting stretchToFit
2294    }
2295    if { $_currentNumIsolines != $style(-levels) } {
2296        set _currentNumIsolines $style(-levels)
2297        set _settings(numIsolines) $_currentNumIsolines
2298        $itk_component(numisolines) value $_currentNumIsolines
2299        UpdateContourList
2300        DrawLegend
2301    }
2302    SendCmd "outline add $tag"
2303    SendCmd "outline color [Color2RGB $itk_option(-plotforeground)] $tag"
2304    SendCmd "outline visible $_settings(outline) $tag"
2305    set scale [GetHeightmapScale]
2306    SendCmd "[list heightmap add contourlist $_contourList $scale $tag]"
2307    set _comp2scale($tag) $_settings(heightmapScale)
2308    SendCmd "heightmap edges $_settings(edges) $tag"
2309    SendCmd "heightmap wireframe $_settings(wireframe) $tag"
2310    SetCurrentColormap $style(-color)
2311    set color [$itk_component(isolinecolor) value]
2312    SendCmd "heightmap isolinecolor [Color2RGB $color] $tag"
2313    SendCmd "heightmap lighting $_settings(isHeightmap) $tag"
2314    SendCmd "heightmap isolines $_settings(isolinesVisible) $tag"
2315    SendCmd "heightmap surface $_settings(colormapVisible) $tag"
2316    SendCmd "heightmap opacity $style(-opacity) $tag"
2317    set _settings(opacity) [expr $style(-opacity) * 100.0]
2318}
2319
2320itcl::body Rappture::VtkHeightmapViewer::IsValidObject { dataobj } {
2321    if {[catch {$dataobj isa Rappture::Field} valid] != 0 || !$valid} {
2322        return 0
2323    }
2324    return 1
2325}
2326
2327# ----------------------------------------------------------------------
2328# USAGE: ReceiveLegend <colormap> <title> <min> <max> <size>
2329#
2330# Invoked automatically whenever the "legend" command comes in from
2331# the rendering server.  Indicates that binary image data with the
2332# specified <size> will follow.
2333# ----------------------------------------------------------------------
2334itcl::body Rappture::VtkHeightmapViewer::ReceiveLegend { colormap title min max size } {
2335    #puts stderr "ReceiveLegend colormap=$colormap title=$title range=$min,$max size=$size"
2336    if { [isconnected] } {
2337        set bytes [ReceiveBytes $size]
2338        if { ![info exists _image(legend)] } {
2339            set _image(legend) [image create photo]
2340        }
2341        $_image(legend) configure -data $bytes
2342        #puts stderr "read $size bytes for [image width $_image(legend)]x[image height $_image(legend)] legend>"
2343        if { [catch {DrawLegend} errs] != 0 } {
2344            global errorInfo
2345            puts stderr "errs=$errs errorInfo=$errorInfo"
2346        }
2347    }
2348}
2349
2350#
2351# DrawLegend --
2352#
2353#       Draws the legend in the own canvas on the right side of the plot area.
2354#
2355itcl::body Rappture::VtkHeightmapViewer::DrawLegend {} {
2356    set fname $_curFldName
2357    set c $itk_component(view)
2358    set w [winfo width $c]
2359    set h [winfo height $c]
2360    set font "Arial 8"
2361    set lineht [font metrics $font -linespace]
2362   
2363    if { [string match "component*" $fname] } {
2364        set title ""
2365    } else {
2366        if { [info exists _fields($fname)] } {
2367            foreach { title units } $_fields($fname) break
2368            if { $units != "" } {
2369                set title [format "%s (%s)" $title $units]
2370            }
2371        } else {
2372            set title $fname
2373        }
2374    }
2375    set x [expr $w - 2]
2376    if { !$_settings(legendVisible) } {
2377        $c delete legend
2378        return
2379    }
2380    if { [$c find withtag "legend"] == "" } {
2381        set y 2
2382        # If there's a legend title, create a text item for the title.
2383        $c create text $x $y \
2384            -anchor ne \
2385            -fill $itk_option(-plotforeground) -tags "title legend" \
2386            -font $font
2387        if { $title != "" } {
2388            incr y $lineht
2389        }
2390        $c create text $x $y \
2391            -anchor ne \
2392            -fill $itk_option(-plotforeground) -tags "vmax legend" \
2393            -font $font
2394        incr y $lineht
2395        $c create image $x $y \
2396            -anchor ne \
2397            -image $_image(legend) -tags "colormap legend"
2398        $c create rectangle $x $y 1 1 \
2399            -fill "" -outline "" -tags "sensor legend"
2400        $c create text $x [expr {$h-2}] \
2401            -anchor se \
2402            -fill $itk_option(-plotforeground) -tags "vmin legend" \
2403            -font $font
2404        $c bind sensor <Enter> [itcl::code $this EnterLegend %x %y]
2405        $c bind sensor <Leave> [itcl::code $this LeaveLegend]
2406        $c bind sensor <Motion> [itcl::code $this MotionLegend %x %y]
2407    }
2408    $c delete isoline
2409    set x2 $x
2410    set iw [image width $_image(legend)]
2411    set ih [image height $_image(legend)]
2412    set x1 [expr $x2 - ($iw*12)/10]
2413    set color [$itk_component(isolinecolor) value]
2414
2415    # Draw the isolines on the legend.
2416    array unset _isolines
2417    if { $color != "none"  && [info exists _limits($_curFldName)] &&
2418         $_settings(isolinesVisible) && $_currentNumIsolines > 0 } {
2419
2420        foreach { vmin vmax } $_limits($_curFldName) break
2421        set range [expr double($vmax - $vmin)]
2422        if { $range <= 0.0 } {
2423            set range 1.0;              # Min is greater or equal to max.
2424        }
2425        set tags "isoline legend"
2426        set offset [expr 2 + $lineht]
2427        if { $title != "" } {
2428            incr offset $lineht
2429        }
2430        foreach value $_contourList {
2431            set norm [expr 1.0 - (($value - $vmin) / $range)]
2432            set y1 [expr int(round(($norm * $ih) + $offset))]
2433            for { set off 0 } { $off < 3 } { incr off } {
2434                set _isolines([expr $y1 + $off]) $value
2435                set _isolines([expr $y1 - $off]) $value
2436            }
2437            $c create line $x1 $y1 $x2 $y1 -fill $color -tags $tags
2438        }
2439    }
2440
2441    $c bind title <ButtonPress> [itcl::code $this Combo post]
2442    $c bind title <Enter> [itcl::code $this Combo activate]
2443    $c bind title <Leave> [itcl::code $this Combo deactivate]
2444    # Reset the item coordinates according the current size of the plot.
2445    if { [info exists _limits($_curFldName)] } {
2446        foreach { vmin vmax } $_limits($_curFldName) break
2447        $c itemconfigure vmin -text [format %g $vmin]
2448        $c itemconfigure vmax -text [format %g $vmax]
2449    }
2450    set y 2
2451    # If there's a legend title, move the title to the correct position
2452    if { $title != "" } {
2453        $c itemconfigure title -text $title
2454        $c coords title $x $y
2455        incr y $lineht
2456    }
2457    $c coords vmax $x $y
2458    incr y $lineht
2459    $c coords colormap $x $y
2460    $c coords sensor [expr $x - $iw] $y $x [expr $y + $ih]
2461    $c raise sensor
2462    $c coords vmin $x [expr {$h - 2}]
2463}
2464
2465#
2466# EnterLegend --
2467#
2468itcl::body Rappture::VtkHeightmapViewer::EnterLegend { x y } {
2469    SetLegendTip $x $y
2470}
2471
2472#
2473# MotionLegend --
2474#
2475itcl::body Rappture::VtkHeightmapViewer::MotionLegend { x y } {
2476    Rappture::Tooltip::tooltip cancel
2477    set c $itk_component(view)
2478    set cw [winfo width $c]
2479    set ch [winfo height $c]
2480    if { $x >= 0 && $x < $cw && $y >= 0 && $y < $ch } {
2481        SetLegendTip $x $y
2482    }
2483}
2484
2485#
2486# LeaveLegend --
2487#
2488itcl::body Rappture::VtkHeightmapViewer::LeaveLegend { } {
2489    Rappture::Tooltip::tooltip cancel
2490    .rappturetooltip configure -icon ""
2491}
2492
2493#
2494# SetLegendTip --
2495#
2496itcl::body Rappture::VtkHeightmapViewer::SetLegendTip { x y } {
2497    set fname $_curFldName
2498    set c $itk_component(view)
2499    set w [winfo width $c]
2500    set h [winfo height $c]
2501    set font "Arial 8"
2502    set lineht [font metrics $font -linespace]
2503   
2504    set ih [image height $_image(legend)]
2505    # Subtract off the offset of the color ramp from the top of the canvas
2506    set iy [expr $y - ($lineht + 2)]
2507
2508    if { [string match "component*" $fname] } {
2509        set title ""
2510    } else {
2511        if { [info exists _fields($fname)] } {
2512            foreach { title units } $_fields($fname) break
2513            if { $units != "" } {
2514                set title [format "%s (%s)" $title $units]
2515            }
2516        } else {
2517            set title $fname
2518        }
2519    }
2520    # If there's a legend title, increase the offset by the line height.
2521    if { $title != "" } {
2522        incr iy -$lineht
2523    }
2524
2525    # Make a swatch of the selected color
2526    if { [catch { $_image(legend) get 10 $iy } pixel] != 0 } {
2527        return
2528    }
2529
2530    if { ![info exists _image(swatch)] } {
2531        set _image(swatch) [image create photo -width 24 -height 24]
2532    }
2533    set color [eval format "\#%02x%02x%02x" $pixel]
2534    $_image(swatch) put black  -to 0 0 23 23
2535    $_image(swatch) put $color -to 1 1 22 22
2536
2537    # Compute the value of the point
2538    if { [info exists _limits($fname)] } {
2539        foreach { vmin vmax } $_limits($fname) break
2540        set t [expr 1.0 - (double($iy) / double($ih-1))]
2541        set value [expr $t * ($vmax - $vmin) + $vmin]
2542    } else {
2543        set value 0.0
2544    }
2545    set tipx [expr $x + 15]
2546    set tipy [expr $y - 5]
2547    .rappturetooltip configure -icon $_image(swatch)
2548    if { [info exists _isolines($y)] } {
2549        Rappture::Tooltip::text $c [format "$title %g (isoline)" $_isolines($y)]
2550    } else {
2551        Rappture::Tooltip::text $c [format "$title %g" $value]
2552    }
2553    Rappture::Tooltip::tooltip show $c +$tipx,+$tipy   
2554}
2555
2556# ----------------------------------------------------------------------
2557# USAGE: _dropdown post
2558# USAGE: _dropdown unpost
2559# USAGE: _dropdown select
2560#
2561# Used internally to handle the dropdown list for this combobox.  The
2562# post/unpost options are invoked when the list is posted or unposted
2563# to manage the relief of the controlling button.  The select option
2564# is invoked whenever there is a selection from the list, to assign
2565# the value back to the gauge.
2566# ----------------------------------------------------------------------
2567itcl::body Rappture::VtkHeightmapViewer::Combo {option} {
2568    set c $itk_component(view)
2569    switch -- $option {
2570        post {
2571            foreach { x1 y1 x2 y2 } [$c bbox title] break
2572            set x1 [expr [winfo width $itk_component(view)] - [winfo reqwidth $itk_component(fieldmenu)]]
2573            set x [expr $x1 + [winfo rootx $itk_component(view)]]
2574            set y [expr $y2 + [winfo rooty $itk_component(view)]]
2575            tk_popup $itk_component(fieldmenu) $x $y
2576        }
2577        activate {
2578            $c itemconfigure title -fill red
2579        }
2580        deactivate {
2581            $c itemconfigure title -fill $itk_option(-plotforeground)
2582        }
2583        invoke {
2584            $itk_component(field) value $_curFldLabel
2585            AdjustSetting field
2586        }
2587        default {
2588            error "bad option \"$option\": should be post, unpost, select"
2589        }
2590    }
2591}
2592
2593itcl::body Rappture::VtkHeightmapViewer::GetHeightmapScale {} {
2594    if {  $_settings(isHeightmap) } {
2595        set val $_settings(heightmapScale)
2596        set sval [expr { $val >= 50 ? double($val)/50.0 : 1.0/(2.0-(double($val)/50.0)) }]
2597        return $sval
2598    }
2599    return 0
2600}
2601
2602itcl::body Rappture::VtkHeightmapViewer::SetOrientation { side } {
2603    array set positions {
2604        front  "0.707107 0.707107 0 0"
2605        back   "0 0 0.707107 0.707107"
2606        left   "0.5 0.5 -0.5 -0.5"
2607        right  "0.5 0.5 0.5 0.5"
2608        top    "1 0 0 0"
2609        bottom "0 1 0 0"
2610    }
2611    foreach name { qw qx qy qz } value $positions($side) {
2612        set _view($name) $value
2613    }
2614    set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
2615    $_arcball quaternion $q
2616    SendCmd "camera orient $q"
2617    SendCmd "camera reset"
2618    set _view(xpan) 0
2619    set _view(ypan) 0
2620    set _view(zoom) 1.0
2621}
2622
2623itcl::body Rappture::VtkHeightmapViewer::UpdateContourList {} {
2624    if {$_currentNumIsolines == 0} {
2625        set _contourList ""
2626        return
2627    }
2628    if { ![info exists _limits($_curFldName)] } {
2629        return
2630    }
2631    foreach { vmin vmax } $_limits($_curFldName) break
2632    set v [blt::vector create \#auto]
2633    $v seq $vmin $vmax [expr $_currentNumIsolines+2]
2634    $v delete end 0
2635    set _contourList [$v range 0 end]
2636    blt::vector destroy $v
2637}
Note: See TracBrowser for help on using the repository browser.