source: trunk/gui/scripts/vtkimageviewer.tcl @ 4381

Last change on this file since 4381 was 4381, checked in by ldelgass, 7 years ago

opacity style setting fixes for VTK viewers (expect vtkvolumeviewer which does
not yet support the style setting). Also note that nanovisviewer (and
flowvisviewer?) have a regression which changes the -opacity style to [0,100]
instead of [0,1]

File size: 77.1 KB
Line 
1# -*- mode: tcl; indent-tabs-mode: nil -*-
2# ----------------------------------------------------------------------
3#  COMPONENT: vtkimageviewer - Vtk image viewer
4#
5#  It connects to the Vtk server running on a rendering farm,
6#  transmits data, and displays the results.
7# ======================================================================
8#  AUTHOR:  Michael McLennan, Purdue University
9#  Copyright (c) 2004-2014  HUBzero Foundation, LLC
10#
11#  See the file "license.terms" for information on usage and
12#  redistribution of this file, and for a DISCLAIMER OF ALL WARRANTIES.
13# ======================================================================
14package require Itk
15package require BLT
16#package require Img
17
18option add *VtkImageViewer.width 4i widgetDefault
19option add *VtkImageViewer*cursor crosshair widgetDefault
20option add *VtkImageViewer.height 4i widgetDefault
21option add *VtkImageViewer.foreground black widgetDefault
22option add *VtkImageViewer.controlBackground gray widgetDefault
23option add *VtkImageViewer.controlDarkBackground #999999 widgetDefault
24option add *VtkImageViewer.plotBackground black widgetDefault
25option add *VtkImageViewer.plotForeground white widgetDefault
26option add *VtkImageViewer.font \
27    -*-helvetica-medium-r-normal-*-12-* widgetDefault
28
29# must use this name -- plugs into Rappture::resources::load
30proc VtkImageViewer_init_resources {} {
31    Rappture::resources::register \
32        vtkvis_server Rappture::VtkImageViewer::SetServerList
33}
34
35itcl::class Rappture::VtkImageViewer {
36    inherit Rappture::VisViewer
37
38    itk_option define -plotforeground plotForeground Foreground ""
39    itk_option define -plotbackground plotBackground Background ""
40    itk_option define -mode mode Mode "vtkimage"
41
42    constructor { hostlist args } {
43        Rappture::VisViewer::constructor $hostlist
44    } {
45        # defined below
46    }
47    destructor {
48        # defined below
49    }
50    public proc SetServerList { namelist } {
51        Rappture::VisViewer::SetServerList "vtkvis" $namelist
52    }
53    public method add {dataobj {settings ""}}
54    public method camera {option args}
55    public method delete {args}
56    public method disconnect {}
57    public method download {option args}
58    public method get {args}
59    public method isconnected {}
60    public method limits3 { dataobj }
61    public method parameters {title args} {
62        # do nothing
63    }
64    public method scale {args}
65
66    protected method Connect {}
67    protected method CurrentDatasets {args}
68    protected method Disconnect {}
69    protected method DoResize {}
70    protected method DoRotate {}
71    protected method AdjustSetting {what {value ""}}
72    protected method AdjustMode {}
73    protected method InitSettings { args  }
74    protected method Pan {option x y}
75    protected method Pick {x y}
76    protected method Rebuild {}
77    protected method ReceiveDataset { args }
78    protected method ReceiveImage { args }
79    protected method ReceiveLegend { colormap title min max size }
80    protected method Rotate {option x y}
81    protected method Zoom {option}
82
83    # The following methods are only used by this class.
84    private method BuildAxisTab {}
85    private method BuildCameraTab {}
86    private method BuildColormap { name }
87    private method BuildImageTab {}
88    private method BuildDownloadPopup { widget command }
89    private method Combo { option }
90    private method DrawLegend {}
91    private method EnterLegend { x y }
92    private method EventuallyRequestLegend {}
93    private method EventuallyResize { w h }
94    private method EventuallyRotate { q }
95    private method GetImage { args }
96    private method GetVtkData { args }
97    private method IsValidObject { dataobj }
98    private method LeaveLegend {}
99    private method MotionLegend { x y }
100    private method PanCamera {}
101    private method RequestLegend {}
102    private method SetCurrentColormap { color }
103    private method SetLegendTip { x y }
104    private method SetObjectStyle { dataobj comp }
105    private method SetOrientation { side }
106
107    private variable _arcball ""
108    private variable _dlist ""     ;    # list of data objects
109    private variable _obj2datasets
110    private variable _obj2ovride   ;    # maps dataobj => style override
111    private variable _datasets     ;    # contains all the dataobj-component
112                                   ;    # datasets in the server
113    private variable _colormaps    ;    # contains all the colormaps
114                                   ;    # in the server.
115
116    # The name of the current colormap used.  The colormap is global to all
117    # images displayed.
118    private variable _currentColormap ""
119    private variable _currentNumIsolines -1
120
121    private variable _maxScale 100;     # This is the # of times the x-axis
122                                        # and y-axis ranges can differ before
123                                        # automatically turning on
124                                        # -stretchtofit
125
126    private variable _click        ;    # info used for rotate operations
127    private variable _limits       ;    # Holds overall limits for all dataobjs
128                                        # using the viewer.
129    private variable _view         ;    # view params for 3D view
130    private variable _settings
131    private variable _changed
132    private variable _initialStyle "";  # First found style in dataobjects.
133    private variable _reset 1;          # Indicates if camera needs to be reset
134                                        # to starting position.
135    private variable _beforeConnect 1;  # Indicates if camera needs to be reset
136                                        # to starting position.
137
138    private variable _first ""     ;    # This is the topmost dataset.
139    private variable _start 0
140    private variable _isolines
141    private variable _contourList ""
142
143    common _downloadPopup;              # download options from popup
144    private common _hardcopy
145    private variable _width 0
146    private variable _height 0
147    private variable _legendWidth 0
148    private variable _legendHeight 0
149    private variable _resizePending 0
150    private variable _rotatePending 0
151    private variable _legendPending 0
152    private variable _fieldNames {}
153    private variable _fields
154    private variable _curFldName ""
155    private variable _curFldLabel ""
156    private variable _colorMode "scalar";#  Mode of colormap (vmag or scalar)
157}
158
159itk::usual VtkImageViewer {
160    keep -background -foreground -cursor -font
161    keep -plotbackground -plotforeground -mode
162}
163
164# ----------------------------------------------------------------------
165# CONSTRUCTOR
166# ----------------------------------------------------------------------
167itcl::body Rappture::VtkImageViewer::constructor {hostlist args} {
168    set _serverType "vtkvis"
169
170    EnableWaitDialog 900
171    # Rebuild event
172    $_dispatcher register !rebuild
173    $_dispatcher dispatch $this !rebuild "[itcl::code $this Rebuild]; list"
174
175    # Resize event
176    $_dispatcher register !resize
177    $_dispatcher dispatch $this !resize "[itcl::code $this DoResize]; list"
178
179    # Rotate event
180    $_dispatcher register !rotate
181    $_dispatcher dispatch $this !rotate "[itcl::code $this DoRotate]; list"
182
183    # Legend event
184    $_dispatcher register !legend
185    $_dispatcher dispatch $this !legend "[itcl::code $this RequestLegend]; list"
186
187    #
188    # Populate parser with commands handle incoming requests
189    #
190    $_parser alias image [itcl::code $this ReceiveImage]
191    $_parser alias dataset [itcl::code $this ReceiveDataset]
192    $_parser alias legend [itcl::code $this ReceiveLegend]
193
194    # Create image for legend colorbar.
195    set _image(legend) [image create photo]
196
197    # Initialize the view to some default parameters.
198    array set _view {
199        qw      0.36
200        qx      0.25
201        qy      0.50
202        qz      0.70
203        zoom    1.0
204        xpan    0
205        ypan    0
206        ortho   0
207    }
208    set _arcball [blt::arcball create 100 100]
209    set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
210    $_arcball quaternion $q
211
212    array set _settings {
213        axisFlymode             "static"
214        axisLabels              1
215        axisMinorTicks          1
216        axisVisible             1
217        axisXGrid               0
218        axisYGrid               0
219        axisZGrid               0
220        backingColor            white
221        backingVisible          1
222        colormapDiscrete        0
223        field                   "Default"
224        legendVisible           0
225        level                   127.5
226        numColors               256
227        opacity                 100
228        outline                 0
229        saveOpacity             100
230        stretchToFit            0
231        view3D                  0
232        window                  255.0
233    }
234    array set _changed {
235        opacity                 0
236        colormap                0
237    }
238    itk_component add view {
239        canvas $itk_component(plotarea).view \
240            -highlightthickness 0 -borderwidth 0
241    } {
242        usual
243        ignore -highlightthickness -borderwidth -background
244    }
245
246    itk_component add fieldmenu {
247        menu $itk_component(plotarea).menu \
248            -relief flat \
249            -tearoff no
250    } {
251        usual
252        ignore -background -foreground -relief -tearoff
253    }
254    set c $itk_component(view)
255    bind $c <Configure> [itcl::code $this EventuallyResize %w %h]
256    bind $c <4> [itcl::code $this Zoom in 0.25]
257    bind $c <5> [itcl::code $this Zoom out 0.25]
258    bind $c <KeyPress-Left>  [list %W xview scroll 10 units]
259    bind $c <KeyPress-Right> [list %W xview scroll -10 units]
260    bind $c <KeyPress-Up>    [list %W yview scroll 10 units]
261    bind $c <KeyPress-Down>  [list %W yview scroll -10 units]
262    bind $c <Enter> "focus %W"
263    bind $c <Control-F1> [itcl::code $this ToggleConsole]
264
265    # Fix the scrollregion in case we go off screen
266    $c configure -scrollregion [$c bbox all]
267
268    set _map(id) [$c create image 0 0 -anchor nw -image $_image(plot)]
269    set _map(cwidth) -1
270    set _map(cheight) -1
271    set _map(zoom) 1.0
272    set _map(original) ""
273
274    set f [$itk_component(main) component controls]
275    itk_component add reset {
276        button $f.reset -borderwidth 1 -padx 1 -pady 1 \
277            -highlightthickness 0 \
278            -image [Rappture::icon reset-view] \
279            -command [itcl::code $this Zoom reset]
280    } {
281        usual
282        ignore -highlightthickness
283    }
284    pack $itk_component(reset) -side top -padx 2 -pady { 2 0 }
285    Rappture::Tooltip::for $itk_component(reset) "Reset the view to the default zoom level"
286
287    itk_component add zoomin {
288        button $f.zin -borderwidth 1 -padx 1 -pady 1 \
289            -highlightthickness 0 \
290            -image [Rappture::icon zoom-in] \
291            -command [itcl::code $this Zoom in]
292    } {
293        usual
294        ignore -highlightthickness
295    }
296    pack $itk_component(zoomin) -side top -padx 2 -pady { 2 0 }
297    Rappture::Tooltip::for $itk_component(zoomin) "Zoom in"
298
299    itk_component add zoomout {
300        button $f.zout -borderwidth 1 -padx 1 -pady 1 \
301            -highlightthickness 0 \
302            -image [Rappture::icon zoom-out] \
303            -command [itcl::code $this Zoom out]
304    } {
305        usual
306        ignore -highlightthickness
307    }
308    pack $itk_component(zoomout) -side top -padx 2 -pady { 2 0 }
309    Rappture::Tooltip::for $itk_component(zoomout) "Zoom out"
310
311    itk_component add mode {
312        Rappture::PushButton $f.mode \
313            -onimage [Rappture::icon surface] \
314            -offimage [Rappture::icon surface] \
315            -variable [itcl::scope _settings(view3D)] \
316            -command [itcl::code $this AdjustSetting view3D] \
317    }
318    Rappture::Tooltip::for $itk_component(mode) \
319        "Toggle the surface/contour on/off"
320    pack $itk_component(mode) -padx 2 -pady { 2 0 }
321
322    itk_component add stretchtofit {
323        Rappture::PushButton $f.stretchtofit \
324            -onimage [Rappture::icon stretchtofit] \
325            -offimage [Rappture::icon stretchtofit] \
326            -variable [itcl::scope _settings(stretchToFit)] \
327            -command [itcl::code $this AdjustSetting stretchToFit] \
328    }
329    Rappture::Tooltip::for $itk_component(stretchtofit) \
330        "Stretch plot to fit window on/off"
331    pack $itk_component(stretchtofit) -padx 2 -pady 2
332
333    if { [catch {
334        BuildImageTab
335        BuildAxisTab
336        BuildCameraTab
337    } errs] != 0 } {
338        global errorInfo
339        puts stderr "errs=$errs errorInfo=$errorInfo"
340    }
341
342    # Hack around the Tk panewindow.  The problem is that the requested
343    # size of the 3d view isn't set until an image is retrieved from
344    # the server.  So the panewindow uses the tiny size.
345    set w 10000
346    pack forget $itk_component(view)
347    blt::table $itk_component(plotarea) \
348        0,0 $itk_component(view) -fill both -reqwidth $w
349    blt::table configure $itk_component(plotarea) c1 -resize none
350
351    # Bindings for panning via mouse
352    bind $itk_component(view) <ButtonPress-2> \
353        [itcl::code $this Pan click %x %y]
354    bind $itk_component(view) <B2-Motion> \
355        [itcl::code $this Pan drag %x %y]
356    bind $itk_component(view) <ButtonRelease-2> \
357        [itcl::code $this Pan release %x %y]
358
359    #bind $itk_component(view) <ButtonRelease-3> \
360    #    [itcl::code $this Pick %x %y]
361
362    # Bindings for panning via keyboard
363    bind $itk_component(view) <KeyPress-Left> \
364        [itcl::code $this Pan set -10 0]
365    bind $itk_component(view) <KeyPress-Right> \
366        [itcl::code $this Pan set 10 0]
367    bind $itk_component(view) <KeyPress-Up> \
368        [itcl::code $this Pan set 0 -10]
369    bind $itk_component(view) <KeyPress-Down> \
370        [itcl::code $this Pan set 0 10]
371    bind $itk_component(view) <Shift-KeyPress-Left> \
372        [itcl::code $this Pan set -2 0]
373    bind $itk_component(view) <Shift-KeyPress-Right> \
374        [itcl::code $this Pan set 2 0]
375    bind $itk_component(view) <Shift-KeyPress-Up> \
376        [itcl::code $this Pan set 0 -2]
377    bind $itk_component(view) <Shift-KeyPress-Down> \
378        [itcl::code $this Pan set 0 2]
379
380    # Bindings for zoom via keyboard
381    bind $itk_component(view) <KeyPress-Prior> \
382        [itcl::code $this Zoom out]
383    bind $itk_component(view) <KeyPress-Next> \
384        [itcl::code $this Zoom in]
385
386    bind $itk_component(view) <Enter> "focus $itk_component(view)"
387
388    if {[string equal "x11" [tk windowingsystem]]} {
389        # Bindings for zoom via mouse
390        bind $itk_component(view) <4> [itcl::code $this Zoom out]
391        bind $itk_component(view) <5> [itcl::code $this Zoom in]
392    }
393
394    set _image(download) [image create photo]
395    eval itk_initialize $args
396    Connect
397    set _beforeConnect 0
398}
399
400# ----------------------------------------------------------------------
401# DESTRUCTOR
402# ----------------------------------------------------------------------
403itcl::body Rappture::VtkImageViewer::destructor {} {
404    Disconnect
405    image delete $_image(plot)
406    image delete $_image(download)
407    catch { blt::arcball destroy $_arcball }
408}
409
410itcl::body Rappture::VtkImageViewer::DoResize {} {
411    if { $_width < 2 } {
412        set _width 500
413    }
414    if { $_height < 2 } {
415        set _height 500
416    }
417    set _start [clock clicks -milliseconds]
418    SendCmd "screen size [expr $_width - 20] $_height"
419
420    set font "Arial 8"
421    set lh [font metrics $font -linespace]
422    set h [expr {$_height - 2 * ($lh + 2)}]
423    if { $h != $_legendHeight } {
424        EventuallyRequestLegend
425    } else {
426        DrawLegend
427    }
428    set _resizePending 0
429}
430
431itcl::body Rappture::VtkImageViewer::DoRotate {} {
432    set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
433    SendCmd "camera orient $q"
434    set _rotatePending 0
435}
436
437itcl::body Rappture::VtkImageViewer::EventuallyRequestLegend {} {
438    if { !$_legendPending } {
439        set _legendPending 1
440        $_dispatcher event -idle !legend
441    }
442}
443
444itcl::body Rappture::VtkImageViewer::EventuallyResize { w h } {
445    set _width $w
446    set _height $h
447    $_arcball resize $w $h
448    if { !$_resizePending } {
449        set _resizePending 1
450        $_dispatcher event -after 250 !resize
451    }
452}
453
454set rotate_delay 100
455
456itcl::body Rappture::VtkImageViewer::EventuallyRotate { q } {
457    foreach { _view(qw) _view(qx) _view(qy) _view(qz) } $q break
458    if { !$_rotatePending } {
459        set _rotatePending 1
460        global rotate_delay
461        $_dispatcher event -after $rotate_delay !rotate
462    }
463}
464
465# ----------------------------------------------------------------------
466# USAGE: add <dataobj> ?<settings>?
467#
468# Clients use this to add a data object to the plot.  The optional
469# <settings> are used to configure the plot.  Allowed settings are
470# -color, -brightness, -width, -linestyle, and -raise.
471# ----------------------------------------------------------------------
472itcl::body Rappture::VtkImageViewer::add {dataobj {settings ""}} {
473    if { ![$dataobj isvalid] } {
474        return;                         # Object doesn't contain valid data.
475    }
476    array set params {
477        -color auto
478        -width 1
479        -linestyle solid
480        -brightness 0
481        -raise 0
482        -description ""
483        -param ""
484        -type ""
485    }
486    array set params $settings
487    set params(-description) ""
488    set params(-param) ""
489    array set params $settings
490
491    if {$params(-color) == "auto" || $params(-color) == "autoreset"} {
492        # can't handle -autocolors yet
493        set params(-color) white
494    }
495    set pos [lsearch -exact $_dlist $dataobj]
496    if {$pos < 0} {
497        lappend _dlist $dataobj
498    }
499    set _obj2ovride($dataobj-color) $params(-color)
500    set _obj2ovride($dataobj-width) $params(-width)
501    set _obj2ovride($dataobj-raise) $params(-raise)
502    $_dispatcher event -idle !rebuild
503}
504
505
506# ----------------------------------------------------------------------
507# USAGE: delete ?<dataobj1> <dataobj2> ...?
508#
509#       Clients use this to delete a dataobj from the plot.  If no dataobjs
510#       are specified, then all dataobjs are deleted.  No data objects are
511#       deleted.  They are only removed from the display list.
512#
513# ----------------------------------------------------------------------
514itcl::body Rappture::VtkImageViewer::delete {args} {
515    if { [llength $args] == 0} {
516        set args $_dlist
517    }
518    # Delete all specified dataobjs
519    set changed 0
520    foreach dataobj $args {
521        set pos [lsearch -exact $_dlist $dataobj]
522        if { $pos < 0 } {
523            continue;                   # Don't know anything about it.
524        }
525        # Remove it from the dataobj list.
526        set _dlist [lreplace $_dlist $pos $pos]
527        array unset _obj2ovride $dataobj-*
528        array unset _settings $dataobj-*
529        set changed 1
530    }
531    # If anything changed, then rebuild the plot
532    if { $changed } {
533        $_dispatcher event -idle !rebuild
534    }
535}
536
537# ----------------------------------------------------------------------
538# USAGE: get ?-objects?
539# USAGE: get ?-visible?
540# USAGE: get ?-image view?
541#
542# Clients use this to query the list of objects being plotted, in
543# order from bottom to top of this result.  The optional "-image"
544# flag can also request the internal images being shown.
545# ----------------------------------------------------------------------
546itcl::body Rappture::VtkImageViewer::get {args} {
547    if {[llength $args] == 0} {
548        set args "-objects"
549    }
550    set op [lindex $args 0]
551    switch -- $op {
552        "-objects" {
553            # put the dataobj list in order according to -raise options
554            set dlist {}
555            foreach dataobj $_dlist {
556                if { ![IsValidObject $dataobj] } {
557                    continue
558                }
559                if {[info exists _obj2ovride($dataobj-raise)] &&
560                    $_obj2ovride($dataobj-raise)} {
561                    set dlist [linsert $dlist 0 $dataobj]
562                } else {
563                    lappend dlist $dataobj
564                }
565            }
566            return $dlist
567        }
568        "-visible" {
569            set dlist {}
570            foreach dataobj $_dlist {
571                if { ![IsValidObject $dataobj] } {
572                    continue
573                }
574                if { ![info exists _obj2ovride($dataobj-raise)] } {
575                    # No setting indicates that the object isn't visible.
576                    continue
577                }
578                # Otherwise use the -raise parameter to put the object to
579                # the front of the list.
580                if { $_obj2ovride($dataobj-raise) } {
581                    set dlist [linsert $dlist 0 $dataobj]
582                } else {
583                    lappend dlist $dataobj
584                }
585            }
586            return $dlist
587        }           
588        -image {
589            if {[llength $args] != 2} {
590                error "wrong # args: should be \"get -image view\""
591            }
592            switch -- [lindex $args end] {
593                view {
594                    return $_image(plot)
595                }
596                default {
597                    error "bad image name \"[lindex $args end]\": should be view"
598                }
599            }
600        }
601        default {
602            error "bad option \"$op\": should be -objects or -image"
603        }
604    }
605}
606
607#
608# scale  --
609#
610#       This gets called either incrementally as new simulations are
611#       added or all at once as a sequence of images.
612#       This  accounts for all objects--even those not showing on the
613#       screen.  Because of this, the limits are appropriate for all
614#       objects as the user scans through data in the ResultSet viewer.
615#
616itcl::body Rappture::VtkImageViewer::scale {args} {
617    foreach dataobj $args {
618        if { ![$dataobj isvalid] } {
619            continue;                   # Object doesn't contain valid data.
620        }
621        foreach axis { x y } {
622            set lim [$dataobj limits $axis]
623            if { ![info exists _limits($axis)] } {
624                set _limits($axis) $lim
625                continue
626            }
627            foreach {min max} $lim break
628            foreach {amin amax} $_limits($axis) break
629            if { $amin > $min } {
630                set amin $min
631            }
632            if { $amax < $max } {
633                set amax $max
634            }
635            set _limits($axis) [list $amin $amax]
636            set units [$dataobj hints ${axis}units]
637            set found($units) 1
638        }
639        foreach { fname lim } [$dataobj fieldlimits] {
640            if { ![info exists _limits($fname)] } {
641                set _limits($fname) $lim
642                continue
643            }
644            foreach {min max} $lim break
645            foreach {fmin fmax} $_limits($fname) break
646            if { $fmin > $min } {
647                set fmin $min
648            }
649            if { $fmax < $max } {
650                set fmax $max
651            }
652            set _limits($fname) [list $fmin $fmax]
653        }
654    }
655    if { [array size found] > 1 } {
656        set _settings(stretchToFit) 1
657    } else {
658        # Check if the range of the x and y axes requires that we stretch
659        # the contour to fit the plotting area.  This can happen when the
660        # x and y scales differ greatly (> 100x)
661        foreach {xmin xmax} $_limits(x) break
662        foreach {ymin ymax} $_limits(y) break
663        if { (($xmax - $xmin) > (($ymax -$ymin) * $_maxScale)) ||
664             ((($xmax - $xmin) * $_maxScale) < ($ymax -$ymin)) } {
665            set _settings(stretchToFit) 1
666        }
667    }
668}
669
670# ----------------------------------------------------------------------
671# USAGE: download coming
672# USAGE: download controls <downloadCommand>
673# USAGE: download now
674#
675# Clients use this method to create a downloadable representation
676# of the plot.  Returns a list of the form {ext string}, where
677# "ext" is the file extension (indicating the type of data) and
678# "string" is the data itself.
679# ----------------------------------------------------------------------
680itcl::body Rappture::VtkImageViewer::download {option args} {
681    switch $option {
682        coming {
683            if {[catch {
684                blt::winop snap $itk_component(plotarea) $_image(download)
685            }]} {
686                $_image(download) configure -width 1 -height 1
687                $_image(download) put #000000
688            }
689        }
690        controls {
691            set popup .vtkviewerdownload
692            if { ![winfo exists .vtkviewerdownload] } {
693                set inner [BuildDownloadPopup $popup [lindex $args 0]]
694            } else {
695                set inner [$popup component inner]
696            }
697            set _downloadPopup(image_controls) $inner.image_frame
698            set num [llength [get]]
699            set num [expr {($num == 1) ? "1 result" : "$num results"}]
700            set word [Rappture::filexfer::label downloadWord]
701            $inner.summary configure -text "$word $num in the following format:"
702            update idletasks            ;# Fix initial sizes
703            return $popup
704        }
705        now {
706            set popup .vtkviewerdownload
707            if {[winfo exists .vtkviewerdownload]} {
708                $popup deactivate
709            }
710            switch -- $_downloadPopup(format) {
711                "image" {
712                    return [$this GetImage [lindex $args 0]]
713                }
714                "vtk" {
715                    return [$this GetVtkData [lindex $args 0]]
716                }
717            }
718            return ""
719        }
720        default {
721            error "bad option \"$option\": should be coming, controls, now"
722        }
723    }
724}
725
726# ----------------------------------------------------------------------
727# USAGE: Connect ?<host:port>,<host:port>...?
728#
729# Clients use this method to establish a connection to a new
730# server, or to reestablish a connection to the previous server.
731# Any existing connection is automatically closed.
732# ----------------------------------------------------------------------
733itcl::body Rappture::VtkImageViewer::Connect {} {
734    global readyForNextFrame
735    set readyForNextFrame 1
736    set _reset 1
737    set _hosts [GetServerList "vtkvis"]
738    if { "" == $_hosts } {
739        return 0
740    }
741    set result [VisViewer::Connect $_hosts]
742    if { $result } {
743        if { $_reportClientInfo }  {
744            # Tell the server the viewer, hub, user and session.
745            # Do this immediately on connect before buffering any commands
746            global env
747
748            set info {}
749            set user "???"
750            if { [info exists env(USER)] } {
751                set user $env(USER)
752            }
753            set session "???"
754            if { [info exists env(SESSION)] } {
755                set session $env(SESSION)
756            }
757            lappend info "hub" [exec hostname]
758            lappend info "client" "vtkimageviewer"
759            lappend info "user" $user
760            lappend info "session" $session
761            SendCmd "clientinfo [list $info]"
762        }
763        set w [winfo width $itk_component(view)]
764        set h [winfo height $itk_component(view)]
765        EventuallyResize $w $h
766    }
767    return $result
768}
769
770#
771# isconnected --
772#
773#       Indicates if we are currently connected to the visualization server.
774#
775itcl::body Rappture::VtkImageViewer::isconnected {} {
776    return [VisViewer::IsConnected]
777}
778
779#
780# disconnect --
781#
782itcl::body Rappture::VtkImageViewer::disconnect {} {
783    Disconnect
784    set _reset 1
785}
786
787#
788# Disconnect --
789#
790#       Clients use this method to disconnect from the current rendering
791#       server.
792#
793itcl::body Rappture::VtkImageViewer::Disconnect {} {
794    VisViewer::Disconnect
795
796    $_dispatcher cancel !rebuild
797    $_dispatcher cancel !resize
798    $_dispatcher cancel !rotate
799    $_dispatcher cancel !legend
800    # disconnected -- no more data sitting on server
801    array unset _datasets
802    array unset _data
803    array unset _colormaps
804    array unset _obj2datasets
805    global readyForNextFrame
806    set readyForNextFrame 1
807}
808
809# ----------------------------------------------------------------------
810# USAGE: ReceiveImage -bytes <size> -type <type> -token <token>
811#
812# Invoked automatically whenever the "image" command comes in from
813# the rendering server.  Indicates that binary image data with the
814# specified <size> will follow.
815# ----------------------------------------------------------------------
816itcl::body Rappture::VtkImageViewer::ReceiveImage { args } {
817    global readyForNextFrame
818    set readyForNextFrame 1
819    array set info {
820        -token "???"
821        -bytes 0
822        -type image
823    }
824    array set info $args
825    set bytes [ReceiveBytes $info(-bytes)]
826    if { $info(-type) == "image" } {
827        if 0 {
828            set f [open "last.ppm" "w"]
829            puts $f $bytes
830            close $f
831        }
832        $_image(plot) configure -data $bytes
833        set time [clock seconds]
834        set date [clock format $time]
835        #puts stderr "$date: received image [image width $_image(plot)]x[image height $_image(plot)] image>"       
836        if { $_start > 0 } {
837            set finish [clock clicks -milliseconds]
838            #puts stderr "round trip time [expr $finish -$_start] milliseconds"
839            set _start 0
840        }
841    } elseif { $info(type) == "print" } {
842        set tag $this-print-$info(-token)
843        set _hardcopy($tag) $bytes
844    }
845}
846
847#
848# ReceiveDataset --
849#
850itcl::body Rappture::VtkImageViewer::ReceiveDataset { args } {
851    if { ![isconnected] } {
852        return
853    }
854    set option [lindex $args 0]
855    switch -- $option {
856        "scalar" {
857            set option [lindex $args 1]
858            switch -- $option {
859                "world" {
860                    foreach { x y z value tag } [lrange $args 2 end] break
861                }
862                "pixel" {
863                    foreach { x y value tag } [lrange $args 2 end] break
864                }
865            }
866        }
867        "vector" {
868            set option [lindex $args 1]
869            switch -- $option {
870                "world" {
871                    foreach { x y z vx vy vz tag } [lrange $args 2 end] break
872                }
873                "pixel" {
874                    foreach { x y vx vy vz tag } [lrange $args 2 end] break
875                }
876            }
877        }
878        "names" {
879            foreach { name } [lindex $args 1] {
880                #puts stderr "Dataset: $name"
881            }
882        }
883        default {
884            error "unknown dataset option \"$option\" from server"
885        }
886    }
887}
888
889# ----------------------------------------------------------------------
890# USAGE: Rebuild
891#
892# Called automatically whenever something changes that affects the
893# data in the widget.  Clears any existing data and rebuilds the
894# widget to display new data.
895# ----------------------------------------------------------------------
896itcl::body Rappture::VtkImageViewer::Rebuild {} {
897    set w [winfo width $itk_component(view)]
898    set h [winfo height $itk_component(view)]
899    if { $w < 2 || $h < 2 } {
900        $_dispatcher event -idle !rebuild
901        return
902    }
903
904    # Turn on buffering of commands to the server.  We don't want to
905    # be preempted by a server disconnect/reconnect (which automatically
906    # generates a new call to Rebuild).   
907    StartBufferingCommands
908
909    if { $_width != $w || $_height != $h || $_reset } {
910        set _width $w
911        set _height $h
912        $_arcball resize $w $h
913        DoResize
914        if { $_settings(stretchToFit) } {
915            AdjustSetting stretchToFit
916        }
917    }
918    if { $_reset } {
919        #
920        # Reset the camera and other view parameters
921        #
922        InitSettings view3D background
923
924        # Let's see how this goes.  I think it's preferable to overloading the
925        # axis title with the exponent.
926        SendCmd "axis exp 0 0 0 1"
927
928        SendCmd "axis lrot z 90"
929        set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
930        $_arcball quaternion $q
931        if {$_settings(view3D) } {
932            if { $_view(ortho)} {
933                SendCmd "camera mode ortho"
934            } else {
935                SendCmd "camera mode persp"
936            }
937            DoRotate
938            SendCmd "camera reset"
939        }
940        PanCamera
941        StopBufferingCommands
942        SendCmd "imgflush"
943        StartBufferingCommands
944    }
945
946    set _first ""
947    # Start off with no datasets are visible.
948    SendCmd "dataset visible 0"
949    foreach dataobj [get -objects] {
950        if { [info exists _obj2ovride($dataobj-raise)] &&  $_first == "" } {
951            set _first $dataobj
952        }
953        set _obj2datasets($dataobj) ""
954        foreach comp [$dataobj components] {
955            set tag $dataobj-$comp
956            if { ![info exists _datasets($tag)] } {
957                set bytes [$dataobj vtkdata $comp]
958                if 0 {
959                    set f [open /tmp/vtkimage.vtk "w"]
960                    puts $f $bytes
961                    close $f
962                }
963                set length [string length $bytes]
964                if { $_reportClientInfo }  {
965                    set info {}
966                    lappend info "tool_id"       [$dataobj hints toolId]
967                    lappend info "tool_name"     [$dataobj hints toolName]
968                    lappend info "tool_version"  [$dataobj hints toolRevision]
969                    lappend info "tool_title"    [$dataobj hints toolTitle]
970                    lappend info "dataset_label" [$dataobj hints label]
971                    lappend info "dataset_size"  $length
972                    lappend info "dataset_tag"   $tag
973                    SendCmd [list "clientinfo" $info]
974                }
975                SendCmd "dataset add $tag data follows $length"
976                append _outbuf $bytes
977                set _datasets($tag) 1
978                SetObjectStyle $dataobj $comp
979            }
980            lappend _obj2datasets($dataobj) $tag
981            if { [info exists _obj2ovride($dataobj-raise)] } {
982                # Setting dataset visible enables outline
983                # and image
984                SendCmd "dataset visible 1 $tag"
985            }
986        }
987    }
988    if { $_first != ""  } {
989        $itk_component(field) choices delete 0 end
990        $itk_component(fieldmenu) delete 0 end
991        array unset _fields
992        set _curFldName ""
993        foreach cname [$_first components] {
994            foreach fname [$_first fieldnames $cname] {
995                if { [info exists _fields($fname)] } {
996                    continue
997                }
998                foreach { label units components } \
999                    [$_first fieldinfo $fname] break
1000                $itk_component(field) choices insert end "$fname" "$label"
1001                $itk_component(fieldmenu) add radiobutton -label "$label" \
1002                    -value $label -variable [itcl::scope _curFldLabel] \
1003                    -selectcolor red \
1004                    -activebackground $itk_option(-plotbackground) \
1005                    -activeforeground $itk_option(-plotforeground) \
1006                    -font "Arial 8" \
1007                    -command [itcl::code $this Combo invoke]
1008                set _fields($fname) [list $label $units $components]
1009                if { $_curFldName == "" } {
1010                    set _curFldName $fname
1011                    set _curFldLabel $label
1012                }
1013            }
1014        }
1015        $itk_component(field) value $_curFldLabel
1016    }
1017    InitSettings stretchToFit outline
1018
1019    if { $_reset } {
1020        SendCmd "axis tickpos outside"
1021        foreach axis { x y z } {
1022            SendCmd "axis lformat $axis %g"
1023        }
1024       
1025        foreach axis { x y z } {
1026            set label [$_first hints ${axis}label]
1027            if { $label == "" } {
1028                set label [string toupper $axis]
1029            }
1030            # May be a space in the axis label.
1031            SendCmd [list axis name $axis $label]
1032
1033            if {$axis == "z" && [$_first hints ${axis}units] == ""} {
1034                set units [lindex $_fields($_curFldName) 1]
1035            } else {
1036                set units [$_first hints ${axis}units]
1037            }
1038            if { $units != "" } {
1039                # May be a space in the axis units.
1040                SendCmd [list axis units $axis $units]
1041            }
1042        }
1043        #
1044        # Reset the camera and other view parameters
1045        #
1046        set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
1047        $_arcball quaternion $q
1048        if {$_settings(view3D) } {
1049            if { $_view(ortho)} {
1050                SendCmd "camera mode ortho"
1051            } else {
1052                SendCmd "camera mode persp"
1053            }
1054            DoRotate
1055            SendCmd "camera reset"
1056        }
1057        PanCamera
1058        InitSettings axisXGrid axisYGrid axisZGrid \
1059            axisVisible axisLabels field view3D
1060        if { [array size _fields] < 2 } {
1061            blt::table forget $itk_component(field) $itk_component(field_l)
1062        }
1063        RequestLegend
1064        set _reset 0
1065    }
1066    global readyForNextFrame
1067    set readyForNextFrame 0;            # Don't advance to the next frame
1068
1069    # Actually write the commands to the server socket.  If it fails, we don't
1070    # care.  We're finished here.
1071    blt::busy hold $itk_component(hull)
1072    StopBufferingCommands
1073    blt::busy release $itk_component(hull)
1074}
1075
1076# ----------------------------------------------------------------------
1077# USAGE: CurrentDatasets ?-all -visible? ?dataobjs?
1078#
1079# Returns a list of server IDs for the current datasets being displayed.  This
1080# is normally a single ID, but it might be a list of IDs if the current data
1081# object has multiple components.
1082# ----------------------------------------------------------------------
1083itcl::body Rappture::VtkImageViewer::CurrentDatasets {args} {
1084    set flag [lindex $args 0]
1085    switch -- $flag {
1086        "-all" {
1087            if { [llength $args] > 1 } {
1088                error "CurrentDatasets: can't specify dataobj after \"-all\""
1089            }
1090            set dlist [get -objects]
1091        }
1092        "-visible" {
1093            if { [llength $args] > 1 } {
1094                set dlist {}
1095                set args [lrange $args 1 end]
1096                foreach dataobj $args {
1097                    if { [info exists _obj2ovride($dataobj-raise)] } {
1098                        lappend dlist $dataobj
1099                    }
1100                }
1101            } else {
1102                set dlist [get -visible]
1103            }
1104        }           
1105        default {
1106            set dlist $args
1107        }
1108    }
1109    set rlist ""
1110    foreach dataobj $dlist {
1111        foreach comp [$dataobj components] {
1112            set tag $dataobj-$comp
1113            if { [info exists _datasets($tag)] && $_datasets($tag) } {
1114                lappend rlist $tag
1115            }
1116        }
1117    }
1118    return $rlist
1119}
1120
1121# ----------------------------------------------------------------------
1122# USAGE: Zoom in
1123# USAGE: Zoom out
1124# USAGE: Zoom reset
1125#
1126# Called automatically when the user clicks on one of the zoom
1127# controls for this widget.  Changes the zoom for the current view.
1128# ----------------------------------------------------------------------
1129itcl::body Rappture::VtkImageViewer::Zoom {option} {
1130    switch -- $option {
1131        "in" {
1132            set _view(zoom) [expr {$_view(zoom)*1.25}]
1133            SendCmd "camera zoom $_view(zoom)"
1134        }
1135        "out" {
1136            set _view(zoom) [expr {$_view(zoom)*0.8}]
1137            SendCmd "camera zoom $_view(zoom)"
1138        }
1139        "reset" {
1140            array set _view {
1141                qw      0.36
1142                qx      0.25
1143                qy      0.50
1144                qz      0.70
1145                zoom    1.0
1146                xpan    0
1147                ypan    0
1148            }
1149            if { $_first != "" } {
1150                set location [$_first hints camera]
1151                if { $location != "" } {
1152                    array set _view $location
1153                }
1154            }
1155            set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
1156            $_arcball quaternion $q
1157            if {$_settings(view3D) } {
1158                DoRotate
1159            }
1160            SendCmd "camera reset"
1161        }
1162    }
1163}
1164
1165itcl::body Rappture::VtkImageViewer::PanCamera {} {
1166    set x $_view(xpan)
1167    set y $_view(ypan)
1168    SendCmd "camera pan $x $y"
1169}
1170
1171
1172# ----------------------------------------------------------------------
1173# USAGE: Rotate click <x> <y>
1174# USAGE: Rotate drag <x> <y>
1175# USAGE: Rotate release <x> <y>
1176#
1177# Called automatically when the user clicks/drags/releases in the
1178# plot area.  Moves the plot according to the user's actions.
1179# ----------------------------------------------------------------------
1180itcl::body Rappture::VtkImageViewer::Rotate {option x y} {
1181    switch -- $option {
1182        "click" {
1183            $itk_component(view) configure -cursor fleur
1184            set _click(x) $x
1185            set _click(y) $y
1186        }
1187        "drag" {
1188            if {[array size _click] == 0} {
1189                Rotate click $x $y
1190            } else {
1191                set w [winfo width $itk_component(view)]
1192                set h [winfo height $itk_component(view)]
1193                if {$w <= 0 || $h <= 0} {
1194                    return
1195                }
1196
1197                if {[catch {
1198                    # this fails sometimes for no apparent reason
1199                    set dx [expr {double($x-$_click(x))/$w}]
1200                    set dy [expr {double($y-$_click(y))/$h}]
1201                }]} {
1202                    return
1203                }
1204                if { $dx == 0 && $dy == 0 } {
1205                    return
1206                }
1207                set q [$_arcball rotate $x $y $_click(x) $_click(y)]
1208                EventuallyRotate $q
1209                set _click(x) $x
1210                set _click(y) $y
1211            }
1212        }
1213        "release" {
1214            Rotate drag $x $y
1215            $itk_component(view) configure -cursor ""
1216            catch {unset _click}
1217        }
1218        default {
1219            error "bad option \"$option\": should be click, drag, release"
1220        }
1221    }
1222}
1223
1224itcl::body Rappture::VtkImageViewer::Pick {x y} {
1225    foreach tag [CurrentDatasets -visible] {
1226        SendCmd "dataset getscalar pixel $x $y $tag"
1227    }
1228}
1229
1230# ----------------------------------------------------------------------
1231# USAGE: $this Pan click x y
1232#        $this Pan drag x y
1233#        $this Pan release x y
1234#
1235# Called automatically when the user clicks on one of the zoom
1236# controls for this widget.  Changes the zoom for the current view.
1237# ----------------------------------------------------------------------
1238itcl::body Rappture::VtkImageViewer::Pan {option x y} {
1239    switch -- $option {
1240        "set" {
1241            set w [winfo width $itk_component(view)]
1242            set h [winfo height $itk_component(view)]
1243            set x [expr $x / double($w)]
1244            set y [expr $y / double($h)]
1245            set _view(xpan) [expr $_view(xpan) + $x]
1246            set _view(ypan) [expr $_view(ypan) + $y]
1247            PanCamera
1248            return
1249        }
1250        "click" {
1251            set _click(x) $x
1252            set _click(y) $y
1253            $itk_component(view) configure -cursor hand1
1254        }
1255        "drag" {
1256            if { ![info exists _click(x)] } {
1257                set _click(x) $x
1258            }
1259            if { ![info exists _click(y)] } {
1260                set _click(y) $y
1261            }
1262            set w [winfo width $itk_component(view)]
1263            set h [winfo height $itk_component(view)]
1264            set dx [expr ($_click(x) - $x)/double($w)]
1265            set dy [expr ($_click(y) - $y)/double($h)]
1266            set _click(x) $x
1267            set _click(y) $y
1268            set _view(xpan) [expr $_view(xpan) - $dx]
1269            set _view(ypan) [expr $_view(ypan) - $dy]
1270            PanCamera
1271        }
1272        "release" {
1273            Pan drag $x $y
1274            $itk_component(view) configure -cursor ""
1275        }
1276        default {
1277            error "unknown option \"$option\": should set, click, drag, or release"
1278        }
1279    }
1280}
1281
1282# ----------------------------------------------------------------------
1283# USAGE: InitSettings <what> ?<value>?
1284#
1285# Used internally to update rendering settings whenever parameters
1286# change in the popup settings panel.  Sends the new settings off
1287# to the back end.
1288# ----------------------------------------------------------------------
1289itcl::body Rappture::VtkImageViewer::InitSettings { args } {
1290    foreach spec $args {
1291        if { [info exists _settings($_first-$spec)] } {
1292            # Reset global setting with dataobj specific setting
1293            set _settings($spec) $_settings($_first-$spec)
1294        }
1295        AdjustSetting $spec
1296    }
1297}
1298
1299#
1300# AdjustSetting --
1301#
1302#       Changes/updates a specific setting in the widget.  There are
1303#       usually user-setable option.  Commands are sent to the render
1304#       server.
1305#
1306itcl::body Rappture::VtkImageViewer::AdjustSetting {what {value ""}} {
1307    if { $_beforeConnect } {
1308        return
1309    }
1310    switch -- $what {
1311        "axisFlymode" {
1312            set mode [$itk_component(axisflymode) value]
1313            set mode [$itk_component(axisflymode) translate $mode]
1314            set _settings($what) $mode
1315            SendCmd "axis flymode $mode"
1316        }
1317        "axisLabels" {
1318            set bool $_settings(axisLabels)
1319            SendCmd "axis labels all $bool"
1320        }
1321        "axisMinorTicks" {
1322            set bool $_settings(axisMinorTicks)
1323            foreach axis { x y z } {
1324                SendCmd "axis minticks ${axis} $bool"
1325            }
1326        }
1327        "axisVisible" {
1328            set bool $_settings(axisVisible)
1329            SendCmd "axis visible all $bool"
1330        }
1331        "axisXGrid" - "axisYGrid" - "axisZGrid" {
1332            set axis [string tolower [string range $what 4 4]]
1333            set bool $_settings($what)
1334            SendCmd "axis grid $axis $bool"
1335        }
1336        "background" {
1337            set bg [$itk_component(background) value]
1338            array set fgcolors {
1339                "black" "white"
1340                "white" "black"
1341                "grey"  "black"
1342            }
1343            set fg $fgcolors($bg)
1344            configure -plotbackground $bg -plotforeground $fg
1345            $itk_component(view) delete "legend"
1346            SendCmd "screen bgcolor [Color2RGB $bg]"
1347            SendCmd "outline color [Color2RGB $fg]"
1348            SendCmd "axis color all [Color2RGB $fg]"
1349            DrawLegend
1350        }
1351        "backingColor" {
1352            set color [$itk_component(backingcolor) value]
1353            if { $color == "none" } {
1354                if { $_settings(backingVisible) } {
1355                    SendCmd "image backing 0"
1356                    set _settings(backingVisible) 0
1357                }
1358            } else {
1359                if { !$_settings(backingVisible) } {
1360                    SendCmd "image backing 1"
1361                    set _settings(backingVisible) 1
1362                }
1363                SendCmd "image color [Color2RGB $color]"
1364            }
1365        }
1366        "backingVisible" {
1367            set bool $_settings($what)
1368            SendCmd "image backing $bool"
1369        }
1370        "colormap" {
1371            set _changed(colormap) 1
1372            StartBufferingCommands
1373            set color [$itk_component(colormap) value]
1374            set _settings(colormap) $color
1375            SetCurrentColormap $color
1376            if {$_settings(colormapDiscrete)} {
1377                 SendCmd "colormap res $_settings(numColors) $color"
1378            }
1379            StopBufferingCommands
1380            EventuallyRequestLegend
1381        }
1382        "colormapDiscrete" {
1383            set bool $_settings($what)
1384            StartBufferingCommands
1385            if {$bool} {
1386                SendCmd "colormap res $_settings(numColors)"
1387            } else {
1388                SendCmd "colormap res default"
1389            }
1390            StopBufferingCommands
1391            EventuallyRequestLegend
1392        }
1393        "field" {
1394            set label [$itk_component(field) value]
1395            set fname [$itk_component(field) translate $label]
1396            set _settings(field) $fname
1397            if { [info exists _fields($fname)] } {
1398                foreach { label units components } $_fields($fname) break
1399                if { $components > 1 } {
1400                    set _colorMode vmag
1401                } else {
1402                    set _colorMode scalar
1403                }
1404                set _curFldName $fname
1405                set _curFldLabel $label
1406            } else {
1407                puts stderr "unknown field \"$fname\""
1408                return
1409            }
1410
1411            # Get the new limits because the field changed.
1412            SendCmd "dataset scalar $_curFldName"
1413            #SendCmd "image colormode scalar $_curFldName"
1414            SendCmd "camera reset"
1415            DrawLegend
1416        }
1417        "view3D" {
1418            set bool $_settings(view3D)
1419            set c $itk_component(view)
1420            StartBufferingCommands
1421            # Fix image scale: 0 for contours, 1 for images.
1422            if { $bool } {
1423                set _settings(opacity) $_settings(saveOpacity)
1424            } else {
1425                set _settings(opacity) 100
1426            }
1427            AdjustSetting opacity
1428            if { $bool } {
1429                $itk_component(opacity) configure -state normal
1430                $itk_component(opacity_l) configure -state normal
1431                if {$_view(ortho)} {
1432                    SendCmd "camera mode ortho"
1433                } else {
1434                    SendCmd "camera mode persp"
1435                }
1436                SendCmd "camera aspect native"
1437            } else {
1438                $itk_component(opacity) configure -state disabled
1439                $itk_component(opacity_l) configure -state disabled
1440                SendCmd "camera mode image"
1441                if {$_settings(stretchToFit)} {
1442                    SendCmd "camera aspect window"
1443                }
1444            }
1445            if { $bool } {
1446                set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
1447                $_arcball quaternion $q
1448                SendCmd "camera orient $q"
1449            } else {
1450                bind $c <ButtonPress-1> {}
1451                bind $c <B1-Motion> {}
1452                bind $c <ButtonRelease-1> {}
1453            }
1454            SendCmd "camera reset"
1455            # Fix the mouse bindings for rotation/panning and the
1456            # camera mode. Ideally we'd create a bindtag for these.
1457            if { $bool } {
1458                # Bindings for rotation via mouse
1459                bind $c <ButtonPress-1> \
1460                    [itcl::code $this Rotate click %x %y]
1461                bind $c <B1-Motion> \
1462                    [itcl::code $this Rotate drag %x %y]
1463                bind $c <ButtonRelease-1> \
1464                    [itcl::code $this Rotate release %x %y]
1465            }
1466            StopBufferingCommands
1467        }
1468        "window" {
1469            set val $_settings(window)
1470            SendCmd "image window $val"
1471        }
1472        "level" {
1473            set val $_settings(level)
1474            SendCmd "image level $val"
1475        }
1476        "legendVisible" {
1477            if { !$_settings($what) } {
1478                $itk_component(view) delete legend
1479            }
1480            DrawLegend
1481        }
1482        "opacity" {
1483            set _changed(opacity) 1
1484            if { $_settings(view3D) } {
1485                set _settings(saveOpacity) $_settings(opacity)
1486                set val $_settings(opacity)
1487                set sval [expr { 0.01 * double($val) }]
1488                SendCmd "image opacity $sval"
1489            } else {
1490                SendCmd "image opacity 1"
1491            }
1492        }
1493        "outline" {
1494            set bool $_settings(outline)
1495            SendCmd "outline visible $bool"
1496        }
1497        "stretchToFit" {
1498            set bool $_settings($what)
1499            if { $bool } {
1500                if { $_settings(view3D) } {
1501                    SendCmd "camera aspect native"
1502                } else {
1503                    SendCmd "camera aspect window"
1504                }
1505            } else {
1506                SendCmd "camera aspect native"
1507            }
1508        }
1509        default {
1510            error "don't know how to fix $what"
1511        }
1512    }
1513}
1514
1515#
1516# RequestLegend --
1517#
1518#       Request a new legend from the server.  The size of the legend
1519#       is determined from the height of the canvas. 
1520#
1521# This should be called when
1522#       1.  A new current colormap is set.
1523#       2.  Window is resized.
1524#       3.  The limits of the data have changed.  (Just need a redraw).
1525#       4.  Number of isolines have changed. (Just need a redraw).
1526#       5.  Legend becomes visible (Just need a redraw).
1527#
1528itcl::body Rappture::VtkImageViewer::RequestLegend {} {
1529    set _legendPending 0
1530    set font "Arial 8"
1531    set w 12
1532    set lineht [font metrics $font -linespace]
1533    # color ramp height = (canvas height) - (min and max value lines) - 2
1534    set h [expr {$_height - 2 * ($lineht + 2)}]
1535    set _legendHeight $h
1536
1537    set fname $_curFldName
1538    if { [string match "component*" $fname] } {
1539        set title ""
1540    } else {
1541        if { [info exists _fields($fname)] } {
1542            foreach { title units } $_fields($fname) break
1543            if { $units != "" } {
1544                set title [format "%s (%s)" $title $units]
1545            }
1546        } else {
1547            set title $fname
1548        }
1549    }
1550    # If there's a title too, substract one more line
1551    if { $title != "" } {
1552        incr h -$lineht
1553    }
1554    if { $h < 1 } {
1555        return
1556    }
1557    # Set the legend on the first image dataset.
1558    if { $_currentColormap != "" && $_currentColormap != "none" } {
1559        SendCmd "legend $_currentColormap scalar $_curFldName {} $w $h 0"
1560    }
1561}
1562
1563#
1564# SetCurrentColormap --
1565#
1566itcl::body Rappture::VtkImageViewer::SetCurrentColormap { name } {
1567    # Keep track of the colormaps that we build.
1568    if { $name != "none" && ![info exists _colormaps($name)] } {
1569        BuildColormap $name
1570        set _colormaps($name) 1
1571    }
1572    set _currentColormap $name
1573    SendCmd "image colormap $_currentColormap"
1574}
1575
1576
1577#
1578# BuildColormap --
1579#
1580#       Build the designated colormap on the server.
1581#
1582itcl::body Rappture::VtkImageViewer::BuildColormap { name } {
1583    set cmap [ColorsToColormap $name]
1584    if { [llength $cmap] == 0 } {
1585        set cmap "0.0 0.0 0.0 0.0 1.0 1.0 1.0 1.0"
1586    }
1587    set wmap "0.0 1.0 1.0 1.0"
1588    SendCmd "colormap add $name { $cmap } { $wmap }"
1589}
1590
1591# ----------------------------------------------------------------------
1592# CONFIGURATION OPTION: -mode
1593# ----------------------------------------------------------------------
1594itcl::configbody Rappture::VtkImageViewer::mode {
1595    switch -- $itk_option(-mode) {
1596        "volume" {
1597            set _settings(view3D) 1
1598        }
1599        "vtkimage" {
1600            set _settings(view3D) 0
1601        }
1602        default {
1603            error "unknown mode settings \"$itk_option(-mode)\""
1604        }
1605    }
1606    if { !$_reset } {
1607        AdjustSetting view3D
1608    }
1609}
1610
1611# ----------------------------------------------------------------------
1612# CONFIGURATION OPTION: -plotbackground
1613# ----------------------------------------------------------------------
1614itcl::configbody Rappture::VtkImageViewer::plotbackground {
1615    if { [isconnected] } {
1616        set rgb [Color2RGB $itk_option(-plotbackground)]
1617        if { !$_reset } {
1618            SendCmd "screen bgcolor $rgb"
1619        }
1620        $itk_component(view) configure -background $itk_option(-plotbackground)
1621    }
1622}
1623
1624# ----------------------------------------------------------------------
1625# CONFIGURATION OPTION: -plotforeground
1626# ----------------------------------------------------------------------
1627itcl::configbody Rappture::VtkImageViewer::plotforeground {
1628    if { [isconnected] } {
1629        set rgb [Color2RGB $itk_option(-plotforeground)]
1630        if { !$_reset } {
1631            SendCmd "outline color $rgb"
1632            SendCmd "axis color all $rgb"
1633        }
1634    }
1635}
1636
1637itcl::body Rappture::VtkImageViewer::limits3 { dataobj } {
1638    lappend limits x [$dataobj limits x]
1639    lappend limits y [$dataobj limits y]
1640    if { [catch { $dataobj limits $_curFldName } vlim] != 0 } {
1641        set vlim [$dataobj limits v]
1642    }
1643    lappend limits v $vlim
1644    return $limits
1645}
1646
1647itcl::body Rappture::VtkImageViewer::BuildImageTab {} {
1648
1649    set fg [option get $itk_component(hull) font Font]
1650    #set bfg [option get $itk_component(hull) boldFont Font]
1651
1652    set inner [$itk_component(main) insert end \
1653        -title "Image Settings" \
1654        -icon [Rappture::icon contour2]]
1655    $inner configure -borderwidth 4
1656
1657    checkbutton $inner.legend \
1658        -text "Legend" \
1659        -variable [itcl::scope _settings(legendVisible)] \
1660        -command [itcl::code $this AdjustSetting legendVisible] \
1661        -font "Arial 9"
1662
1663    checkbutton $inner.outline \
1664        -text "Outline" \
1665        -variable [itcl::scope _settings(outline)] \
1666        -command [itcl::code $this AdjustSetting outline] \
1667        -font "Arial 9"
1668
1669    checkbutton $inner.backing \
1670        -text "Backing" \
1671        -variable [itcl::scope _settings(backingVisible)] \
1672        -command [itcl::code $this AdjustSetting backingVisible] \
1673        -font "Arial 9"
1674
1675    checkbutton $inner.stretch \
1676        -text "Stretch to fit" \
1677        -variable [itcl::scope _settings(stretchToFit)] \
1678        -command [itcl::code $this AdjustSetting stretchToFit] \
1679        -font "Arial 9"
1680
1681    checkbutton $inner.colormapDiscrete \
1682        -text "Discrete Colormap" \
1683        -variable [itcl::scope _settings(colormapDiscrete)] \
1684        -command [itcl::code $this AdjustSetting colormapDiscrete] \
1685        -font "Arial 9"
1686
1687    itk_component add field_l {
1688        label $inner.field_l -text "Field" -font "Arial 9"
1689    } {
1690        ignore -font
1691    }
1692    itk_component add field {
1693        Rappture::Combobox $inner.field -width 10 -editable no
1694    }
1695    bind $inner.field <<Value>> \
1696        [itcl::code $this AdjustSetting field]
1697
1698    label $inner.colormap_l -text "Colormap" -font "Arial 9"
1699    itk_component add colormap {
1700        Rappture::Combobox $inner.colormap -width 10 -editable no
1701    }
1702    $inner.colormap choices insert end [GetColormapList -includeNone]
1703
1704    $itk_component(colormap) value "BCGYR"
1705    bind $inner.colormap <<Value>> \
1706        [itcl::code $this AdjustSetting colormap]
1707
1708    label $inner.backingcolor_l -text "Backing Color" -font "Arial 9"
1709    itk_component add backingcolor {
1710        Rappture::Combobox $inner.backingcolor -width 10 -editable no
1711    }
1712    $inner.backingcolor choices insert end \
1713        "black"              "black"            \
1714        "blue"               "blue"             \
1715        "cyan"               "cyan"             \
1716        "green"              "green"            \
1717        "grey"               "grey"             \
1718        "magenta"            "magenta"          \
1719        "orange"             "orange"           \
1720        "red"                "red"              \
1721        "white"              "white"            \
1722        "none"               "none"
1723
1724    $itk_component(backingcolor) value "white"
1725    bind $inner.backingcolor <<Value>> \
1726        [itcl::code $this AdjustSetting backingColor]
1727
1728    label $inner.background_l -text "Background Color" -font "Arial 9"
1729    itk_component add background {
1730        Rappture::Combobox $inner.background -width 10 -editable no
1731    }
1732    $inner.background choices insert end \
1733        "black"              "black"            \
1734        "white"              "white"            \
1735        "grey"               "grey"             
1736
1737    $itk_component(background) value "white"
1738    bind $inner.background <<Value>> [itcl::code $this AdjustSetting background]
1739
1740    itk_component add opacity_l {
1741        label $inner.opacity_l -text "Opacity" -font "Arial 9"
1742    } {
1743        ignore -font
1744    }
1745    itk_component add opacity {
1746        ::scale $inner.opacity -from 0 -to 100 -orient horizontal \
1747            -variable [itcl::scope _settings(opacity)] \
1748            -showvalue off \
1749            -command [itcl::code $this AdjustSetting opacity]
1750    }
1751
1752    itk_component add window_l {
1753        label $inner.window_l -text "Window" -font "Arial 9"
1754    } {
1755        ignore -font
1756    }
1757    itk_component add window {
1758        ::scale $inner.window -from 0 -to 255 -orient horizontal \
1759            -variable [itcl::scope _settings(window)] \
1760            -showvalue off \
1761            -command [itcl::code $this AdjustSetting window]
1762    }
1763    itk_component add level_l {
1764        label $inner.level_l -text "Level" -font "Arial 9"
1765    } {
1766        ignore -font
1767    }
1768    itk_component add level {
1769        ::scale $inner.level -from 0 -to 255 -orient horizontal \
1770            -variable [itcl::scope _settings(level)] \
1771            -showvalue off \
1772            -command [itcl::code $this AdjustSetting level]
1773    }
1774
1775    frame $inner.separator1 -height 2 -relief sunken -bd 1
1776    frame $inner.separator2 -height 2 -relief sunken -bd 1
1777
1778    blt::table $inner \
1779        0,0 $inner.field_l -anchor w -pady 2 \
1780        0,1 $inner.field -anchor w -pady 2 -fill x \
1781        1,0 $inner.colormap_l -anchor w -pady 2  \
1782        1,1 $inner.colormap   -anchor w -pady 2 -fill x  \
1783        2,0 $inner.backingcolor_l  -anchor w -pady 2  \
1784        2,1 $inner.backingcolor    -anchor w -pady 2 -fill x  \
1785        3,0 $inner.background_l -anchor w -pady 2 \
1786        3,1 $inner.background -anchor w -pady 2  -fill x \
1787        4,0 $inner.backing -anchor w -pady 2 -cspan 2 \
1788        5,0 $inner.stretch    -anchor w -pady 2 -cspan 2 \
1789        7,0 $inner.legend     -anchor w -pady 2 -cspan 2 \
1790        8,0 $inner.colormapDiscrete -anchor w -pady 2 -cspan 2 \
1791        11,0 $inner.separator1 -padx 2 -fill x -cspan 2 \
1792        12,0 $inner.outline    -anchor w -pady 2 -cspan 2 \
1793        13,0 $inner.separator2 -padx 2 -fill x -cspan 2 \
1794        15,0 $inner.opacity_l -anchor w -pady 2 \
1795        15,1 $inner.opacity   -fill x   -pady 2 \
1796        16,0 $inner.window_l -anchor w -pady 2 \
1797        16,1 $inner.window   -fill x   -pady 2 \
1798        17,0 $inner.level_l -anchor w -pady 2 \
1799        17,1 $inner.level   -fill x   -pady 2
1800
1801    blt::table configure $inner r* c* -resize none
1802    blt::table configure $inner r19 c1 -resize expand
1803}
1804
1805itcl::body Rappture::VtkImageViewer::BuildAxisTab {} {
1806
1807    set fg [option get $itk_component(hull) font Font]
1808    #set bfg [option get $itk_component(hull) boldFont Font]
1809
1810    set inner [$itk_component(main) insert end \
1811        -title "Axis Settings" \
1812        -icon [Rappture::icon axis2]]
1813    $inner configure -borderwidth 4
1814
1815    checkbutton $inner.visible \
1816        -text "Axes" \
1817        -variable [itcl::scope _settings(axisVisible)] \
1818        -command [itcl::code $this AdjustSetting axisVisible] \
1819        -font "Arial 9"
1820    checkbutton $inner.labels \
1821        -text "Axis Labels" \
1822        -variable [itcl::scope _settings(axisLabels)] \
1823        -command [itcl::code $this AdjustSetting axisLabels] \
1824        -font "Arial 9"
1825    label $inner.grid_l -text "Grid" -font "Arial 9"
1826    checkbutton $inner.xgrid \
1827        -text "X" \
1828        -variable [itcl::scope _settings(axisXGrid)] \
1829        -command [itcl::code $this AdjustSetting axisXGrid] \
1830        -font "Arial 9"
1831    checkbutton $inner.ygrid \
1832        -text "Y" \
1833        -variable [itcl::scope _settings(axisYGrid)] \
1834        -command [itcl::code $this AdjustSetting axisYGrid] \
1835        -font "Arial 9"
1836    checkbutton $inner.zgrid \
1837        -text "Z" \
1838        -variable [itcl::scope _settings(axisZGrid)] \
1839        -command [itcl::code $this AdjustSetting axisZGrid] \
1840        -font "Arial 9"
1841    checkbutton $inner.minorticks \
1842        -text "Minor Ticks" \
1843        -variable [itcl::scope _settings(axisMinorTicks)] \
1844        -command [itcl::code $this AdjustSetting axisMinorTicks] \
1845        -font "Arial 9"
1846
1847
1848    label $inner.mode_l -text "Mode" -font "Arial 9"
1849
1850    itk_component add axisflymode {
1851        Rappture::Combobox $inner.mode -width 10 -editable no
1852    }
1853    $inner.mode choices insert end \
1854        "static_triad"    "static" \
1855        "closest_triad"   "closest" \
1856        "furthest_triad"  "farthest" \
1857        "outer_edges"     "outer"         
1858    $itk_component(axisflymode) value "static"
1859    bind $inner.mode <<Value>> [itcl::code $this AdjustSetting axisFlymode]
1860
1861    blt::table $inner \
1862        0,0 $inner.visible -anchor w -cspan 4 \
1863        1,0 $inner.labels  -anchor w -cspan 4 \
1864        2,0 $inner.minorticks  -anchor w -cspan 4 \
1865        4,0 $inner.grid_l  -anchor w \
1866        4,1 $inner.xgrid   -anchor w \
1867        4,2 $inner.ygrid   -anchor w \
1868        4,3 $inner.zgrid   -anchor w \
1869        5,0 $inner.mode_l  -anchor w -padx { 2 0 } \
1870        5,1 $inner.mode    -fill x -cspan 3
1871
1872    blt::table configure $inner r* c* -resize none
1873    blt::table configure $inner r7 c6 -resize expand
1874    blt::table configure $inner r3 -height 0.125i
1875}
1876
1877
1878itcl::body Rappture::VtkImageViewer::BuildCameraTab {} {
1879    set inner [$itk_component(main) insert end \
1880        -title "Camera Settings" \
1881        -icon [Rappture::icon camera]]
1882    $inner configure -borderwidth 4
1883
1884    label $inner.view_l -text "view" -font "Arial 9"
1885    set f [frame $inner.view]
1886    foreach side { front back left right top bottom } {
1887        button $f.$side  -image [Rappture::icon view$side] \
1888            -command [itcl::code $this SetOrientation $side]
1889        Rappture::Tooltip::for $f.$side "Change the view to $side"
1890        pack $f.$side -side left
1891    }
1892
1893    blt::table $inner \
1894        0,0 $inner.view_l -anchor e -pady 2 \
1895        0,1 $inner.view -anchor w -pady 2
1896
1897    set labels { qx qy qz qw xpan ypan zoom }
1898    set row 1
1899    foreach tag $labels {
1900        label $inner.${tag}label -text $tag -font "Arial 9"
1901        entry $inner.${tag} -font "Arial 9"  -bg white \
1902            -textvariable [itcl::scope _view($tag)]
1903        bind $inner.${tag} <Return> \
1904            [itcl::code $this camera set ${tag}]
1905        bind $inner.${tag} <KP_Enter> \
1906            [itcl::code $this camera set ${tag}]
1907        blt::table $inner \
1908            $row,0 $inner.${tag}label -anchor e -pady 2 \
1909            $row,1 $inner.${tag} -anchor w -pady 2
1910        blt::table configure $inner r$row -resize none
1911        incr row
1912    }
1913    checkbutton $inner.ortho \
1914        -text "Orthographic Projection" \
1915        -variable [itcl::scope _view(ortho)] \
1916        -command [itcl::code $this camera set ortho] \
1917        -font "Arial 9"
1918    blt::table $inner \
1919            $row,0 $inner.ortho -cspan 2 -anchor w -pady 2
1920    blt::table configure $inner r$row -resize none
1921    incr row
1922
1923    blt::table configure $inner c* r* -resize none
1924    blt::table configure $inner c2 -resize expand
1925    blt::table configure $inner r$row -resize expand
1926}
1927
1928#
1929#  camera --
1930#
1931itcl::body Rappture::VtkImageViewer::camera {option args} {
1932    switch -- $option {
1933        "show" {
1934            puts [array get _view]
1935        }
1936        "set" {
1937            set who [lindex $args 0]
1938            set x $_view($who)
1939            set code [catch { string is double $x } result]
1940            if { $code != 0 || !$result } {
1941                return
1942            }
1943            switch -- $who {
1944                "ortho" {
1945                    if {$_view(ortho)} {
1946                        SendCmd "camera mode ortho"
1947                    } else {
1948                        SendCmd "camera mode persp"
1949                    }
1950                }
1951                "xpan" - "ypan" {
1952                    PanCamera
1953                }
1954                "qx" - "qy" - "qz" - "qw" {
1955                    set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
1956                    $_arcball quaternion $q
1957                    EventuallyRotate $q
1958                }
1959                "zoom" {
1960                    SendCmd "camera zoom $_view(zoom)"
1961                }
1962            }
1963        }
1964    }
1965}
1966
1967itcl::body Rappture::VtkImageViewer::GetVtkData { args } {
1968    set bytes ""
1969    foreach dataobj [get] {
1970        foreach comp [$dataobj components] {
1971            set tag $dataobj-$comp
1972            set contents [$dataobj vtkdata $comp]
1973            append bytes "$contents\n"
1974        }
1975    }
1976    return [list .vtk $bytes]
1977}
1978
1979itcl::body Rappture::VtkImageViewer::GetImage { args } {
1980    if { [image width $_image(download)] > 0 &&
1981         [image height $_image(download)] > 0 } {
1982        set bytes [$_image(download) data -format "jpeg -quality 100"]
1983        set bytes [Rappture::encoding::decode -as b64 $bytes]
1984        return [list .jpg $bytes]
1985    }
1986    return ""
1987}
1988
1989itcl::body Rappture::VtkImageViewer::BuildDownloadPopup { popup command } {
1990    Rappture::Balloon $popup \
1991        -title "[Rappture::filexfer::label downloadWord] as..."
1992    set inner [$popup component inner]
1993    label $inner.summary -text "" -anchor w
1994    radiobutton $inner.vtk_button -text "VTK data file" \
1995        -variable [itcl::scope _downloadPopup(format)] \
1996        -font "Arial 9 " \
1997        -value vtk 
1998    Rappture::Tooltip::for $inner.vtk_button "Save as VTK data file."
1999    radiobutton $inner.image_button -text "Image File" \
2000        -variable [itcl::scope _downloadPopup(format)] \
2001        -font "Arial 9 " \
2002        -value image
2003    Rappture::Tooltip::for $inner.image_button \
2004        "Save as digital image."
2005
2006    button $inner.ok -text "Save" \
2007        -highlightthickness 0 -pady 2 -padx 3 \
2008        -command $command \
2009        -compound left \
2010        -image [Rappture::icon download]
2011
2012    button $inner.cancel -text "Cancel" \
2013        -highlightthickness 0 -pady 2 -padx 3 \
2014        -command [list $popup deactivate] \
2015        -compound left \
2016        -image [Rappture::icon cancel]
2017
2018    blt::table $inner \
2019        0,0 $inner.summary -cspan 2  \
2020        1,0 $inner.vtk_button -anchor w -cspan 2 -padx { 4 0 } \
2021        2,0 $inner.image_button -anchor w -cspan 2 -padx { 4 0 } \
2022        4,1 $inner.cancel -width .9i -fill y \
2023        4,0 $inner.ok -padx 2 -width .9i -fill y
2024    blt::table configure $inner r3 -height 4
2025    blt::table configure $inner r4 -pady 4
2026    raise $inner.image_button
2027    $inner.vtk_button invoke
2028    return $inner
2029}
2030
2031#
2032# SetObjectStyle --
2033#
2034#       Set the style of the image/contour object.  This gets calls
2035#       for each dataset once as it is loaded.  It can overridden by
2036#       the user controls.
2037#
2038#
2039itcl::body Rappture::VtkImageViewer::SetObjectStyle { dataobj comp } {
2040    # Parse style string.
2041    set tag $dataobj-$comp
2042    array set style {
2043        -color none
2044        -opacity 1.0
2045    }
2046    set stylelist [$dataobj style $comp]
2047    if { $stylelist != "" } {
2048        array set style $stylelist
2049    }
2050    # This is too complicated.  We want to set the colormap, number of
2051    # isolines and opacity for the dataset.  They can be the default values,
2052    # the style hints loaded with the dataset, or set by user controls.  As
2053    # datasets get loaded, they first use the defaults that are overidden
2054    # by the style hints.  If the user changes the global controls, then that
2055    # overrides everything else.  I don't know what it means when global
2056    # controls are specified as style hints by each dataset.  It complicates
2057    # the code to handle aberrant cases.
2058
2059    if { $_changed(opacity) } {
2060        set style(-opacity) [expr $_settings(opacity) * 0.01]
2061    }
2062    if { $_changed(colormap) } {
2063        set style(-color) $_settings(colormap)
2064    }
2065    if { $_currentColormap == "" } {
2066        $itk_component(colormap) value $style(-color)
2067    }
2068    if { [info exists style(-stretchtofit)] } {
2069        set _settings(stretchToFit) $style(-stretchtofit)
2070        AdjustSetting stretchToFit
2071    }
2072    SendCmd "outline add $tag"
2073    SendCmd "outline color [Color2RGB $itk_option(-plotforeground)] $tag"
2074    SendCmd "outline visible $_settings(outline) $tag"
2075    SendCmd "image add $tag"
2076    SetCurrentColormap $style(-color)
2077    set color [$itk_component(backingcolor) value]
2078    SendCmd "image color [Color2RGB $color] $tag"
2079    SendCmd "image opacity $style(-opacity) $tag"
2080    set _settings(opacity) [expr $style(-opacity) * 100.0]
2081}
2082
2083itcl::body Rappture::VtkImageViewer::IsValidObject { dataobj } {
2084    if {[catch {$dataobj isa Rappture::Field} valid] != 0 || !$valid} {
2085        return 0
2086    }
2087    return 1
2088}
2089
2090# ----------------------------------------------------------------------
2091# USAGE: ReceiveLegend <colormap> <title> <min> <max> <size>
2092#
2093# Invoked automatically whenever the "legend" command comes in from
2094# the rendering server.  Indicates that binary image data with the
2095# specified <size> will follow.
2096# ----------------------------------------------------------------------
2097itcl::body Rappture::VtkImageViewer::ReceiveLegend { colormap title min max size } {
2098    #puts stderr "ReceiveLegend colormap=$colormap title=$title range=$min,$max size=$size"
2099    if { [isconnected] } {
2100        set bytes [ReceiveBytes $size]
2101        if { ![info exists _image(legend)] } {
2102            set _image(legend) [image create photo]
2103        }
2104        $_image(legend) configure -data $bytes
2105        #puts stderr "read $size bytes for [image width $_image(legend)]x[image height $_image(legend)] legend>"
2106        if { [catch {DrawLegend} errs] != 0 } {
2107            global errorInfo
2108            puts stderr "errs=$errs errorInfo=$errorInfo"
2109        }
2110    }
2111}
2112
2113#
2114# DrawLegend --
2115#
2116#       Draws the legend in the own canvas on the right side of the plot area.
2117#
2118itcl::body Rappture::VtkImageViewer::DrawLegend {} {
2119    set fname $_curFldName
2120    set c $itk_component(view)
2121    set w [winfo width $c]
2122    set h [winfo height $c]
2123    set font "Arial 8"
2124    set lineht [font metrics $font -linespace]
2125   
2126    if { [string match "component*" $fname] } {
2127        set title ""
2128    } else {
2129        if { [info exists _fields($fname)] } {
2130            foreach { title units } $_fields($fname) break
2131            if { $units != "" } {
2132                set title [format "%s (%s)" $title $units]
2133            }
2134        } else {
2135            set title $fname
2136        }
2137    }
2138    set x [expr $w - 2]
2139    if { !$_settings(legendVisible) } {
2140        $c delete legend
2141        return
2142    }
2143    if { [$c find withtag "legend"] == "" } {
2144        set y 2
2145        # If there's a legend title, create a text item for the title.
2146        $c create text $x $y \
2147            -anchor ne \
2148            -fill $itk_option(-plotforeground) -tags "title legend" \
2149            -font $font
2150        if { $title != "" } {
2151            incr y $lineht
2152        }
2153        $c create text $x $y \
2154            -anchor ne \
2155            -fill $itk_option(-plotforeground) -tags "vmax legend" \
2156            -font $font
2157        incr y $lineht
2158        $c create image $x $y \
2159            -anchor ne \
2160            -image $_image(legend) -tags "colormap legend"
2161        $c create rectangle $x $y 1 1 \
2162            -fill "" -outline "" -tags "sensor legend"
2163        $c create text $x [expr {$h-2}] \
2164            -anchor se \
2165            -fill $itk_option(-plotforeground) -tags "vmin legend" \
2166            -font $font
2167        $c bind sensor <Enter> [itcl::code $this EnterLegend %x %y]
2168        $c bind sensor <Leave> [itcl::code $this LeaveLegend]
2169        $c bind sensor <Motion> [itcl::code $this MotionLegend %x %y]
2170    }
2171
2172    set x2 $x
2173    set iw [image width $_image(legend)]
2174    set ih [image height $_image(legend)]
2175    set x1 [expr $x2 - ($iw*12)/10]
2176
2177    $c bind title <ButtonPress> [itcl::code $this Combo post]
2178    $c bind title <Enter> [itcl::code $this Combo activate]
2179    $c bind title <Leave> [itcl::code $this Combo deactivate]
2180    # Reset the item coordinates according the current size of the plot.
2181    if { [info exists _limits($_curFldName)] } {
2182        foreach { vmin vmax } $_limits($_curFldName) break
2183        $c itemconfigure vmin -text [format %g $vmin]
2184        $c itemconfigure vmax -text [format %g $vmax]
2185    }
2186    set y 2
2187    # If there's a legend title, move the title to the correct position
2188    if { $title != "" } {
2189        $c itemconfigure title -text $title
2190        $c coords title $x $y
2191        incr y $lineht
2192    }
2193    $c coords vmax $x $y
2194    incr y $lineht
2195    $c coords colormap $x $y
2196    $c coords sensor [expr $x - $iw] $y $x [expr $y + $ih]
2197    $c raise sensor
2198    $c coords vmin $x [expr {$h - 2}]
2199}
2200
2201#
2202# EnterLegend --
2203#
2204itcl::body Rappture::VtkImageViewer::EnterLegend { x y } {
2205    SetLegendTip $x $y
2206}
2207
2208#
2209# MotionLegend --
2210#
2211itcl::body Rappture::VtkImageViewer::MotionLegend { x y } {
2212    Rappture::Tooltip::tooltip cancel
2213    set c $itk_component(view)
2214    set cw [winfo width $c]
2215    set ch [winfo height $c]
2216    if { $x >= 0 && $x < $cw && $y >= 0 && $y < $ch } {
2217        SetLegendTip $x $y
2218    }
2219}
2220
2221#
2222# LeaveLegend --
2223#
2224itcl::body Rappture::VtkImageViewer::LeaveLegend { } {
2225    Rappture::Tooltip::tooltip cancel
2226    .rappturetooltip configure -icon ""
2227}
2228
2229#
2230# SetLegendTip --
2231#
2232itcl::body Rappture::VtkImageViewer::SetLegendTip { x y } {
2233    set fname $_curFldName
2234    set c $itk_component(view)
2235    set w [winfo width $c]
2236    set h [winfo height $c]
2237    set font "Arial 8"
2238    set lineht [font metrics $font -linespace]
2239   
2240    set ih [image height $_image(legend)]
2241    # Subtract off the offset of the color ramp from the top of the canvas
2242    set iy [expr $y - ($lineht + 2)]
2243
2244    if { [string match "component*" $fname] } {
2245        set title ""
2246    } else {
2247        if { [info exists _fields($fname)] } {
2248            foreach { title units } $_fields($fname) break
2249            if { $units != "" } {
2250                set title [format "%s (%s)" $title $units]
2251            }
2252        } else {
2253            set title $fname
2254        }
2255    }
2256    # If there's a legend title, increase the offset by the line height.
2257    if { $title != "" } {
2258        incr iy -$lineht
2259    }
2260
2261    # Make a swatch of the selected color
2262    if { [catch { $_image(legend) get 10 $iy } pixel] != 0 } {
2263        return
2264    }
2265
2266    if { ![info exists _image(swatch)] } {
2267        set _image(swatch) [image create photo -width 24 -height 24]
2268    }
2269    set color [eval format "\#%02x%02x%02x" $pixel]
2270    $_image(swatch) put black  -to 0 0 23 23
2271    $_image(swatch) put $color -to 1 1 22 22
2272
2273    # Compute the value of the point
2274    if { [info exists _limits($fname)] } {
2275        foreach { vmin vmax } $_limits($fname) break
2276        set t [expr 1.0 - (double($iy) / double($ih-1))]
2277        set value [expr $t * ($vmax - $vmin) + $vmin]
2278    } else {
2279        set value 0.0
2280    }
2281    set tipx [expr $x + 15]
2282    set tipy [expr $y - 5]
2283    .rappturetooltip configure -icon $_image(swatch)
2284    if { [info exists _isolines($y)] } {
2285        Rappture::Tooltip::text $c [format "$title %g (isoline)" $_isolines($y)]
2286    } else {
2287        Rappture::Tooltip::text $c [format "$title %g" $value]
2288    }
2289    Rappture::Tooltip::tooltip show $c +$tipx,+$tipy   
2290}
2291
2292# ----------------------------------------------------------------------
2293# USAGE: _dropdown post
2294# USAGE: _dropdown unpost
2295# USAGE: _dropdown select
2296#
2297# Used internally to handle the dropdown list for this combobox.  The
2298# post/unpost options are invoked when the list is posted or unposted
2299# to manage the relief of the controlling button.  The select option
2300# is invoked whenever there is a selection from the list, to assign
2301# the value back to the gauge.
2302# ----------------------------------------------------------------------
2303itcl::body Rappture::VtkImageViewer::Combo {option} {
2304    set c $itk_component(view)
2305    switch -- $option {
2306        post {
2307            foreach { x1 y1 x2 y2 } [$c bbox title] break
2308            set x1 [expr [winfo width $itk_component(view)] - [winfo reqwidth $itk_component(fieldmenu)]]
2309            set x [expr $x1 + [winfo rootx $itk_component(view)]]
2310            set y [expr $y2 + [winfo rooty $itk_component(view)]]
2311            tk_popup $itk_component(fieldmenu) $x $y
2312        }
2313        activate {
2314            $c itemconfigure title -fill red
2315        }
2316        deactivate {
2317            $c itemconfigure title -fill $itk_option(-plotforeground)
2318        }
2319        invoke {
2320            $itk_component(field) value $_curFldLabel
2321            AdjustSetting field
2322        }
2323        default {
2324            error "bad option \"$option\": should be post, unpost, select"
2325        }
2326    }
2327}
2328
2329itcl::body Rappture::VtkImageViewer::SetOrientation { side } {
2330    array set positions {
2331        front  "0.707107 0.707107 0 0"
2332        back   "0 0 0.707107 0.707107"
2333        left   "0.5 0.5 -0.5 -0.5"
2334        right  "0.5 0.5 0.5 0.5"
2335        top    "1 0 0 0"
2336        bottom "0 1 0 0"
2337    }
2338    foreach name { qw qx qy qz } value $positions($side) {
2339        set _view($name) $value
2340    }
2341    set q [list $_view(qw) $_view(qx) $_view(qy) $_view(qz)]
2342    $_arcball quaternion $q
2343    SendCmd "camera orient $q"
2344    SendCmd "camera reset"
2345    set _view(xpan) 0
2346    set _view(ypan) 0
2347    set _view(zoom) 1.0
2348}
Note: See TracBrowser for help on using the repository browser.